WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ChiDistribution[ν]

自由度 ν のカイ()分布を表す．

詳細
Details and Options Details and Options
予備知識
例題  
例  
スコープ  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

ChiDistribution

ChiDistribution[ν]

自由度 ν のカイ()分布を表す．

詳細

予備知識

  • ChiDistribution[ν]は，分布の自由度を表す正の値 ν でパラメータ化された統計的分布を表す．ν はカイ分布の確率密度関数(PDF)の一般的な形を決定し，PDFは ν の値によって単調減少になるか，領域の下限値に近付くにつれて特異値となり得る単一の峰（絶対最大値）を持つようになるかする．
  • ChiDistributionは，カイ二乗確率変数の平方根が従う分布である．言い換えれば， が確率変数であり， （ は「として分布」を表す）であるなら，である．標準正規分布に従う独立確率変数, , …, のベクトルのノルムもまた，自由度が のカイ分布に従う．カイ分布は，その統計的有意性に加え，理想気体の速度分布，さまざまな条件下での発射確度，分散液に対するレーダーの効果等，多くの科学的応用に見ることができる．
  • RandomVariateを使って，カイ分布から1つあるいは複数の機械精度あるいは任意精度の（後者はWorkingPrecisionオプションによる）擬似乱数変量を与えることができる．Distributed[x,ChiDistribution[ν]]（より簡略な表記では xChiDistribution[ν]）を使って，確率変数 x がカイ分布に従って分布していると宣言することができる．このような宣言は，Probability，NProbability，Expectation，NExpectation等の関数で用いることができる．
  • 確率密度関数および累積分布関数は，PDF[ChiDistribution[ν],x]およびCDF[ChiDistribution[ν],x]を使って得ることができる．平均，中央値，分散，原点の周りのモーメント，中心モーメントはそれぞれ，Mean，Median，Variance，Moment，CentralMomentを使って計算することができる．
  • DistributionFitTestを使って与えられたデータ集合がカイ分布と一致するかどうかを検定することが，EstimatedDistributionを使って与えられたデータからカイパラメトリック分布を推定することが，FindDistributionParametersを使ってデータをカイ分布にフィットすることが可能である．ProbabilityPlotを使って記号カイ分布のCDFに対する与えられたデータのCDFプロットを生成することができ，QuantilePlotを使って記号カイ分布の変位値に対する与えられたデータの変位値プロットを生成することができる．
  • TransformedDistributionを使って変換されたカイ分布を，CensoredDistributionを使って上限値と下限値の間で打ち切られた値の分布を，TruncatedDistributionを使って上限値と下限値の間で切断された値の分布を表すことができる．CopulaDistributionを使ってカイ分布を含むより高次元の分布を構築することが，ProductDistributionを使ってカイ分布を含む独立成分分布との結合分布を計算することができる．
  • ChiDistributionは多くの他の分布と密接に関係している．例えば，および について，ChiDistribution[η]は，RayleighDistribution[η]およびMaxwellDistribution[η]とそれぞれ等しい．さらに，ChiDistributionは，XNakagamiDistribution[m,ω]が独立確率変数であれば である（ただしYChiDistribution[2m]）という意味において，より一般的なNakagamiDistributionの特殊ケースであると見ることができる．ChiDistributionは，NoncentralChiSquareDistributionの変換として得ることができ，GammaDistribution，NormalDistribution，HalfNormalDistributionとも密接に関係している．

例題

すべて開く すべて閉じる

例  (4)

確率密度関数：

