WOLFRAM

Wolfram 语言与系统参考资料中心

BesselY[n,z]

给出第二类贝塞尔函数 TemplateBox[{n, z}, BesselY].

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数值运算  
特殊值  
可视化  
Show More Show More
函数的属性  
微分  
积分  
级数展开式  
积分变换  
函数恒等式和化简  
函数表示  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

BesselY

BesselY[n,z]

给出第二类贝塞尔函数 TemplateBox[{n, z}, BesselY].

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (5)

数值化计算：

Wolfram Language code: BesselY[0, 2.5]

在实数的子集上绘制 ：

Wolfram Language code: Plot[BesselY[0, r], {r, 0, 15}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[BesselY[1 / 2, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

在原点的级数展开：

Wolfram Language code: Series[BesselY[0, x], {x, 0, 3}]

在 Infinity 的级数展开：

Wolfram Language code: Series[BesselY[0, x], {x, ∞, 2}]//Normal

范围  (44)

数值运算  (6)

进行数值运算：

Wolfram Language code: BesselY[0, 1.0]

高精度求值：

Wolfram Language code: N[BesselY[0, 1], 50]

输出精度与输入精度一致：

Wolfram Language code: BesselY[0, 1.0000000000000000000000000000000000000000]

对复变量和参量求值：

Wolfram Language code: BesselY[0.5 I, 3 - I]

在高精度条件下高效计算 BesselY：

Wolfram Language code: BesselY[0, 1`500]//Timing
Wolfram Language code: BesselY[0, 1`5000];//Timing

使用 Interval 和 CenteredInterval 对象计算最坏情况下的保证区间：

Wolfram Language code: BesselY[1 / 2, Interval[{1, 1.2}]]
Wolfram Language code: BesselY[1 / 2, CenteredInterval[2, 1 / 100]]

或使用 Around 计算平均情况下的统计区间：

Wolfram Language code: BesselY[2, Around[2, 0.01]]

计算数组的逐元素数值：

Wolfram Language code: BesselY[0.5, {{1, 2}, {3, 4}}]

或使用 MatrixFunction 计算矩阵 BesselY 函数：

Wolfram Language code: MatrixFunction[BesselY[0.5, #]&, {{1, 2}, {3, 4}}]

特殊值  (4)

整数 () 阶数的 BesselY 函数在 处的值：

Wolfram Language code: {BesselY[0, 0], BesselY[1, 0]}

对于半整数指数，BesselY 求解为初等函数：

Wolfram Language code: Table[BesselY[(2n + 1) / 2, x], {n, 0, 2}]

无穷处的极限值：

Wolfram Language code: Limit[BesselY[n, x], x -> Infinity]

TemplateBox[{0, x}, BesselY] 的前三个零点：

Wolfram Language code: {BesselYZero[0, 1], BesselYZero[0, 2], BesselYZero[0, 3]}//N

用 Solve 求 TemplateBox[{0, x}, BesselY] 的第一个零点：

Wolfram Language code: sol = Solve[BesselY[0, x] == 0 && 0 < x < 3, x]//N

可视化结果：

Wolfram Language code: xzero = x /. First@sol;Plot[BesselY[0, x], {x, -1, 8}, Epilog -> Style[Point[{xzero, BesselY[0, xzero]}], PointSize[Large], Red]]

可视化  (3)

绘制整数() 阶数的 BesselY 函数：

Wolfram Language code: Plot[{BesselY[0, x], BesselY[1, x], BesselY[2, x]}, {x, 0, 10}]

绘制整数阶 () BesselY 函数的实部和虚部：

Wolfram Language code: ReImPlot[{BesselY[0, x], BesselY[1, x], BesselY[2, x]}, {x, -5, 5}]

绘制 TemplateBox[{0, z}, BesselY] 的实部：

Wolfram Language code: ComplexContourPlot[Re[BesselY[0, z]], {z, -4 - 4I, 8 + 4I}, IconizedObject[«PlotOptions»]]

绘制 TemplateBox[{0, z}, BesselY] 的虚部：

Wolfram Language code: ComplexContourPlot[Im[BesselY[0, z]], {z, -4 - 4I, 8 + 4I}, IconizedObject[«PlotOptions»]]

函数的属性  (10)

TemplateBox[{n, z}, BesselY] 是针对所有大于 0 的实数定义的：

Wolfram Language code: FunctionDomain[BesselY[n, x], x]

复定义域：

Wolfram Language code: FunctionDomain[BesselY[n, z], z, Complexes]

TemplateBox[{0, z}, BesselY] 的近似值域：

Wolfram Language code: FunctionRange[BesselY[0, x], x, y]//N

TemplateBox[{1, z}, BesselY] 的近似值域：

Wolfram Language code: FunctionRange[BesselY[1, x], x, y]//N

TemplateBox[{n, z}, BesselY] 不是解析函数：

Wolfram Language code: Table[FunctionAnalytic[BesselY[n, z], z], {n, -2, 2}]

BesselY 既不是非递增，也不是非递减:

Wolfram Language code: Table[FunctionMonotonicity[BesselY[n, z], z], {n, 5}]
Wolfram Language code: Table[FunctionMonotonicity[BesselY[1 / n, z], z], {n, 5}]

BesselY 不是单射函数：

Wolfram Language code: Table[FunctionInjective[BesselY[n, z], z], {n, 5}]
Wolfram Language code: Table[FunctionInjective[BesselY[1 / n, z], z], {n, 5}]
Wolfram Language code: Plot[{BesselY[1, z], BesselY[2, z], BesselY[1 / 3, z], .2}, {z, 0, 15}]

BesselY 不是满射函数：

Wolfram Language code: Table[FunctionSurjective[BesselY[n, z], z], {n, 5}]
Wolfram Language code: Table[FunctionSurjective[BesselY[1 / n, z], z], {n, 5}]
Wolfram Language code: Plot[{BesselY[1, z], BesselY[2, z], BesselY[1 / 3, z], 1}, {z, 0, 15}]

BesselY 既不是非负，也不是非正：

Wolfram Language code: Table[FunctionSign[BesselY[n, z], z], {n, 4}]

z≤0 时，TemplateBox[{n, z}, BesselY] 有奇点或断点：

Wolfram Language code: FunctionSingularities[BesselY[n, z], z]
Wolfram Language code: FunctionDiscontinuities[BesselY[n, z], z]

BesselY 既不凸，也不凹：

Wolfram Language code: Table[FunctionConvexity[BesselY[a, z], z], {a, 5}]

TraditionalForm 格式：

Wolfram Language code: BesselY[n, r]//TraditionalForm

微分  (3)

一阶导数：

Wolfram Language code: D[BesselY[n, x], x]

高阶导数：

Wolfram Language code: derivs = Table[D[BesselY[n, x], {x, k}], {k, 1, 4}]

绘制阶数 时的高阶导数：

Wolfram Language code: Plot[Evaluate[derivs /. n -> 0], {x, 0, 10}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

阶导数的公式：

Wolfram Language code: D[BesselY[n, x], {x, j}]

积分  (3)

BesselY 函数的不定积分：

Wolfram Language code: Integrate[BesselY[n, x], x]

对含有 BesselY 的表达式进行积分：

Wolfram Language code: Integrate[r BesselY[n, r] ^ 2 , r]
Wolfram Language code: Integrate[BesselY[0, r], r]

BesselY 在实数域上的定积分：

Wolfram Language code: Integrate[BesselY[n, x], {x, 0, Infinity}]

级数展开式  (5)

TemplateBox[{0, x}, BesselY] 在 处的泰勒展开式：

Wolfram Language code: Series[BesselY[0, x], {x, 1, 3}]

绘制 TemplateBox[{0, x}, BesselY] 在 处的前三个近似式：

Wolfram Language code: terms = Normal@Table[Series[BesselY[0, x], {x, 1, m}], {m, 1, 3}]; Plot[{BesselY[0, x], terms}, {x, 0.5, 2.5}]

BesselY 的级数展开式的通项：

Wolfram Language code: SeriesCoefficient[BesselY[0, x], {x, 1, n}]

BesselY 的渐近近似式：

Wolfram Language code: Series[BesselY[n, x], {x, Infinity, 0}]

常点处的泰勒展开式：

Wolfram Language code: Series[BesselY[n, x], {x, x0, 2}]// FullSimplify

BesselY 可被应用于幂级数：

Wolfram Language code: BesselY[1, x / (1 + x) + O[x] ^ 2]

积分变换  (3)

用 LaplaceTransform 计算拉普拉斯变换：

Wolfram Language code: LaplaceTransform[BesselY[n, t], t, s]

HankelTransform:

Wolfram Language code: HankelTransform[BesselY[n, r], r, s ]

MellinTransform:

Wolfram Language code: MellinTransform[BesselY[n, x], x, s]

函数恒等式和化简  (3)

用 FullSimplify 化简贝塞尔函数：

Wolfram Language code: FullSimplify[ r BesselY[2, r] + r BesselY[0, r]]

递推关系式 z (TemplateBox[{{n, -, 1}, z}, BesselY]+TemplateBox[{{n, +, 1}, z}, BesselY])=2 n TemplateBox[{n, z}, BesselY]：

Wolfram Language code: FullSimplify[z(BesselY[n - 1, z] + BesselY[n + 1, z]) == 2n BesselY[n, z]]

对于整数 和任意固定不变的 ，TemplateBox[{{-, n}, z}, BesselY]=(-1)^n TemplateBox[{n, z}, BesselY]：

Wolfram Language code: FullSimplify[BesselY[-n, z] == (-1)^n BesselY[n, z], n∈ℤ]

函数表示  (4)

BesselY 的积分表示：

Wolfram Language code: Integrate[-( 2^n + 1z^-n/ Sqrt[π]Gamma[(1/2) - n])(t^2 - 1)^-n - (1/2)Cos[z t], {t, 1, Infinity}, Assumptions -> { Abs[Re[n]] < (1/2)∧z > 0}]

用 BesselJ 和 Sin 表示非整数阶的 阶函数：

Wolfram Language code: FullSimplify[(BesselJ[n, x]Cos[n π] - BesselJ[-n, x]/Sin[n π]), n ≠ 0]

可用 MeijerG 表示 BesselY：

Wolfram Language code: MeijerGReduce[BesselY[n, x], x]
Wolfram Language code: Activate[%]

可用 DifferenceRoot 表示 BesselY：

Wolfram Language code: DifferenceRootReduce[BesselY[k, z], k]

应用  (2)

解贝塞尔微分方程：

Wolfram Language code: DSolve[x ^ 2 f''[x] + x f'[x] + (x ^ 2 - n ^ 2)f[x] == 0, f[x], x]

求解微分方程：

Wolfram Language code: DSolve[(a + x Cot[x]) y[x] + (x + 2 x^2 Cot[x]) Derivative[1][y][x] + x^2 Derivative[2][y][x] == 0, y[x], x]

求解非均质贝塞尔微分方程：

Wolfram Language code: DSolve[x^2y''[x] + x y'[x] + (x ^ 2 - 1)y[x] == (2/π)x ^ 2, y[x], x]

属性和关系  (3)

用 FullSimplify 简化贝塞尔函数：

Wolfram Language code: FullSimplify[ r BesselY[2, r] + r BesselY[0, r]]

BesselY 可被表示为 DifferentialRoot：

Wolfram Language code: DifferentialRootReduce[BesselY[n, x], x]

BesselY 的指数母函数：

Wolfram Language code: ExponentialGeneratingFunction[BesselY[n, k], n, x]

可能存在的问题  (1)

对于数值自变量，半整数贝塞尔函数不能自动求值：

Wolfram Language code: BesselY[11 / 2, 1]

若自变量为符号，则为：

Wolfram Language code: BesselY[11 / 2, x]

这将致使机器精度求值中存在大误差：

Wolfram Language code: {BesselY[153 / 2, 55.], BesselY[153 / 2, x] /. x -> 55.}

巧妙范例  (1)

绘制 TemplateBox[{0, z}, BesselY] 的黎曼曲面：

Wolfram Language code: With[{n = 0, ε = 1*^-12}, ParametricPlot3D[Table[{r Cos[φ], r Sin[φ], Im[(-1)^n k(BesselY[n, r Exp[I φ]] + 2I k BesselJ[n, r Exp[I φ]])]}, {k, -2, 2}], {r, ε, 3}, {φ, -π + ε, π - ε}, BoxRatios -> {1, 1, 2.5}, Mesh -> None, PlotStyle -> Directive[Hue[0.46], Opacity[0.6]]]]

绘制 TemplateBox[{{1, /, 3}, z}, BesselY] 的黎曼曲面：

Wolfram Language code: With[{ν = 1 / 3, ε = 1*^-12}, ParametricPlot3D[Table[{r Cos[φ], r Sin[φ], Im[Exp[-k ν π I] BesselY[ν, r Exp[I φ]] + 2 I Cos[ν π]ChebyshevU[k - 1, Cos[ν π]] BesselJ[ν, r Exp[I φ]]]}, {k, -2, 2}], {r, ε, 3}, {φ, -π + ε, π - ε}, BoxRatios -> {1, 1, 2.5}, Mesh -> None, PlotStyle -> Directive[Hue[0.23], Opacity[0.6]]]]
Wolfram Research (1988)，BesselY，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BesselY.html （更新于 2022 年）.

文本

Wolfram Research (1988)，BesselY，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BesselY.html （更新于 2022 年）.

CMS

Wolfram 语言. 1988. "BesselY." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2022. https://reference.wolfram.com/language/ref/BesselY.html.

APA

Wolfram 语言. (1988). BesselY. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BesselY.html 年

BibTeX

@misc{reference.wolfram_2026_bessely, author="Wolfram Research", title="{BesselY}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/BesselY.html}", note=[Accessed: 13-July-2026]}

BibLaTeX

@online{reference.wolfram_2026_bessely, organization={Wolfram Research}, title={BesselY}, year={2022}, url={https://reference.wolfram.com/language/ref/BesselY.html}, note=[Accessed: 13-July-2026]}