WOLFRAM

Wolfram 语言与系统参考资料中心

BrownForsytheTest[data]

检验 data 的方差是否为1.

BrownForsytheTest[{data1,data2,…}]

检验 data1 和 data2 的方差是否相等.

BrownForsytheTest[dspec,]

检验一个离散量数和 的关系.

BrownForsytheTest[dspec,,"property"]

返回 "property" 的值.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
检验  
报告  
选项  
AlternativeHypothesis  
SignificanceLevel  
VerifyTestAssumptions  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

BrownForsytheTest

BrownForsytheTest[data]

检验 data 的方差是否为1.

BrownForsytheTest[{data1,data2,…}]

检验 data1 和 data2 的方差是否相等.

BrownForsytheTest[dspec,]

检验一个离散量数和 的关系.

BrownForsytheTest[dspec,,"property"]

返回 "property" 的值.

更多信息和选项

  • BrownForsytheTest 检验零假设 与备择假设 ：
  • data
    {data1,data2}
    {data1,data2,…}不全相等
  • 其中 σi2 为 datai 的总体方差.
  • 默认情况下，返回一个概率值或者 值.
  • 一个较小的 值表明 不可能为真.
  • 在 dspec 中，data 必须是单变量 {x1,x2,…}.
  • 参数 可以是任意正实数. 在未指定的情况下为1，在 dspec 中组数大于 2 的情况下则被忽略.
  • BrownForsytheTest 假设数据服从正态分布.
  • BrownForsytheTest 比起 LeveneTest 对正态性假设较不敏感.
  • BrownForsytheTest[data,,"HypothesisTestData"] 返回一个 HypothesisTestData 对象 htd ， 可以使用 htd["property"] 的形式提取额外检验结果和属性.
  • BrownForsytheTest[data,,"property"] 可用于直接给出 "property" 的值.
  • 与检验结果报告相关的属性包括：
  • "DegreesOfFreedom"检验中所用的自由度
    "PValue" 值列表
    "PValueTable" 值组成的格式化表格
    "ShortTestConclusion"检验结论的简短描述
    "TestConclusion"检验结论的描述
    "TestData"检验统计量和 值对组成的列表
    "TestDataTable" 值和检验统计量组成的格式化表格
    "TestStatistic"检验统计量组成的列表
    "TestStatisticTable"检验统计量的格式化的表格
  • 当样本数 给定，BrownForsytheTest 等价于 FisherRatioTest.
  • 对于 -样本的情况，BrownForsytheTest 是 LeveneTest 的修正，用函数 fn 替代 Abs[dataij-Mean[dataij]] 中的 Mean. 函数 fn 通常为选定为 Median，但如果数据为重尾型，则使用TrimmedMean[#,1/10]&.
  • 可以使用下列选项：
  • AlternativeHypothesis "Unequal"备择假设的不等性
    SignificanceLevel 0.05用于诊断和报告的分界点
    VerifyTestAssumptions Automatic设置要运行哪个诊断检验
  • 对于 BrownForsytheTest，选择一个临界值 ，使得只有当 时，拒绝 . 用于 "TestConclusion" 和 "ShortTestConclusion" 属性的 值由 SignificanceLevel 选项控制. 值 也用于包含正态性和对称性的假设诊断检验. 默认情况下， 设为 0.05.
  • 在 BrownForsytheTest 中 VerifyTestAssumptions 的已命名设置包括：
  • "Normality"验证所有数据是否服从正态分布

范例

打开所有单元 关闭所有单元

基本范例  (2)

检验两个数据集方差是否相等：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {2, 100}];
Wolfram Language code: BrownForsytheTest[data]

创建一个 HypothesisTestData 对象，用于进一步的属性提取：

Wolfram Language code: ℋ = BrownForsytheTest[data, Automatic, "HypothesisTestData"]

检验的属性：

Wolfram Language code: ℋ["Properties"]

检验两个数据集的方差比率与一个特定值的关系：