Wolfram Language code: Plot[Table[PDF[ChiDistribution[ν], x], {ν, {.5, 1, 4}}]//Evaluate, {x, 0, 4}, Filling -> Axis]
Wolfram Language code: PDF[ChiDistribution[ν], x]

累積分布関数：

Wolfram Language code: Plot[Table[CDF[ChiDistribution[ν], x], {ν, {.5, 1, 4}}]//Evaluate, {x, 0, 4}, Filling -> Axis]
Wolfram Language code: CDF[ChiDistribution[ν], x]

カイ分布の平均と分散はGamma関数に関連している：

Wolfram Language code: Mean[ChiDistribution[ν]]
Wolfram Language code: Variance[ChiDistribution[ν]]

中央値：

Wolfram Language code: Median[ChiDistribution[ν]]

スコープ  (8)

カイ分布から擬似乱数のサンプルを生成する：

Wolfram Language code: data = RandomVariate[ChiDistribution[3], 10 ^ 4];

このヒストグラムを確率密度関数と比較する：

Wolfram Language code: Show[ Histogram[data, 20, "PDF"], Plot[PDF[ChiDistribution[3], x], {x, 0, 5}, PlotStyle -> Thick]]

分布母数推定：

Wolfram Language code: sample = RandomVariate[ChiDistribution[7], 10 ^ 3];

サンプルデータから分布母数を推定する：

Wolfram Language code: edist = EstimatedDistribution[sample, ChiDistribution[ν]]

サンプルの密度ヒストグラムを推定分布の確率密度関数と比較する：

Wolfram Language code: Show[Histogram[sample, Automatic, "PDF"], Plot[PDF[edist, x], {x, 0, 5}, PlotStyle -> Thick]]

歪度：

Wolfram Language code: Plot[Skewness[ChiDistribution[ν]], {ν, 0, 10}]
Wolfram Language code: Skewness[ChiDistribution[ν]]

極限ではカイ分布は対称になる：

Wolfram Language code: Limit[Skewness[ChiDistribution[ν]], ν -> ∞]

尖度：

Wolfram Language code: Plot[Kurtosis[ChiDistribution[ν]], {ν, 0, 10}]
Wolfram Language code: Kurtosis[ChiDistribution[ν]]

極限ではカイ分布の尖度はNormalDistributionの尖度と同じになる：

Wolfram Language code: Limit[Kurtosis[ChiDistribution[ν]], ν -> ∞]

母数の関数としての閉じた形の種々のモーメント：

Wolfram Language code: FormulaGrid[list_, type_] := Grid[...]

Moment：

Wolfram Language code: FormulaGrid[Table[Moment[ChiDistribution[ν], k], {k, 5}], M]

記号次数の閉じた形：

Wolfram Language code: Moment[ChiDistribution[ν], r]

CentralMoment：

Wolfram Language code: FormulaGrid[Table[CentralMoment[ChiDistribution[ν], k]//FullSimplify, {k, 5}], CM]

FactorialMoment：

Wolfram Language code: FormulaGrid[Table[FactorialMoment[ChiDistribution[ν], k]//FullSimplify, {k, 5}], FM]

Cumulant：

Wolfram Language code: FormulaGrid[Table[Cumulant[ChiDistribution[ν], k]//FullSimplify, {k, 5}], C]

ハザード関数：

Wolfram Language code: Plot[Table[HazardFunction[ChiDistribution[ν], x], {ν, {1, 5, 10}}]//Evaluate, {x, 0, 5}, Filling -> Axis]
Wolfram Language code: HazardFunction[ChiDistribution[ν], x]

分位関数：

Wolfram Language code: Plot[Table[Quantile[ChiDistribution[ν], q], {ν, {2, 5, 10}}]//Evaluate, {q, 0, 1}, Filling -> Axis]
Wolfram Language code: Quantile[ChiDistribution[ν], q]

無次元Quantityを使って自由度母数 ν を指定する：

Wolfram Language code: ChiDistribution[Quantity[3, "dozens"]]

アプリケーション  (1)

4Dベクトルの構成要素は正規分布に従う．ベクトルの長さの分布を求める：

Wolfram Language code: 𝒟 = TransformedDistribution[Norm[{u, v, w, z}], {u, v, w, z}ProductDistribution[{NormalDistribution[Quantity[0, "Centimeters"], Quantity[1, "Centimeters"]], 4}]]
Wolfram Language code: Plot[PDF[𝒟, Quantity[x, "Centimeters"]], {x, 0, 5}, Filling -> Axis, AxesLabel -> {"cm"}]

ベクトルの平均長を求める：

Wolfram Language code: Mean[𝒟]

30のベクトルのサンプルが取り得る長さのシミュレーションを行う：

Wolfram Language code: ListPlot[{RandomVariate[𝒟, 30], {{0, Mean[𝒟]}, {30, Mean[𝒟]}}}, Joined -> {False, True}, Filling -> Axis, AxesLabel -> Automatic]

特性と関係  (8)

ChiDistribution[ν]は ν->∞で正規分布に収束する：

Wolfram Language code: {μ, σ} = {Mean[ChiDistribution[ν]], StandardDeviation[ChiDistribution[ν]]}
Wolfram Language code: Table[Plot[{PDF[ChiDistribution[ν], x], PDF[NormalDistribution[μ, σ], x]}, {x, μ - 2σ, μ + 2σ}, AxesOrigin -> {μ - 3σ, 0}, Ticks -> {{{μ - 2σ, HoldForm[μ - 2σ]}, {μ, HoldForm[μ]}, {μ + 2σ, HoldForm[μ + 2σ]}}, Automatic}, PlotLabel -> ν], {ν, {5, 10, 25, 100}}]

他の分布との関係：

カイ変数の二乗はChiSquareDistributionに従う：

Wolfram Language code: TransformedDistribution[u ^ 2, uChiDistribution[ν]]

のカイ分布は のHalfNormalDistributionに等しい：

Wolfram Language code: PDF[ChiDistribution[1], x]
Wolfram Language code: PDF[HalfNormalDistribution[Sqrt[π / 2]], x]
Wolfram Language code: % - %%

のカイ分布はのRayleighDistributionに等しい：

Wolfram Language code: PDF[ChiDistribution[2], x]
Wolfram Language code: PDF[RayleighDistribution[1], x]
Wolfram Language code: % - %%

のカイ分布は のMaxwellDistributionに等しい：

Wolfram Language code: PDF[ChiDistribution[3], x]
Wolfram Language code: PDF[MaxwellDistribution[1], x]
Wolfram Language code: % - %%

カイ分布はGammaDistributionの特殊ケースである：

Wolfram Language code: PDF[GammaDistribution[1 / 2 ν, Sqrt[2], 2, 0], x]
Wolfram Language code: PDF[ChiDistribution[ν], x]
Wolfram Language code: % - %%//Simplify

個の標準正規分布に従う変数のノルムはカイ分布に従う：

Wolfram Language code: TransformedDistribution[Norm[{x, y, z}], {x, y, z}ProductDistribution[{NormalDistribution[], 3}]]

考えられる問題  (2)

ChiDistributionは，ν が正の実数でない場合は定義されない：

Wolfram Language code: Mean[ChiDistribution[-3]]

記号出力に無効な母数値を代入すると意味のない結果となる：

Wolfram Language code: Mean[ChiDistribution[ν]] /. {ν -> I}

おもしろい例題  (1)

累積分布関数の等高線を持つ ν のさまざまな値についての確率密度関数：

Wolfram Language code: cdf = Function[{x, ν}, Evaluate[CDF[ChiDistribution[ν], x]]]; ql = {0.025, 0.10, 0.25, 0.5, 0.75, 0.90, 0.975}; cl = Table[ColorData["Rainbow"][q], {q, Join[{0.0}, ql]}];
Wolfram Language code: Legended[Plot3D[PDF[ChiDistribution[ν], x], {x, 0, 3}, {ν, 1, 5}, PlotTheme -> "Marketing", MeshFunctions -> {cdf}, Mesh -> {ql}, MeshStyle -> GrayLevel[0.8], MeshShading -> cl, AxesLabel -> Automatic, PlotPoints -> 100, BaseStyle -> Opacity[0.9], ImageSize -> 400, PlotRange -> {0, 0.8}], BarLegend["Rainbow", ql, LegendLabel -> "prob"]]
Wolfram Research (2007), ChiDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/ChiDistribution.html （2016年に更新）.

テキスト

Wolfram Research (2007), ChiDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/ChiDistribution.html （2016年に更新）.

CMS

Wolfram Language. 2007. "ChiDistribution." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2016. https://reference.wolfram.com/language/ref/ChiDistribution.html.

APA

Wolfram Language. (2007). ChiDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ChiDistribution.html

BibTeX

@misc{reference.wolfram_2026_chidistribution, author="Wolfram Research", title="{ChiDistribution}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/ChiDistribution.html}", note=[Accessed: 11-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_chidistribution, organization={Wolfram Research}, title={ChiDistribution}, year={2016}, url={https://reference.wolfram.com/language/ref/ChiDistribution.html}, note=[Accessed: 11-September-2026]}