WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BenktanderGibratDistribution[a,b]

母数が a と b のタイプIのベンクタンダー(Benktander)分布を表す．

詳細
Details and Options Details and Options
予備知識
例題  
例  
スコープ  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

BenktanderGibratDistribution

BenktanderGibratDistribution[a,b]

母数が a と b のタイプIのベンクタンダー(Benktander)分布を表す．

詳細

予備知識

  • BenktanderGibratDistribution[a,b]は，区間上で定義され，を満足し，確率密度関数(PDF)の全体的な動作を決定する2つの正の値 a および b でパラメータ化された，連続統計分布を表す．a および b の値によって，ベンクタンダー・ジブラ分布のPDFは，単調減少か，あるいは領域の最左境界に近付く特異値がある可能性がある単峰になる．BenktanderGibratDistributionのPDFの裾部は，（大きい の値について，PDFが指数的よりも遅く減少するという意味で）「重い」．しかし，この分布は「裾部が重い」というよりも「準指数的」であるとみなされている．（この動作は，分布のSurvivalFunctionを解析することによって，数量的に正確にできる．）
  • ベンクタンダー・ジブラ分布は，経験的平均超過関数がパレート分布と指数分布の「中間的」分布の必要性を示唆していることに気付いた，スウェーデンの保険数理士であるGunnar Benktanderによって考案された．ベンクタンダー・ジブラ分布は，保険数理のアプリケーションにおける資産の損失のモデル化に最もよく使われている．さらに，ベンクタンダー・ジブラ分布のような半指数分布は，ランダムウォークの特性を研究する上でも有益である．ベンクタンダー・ジブラ分布は，タイプIのベンクタンダー分布と呼ばれることがある．タイプIIはベンクタンダー・ワイブル分布として知られ，Wolfram言語ではBenktanderWeibullDistributionとして実装されている．どちらの分布も，両分布のPDFが定性的に似ている点で対数正規分布に「近い」とみなされている．
  • RandomVariateを使ってベンクタンダー・ジブラ分布から，1つあるいは複数の機械精度あるいは任意精度（後者はWorkingPrecisionオプションを介す）の擬似乱数変量を得ることができる．Distributed[x,BenktanderWeibullDistribution[a,b]]（より簡略すると xBenktanderWeibullDistribution[a,b]）を使って，確率変数 x がベンクタンダー・ジブラ分布に従って分布していると宣言することができる．このような宣言は，Probability，NProbability，Expectation，NExpectation等の関数で使うことができる．
  • 確率密度関数および累積分布関数は，PDF[BenktanderGibratDistribution[a,b],x]およびCDF[BenktanderGibratDistribution[a,b],x]を使って得られることがある．平均，中央値，分散，原点の周りのモーメント，中心モーメントは，それぞれMean，Median，Variance，Moment，CentralMomentを使って計算することができる．
  • DistributionFitTestを使って，与えられたデータ集合がベンクタンダー・ジブラ分布と一致するかどうかを検定することが，EstimatedDistributionを使って与えられたデータからベンクタンダー・ジブラパラメトリック分布を推定することが，FindDistributionParametersを使ってデータをベンクタンダー・ジブラ分布にフィットすることができる．ProbabilityPlotを使って記号ベンクタンダー・ジブラ分布のCDFに対する与えられたデータのCDFのプロットを生成することが，QuantilePlotを使って記号ベンクタンダー・ジブラ分布の変位値に対する与えられたデータの変位値のプロットを生成することができる．
  • TransformedDistributionを使って変換されたベンクタンダー・ジブラ分布を表すことが，CensoredDistributionを使って上限値と下限値の間で切り取られた値の分布を表すことが，TruncatedDistributionを使って上限値と下限値の間で切断された値の分布を表すことができる．CopulaDistributionを使ってベンクタンダー・ジブラ分布を含む高次元分布を構築することが，ProductDistributionを使ってベンクタンダー・ジブラ分布を含む独立成分分布の結合分布を計算することができる．
  • BenktanderGibratDistributionは，数多くの他の統計分布と関連している．例えば，先に記したように，BenktanderGibratDistributionとBenktanderWeibullDistributionは，ParetoDistributionとExponentialDistributionの中間分布であるとみなされる同じ分布「族」に属する．定性的には，BenktanderGibratDistributionのPDFはLogNormalDistributionのそれに類似しており，これによってBenktanderGibratDistributionとNormalDistributionおよびJohnsonDistributionとの（定性的）関係が導かれる．ParetoDistributionは，b が0に近付くにつれてBenktanderGibratDistribution[a,b]のPDFがParetoDistribution[1,a+1]のそれに近付くという意味で，BenktanderGibratDistributionの極限のケースであるとみなされる．この事実は，b が0に近付くにつれてBenktanderGibratDistribution[a,b]とBenktanderWeibullDistribution[a,b]の両方のPDFが同じ極限関数に近付くことを暗に示している．さらに，ベンクタンダー・ジブラ分布に関連する定常再生分布はBeniniDistribution[a,b,1]のPDFとその領域上で全く同じ式を持つ．

例題

すべて開く すべて閉じる

例  (4)

確率密度関数：

Wolfram Language code: Plot[Table[PDF[BenktanderGibratDistribution[a, 3], x], {a, {3, 4, 5}}]//Evaluate, {x, 1, 1.8}, Filling -> Axis]
Wolfram Language code: Plot[Table[PDF[BenktanderGibratDistribution[2, b], x], {b, {.5, 1, 2}}]//Evaluate, {x, 1, 2.2}, Filling -> Axis]
Wolfram Language code: PDF[BenktanderGibratDistribution[a, b], x]

累積分布関数：

Wolfram Language code: Plot[Table[CDF[BenktanderGibratDistribution[a, 3], x], {a, {3, 4, 5}}]//Evaluate, {x, 1, 1.8}, Filling -> Axis]
Wolfram Language code: Plot[Table[CDF[BenktanderGibratDistribution[2, b], x], {b, {.5, 1, 2}}]//Evaluate, {x, 1, 2.}, Filling -> Axis]
Wolfram Language code: CDF[BenktanderGibratDistribution[a, b], x]

平均と分散：

Wolfram Language code: Mean[BenktanderGibratDistribution[a, b]]
Wolfram Language code: Variance[BenktanderGibratDistribution[a, b]]//Together

中央値は数値的に求めることができる：

Wolfram Language code: Median[BenktanderGibratDistribution[2, 3]]//N

スコープ  (8)

ベンクタンダー・ジブラ分布から擬似乱数のサンプルを生成する：

Wolfram Language code: data = RandomVariate[BenktanderGibratDistribution[3, 3], 10 ^ 4];

そのヒストグラムを確率密度関数と比較する：

Wolfram Language code: Show[Histogram[data, {1, 2.5, .1}, "PDF"], Plot[PDF[BenktanderGibratDistribution[3, 3], x], {x, 1, 2.5}, PlotStyle -> Thick]]

分布母数推定：

Wolfram Language code: sample = RandomVariate[BenktanderGibratDistribution[3.5, 4], 10 ^ 3];

サンプルデータから分布母数を推定する：

Wolfram Language code: edist = EstimatedDistribution[sample, BenktanderGibratDistribution[a, b]]

サンプルの密度ヒストグラムを推定分布の確率密度関数と比較する：

Wolfram Language code: Show[Histogram[sample, {1, 2.5, 0.1}, "PDF"], Plot[PDF[edist, x], {x, 1, 2.5}, PlotStyle -> Thick]]

歪度：

Wolfram Language code: Plot3D[Skewness[BenktanderGibratDistribution[a, b]], {a, 3, 10}, {b, 1, 3}, MeshFunctions -> {#3&}, MeshShading -> ColorData[35, "ColorList"], AxesLabel -> Automatic]
Wolfram Language code: Skewness[BenktanderGibratDistribution[a, b]]

尖度：

Wolfram Language code: Plot3D[Kurtosis[BenktanderGibratDistribution[a, b]], {a, 3, 10}, {b, 1, 3}, MeshFunctions -> {#3&}, MeshShading -> ColorData[35, "ColorList"], AxesLabel -> Automatic]
Wolfram Language code: Kurtosis[BenktanderGibratDistribution[a, b]]

母数の関数としての閉じた形の種々のモーメント：

Wolfram Language code: FormulaGrid[list_, type_] := Grid[...]

Moment：

Wolfram Language code: FormulaGrid[Table[Moment[BenktanderGibratDistribution[a, b], r]//Together, {r, 3}], M]

記号次数の閉じた形：

Wolfram Language code: Moment[BenktanderGibratDistribution[a, b], r]

CentralMoment：

Wolfram Language code: FormulaGrid[Table[CentralMoment[BenktanderGibratDistribution[a, b], r]//FullSimplify, {r, 3}], CM]

FactorialMoment：

Wolfram Language code: FormulaGrid[Table[FactorialMoment[BenktanderGibratDistribution[a, b], r]//Together, {r, 3}], FM]

Cumulant：

Wolfram Language code: FormulaGrid[Table[Cumulant[BenktanderGibratDistribution[a, b], r]//FullSimplify, {r, 3}], C]

ハザード関数：

Wolfram Language code: Plot[Table[HazardFunction[BenktanderGibratDistribution[2, b], x], {b, {0.5, 1, 2}}]//Evaluate, {x, 1, 6}, Filling -> Axis, AxesOrigin -> {1, 0}]
Wolfram Language code: Plot[Table[HazardFunction[BenktanderGibratDistribution[a, 0.3], x], {a, {0.5, 1, 2}}]//Evaluate, {x, 1, 6}, Filling -> Axis, AxesOrigin -> {1, 0}]
Wolfram Language code: HazardFunction[BenktanderGibratDistribution[a, b], x]

分位関数：

Wolfram Language code: Plot[Table[Quantile[BenktanderGibratDistribution[3, b], q], {b, {0.01, 1, 4}}]//Evaluate, {q, 0, 0.99}, Filling -> Axis]
Wolfram Language code: Plot[Table[Quantile[BenktanderGibratDistribution[a, 0.3], q], {a, {0.5, 1, 2}}]//Evaluate, {q, 0, 0.98}, Filling -> Axis]

無次元のQuantityを使ってBenktanderGibratDistributionを定義する：

Wolfram Language code: 𝒟 = BenktanderGibratDistribution[Quantity[2*1, "Dozens"], 2.5]

アプリケーション  (3)

ある保険会社が保険免責金額を単位にした保険請求の大きさが母数がタイプIのベンクタンダー分布（母数は と ）に従うことを発見した．請求の大きさが2を超える確率を求める：

Wolfram Language code: Probability[s > 2, sBenktanderGibratDistribution[1, 0.5]]

タイプIのベンクタンダー分布の平均超過関数を計算する：

Wolfram Language code: Subscript[e, BI] = Expectation[x - sx > s, xBenktanderGibratDistribution[a, b], Assumptions -> s > 1]

大きい の値に対してはジブラ分布としても知られる対数正規分布に近付く：

Wolfram Language code: Assuming[s > 0, Expectation[x - sx > s, xLogNormalDistribution[μ, σ]] == -s + (E^μ + (σ^2/2) Erfc[(Log[s] - μ - σ^2/Sqrt[2] σ)]/Erfc[(Log[s] - μ/Sqrt[2] σ)])//FullSimplify]

今度は，相補誤差関数を大きい引数でのその漸近解析で置換する：

Wolfram Language code: -s + (E^μ + (σ^2/2) Erfc[(Log[s] - μ - σ^2/Sqrt[2] σ)]/Erfc[(Log[s] - μ/Sqrt[2] σ)]) /. Erfc[x_] -> Normal[Series[Erfc[x], {x, ∞, 1}]]//FullSimplify

タイプIのベンクタンダー分布に関連する定常再生分布を求める：

Wolfram Language code: StanionaryRenewalDistribution[dist_, lb_] := ProbabilityDistribution[{"CDF", (1 - Expectation[Max[x - t, 0], xdist] / (Mean[dist] - lb))}, {t, lb, Infinity}, Assumptions -> DistributionParameterAssumptions[dist]]
Wolfram Language code: srdist = StanionaryRenewalDistribution[BenktanderGibratDistribution[a, b], 1]//Simplify

BeniniDistributionと比較する：

Wolfram Language code: PDF[BeniniDistribution[a, b, 1], x]//Simplify

特性と関係  (3)

他の分布との関係：

ParetoDistributionはBenktanderGibratDistributionの極限のケースである：

Wolfram Language code: Limit[PDF[BenktanderGibratDistribution[a, b], x], b -> 0]
Wolfram Language code: PDF[ParetoDistribution[1, a + 1], x]
Wolfram Language code: % - %%

タイプIのベンクタンダー分布は準指数的である：

Wolfram Language code: dassum = DistributionParameterAssumptions[BenktanderGibratDistribution[a, b]];
Wolfram Language code: Limit[Exp[c x]Refine[PDF[BenktanderGibratDistribution[a, b], x], x > 1], x -> ∞, Assumptions -> c > 0 && dassum]

おもしろい例題  (1)

累積分布関数の等高線を持つ a のさまざまな値についての確率密度関数：

Wolfram Language code: dist = BenktanderGibratDistribution[a, 3];cdf = Function[{x, a}, Evaluate[CDF[dist, x]]]; ql = {0.025, 0.10, 0.25, 0.5, 0.75, 0.90, 0.975}; cl = Table[ColorData["Rainbow"][q], {q, Join[{0.0}, ql]}];
Wolfram Language code: Legended[Plot3D[PDF[dist, x], {x, 1, 2.2}, {a, 3, 7}, PlotTheme -> "Marketing", MeshFunctions -> {cdf}, Mesh -> {ql}, MeshStyle -> GrayLevel[0.8], PlotRange -> All, MeshShading -> cl, AxesLabel -> Automatic, BaseStyle -> Opacity[0.9], ImageSize -> 400], BarLegend["Rainbow", ql, LegendLabel -> "prob"]]
Wolfram Research (2010), BenktanderGibratDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/BenktanderGibratDistribution.html （2016年に更新）.

テキスト

Wolfram Research (2010), BenktanderGibratDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/BenktanderGibratDistribution.html （2016年に更新）.

CMS

Wolfram Language. 2010. "BenktanderGibratDistribution." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2016. https://reference.wolfram.com/language/ref/BenktanderGibratDistribution.html.

APA

Wolfram Language. (2010). BenktanderGibratDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BenktanderGibratDistribution.html

BibTeX

@misc{reference.wolfram_2026_benktandergibratdistribution, author="Wolfram Research", title="{BenktanderGibratDistribution}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/BenktanderGibratDistribution.html}", note=[Accessed: 08-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_benktandergibratdistribution, organization={Wolfram Research}, title={BenktanderGibratDistribution}, year={2016}, url={https://reference.wolfram.com/language/ref/BenktanderGibratDistribution.html}, note=[Accessed: 08-August-2026]}