Wolfram Language code: SeedRandom["test"]; data1 = RandomVariate[NormalDistribution[0, 1], 100]; data2 = RandomVariate[NormalDistribution[0, 2.5], 250];
Wolfram Language code: BrownForsytheTest[{data1, data2}, 1 / 4, "TestDataTable"]
Wolfram Language code: Variance[data1] / Variance[data2]

对备择假设 进行检验：

Wolfram Language code: BrownForsytheTest[{data1, data2}, 1 / 4, AlternativeHypothesis -> "Less"]

范围  (10)

检验  (8)

检验一个数据集的方差是否为1：

Wolfram Language code: SeedRandom[1]; data1 = RandomVariate[NormalDistribution[], 500]; data2 = RandomVariate[NormalDistribution[1, .3], 500];

在 下，-值在 [0,1] 之间均匀分布：

Wolfram Language code: BrownForsytheTest[data1]

当 为假时， 值通常较小：

Wolfram Language code: BrownForsytheTest[data2]

将一个数据集的方差与一个特定的值比较：

Wolfram Language code: SeedRandom["val"];data1 = RandomVariate[NormalDistribution[0, 2], 10^4]; data2 = RandomVariate[NormalDistribution[0, 2.1], 10^4];
Wolfram Language code: BrownForsytheTest[data1, 2^2]
Wolfram Language code: BrownForsytheTest[data2, 2^2]

比较两个数据集的方差：

Wolfram Language code: SeedRandom["2"];data1 = RandomVariate[NormalDistribution[0, 3], 500]; data2 = RandomVariate[NormalDistribution[1, 3], 500];

在 下，-值在 [0,1] 上均匀分布：

Wolfram Language code: BrownForsytheTest[{data1, data2}]

Brown–Forsythe 检验的 -值样本直方图：

Wolfram Language code: sample = Table[Quiet@BrownForsytheTest[{RandomVariate[NormalDistribution[0, 3], 100], RandomVariate[NormalDistribution[1, 3], 100]}], {5 10 ^ 3}];
Wolfram Language code: Histogram[sample, Automatic, PDF]

当方差不相等时，-值通常很小：

Wolfram Language code: data3 = RandomVariate[NormalDistribution[10, 1], 350];
Wolfram Language code: BrownForsytheTest[{data1, data3}]

检验两个数据集方差的比率是否为一个特定的值：

Wolfram Language code: SeedRandom["ratio"];data1 = RandomVariate[NormalDistribution[0, 2], 500]; data2 = RandomVariate[NormalDistribution[0, 1], 500];
Wolfram Language code: Subscript[σ, 0] = 4;

以下形式是等价的：

Wolfram Language code: BrownForsytheTest[{data1, data2}, Subscript[σ, 0]]
Wolfram Language code: BrownForsytheTest[{data2, data1}, 1 / Subscript[σ, 0]]

当决定 时，需要考虑数据集的顺序：

Wolfram Language code: BrownForsytheTest[{data2, data1}, Subscript[σ, 0]]

检验三个总体的方差是否相同：

Wolfram Language code: SeedRandom["3"];data1 = RandomVariate[NormalDistribution[10, 1], 500]; data2 = RandomVariate[NormalDistribution[0, 1], 200]; data3 = RandomVariate[NormalDistribution[-3, 1], 400];
Wolfram Language code: BrownForsytheTest[{data1, data2, data3}]

创建一个 HypothesisTestData 对象，以进行重复属性提取：

Wolfram Language code: SeedRandom["prop"];data = RandomVariate[NormalDistribution[], {2, 10^4}];
Wolfram Language code: ℋ = BrownForsytheTest[data, 1, "HypothesisTestData"];

可用于提取的属性：

Wolfram Language code: ℋ["Properties"]

从一个 HypothesisTestData 提取某些属性：

Wolfram Language code: SeedRandom["obj"];data = RandomVariate[NormalDistribution[], {2, 10^4}];
Wolfram Language code: ℋ = BrownForsytheTest[data, 1, "HypothesisTestData"];

值、检验统计量和自由度：

Wolfram Language code: ℋ["PValue"]
Wolfram Language code: ℋ["TestStatistic"]
Wolfram Language code: ℋ["DegreesOfFreedom"]

同时提取任意数目的属性：

Wolfram Language code: SeedRandom["m"];data = RandomVariate[NormalDistribution[], {2, 100}];
Wolfram Language code: ℋ = BrownForsytheTest[data, 1, "HypothesisTestData"];

值、检验统计量和自由度：

Wolfram Language code: ℋ["PValue", "TestStatistic", "DegreesOfFreedom"]

报告  (2)

将检验结果制作成表格：

Wolfram Language code: SeedRandom["tab"];data = RandomVariate[NormalDistribution[], {2, 10^3}];
Wolfram Language code: ℋ = BrownForsytheTest[data, 1, "HypothesisTestData"];
Wolfram Language code: ℋ["TestDataTable"]

使用 "TestData" 可以提取表格中的值：

Wolfram Language code: ℋ["TestData"]

将 值或者检验统计量制作成表格：

Wolfram Language code: SeedRandom["tab"];data = RandomVariate[NormalDistribution[], {3, 10^4}];
Wolfram Language code: ℋ = BrownForsytheTest[data, 1, "HypothesisTestData"];
Wolfram Language code: ℋ["PValueTable"]

将 值或者检验统计量制作成表格：

Wolfram Language code: ℋ["PValue"]
Wolfram Language code: ℋ["TestStatisticTable"]

来自表格的检验统计量：

Wolfram Language code: ℋ["TestStatistic"]

选项  (8)

AlternativeHypothesis  (3)

默认情况下，执行一个双侧检验：

Wolfram Language code: SeedRandom["alt"];data = RandomVariate[NormalDistribution[], 100];

检验 ⟷ ：

Wolfram Language code: BrownForsytheTest[data, 1, AlternativeHypothesis -> "Unequal"]
Wolfram Language code: BrownForsytheTest[data, 1, AlternativeHypothesis -> Automatic]

执行一个双侧检验或者一个单侧检验：

Wolfram Language code: SeedRandom["alt"];data = RandomVariate[NormalDistribution[0, 1.25], 100];

检验 ⟷ ：

Wolfram Language code: BrownForsytheTest[data, Automatic, AlternativeHypothesis -> "Unequal"]

检验 ⟷ :

Wolfram Language code: BrownForsytheTest[data, Automatic, AlternativeHypothesis -> "Less"]

检验 ⟷ :

Wolfram Language code: BrownForsytheTest[data, Automatic, AlternativeHypothesis -> "Greater"]

当均值为零时，执行单侧检验：

Wolfram Language code: SeedRandom["null"]; data1 = RandomVariate[NormalDistribution[0, .9], 100]; data2 = RandomVariate[NormalDistribution[0, 1], 100];
Wolfram Language code: Variance[data1] / Variance[data2]

检验 ⟷ :

Wolfram Language code: BrownForsytheTest[{data1, data2}, 1, AlternativeHypothesis -> "Less"]

检验 ⟷ :

Wolfram Language code: BrownForsytheTest[{data1, data2}, 1.5, AlternativeHypothesis -> "Less"]

SignificanceLevel  (2)

设置诊断检验的显著性水平：

Wolfram Language code: data = BlockRandom[SeedRandom[5];RandomVariate[StudentTDistribution[3], 50]];
Wolfram Language code: BrownForsytheTest[data, 1, SignificanceLevel -> .005]

默认情况下，使用 0.05：

Wolfram Language code: BrownForsytheTest[data, 1, SignificanceLevel -> Automatic]

对 "TestConclusion" 和 "ShortTestConclusion" 也使用显著性水平：

Wolfram Language code: data = BlockRandom[SeedRandom[1];RandomVariate[NormalDistribution[0, 1], 100]];
Wolfram Language code: ℋ1 = BrownForsytheTest[data, 1.5, "HypothesisTestData", SignificanceLevel -> .05];
Wolfram Language code: ℋ2 = BrownForsytheTest[data, 1.5, "HypothesisTestData", SignificanceLevel -> .01];
Wolfram Language code: ℋ1["TestConclusion"]//TraditionalForm
Wolfram Language code: ℋ2["TestConclusion"]//TraditionalForm
Wolfram Language code: ℋ1["ShortTestConclusion"]
Wolfram Language code: ℋ2["ShortTestConclusion"]

VerifyTestAssumptions  (3)

使用 All 或者 None，可以以分组方式控制诊断：

Wolfram Language code: SeedRandom["ver"];data1 = RandomVariate[StudentTDistribution[3], 1000]; data2 = RandomVariate[NormalDistribution[0, Sqrt[3]], 1000];

验证所有假定：

Wolfram Language code: BrownForsytheTest[{data1, data2}, 1 / 4, VerifyTestAssumptions -> All]

不对假定进行检查：

Wolfram Language code: BrownForsytheTest[{data1, data2}, 1 / 4, VerifyTestAssumptions -> None]

诊断可以独立控制：

Wolfram Language code: SeedRandom["ver"];data1 = RandomVariate[StudentTDistribution[2], 1000]; data2 = RandomVariate[NormalDistribution[0, Sqrt[3]], 1000];

检查正态性：

Wolfram Language code: BrownForsytheTest[{data1, data2}, 1 / 4, VerifyTestAssumptions -> "Normality"]

将假定值设为 True：

Wolfram Language code: BrownForsytheTest[{data1, data2}, 1 / 4, VerifyTestAssumptions -> "Normality" -> True]

为了进行模拟，避开诊断检验通常是有用的：

Wolfram Language code: SeedRandom["test"];data = RandomVariate[NormalDistribution[], {1000, 100}];
Wolfram Language code: AbsoluteTiming[T = Quiet@BrownForsytheTest[#, Automatic, "TestStatistic"]& /@ data;]

设计中已经包含了检验假定，因此我们可以节省大量时间：

Wolfram Language code: AbsoluteTiming[T2 = Quiet@BrownForsytheTest[#, Automatic, "TestStatistic", VerifyTestAssumptions -> None]& /@ data;]

结果是相同的：

Wolfram Language code: SmoothHistogram[{T, T2}]

应用  (1)

使用 Brown–Forsythe 检验判断对于等均值-检验是否需要近似的自由度：

Wolfram Language code: data1 = {-0.509, 2.25, -0.553, 1.234, 0.527, 0.319, 1.315, 1.024, 0.212, 0.835, 0.215, 0.652, 0.705, 0.683, -0.804};
Wolfram Language code: data2 = {-0.714, 4.559, 1.546, 2.819, -0.814, -4.146, 0.409, -3.241, -3.987, -2.739, 0.254, -4.887, -7.827, 0.424, -0.095};
Wolfram Language code: L[x_] := Length[x];v[x_] := Variance[x]

双样本 检验：

Wolfram Language code: ttest[𝒹1_, 𝒹2_, μ0_, df_] := With[{t = (Mean[𝒹1] - Mean[𝒹2] - μ0/Sqrt[(v[𝒹1]/L[𝒹1]) + (v[𝒹2]/L[𝒹2])])}, {"T" -> t, "p" -> 2 Min[SurvivalFunction[StudentTDistribution[df], t], CDF[StudentTDistribution[df], t]], "df" -> df}]

如果两个样本具有相等的方差，则可以使用下列自由度；否则，需要一个 Satterthwaite 近似：

Wolfram Language code: evDF[𝒹1_, 𝒹2_] := L[𝒹1] + L[𝒹2] - 2
Wolfram Language code: SatterthwaiteDF[𝒹1_, 𝒹2_] := (((v[𝒹1]/L[𝒹1]) + (v[𝒹2]/L[𝒹2]))^2/((v[𝒹1]/L[𝒹1]))^2 / (L[𝒹1] - 1) + ((v[𝒹2]/L[𝒹2]))^2 / (L[𝒹2] - 1))

Brown–Forsythe检验表明方差是不相等的：

Wolfram Language code: BrownForsytheTest[{data1, data2}, 1, "TestDataTable"]

在 0.05 显著性水平下，自由度的选择影响了检验结论：

Wolfram Language code: ttest[data1, data2, 0, evDF[data1, data2]]
Wolfram Language code: ttest[data1, data2, 0, SatterthwaiteDF[data1, data2]]

TTest 自动使用 Satterthwaite 近似：

Wolfram Language code: TTest[{data1, data2}, 0, {"TestDataTable", "DegreesOfFreedom"}]

属性和关系  (8)

当给定单个数据集时，Brown-Forsythe 检验等价于 FisherRatioTest：

Wolfram Language code: SeedRandom["e"];data = RandomVariate[NormalDistribution[], 100];
Wolfram Language code: BrownForsytheTest[data]
Wolfram Language code: FisherRatioTest[data]

给定长度为 的单个数据集，在 下，检验统计量服从 ChiSquareDistribution[n-1]：

Wolfram Language code: SeedRandom["chi"];data = RandomVariate[NormalDistribution[], {1000, 100}];
Wolfram Language code: T = BrownForsytheTest[#, Automatic, "TestStatistic", VerifyTestAssumptions -> None]& /@ data;
Wolfram Language code: Show[SmoothHistogram[T], Plot[PDF[ChiSquareDistribution[99], x], {x, 50, 160}, PlotStyle -> Orange]]

自由度的最大似然估计接近 ：

Wolfram Language code: EstimatedDistribution[T, ChiSquareDistribution[df]]
Wolfram Language code: DistributionFitTest[T, ChiSquareDistribution[99]]

给定长度为 n 和 m 的两个数据集，在 下，检验统计量服从 FRatioDistribution[1,n+m-2]：

Wolfram Language code: n = 100; m = 75; SeedRandom["F"]; data1 = RandomVariate[NormalDistribution[], {1000, n}]; data2 = RandomVariate[NormalDistribution[], {1000, m}];
Wolfram Language code: T = MapThread[BrownForsytheTest[{#1, #2}, Automatic, "TestStatistic", VerifyTestAssumptions -> None]&, {data1, data2}];
Wolfram Language code: Show[Histogram[T, {0.2}, "PDF"], Plot[PDF[FRatioDistribution[1, n + m - 2], x], {x, 0, 8}, PlotRange -> {0, 1}]]
Wolfram Language code: DistributionFitTest[T, FRatioDistribution[1, n + m - 2], "TestConclusion"]

给定两个数据集，Brown–Forsythe 检验比起 FisherRatioTest 对正态性假设较为不敏感：

Wolfram Language code: SeedRandom["F"];data1 = RandomVariate[LaplaceDistribution[1, 2], {1000, 100}]; data2 = RandomVariate[LaplaceDistribution[1, 2], {1000, 75}];
Wolfram Language code: fisher = MapThread[FisherRatioTest[{#1, #2}, VerifyTestAssumptions -> None]&, {data1, data2}];
Wolfram Language code: levene = MapThread[BrownForsytheTest[{#1, #2}, VerifyTestAssumptions -> None]&, {data1, data2}];

Fisher-Ratio 检验倾向于低估 值，因而产生更多的第一类错误：

Wolfram Language code: Histogram[{fisher, levene}, Automatic, "PDF"]

双样本的检验统计量：

Wolfram Language code: Subscript[n, 1] = 100;Subscript[n, 2] = 75;Subscript[σ, 0] = 2;
Wolfram Language code: SeedRandom["2"];data1 = RandomVariate[NormalDistribution[0, Subscript[σ, 0]], Subscript[n, 1]]; data2 = RandomVariate[NormalDistribution[0, 1], Subscript[n, 2]];
Wolfram Language code: Subscript[n, t] = Subscript[n, 1] + Subscript[n, 2];
Wolfram Language code: bfor[d1_, d2_, f_] := Block[{μZ1, μZ2, z1, z2, μZZ}, z1 = Abs@Standardize[d1, f, 1&]; z2 = Subscript[σ, 0]Abs@Standardize[d2, f, 1&]; μZ1 = Mean[z1];μZ2 = Mean[z2]; μZZ = (Subscript[n, 1] μZ1 + Subscript[n, 2] μZ2/Subscript[n, t]); (Subscript[n, t] - 2)(Subscript[n, 1](μZ1 - μZZ)^2 + Subscript[n, 2](μZ2 - μZZ)^2/(z1 - μZ1).(z1 - μZ1) + (z2 - μZ2).(z2 - μZ2))]

通常，Median 作为标准化函数使用：

Wolfram Language code: bfor[data1, data2, Median]
Wolfram Language code: BrownForsytheTest[{data1, data2}, Subscript[σ, 0] ^ 2, "TestStatistic"]

对重尾数据，使用 10% TrimmedMean：

Wolfram Language code: data3 = RandomVariate[CauchyDistribution[0, Subscript[σ, 0]], Subscript[n, 1]]; data4 = RandomVariate[CauchyDistribution[0, 1], Subscript[n, 2]];
Wolfram Language code: bfor[data3, data4, TrimmedMean[#, .1]&]
Wolfram Language code: BrownForsytheTest[{data3, data4}, Subscript[σ, 0] ^ 2, "TestStatistic", VerifyTestAssumptions -> None]

LeveneTest 是等价的，但是总是使用 Mean 来标准化：

Wolfram Language code: bfor[data1, data2, Mean]
Wolfram Language code: LeveneTest[{data1, data2}, Subscript[σ, 0] ^ 2, "TestStatistic"]

三样本检验统计量：

Wolfram Language code: Subscript[n, 1] = 1000;Subscript[n, 2] = 750;Subscript[n, 3] = 1500;
Wolfram Language code: SeedRandom["3"];data1 = RandomVariate[NormalDistribution[-4, 3], Subscript[n, 1]]; data2 = RandomVariate[NormalDistribution[1, 3], Subscript[n, 2]]; data3 = RandomVariate[NormalDistribution[5, 3], Subscript[n, 3]];
Wolfram Language code: Subscript[n, t] = Subscript[n, 1] + Subscript[n, 2] + Subscript[n, 3];
Wolfram Language code: bfor3[d1_, d2_, d3_] := Block[{μZ1, μZ2, μZ3, z1, z2, z3, μZZ}, z1 = Abs[d1 - Median[d1]]; z2 = Abs[d2 - Median[d2]]; z3 = Abs[d3 - Median[d3]]; μZ1 = Mean[z1];μZ2 = Mean[z2];μZ3 = Mean[z3]; μZZ = (Subscript[n, 1]μZ1 + Subscript[n, 2]μZ2 + Subscript[n, 3]μZ3/Subscript[n, t]); ((Subscript[n, t] - 3)/2)(Subscript[n, 1](μZ1 - μZZ)^2 + Subscript[n, 2](μZ2 - μZZ)^2 + Subscript[n, 3](μZ3 - μZZ)^2/Total[(z1 - μZ1) ^ 2] + Total[(z2 - μZ2) ^ 2] + Total[(z3 - μZ3) ^ 2])]
Wolfram Language code: bfor3[data1, data2, data3]
Wolfram Language code: BrownForsytheTest[{data1, data2, data3}, 1, "TestStatistic"]

Brown–Forsythe 检验仅当输入为 TimeSeries 时适用于值：

Wolfram Language code: ts = TemporalData[TimeSeries, {{{1.224578634529677, 0.47929635789978015, 0.6572781300178168, 0.21496048742669355, 0.7299608014554928, -0.2495111111278263, -1.3286551762002712, 0.552725018274874, 0.19272112205837066, 1.1809144012420882, -1.1671 ... 40938613662046, 1.052394590214582, 0.9345044123980388, 0.38537803109557855, -0.48660931166089394, -0.71203560340161}}, {{0, 100, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ValueDimensions -> 1, ResamplingMethod -> None}}, False, 10.1];
Wolfram Language code: BrownForsytheTest[ts]
Wolfram Language code: BrownForsytheTest[ts["Values"]]

当输入为 TemporalData 时，Brown–Forsythe 检验适用于所有值在一起：

Wolfram Language code: td = TemporalData[Automatic, {{{-0.25275046867718637, -0.7175779198306353, -1.9370139837317764, 0.006665621735740701, -0.3730807122324292, 0.6740106823161018, 0.8562214990564344, 0.955785083955732, 1.7020898014886303, 1.8523009430646802, 0.244 ... 3951759101545, -1.1611722313627828, 1.1602446901533021, 1.1052173095128992, 1.1089143920161917, -0.13837156328402}}, {{0, 100, 1}}, 2, {"Continuous", 2}, {"Discrete", 1}, 1, {ValueDimensions -> 1, ResamplingMethod -> None}}, False, 10.1];
Wolfram Language code: BrownForsytheTest[td]

仅检验所有值：

Wolfram Language code: data = td["ValueList"]//Flatten; BrownForsytheTest[data]

检验两个路径的变量是否相等：

Wolfram Language code: {data1, data2} = td["ValueList"];
Wolfram Language code: BrownForsytheTest[{data1, data2}]

可能存在的问题  (3)

Brown–Forsythe 检验假定数据从 NormalDistribution 中抽取：

Wolfram Language code: SeedRandom["n"];data = RandomVariate[LaplaceDistribution[1, 2], {2, 100}];
Wolfram Language code: BrownForsytheTest[data, 1, "TestDataTable"]

对非正态数据，使用 ConoverTest 或者 SiegelTukeyTest：

Wolfram Language code: ConoverTest[data, 1, "TestDataTable"]
Wolfram Language code: SiegelTukeyTest[data, 1, "TestDataTable"]

在组数大于 2 时，Brown–Forsythe 检验忽略参数 ：

Wolfram Language code: SeedRandom["1"];data = RandomVariate[NormalDistribution[1, 2], {4, 100}];
Wolfram Language code: Length[data]
Wolfram Language code: BrownForsytheTest[data, 2, "TestDataTable"]

当有两组以上数据时，Brown–Forsythe 检验仅允许对备择假设的双边检验：

Wolfram Language code: SeedRandom["alt"];data = RandomVariate[NormalDistribution[1, 2], {4, 100}];
Wolfram Language code: BrownForsytheTest[data, 1, AlternativeHypothesis -> "Unequal"]
Wolfram Language code: BrownForsytheTest[data, 1, AlternativeHypothesis -> "Greater"]
Wolfram Language code: BrownForsytheTest[data, 1, AlternativeHypothesis -> "Less"]

巧妙范例  (1)

当零假设 为真时，计算统计量：

Wolfram Language code: SeedRandom["neat"];data = RandomVariate[NormalDistribution[], {250, 100}];
Wolfram Language code: T1 = BrownForsytheTest[#, 1, "TestStatistic", VerifyTestAssumptions -> None]& /@ data;

给出一个特定选择的检验统计量：

Wolfram Language code: T2 = BrownForsytheTest[#, 3, "TestStatistic", VerifyTestAssumptions -> None]& /@ data;

比较检验统计量的分布：

Wolfram Language code: SmoothHistogram[{T1, T2}, Filling -> Axis, PlotLegends -> {"SubscriptBox[H, 0] is True", "SubscriptBox[H, 0] is False"}, PlotStyle -> Thick]
Wolfram Research (2010)，BrownForsytheTest，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BrownForsytheTest.html （更新于 2017 年）.

文本

Wolfram Research (2010)，BrownForsytheTest，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BrownForsytheTest.html （更新于 2017 年）.

CMS

Wolfram 语言. 2010. "BrownForsytheTest." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2017. https://reference.wolfram.com/language/ref/BrownForsytheTest.html.

APA

Wolfram 语言. (2010). BrownForsytheTest. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BrownForsytheTest.html 年

BibTeX

@misc{reference.wolfram_2026_brownforsythetest, author="Wolfram Research", title="{BrownForsytheTest}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/BrownForsytheTest.html}", note=[Accessed: 16-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_brownforsythetest, organization={Wolfram Research}, title={BrownForsytheTest}, year={2017}, url={https://reference.wolfram.com/language/ref/BrownForsytheTest.html}, note=[Accessed: 16-August-2026]}