Wolfram 语言与系统参考资料中心

ChiDistribution

ChiDistribution[ν]

表示一个自由度为 ν 的分布.

背景

ChiDistribution[ν] 表示了一个参数为正值 ν 的统计分布：分布，参数表示分布的自由度. ν 决定了分布的概率密度函数（PDF）的一般形状，根据 ν 的值，PDF 可能是单调递减的也可能是有单个“山峰”（即一个绝对最大值）而在定义域下界附近有潜在奇点的形状.
ChiDistribution 是卡方随机变量的平方根的分布. 换句话说，若是一个随机变量且（其中读作“的分布是”），那么 . 由一组标准正态分布的独立随机变量 , , …, 构成的向量的范数也服从自由度为的卡方分布. 除了统计显著性之外，分布也出现在许多科学应用中，包括理想气体的速度分布，在各种条件下子弹的准确性，以及雷达在流体色散中的效果.
RandomVariate 可被用于给出分布的一个或多个机器精度或任意精度（后者可用 WorkingPrecision 选项指定）的伪随机变量. Distributed[x,ChiDistribution[ν]]，更简洁的写法是 xChiDistribution[ν]，可被用于声明随机变量 x 是分布的. 这样一个声明之后可用在如 Probability、NProbability、Expectation 以及 NExpectation 这样的函数中.
概率密度函数和累积分布函数可用 PDF[ChiDistribution[ν],x] 和 CDF[ChiDistribution[ν],x] 求得. 平均数、中位数、方差、原点矩及中心矩可分别用 Mean、Median、Variance、Moment 和 CentralMoment 计算.
DistributionFitTest 可被用于测试给定的数据集是否与分布一致，EstimatedDistribution 可被用于根据给定数据估算参数化分布，而 FindDistributionParameters 可拟合数据和分布. ProbabilityPlot 可被用于生成给定数据的 CDF 相对于符号分布的 CDF 的图线，而 QuantilePlot 可被用于生成给定数据的分位数相对于符号分布的分位数的图线.
TransformedDistribution 可被用于表示转换的分布，CensoredDistribution 可被用于表示删截后位于上限值和下限值之间的值分布，而 TruncatedDistribution 可被用于表示截断后位于上限值和下限值之间的值分布. CopulaDistribution 可被用于建立包含了分布的高维分布，而 ProductDistribution 可被用于计算包括分布在内的，若干个独立分量的联合分布.
ChiDistribution 与许多其它分布密切相关. 例如，对和，ChiDistribution[η] 分别等价于 RayleighDistribution[η] 和 MaxwellDistribution[η]. 此外，ChiDistribution 可被看作是更一般的 NakagamiDistribution 的特例，意思是说若 XNakagamiDistribution[m,ω] 是一个独立随机变量，那么，其中 YChiDistribution[2m]. ChiDistribution 也可以从 NoncentralChiSquareDistribution 经过变换得到，它还和 GammaDistribution、NormalDistribution 及 HalfNormalDistribution 密切相关.

范例

打开所有单元关闭所有单元

基本范例 (4)

概率密度函数：

Wolfram Language code: Plot[Table[PDF[ChiDistribution[ν], x], {ν, {.5, 1, 4}}]//Evaluate, {x, 0, 4}, Filling -> Axis]

Wolfram Language code: PDF[ChiDistribution[ν], x]

累积分布函数：

Wolfram Language code: Plot[Table[CDF[ChiDistribution[ν], x], {ν, {.5, 1, 4}}]//Evaluate, {x, 0, 4}, Filling -> Axis]

Wolfram Language code: CDF[ChiDistribution[ν], x]

一个分布的均值和方差与 Gamma 函数有关：

Wolfram Language code: Mean[ChiDistribution[ν]]

Wolfram Language code: Variance[ChiDistribution[ν]]

中位数：

Wolfram Language code: Median[ChiDistribution[ν]]

范围 (8)

生成服从分布的伪随机数样本：

Wolfram Language code: data = RandomVariate[ChiDistribution[3], 10 ^ 4];

比较直方图和概率密度函数：

Wolfram Language code:

Show[
	Histogram[data, 20, "PDF"], 
	Plot[PDF[ChiDistribution[3], x], {x, 0, 5}, PlotStyle -> Thick]]

分布参数估计：

Wolfram Language code: sample = RandomVariate[ChiDistribution[7], 10 ^ 3];

从样本数据估计分布参数：

Wolfram Language code: edist = EstimatedDistribution[sample, ChiDistribution[ν]]

比较样本的密度直方图和估计分布的概率密度函数：

Wolfram Language code: Show[Histogram[sample, Automatic, "PDF"], Plot[PDF[edist, x], {x, 0, 5}, PlotStyle -> Thick]]

偏度：

Wolfram Language code: Plot[Skewness[ChiDistribution[ν]], {ν, 0, 10}]

Wolfram Language code: Skewness[ChiDistribution[ν]]

在极限时，分布变成对称的：

Wolfram Language code: Limit[Skewness[ChiDistribution[ν]], ν -> ∞]

峰度：

Wolfram Language code: Plot[Kurtosis[ChiDistribution[ν]], {ν, 0, 10}]

Wolfram Language code: Kurtosis[ChiDistribution[ν]]

在极限时，分布与 NormalDistribution 具有相同的峰度：

Wolfram Language code: Limit[Kurtosis[ChiDistribution[ν]], ν -> ∞]

以参数的函数形式表示不同矩的解析式：

Wolfram Language code: FormulaGrid[list_, type_] := Grid[...]

Moment：

Wolfram Language code: FormulaGrid[Table[Moment[ChiDistribution[ν], k], {k, 5}], M]

具有符号式阶数的解析式：

Wolfram Language code: Moment[ChiDistribution[ν], r]

CentralMoment：

Wolfram Language code: FormulaGrid[Table[CentralMoment[ChiDistribution[ν], k]//FullSimplify, {k, 5}], CM]

FactorialMoment：

Wolfram Language code: FormulaGrid[Table[FactorialMoment[ChiDistribution[ν], k]//FullSimplify, {k, 5}], FM]

Cumulant：

Wolfram Language code: FormulaGrid[Table[Cumulant[ChiDistribution[ν], k]//FullSimplify, {k, 5}], C]

风险函数：

Wolfram Language code: Plot[Table[HazardFunction[ChiDistribution[ν], x], {ν, {1, 5, 10}}]//Evaluate, {x, 0, 5}, Filling -> Axis]

Wolfram Language code: HazardFunction[ChiDistribution[ν], x]

分位数函数：

Wolfram Language code: Plot[Table[Quantile[ChiDistribution[ν], q], {ν, {2, 5, 10}}]//Evaluate, {q, 0, 1}, Filling -> Axis]

Wolfram Language code: Quantile[ChiDistribution[ν], q]

使用无量纲 Quantity 来指定自由度参数 ν：

Wolfram Language code: ChiDistribution[Quantity[3, "dozens"]]

应用 (1)

一个四维向量的各分量都服从正态分布. 求该向量长度的分布：

Wolfram Language code:

𝒟 = TransformedDistribution[Norm[{u, v, w, z}], {u, v, w, z}ProductDistribution[{NormalDistribution[Quantity[0, "Centimeters"], Quantity[1, "Centimeters"]], 4}]]

Wolfram Language code: Plot[PDF[𝒟, Quantity[x, "Centimeters"]], {x, 0, 5}, Filling -> Axis, AxesLabel -> {"cm"}]

求向量的平均长度：

Wolfram Language code: Mean[𝒟]

模拟由30个向量组成的样本的可能长度：

Wolfram Language code:

ListPlot[{RandomVariate[𝒟, 30], {{0, Mean[𝒟]}, {30, Mean[𝒟]}}}, Joined -> {False, True}, Filling -> Axis, AxesLabel -> Automatic]

属性和关系 (8)

当 ν->∞，ChiDistribution[ν] 收敛为一个正态分布：

Wolfram Language code: {μ, σ} = {Mean[ChiDistribution[ν]], StandardDeviation[ChiDistribution[ν]]}

Wolfram Language code:

Table[Plot[{PDF[ChiDistribution[ν], x], PDF[NormalDistribution[μ, σ], x]}, {x, μ - 2σ, μ + 2σ}, AxesOrigin -> {μ - 3σ, 0}, Ticks -> {{{μ - 2σ, HoldForm[μ - 2σ]}, {μ, HoldForm[μ]}, {μ + 2σ, HoldForm[μ + 2σ]}}, Automatic}, PlotLabel -> ν], {ν, {5, 10, 25, 100}}]

与其它分布的关系：

一个变量的平方服从 ChiSquareDistribution：

Wolfram Language code: TransformedDistribution[u ^ 2, uChiDistribution[ν]]

的分布等价于的 HalfNormalDistribution：

Wolfram Language code: PDF[ChiDistribution[1], x]

Wolfram Language code: PDF[HalfNormalDistribution[Sqrt[π / 2]], x]

Wolfram Language code: % - %%

的分布等价于的 RayleighDistribution：

Wolfram Language code: PDF[ChiDistribution[2], x]

Wolfram Language code: PDF[RayleighDistribution[1], x]

Wolfram Language code: % - %%

的分布等价于的 MaxwellDistribution：

Wolfram Language code: PDF[ChiDistribution[3], x]

Wolfram Language code: PDF[MaxwellDistribution[1], x]

Wolfram Language code: % - %%

分布是 GammaDistribution 的一个特例：

Wolfram Language code: PDF[GammaDistribution[1 / 2 ν, Sqrt[2], 2, 0], x]

Wolfram Language code: PDF[ChiDistribution[ν], x]

Wolfram Language code: % - %%//Simplify

个服从标准正态分布的变量的范数服从一个分布：

Wolfram Language code: TransformedDistribution[Norm[{x, y, z}], {x, y, z}ProductDistribution[{NormalDistribution[], 3}]]

可能存在的问题 (2)

当 ν 不是一个正实数时，ChiDistribution 是没有定义的：

Wolfram Language code: Mean[ChiDistribution[-3]]

把无效的参数代入符号式输出，所得到的结果没有意义：

Wolfram Language code: Mean[ChiDistribution[ν]] /. {ν -> I}

巧妙范例 (1)

取不同 ν 值时的概率密度函数与累积分布函数等高图：

Wolfram Language code:

cdf = Function[{x, ν}, Evaluate[CDF[ChiDistribution[ν], x]]];
ql = {0.025, 0.10, 0.25, 0.5, 0.75, 0.90, 0.975};
cl = Table[ColorData["Rainbow"][q], {q, Join[{0.0}, ql]}];

Wolfram Language code:

Legended[Plot3D[PDF[ChiDistribution[ν], x], {x, 0, 3}, {ν, 1, 5}, PlotTheme -> "Marketing", MeshFunctions -> {cdf}, Mesh -> {ql}, MeshStyle -> GrayLevel[0.8], MeshShading -> cl, AxesLabel -> Automatic, PlotPoints -> 100, BaseStyle -> Opacity[0.9], ImageSize -> 400, PlotRange -> {0, 0.8}], BarLegend["Rainbow", ql, LegendLabel -> "prob"]]

Top

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

ChiDistribution

更多信息

背景

范例

基本范例 (4)

范围 (8)

应用 (1)

属性和关系 (8)

可能存在的问题 (2)

巧妙范例 (1)

文本

CMS

APA

BibTeX

BibLaTeX

ChiDistribution

更多信息

背景

范例

基本范例 (4)

范围 (8)

应用 (1)

属性和关系 (8)

可能存在的问题 (2)

巧妙范例 (1)

参见

技术笔记

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX