BesselY

BesselY[n,z]

第2種ベッセル関数を与える．

詳細

記号操作・数値操作の両方に適した数学関数である．
は，微分方程式を満足させる．
BesselY[n,z]は，複素 z 平面上，〜の範囲で不連続な分枝切断線を持つ．
FullSimplifyとFunctionExpandはBesselYの変換規則を含む．
特別な引数の場合，BesselYは，自動的に厳密値を計算する．
BesselYは任意の数値精度で評価できる．
BesselYは自動的にリストに縫い込まれる．
BesselYはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

例題

すべて開くすべて閉じる

例 (5)

数値的に評価する：

Wolfram Language code: BesselY[0, 2.5]

実数の部分集合上でをプロットする：

Wolfram Language code: Plot[BesselY[0, r], {r, 0, 15}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[BesselY[1 / 2, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

原点における級数展開：

Wolfram Language code: Series[BesselY[0, x], {x, 0, 3}]

Infinityにおける級数展開：

Wolfram Language code: Series[BesselY[0, x], {x, ∞, 2}]//Normal

スコープ (44)

数値評価 (6)

数値的に評価する：

Wolfram Language code: BesselY[0, 1.0]

高精度で評価する：

Wolfram Language code: N[BesselY[0, 1], 50]

出力精度は入力精度に従う：

Wolfram Language code: BesselY[0, 1.0000000000000000000000000000000000000000]

複素引数とパラメータについて評価する：

Wolfram Language code: BesselY[0.5 I, 3 - I]

BesselYを高精度で効率よく評価する：

Wolfram Language code: BesselY[0, 1`500]//Timing

Wolfram Language code: BesselY[0, 1`5000];//Timing

IntervalオブジェクトおよびCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: BesselY[1 / 2, Interval[{1, 1.2}]]

Wolfram Language code: BesselY[1 / 2, CenteredInterval[2, 1 / 100]]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: BesselY[2, Around[2, 0.01]]

配列の要素ごとの値を計算する：

Wolfram Language code: BesselY[0.5, {{1, 2}, {3, 4}}]

MatrixFunctionを使って行列のBesselY関数を計算することもできる：

Wolfram Language code: MatrixFunction[BesselY[0.5, #]&, {{1, 2}, {3, 4}}]

特定の値 (4)

における整数()次数についてのBesselYの値：

Wolfram Language code: {BesselY[0, 0], BesselY[1, 0]}

半整数の指標について，BesselYを評価すると初等関数になる：

Wolfram Language code: Table[BesselY[(2n + 1) / 2, x], {n, 0, 2}]

無限大における極限値：

Wolfram Language code: Limit[BesselY[n, x], x -> Infinity]

の最初の3つの零点：

Wolfram Language code: {BesselYZero[0, 1], BesselYZero[0, 2], BesselYZero[0, 3]}//N

Solveを使っての最初の零点を求める：

Wolfram Language code: sol = Solve[BesselY[0, x] == 0 && 0 < x < 3, x]//N

結果を可視化する：

Wolfram Language code:

xzero = x /. First@sol;Plot[BesselY[0, x], {x, -1, 8}, Epilog -> Style[Point[{xzero, BesselY[0, xzero]}], PointSize[Large], Red]]

可視化 (3)

BesselY関数を整数次数()についてプロットする：

Wolfram Language code: Plot[{BesselY[0, x], BesselY[1, x], BesselY[2, x]}, {x, 0, 10}]

BesselY関数の実部と虚部を整数次数()についてプロットする：

Wolfram Language code: ReImPlot[{BesselY[0, x], BesselY[1, x], BesselY[2, x]}, {x, -5, 5}]

の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[BesselY[0, z]], {z, -4 - 4I, 8 + 4I}, IconizedObject[«PlotOptions»]]

の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[BesselY[0, z]], {z, -4 - 4I, 8 + 4I}, IconizedObject[«PlotOptions»]]

関数の特性 (10)

は，0より大きいすべての実数値について定義される：

Wolfram Language code: FunctionDomain[BesselY[n, x], x]

複素領域：

Wolfram Language code: FunctionDomain[BesselY[n, z], z, Complexes]

の値域を近似する：

Wolfram Language code: FunctionRange[BesselY[0, x], x, y]//N

の値域を近似する：

Wolfram Language code: FunctionRange[BesselY[1, x], x, y]//N

は解析関数ではない：

Wolfram Language code: Table[FunctionAnalytic[BesselY[n, z], z], {n, -2, 2}]

BesselYは非減少でも非増加でもない：

Wolfram Language code: Table[FunctionMonotonicity[BesselY[n, z], z], {n, 5}]

Wolfram Language code: Table[FunctionMonotonicity[BesselY[1 / n, z], z], {n, 5}]

BesselYは単射ではない：

Wolfram Language code: Table[FunctionInjective[BesselY[n, z], z], {n, 5}]

Wolfram Language code: Table[FunctionInjective[BesselY[1 / n, z], z], {n, 5}]

Wolfram Language code: Plot[{BesselY[1, z], BesselY[2, z], BesselY[1 / 3, z], .2}, {z, 0, 15}]

BesselYは全射ではない：

Wolfram Language code: Table[FunctionSurjective[BesselY[n, z], z], {n, 5}]

Wolfram Language code: Table[FunctionSurjective[BesselY[1 / n, z], z], {n, 5}]

Wolfram Language code: Plot[{BesselY[1, z], BesselY[2, z], BesselY[1 / 3, z], 1}, {z, 0, 15}]

BesselYは非負でも非正でもない：

Wolfram Language code: Table[FunctionSign[BesselY[n, z], z], {n, 4}]

は z≤0のとき特異点と不連続点の両方を持つ：

Wolfram Language code: FunctionSingularities[BesselY[n, z], z]

Wolfram Language code: FunctionDiscontinuities[BesselY[n, z], z]

BesselYは凸でも凹でもない：

Wolfram Language code: Table[FunctionConvexity[BesselY[a, z], z], {a, 5}]

TraditionalFormによる表示：

Wolfram Language code: BesselY[n, r]//TraditionalForm

微分 (3)

一次導関数：

Wolfram Language code: D[BesselY[n, x], x]

高次導関数：

Wolfram Language code: derivs = Table[D[BesselY[n, x], {x, k}], {k, 1, 4}]

についての高次導関数をプロットする：

Wolfram Language code:

Plot[Evaluate[derivs /. n -> 0], {x, 0, 10}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

次導関数の式：

Wolfram Language code: D[BesselY[n, x], {x, j}]

積分 (3)

BesselYの不定積分：

Wolfram Language code: Integrate[BesselY[n, x], x]

BesselYを含む式の積分：

Wolfram Language code: Integrate[r BesselY[n, r] ^ 2 , r]

Wolfram Language code: Integrate[BesselY[0, r], r]

BesselYの実領域上での定積分：

Wolfram Language code: Integrate[BesselY[n, x], {x, 0, Infinity}]

級数展開 (5)

の周りののテイラー(Taylor)展開：

Wolfram Language code: Series[BesselY[0, x], {x, 1, 3}]

の周りのの最初の3つの近似をプロットする：

Wolfram Language code:

terms = Normal@Table[Series[BesselY[0, x], {x, 1, m}], {m, 1, 3}];
Plot[{BesselY[0, x], terms}, {x, 0.5, 2.5}]

BesselYの級数展開における一般項：

Wolfram Language code: SeriesCoefficient[BesselY[0, x], {x, 1, n}]

BesselYの漸近的近似：

Wolfram Language code: Series[BesselY[n, x], {x, Infinity, 0}]

生成点におけるテイラー(expansion)展開：

Wolfram Language code: Series[BesselY[n, x], {x, x0, 2}]// FullSimplify

BesselYはベキ級数に適用できる：

Wolfram Language code: BesselY[1, x / (1 + x) + O[x] ^ 2]

積分変換 (3)

LaplaceTransformを使ってラプラス(Laplace)変換を計算する：

Wolfram Language code: LaplaceTransform[BesselY[n, t], t, s]

HankelTransform：

Wolfram Language code: HankelTransform[BesselY[n, r], r, s ]

MellinTransform：

Wolfram Language code: MellinTransform[BesselY[n, x], x, s]

関数の恒等式と簡約 (3)

FullSimplifyを使ってベッセル関数を簡約する：

Wolfram Language code: FullSimplify[ r BesselY[2, r] + r BesselY[0, r]]

再帰関係：

Wolfram Language code: FullSimplify[z(BesselY[n - 1, z] + BesselY[n + 1, z]) == 2n BesselY[n, z]]

整数と任意の固定について $TemplateBox[{{-, n}, z}, BesselY]=(-1)^n TemplateBox[{n, z}, BesselY]$ である：

Wolfram Language code: FullSimplify[BesselY[-n, z] == (-1)^n BesselY[n, z], n∈ℤ]

関数表現 (4)

BesselYの積分表現：

Wolfram Language code:

Integrate[-( 2^n + 1z^-n/ Sqrt[π]Gamma[(1/2) - n])(t^2 - 1)^-n - (1/2)Cos[z t], {t, 1, Infinity}, Assumptions -> { Abs[Re[n]] < (1/2)∧z > 0}]

非整数について BesselJとSinを使って表す：

Wolfram Language code: FullSimplify[(BesselJ[n, x]Cos[n π] - BesselJ[-n, x]/Sin[n π]), n ≠ 0]

BesselYはMeijerGによって表現できる：

Wolfram Language code: MeijerGReduce[BesselY[n, x], x]

Wolfram Language code: Activate[%]

BesselYはDifferenceRootとして表現できる：

Wolfram Language code: DifferenceRootReduce[BesselY[k, z], k]

アプリケーション (2)

ベッセル微分方程式を解く：

Wolfram Language code: DSolve[x ^ 2 f''[x] + x f'[x] + (x ^ 2 - n ^ 2)f[x] == 0, f[x], x]

微分方程式を解く：

Wolfram Language code: DSolve[(a + x Cot[x]) y[x] + (x + 2 x^2 Cot[x]) Derivative[1][y][x] + x^2 Derivative[2][y][x] == 0, y[x], x]

非同次ベッセル微分方程式を解く：

Wolfram Language code: DSolve[x^2y''[x] + x y'[x] + (x ^ 2 - 1)y[x] == (2/π)x ^ 2, y[x], x]

特性と関係 (3)

FullSimplifyを使ってベッセル関数を簡約する：

Wolfram Language code: FullSimplify[ r BesselY[2, r] + r BesselY[0, r]]

BesselYはDifferentialRootとして表すことができる：

Wolfram Language code: DifferentialRootReduce[BesselY[n, x], x]

BesselYの指数母関数：

Wolfram Language code: ExponentialGeneratingFunction[BesselY[n, k], n, x]

考えられる問題 (1)

数値引数の場合，半整数のベッセル関数は自動的には評価されない：

Wolfram Language code: BesselY[11 / 2, 1]

記号引数の場合には評価される：

Wolfram Language code: BesselY[11 / 2, x]

次は，機械精度の評価では非常に不正確になることがある：

Wolfram Language code: {BesselY[153 / 2, 55.], BesselY[153 / 2, x] /. x -> 55.}

おもしろい例題 (1)

のリーマン(Riemann)面をプロットする：

Wolfram Language code:

With[{n = 0, ε = 1*^-12}, ParametricPlot3D[Table[{r Cos[φ], r Sin[φ], Im[(-1)^n k(BesselY[n, r Exp[I φ]] + 2I k BesselJ[n, r Exp[I φ]])]}, {k, -2, 2}], {r, ε, 3}, {φ, -π + ε, π - ε}, BoxRatios -> {1, 1, 2.5}, Mesh -> None, PlotStyle -> Directive[Hue[0.46], Opacity[0.6]]]]

のリーマン面をプロットする：

Wolfram Language code:

With[{ν = 1 / 3, ε = 1*^-12}, ParametricPlot3D[Table[{r Cos[φ], r Sin[φ], Im[Exp[-k ν π I] BesselY[ν, r Exp[I φ]] + 2 I Cos[ν π]ChebyshevU[k - 1, Cos[ν π]] BesselJ[ν, r Exp[I φ]]]}, {k, -2, 2}], {r, ε, 3}, {φ, -π + ε, π - ε}, BoxRatios -> {1, 1, 2.5}, Mesh -> None, PlotStyle -> Directive[Hue[0.23], Opacity[0.6]]]]

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

BesselY

詳細

例題

例 (5)

スコープ (44)

数値評価 (6)

特定の値 (4)

可視化 (3)

関数の特性 (10)

微分 (3)

積分 (3)

級数展開 (5)

積分変換 (3)

関数の恒等式と簡約 (3)

関数表現 (4)

アプリケーション (2)

特性と関係 (3)

考えられる問題 (1)

おもしろい例題 (1)

テキスト

CMS

APA

BibTeX

BibLaTeX

BesselY

詳細

例題

例 (5)

スコープ (44)

数値評価 (6)

特定の値 (4)

可視化 (3)

関数の特性 (10)

微分 (3)

積分 (3)

級数展開 (5)

積分変換 (3)

関数の恒等式と簡約 (3)

関数表現 (4)

アプリケーション (2)

特性と関係 (3)

考えられる問題 (1)

おもしろい例題 (1)

関連項目

テクニカルノート

関連するガイド

関連リンク

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX