Wolfram 语言与系统参考资料中心

BatesDistribution

表示 n 个从 0 到 1 均匀分布的随机变量的均值的分布.

BatesDistribution[n,{min,max}]

表示 n 个从 min 到 max 均匀分布的随机变量的均值的分布.

背景

BatesDistribution[n,{min,max}] 表示定义在从 min 到 max 的区间上的，参数为正整数 n 的一种统计分布，称为贝茨分布. 贝茨分布的概率密度函数（PDF）的整个形状随着 n 的不同差异巨大，在、和时分别是均匀的，三角形的和钟形的. 单变量形式的 BatesDistribution[n] 等价于 BatesDistribution[n,{0,1}]，有时又被称为标准贝茨分布.
从数学上讲，贝茨分布 BatesDistribution[n] 被定义为 n 个统计上独立的均匀分布随机变量的均值，即 XBatesDistribution[n] 等价于，其中对所有的有 X_iUniformDistribution[]. 双变量形式的 BatesDistribution[n,{min,max}] 与单变量形式的意义基本相同除了 UniformDistribution[{min,max}]. 贝茨分布的一个重要应用是在计算领域，的标准贝茨分布历史上曾被用于生成标准正态变量.
RandomVariate 可被用于给出贝茨分布的一个或多个机器精度或任意精度（后者可用 WorkingPrecision 选项指定）的伪随机变量. Distributed[x,BatesDistribution[n,{min,max}]]，更简洁的写法是 xBatesDistribution[n,{min,max}]，可被用于声明随机变量 x 是贝茨分布的. 这样一个声明之后可用在如 Probability、NProbability、Expectation 以及 NExpectation 这样的函数中.
概率密度函数和累积分布函数可用 PDF[BatesDistribution[n,{min,max}],x] 和 CDF[BatesDistribution[n,{min,max}],x] 求得. 平均数、中位数、方差、原点矩及中心矩可分别用 Mean、Median、Variance、Moment 和 CentralMoment 计算.
DistributionFitTest 可被用于测试给定的数据集是否与贝茨分布一致，EstimatedDistribution 可被用于根据给定数据估算贝茨参数化分布， FindDistributionParameters 可拟合数据和贝茨分布. ProbabilityPlot 可被用于生成给定数据的 CDF 相对于符号贝茨分布的 CDF 的图线，而 QuantilePlot 可被用于生成给定数据的分位数相对于符号贝茨分布的分位数的图线.
TransformedDistribution 可被用于表示转换的贝茨分布，CensoredDistribution 可被用于表示删截后位于上限值和下限值之间的值分布，而 TruncatedDistribution 可被用于表示截断后位于上限值和下限值之间的值分布. CopulaDistribution 可被用于建立包含了贝茨分布的高维分布，而 ProductDistribution 可被用于计算包括贝茨分布在内的，若干个独立分量的联合分布.
BatesDistribution 与许多其它分布密切相关. 例如，贝茨分布的 PDF 分别与和时的 UniformDistribution 及 TriangularDistribution 精确相等，而当值很大时其外形和 NormalDistribution 的 PDF 相似. BatesDistribution 也和 UniformSumDistribution 密切相关，后者表示统计独立的，均匀分布的随机变量之和（而不是它们的均值）.

范例

打开所有单元关闭所有单元

基本范例 (4)

概率密度函数：

Wolfram Language code: Plot[Table[PDF[BatesDistribution[n], x], {n, {1, 2, 5}}]//Evaluate, {x, 0, 1}, Filling -> Axis, Exclusions -> None]

累积分布函数：

Wolfram Language code: Plot[Table[CDF[BatesDistribution[n], x], {n, {1, 2, 5}}]//Evaluate, {x, 0, 1}, Filling -> Axis, Exclusions -> None]

均值：

Wolfram Language code: Mean[BatesDistribution[n]]

Wolfram Language code: Mean[BatesDistribution[n, {min, max}]]

方差：

Wolfram Language code: Variance[BatesDistribution[n]]

Wolfram Language code: Variance[BatesDistribution[n, {min, max}]]

范围 (8)

生成一组 Bates 分布的伪随机数样本：

Wolfram Language code: data = RandomVariate[BatesDistribution[4], 10 ^ 4];

比较采样数据直方图与概率密度函数：

Wolfram Language code: Show[Histogram[data, 15, "PDF"], Plot[PDF[BatesDistribution[4], x], {x, 0, 1}, PlotStyle -> Thick]]

分布参数估计：

Wolfram Language code: sample = RandomVariate[BatesDistribution[3], 10 ^ 3];

根据样本数据估计分布参数：

Wolfram Language code: edist = EstimatedDistribution[sample, BatesDistribution[n]]

比较数据直方图与所估计分布的概率密度函数：

Wolfram Language code: Show[Histogram[sample, 20, "PDF"], Plot[PDF[edist, x], {x, 0, 1}, PlotStyle -> Thick]]

偏度：

Wolfram Language code: Skewness[BatesDistribution[n]]

Wolfram Language code: Skewness[BatesDistribution[n, {min, max}]]

峰度与定义域无关：

Wolfram Language code: DiscretePlot[Kurtosis[BatesDistribution[n, {min, max}]], {n, 1, 10}]

Wolfram Language code: Kurtosis[BatesDistribution[n]]//Simplify

Wolfram Language code: Kurtosis[BatesDistribution[n, {min, max}]]//Simplify

峰度的极值与 NormalDistribution 的峰度相同：

Wolfram Language code: Limit[Kurtosis[BatesDistribution[n]], n -> ∞]

以参数的函数形式表示不同矩量的解析式：

Wolfram Language code: FormulaGrid[list_, type_] := Grid[...]

Moment:

Wolfram Language code: FormulaGrid[Table[Moment[BatesDistribution[n], r]//Factor, {r, 5}], M]

具有符号式阶数的解析式：：

Wolfram Language code: Moment[BatesDistribution[n], r]

CentralMoment:

Wolfram Language code: FormulaGrid[Table[CentralMoment[BatesDistribution[n], r], {r, 5}], CM]

具有符号式阶数的解析式：

Wolfram Language code: CentralMoment[BatesDistribution[n], r]

FactorialMoment:

Wolfram Language code: FormulaGrid[Table[FactorialMoment[BatesDistribution[n], r]//Factor, {r, 5}], FM]

Cumulant:

Wolfram Language code: FormulaGrid[Table[Cumulant[BatesDistribution[n], r], {r, 5}], C]

具有符号式阶数的解析式：

Wolfram Language code: Cumulant[BatesDistribution[n], r]

风险函数：

Wolfram Language code:

Plot[Table[HazardFunction[BatesDistribution[n], x], {n, {2, 3, 4}}]//Evaluate, {x, 0, 0.99}, Filling -> Axis, Exclusions -> None]

分位数函数：

Wolfram Language code: Plot[Table[Quantile[BatesDistribution[n], q], {n, {2, 4, 8}}]//Evaluate, {q, 0, 1}, Filling -> Axis, Exclusions -> None]

Quantity 在参数中的一致性使用生成 QuantityDistribution：

Wolfram Language code: pressure𝒟 = BatesDistribution[3, {Quantity[100, "Newtons"/"Meters"^2], Quantity[120, "Newtons"/"Meters"^2]}]

计算平均压强：

Wolfram Language code: Mean[pressure𝒟]

Wolfram Language code: UnitSimplify[%]

应用 (2)

均匀分布的均值服从 Bates 分布：

Wolfram Language code: pdf2 = PDF[TransformedDistribution[(u + v) / 2, {u, v}ProductDistribution[{UniformDistribution[], 2}]], x];

Wolfram Language code: pdf3 = PDF[TransformedDistribution[(u + v + w) / 3, {u, v, w}ProductDistribution[{UniformDistribution[], 3}]], x];

Wolfram Language code:

pdf4 = PDF[TransformedDistribution[(u + v + w + z) / 4, {u, v, w, z}ProductDistribution[{UniformDistribution[], 4}]], x];

Wolfram Language code: Batespdf[n_] := PDF[BatesDistribution[n], x]

Wolfram Language code:

{Plot[{pdf2, pdf3, pdf4}, {x, 0, 1}, Exclusions -> None], Plot[{Batespdf[2], Batespdf[3], Batespdf[4]}, {x, 0, 1}, Exclusions -> None]}

某种设备具有3个寿命阶段：A、B 和 C. 在每个阶段所用的小时数服从上的均匀分布，阶段 C 后，出现故障. 求在同一阶段平均所用时间的分布：

Wolfram Language code: 𝒟 = BatesDistribution[3, {Quantity[0, "Hours"], Quantity[10, "Hours"]}];

Wolfram Language code: Plot[PDF[𝒟, Quantity[x, "Hours"]], {x, 0, 10}, Filling -> Axis, Exclusions -> None, AxesLabel -> {"h"}]

求在同一阶段所用时间的平均值：

Wolfram Language code: Mean[𝒟]

求该设备平均将在同一阶段保持 4 小时以上的概率：

Wolfram Language code: Probability[x > Quantity[4, "Hours"], x𝒟]

Wolfram Language code: N[%]

模拟 30 个这种设备在同一阶段所用的平均时间：

Wolfram Language code:

ListPlot[{RandomVariate[𝒟, 30], {{0, Mean[𝒟]}, {30, Mean[𝒟]}}}, Filling -> Axis, Joined -> {False, True}, AxesLabel -> Automatic]

属性和关系 (5)

当按一定比例进行缩放和平移时，新生成的分布仍然是 Bates 分布：

Wolfram Language code: TransformedDistribution[a * u + b, uBatesDistribution[n, {min, max}], Assumptions -> a > 0]

当使用一个负因子为比例进行缩放时：

Wolfram Language code: TransformedDistribution[a * u + b, uBatesDistribution[n, {min, max}], Assumptions -> a < 0]

默认域是区间：

Wolfram Language code: CharacteristicFunction[BatesDistribution[n, {0, 1}], t]

Wolfram Language code: CharacteristicFunction[BatesDistribution[n], t]

Wolfram Language code: % - %%

与其它分布的关系：

n 个均匀分布的变量的平均值分布服从 Bates 分布：

Wolfram Language code: (CharacteristicFunction[UniformDistribution[{min, max}], t / n]) ^ n

Wolfram Language code: CharacteristicFunction[BatesDistribution[n, {min, max}], t]

Wolfram Language code: Simplify[% - %%]

三角分布是 Bates 分布的一种特殊情形：

Wolfram Language code: CharacteristicFunction[TriangularDistribution[{0, 1}], t]

Wolfram Language code: CharacteristicFunction[BatesDistribution[2], t]

Wolfram Language code: % - %%//FullSimplify

巧妙范例 (1)

取不同 n 值时的概率密度函数与累积分布函数等高图：

Wolfram Language code:

dist = BatesDistribution[Floor[n]];cdf = Function[{x, n}, Evaluate[CDF[dist, x]]];
ql = {0.025, 0.10, 0.25, 0.5, 0.75, 0.90, 0.975};
cl = Table[ColorData["Rainbow"][q], {q, Join[{0.0}, ql]}];

Wolfram Language code:

Legended[Plot3D[PDF[dist, x], {x, 0, 1}, {n, 1, 20}, PlotTheme -> "Marketing", MeshFunctions -> {cdf}, Mesh -> {ql}, MeshStyle -> GrayLevel[0.8], PlotRange -> All, Exclusions -> Sin[Pi n] == 0, MeshShading -> cl, AxesLabel -> Automatic, PlotPoints -> 40, BaseStyle -> Opacity[0.9], ImageSize -> 400], BarLegend["Rainbow", ql, LegendLabel -> "prob"]]

Top

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

BatesDistribution

更多信息

背景

范例

基本范例 (4)

范围 (8)

应用 (2)

属性和关系 (5)

巧妙范例 (1)

文本

CMS

APA

BibTeX

BibLaTeX

BatesDistribution

更多信息

背景

范例

基本范例 (4)

范围 (8)

应用 (2)

属性和关系 (5)

巧妙范例 (1)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX