WOLFRAM

Wolfram 语言与系统参考资料中心

ClusterClassify[data]

通过把数据划分为相似元素组成的分群，产生 ClassifierFunction[…].

ClusterClassify[data,n]

生成具有 n 个分群的 ClassifierFunction[…].

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
CriterionFunction  
FeatureExtractor  
FeatureNames  
Show More Show More
FeatureTypes  
Method  
MissingValueSynthesis  
PerformanceGoal  
RandomSeeding  
权值  
应用  
参见
技术笔记
相关指南
历史
按以下格式引用：

ClusterClassify

ClusterClassify[data]

通过把数据划分为相似元素组成的分群，产生 ClassifierFunction[…].

ClusterClassify[data,n]

生成具有 n 个分群的 ClassifierFunction[…].

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (3)

在某些数值数据上训练 ClassifierFunction:

Wolfram Language code: c = ClusterClassify[{-10, -9, -8, -7, 5, 6, 7, 8, 12}]

使用分类器函数对新未加标签范例分类：

Wolfram Language code: c[0]

对这个范例获得分类概率：

Wolfram Language code: c[0, "Probabilities"]

对多个实例分类：

Wolfram Language code: c[{-10, 0, 30}]

在区间 {-5,5} 上绘制两个不同类别的概率图:

Wolfram Language code: Plot[Values[c[x, "Probabilities"]], {x, -5, 5}]

通过要求类数为5，在某些颜色上训练 ClassifierFunction：

Wolfram Language code: SeedRandom[1234]; colors = RandomColor[70]
Wolfram Language code: c = ClusterClassify[colors, 5]

在某些未添加标签的数据上训练 ClassifierFunction：

Wolfram Language code: c["Red"]

按照类号收集元素：

Wolfram Language code: GatherBy[colors, c]

在某些字符串训练 ClassifierFunction：

Wolfram Language code: string = {"c", "a", "bb", "dddd", "uuu7uuu", "uuuuu4u", "u5uuuuu"};
Wolfram Language code: c = ClusterClassify[string]
Wolfram Language code: components = c[string]

按照类号收集元素：

Wolfram Language code: GatherBy[string, c]

范围  (11)

对实数分类：

Wolfram Language code: data = {-10, -9, -8, -7, 5, 6, 7, 8};
Wolfram Language code: c = ClusterClassify[data]
Wolfram Language code: c[data]

对向量分类：

Wolfram Language code: data = {{1.85, 1.85, 1.75, 1.6}, {0.2, 0.75, 0.1, 0.55}, {1.3, 1.9, 1.25, 1.7}, {0.25, 0.9, 0.3, 0.75}, {0.35, 0.05, 0.7, 0.35}, {0.8, 0.5, 0.7, 0.8}, {1.35, 1.45, 1.6, 1.4}, {0.75, 0.15, 0.7, 0.7}, {1.2, 1.6, 1.55, 1.5}, {1.55, 1.7, 1.95, 1.45}};
Wolfram Language code: c = ClusterClassify[data]
Wolfram Language code: c[data]

对布尔向量分类：

Wolfram Language code: SeedRandom[123]; tfdata = RandomChoice[{True, False}, {20, 3}]
Wolfram Language code: c = ClusterClassify[tfdata]

使用分类器将分群赋予新布尔 True、False 向量：

Wolfram Language code: c[{False, False, False}]

使用分类器对分群赋予布尔 1, 0 向量：

Wolfram Language code: c[{0, 1, 0}]

查看概率：

Wolfram Language code: c[{{False, False, False}, {0, 1, 0}}, "Probabilities"]

对图像分类：

Wolfram Language code: images = {[image], [image], [image], [image], [image], [image]};
Wolfram Language code: c = ClusterClassify[images, 4]
Wolfram Language code: Pick[images, c[images], #]& /@ Range[4]

使用分类器对新图像分群：

Wolfram Language code: newimages = {[image], [image], [image], [image]};
Wolfram Language code: c[newimages]

对三维图像分类：

Wolfram Language code: images3D = Join[Image3D /@ RandomReal[3, {3, 5, 5, 10, 2}], Image3D /@ RandomReal[1, {3, 5, 5, 3, 2}]]
Wolfram Language code: c = ClusterClassify[images3D]
Wolfram Language code: Pick[images3D, c[images3D], #]& /@ Range[2]

对颜色分类：

Wolfram Language code: SeedRandom[1234]; colors = RandomColor[20]
Wolfram Language code: c = ClusterClassify[colors, 3]
Wolfram Language code: c[colors]

对字符串分类：

Wolfram Language code: strings = DictionaryLookup["c" ~~ ___];
Wolfram Language code: c = ClusterClassify[strings, 10]

使用分类器对新字符串分群：

Wolfram Language code: SeedRandom[1234]; newstrings = RandomSample[DictionaryLookup["a" ~~ ___], 30];
Wolfram Language code: GatherBy[newstrings, c]

对异构数据进行分类：

Wolfram Language code: SeedRandom[123]; data = Transpose[{RandomColor[30], RandomSample[DictionaryLookup["a" ~~ ___], 30]}]
Wolfram Language code: c = ClusterClassify[data, UpTo@3, Method -> "Spectral"]
Wolfram Language code: GatherBy[data, c]

对时间分类：

Wolfram Language code: SeedRandom[1234]; data = TimeObject /@ RandomReal[AbsoluteTime[]//Round, 40]
Wolfram Language code: c = ClusterClassify[data, 5]

使用分类器对数据分群：

Wolfram Language code: Pick[data, c[data], #]& /@ Range[5]

对随机实数分类：

Wolfram Language code: SeedRandom[1234]; data = Join[RandomReal[{-1, 1}, 20], RandomReal[{3, 4}, 20]];
Wolfram Language code: c = ClusterClassify[data]

查看分类器信息：

Wolfram Language code: Information[c]

获得使用的特定方法的描述：

Wolfram Language code: Information[c, "MethodDescription"]

产生平面上的随机点并且可视化：

Wolfram Language code: SeedRandom[1234]; data = Join[RandomReal[{-1, 1}, {80, 2}], RandomReal[{2, 4}, {80, 2}]]; ListPlot[data]

对数据分类：

Wolfram Language code: c = ClusterClassify[data]

在该位置上的新随机点分类：

Wolfram Language code: SeedRandom[1234]; datatest = RandomReal[{-1, 4}, {2000, 2}]; decision = c[datatest];

可视化所得分群：

Wolfram Language code: ListPlot[Pick[datatest, decision, #]& /@ {1, 2}]

使用 IndeterminateThreshold 对相同检验数据分类：

Wolfram Language code: decision2 = c[datatest, IndeterminateThreshold -> 0.9];

可视化包含 Indeterminate 分群的所得分群：

Wolfram Language code: ListPlot[Pick[datatest, decision2, #]& /@ {1, 2, Indeterminate}]

选项  (10)

CriterionFunction  (1)

产生某些分隔数据，并且可视化它：

Wolfram Language code: circle[r_, theta_] := {r Sin[theta], r Cos[theta]}; points = RandomVariate[MixtureDistribution[{1, 1}, {UniformDistribution[{{3 / 2, 2}, {0, 2 Pi}}], UniformDistribution[{{0, 1 / 2}, {0, 2 Pi}}]}], 1000]; data = circle@@@points; ListPlot[data, PlotRange -> All]

使用 Automatic CriterionFunction 构建分类器函数：

Wolfram Language code: c = ClusterClassify[data]

使用 Calinski–Harabasz 指数作为 CriterionFunction 构建分类器：

Wolfram Language code: d = ClusterClassify[data, CriterionFunction -> "CalinskiHarabasz"]

比较数据的两个分群：

Wolfram Language code: ListPlot[GroupBy[data, ToString @* c]]
Wolfram Language code: ListPlot[GroupBy[data, ToString @* d]]

FeatureExtractor  (1)

根据图像列表创建 ClassifierFunction，并对新实例进行分类：

Wolfram Language code: flowers = {[image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image]};
Wolfram Language code: c = ClusterClassify[flowers, 3]
Wolfram Language code: c[{[image], [image], [image], [image]}]

创建一个自定义 FeatureExtractor 来提取特征：

Wolfram Language code: fe = FeatureExtraction[flowers, (DominantColors[#, 1]&)]
Wolfram Language code: d = ClusterClassify[flowers, 3, FeatureExtractor -> fe]
Wolfram Language code: GatherBy[flowers, d]

FeatureNames  (1)

产生一个分类器函数，并为每个特征命名：

Wolfram Language code: c = ClusterClassify[{{2.3, "male"}, {4.8, "male"}, {9, "female"}, {5.2, "female"}, {1, "male"}, {10, "male"}, {5, "female"}}, FeatureNames -> {"age", "gender"}]

用关联的形式把分群分配给新的样本：

Wolfram Language code: c[<|"age" -> 3, "gender" -> "male"|>]

也可以使用列表的形式：

Wolfram Language code: c[{3, "male"}]

FeatureTypes  (1)

假定数据为数值型并属于标称特征类型，生成一个分类器函数：

Wolfram Language code: c = ClusterClassify[{{2.3, "male"}, {4.8, "male"}, {9, "female"}, {5.2, "female"}, {1, "male"}, {10, "male"}, {5, "female"}}, FeatureTypes -> {"Numerical", "Nominal"}]

假定数据为标称特征类型，生成一个分类器函数：

Wolfram Language code: d = ClusterClassify[{{2.3, "male"}, {4.8, "male"}, {9, "female"}, {5.2, "female"}, {1, "male"}, {10, "male"}, {5, "female"}}, FeatureTypes -> {"Nominal", "Nominal"}]

比较新实例的结果：

Wolfram Language code: {c[{3, " male"}], d[{3, "male"}]}

Method  (2)

使用均匀分布产生某些数据：

Wolfram Language code: SeedRandom[1234]; Dis = MixtureDistribution[{2, 2}, {UniformDistribution[{{-3, 3}, {-1, 0}}], UniformDistribution[{{-3, 3}, { 2, 3}}]}]; data = RandomVariate[Dis, 1000]; ListPlot[data, PlotRange -> All]

对数据分类：

Wolfram Language code: c = ClusterClassify[data]

用 Information 来获取方法的说明信息：

Wolfram Language code: Information[c, "MethodDescription"]

查看分群数据：

Wolfram Language code: ListPlot[Pick[data, c[data], #]& /@ {1, 2}]

使用 K 均值对数据分类：

Wolfram Language code: c = ClusterClassify[data, 2, Method -> "KMeans"]

查看分群数据：

Wolfram Language code: ListPlot[Pick[data, c[data], #]& /@ {1, 2}]

使用多正态分布产生大数据集，并且可视化：

Wolfram Language code: Dis = MixtureDistribution[{1, 1, 1, 1}, { MultinormalDistribution[{-1, -5}, {{2, 0}, {0, 2}}], MultinormalDistribution[{-7, 1}, {{2, 0}, {0, 2}}], MultinormalDistribution[{2, 7}, {{1, 0}, {0, .2}}], MultinormalDistribution[{5, -20}, {{2, 0}, {0, 2}}]}]; data = RandomVariate[Dis, 70000]; ListPlot[data, PlotRange -> All]

使用 ClusterClassify 通过指定使用的方法查找分群，并且查看 AbsoluteTiming:

Wolfram Language code: {t, c} = ClusterClassify[data, 4, Method -> "KMedoids"]//AbsoluteTiming

查看所得分群：

Wolfram Language code: ListPlot[Pick[data, c[data], #]& /@ Range[4]]

使用 ClusterClassify 查找分群，而不用指定使用的方法，并且查看 AbsoluteTiming:

Wolfram Language code: c = ClusterClassify[data, 4]//AbsoluteTiming

MissingValueSynthesis  (1)

用多元正态分布生成大型数据集并可视化：

Wolfram Language code: Dis = MixtureDistribution[{1, 1, 1, 1}, { MultinormalDistribution[{-1, -5}, {{2, 0}, {0, 2}}], MultinormalDistribution[{-7, 1}, {{2, 0}, {0, 2}}], MultinormalDistribution[{2, 7}, {{1, 0}, {0, .2}}], MultinormalDistribution[{5, -20}, {{2, 0}, {0, 2}}]}]; data = RandomVariate[Dis, 70000]; ListPlot[data, PlotRange -> All]

用 ClusterClassify 求聚类：

Wolfram Language code: c = ClusterClassify[data, 4, Method -> "KMedoids"]

获取缺失数据点的最高聚类概率：

Wolfram Language code: c[{-3, Missing[]}, "TopProbabilities"]

设置缺失值合成，如果有已知的值，则用估计的最可能的值替换每个缺失变量（这是默认行为）：

Wolfram Language code: c[{-3, Missing[]}, "TopProbabilities", MissingValueSynthesis -> "ModeFinding"]

用已知值的随机样本替换缺失的变量：

Wolfram Language code: c[{-3, Missing[]}, "TopProbabilities", MissingValueSynthesis -> "RandomSampling"]

用随机采样策略重复替换缺失变量，获取该点可能聚类的分布：

Wolfram Language code: Counts[Table[c[{-3, Missing[]}, MissingValueSynthesis -> "RandomSampling"], 100]]

PerformanceGoal  (1)

产生均匀分布的数据集，并且可视化：

Wolfram Language code: data = Join[RandomReal[{-1 / 5, 0}, {2000, 3}], RandomReal[{0, 1 / 5}, {2000, 3}]]; ListPointPlot3D[data, PlotRange -> All]

从数据获得分类器，强调训练速度：

Wolfram Language code: {t, d} = ClusterClassify[data, PerformanceGoal -> "TrainingSpeed"]//AbsoluteTiming

对某些随机产生的数据分群，并且查看 AbsoluteTiming:

Wolfram Language code: datatest = RandomReal[{-1 / 2, 1 / 2}, {50000, 3}];
Wolfram Language code: d[datatest];//AbsoluteTiming

从该数据获得分类器，并且强调速度：

Wolfram Language code: {t, c} = ClusterClassify[data, PerformanceGoal -> "Speed"]//AbsoluteTiming

对某些随机产生的数据分群，并且查看 AbsoluteTiming 与上面比较：

Wolfram Language code: c[datatest];//AbsoluteTiming

可视化检验数据的两个分群，并且注意设置 "TrainingSpeed" 如何给出更好的结果：

Wolfram Language code: ListPointPlot3D[Pick[datatest, d[datatest], #]& /@ Range[2]]
Wolfram Language code: ListPointPlot3D[Pick[datatest, c[datatest], #]& /@ Range[2]]

RandomSeeding  (1)

在随机颜色上训练几个分类器：

Wolfram Language code: colors = RandomColor[20]
Wolfram Language code: classifiers = Table[ClusterClassify[colors, 3], 5];

计算新颜色的分类器，并观察结果总是相同的：

Wolfram Language code: #[RGBColor[0.18410183842296557, 0.8929803114282151, 0.139771903636146]]& /@ classifiers

通过使用 RandomSeeding 选项的不同值来对相同颜色上的几个分类器进行训练：

Wolfram Language code: newclassifiers = Table[ClusterClassify[colors, 3, RandomSeeding -> RandomInteger[20]], 5];

计算 的分类器，并观察分类器的不同之处：

Wolfram Language code: #[RGBColor[0.18410183842296557, 0.8929803114282151, 0.139771903636146]]& /@ newclassifiers

权值  (1)

产生某些包含异常值的分开的数据：

Wolfram Language code: data = Join[ Range[0, 5, 0.05], Range[25, 30, 0.05], {90}];
Wolfram Language code: Histogram[data]

将数据分群：

Wolfram Language code: c = ClusterClassify[data]

使用分类器函数，将异常值与另一个点一起分类：

Wolfram Language code: c[{20, 90}]

对数据分群，在异常点上添加大的权值：

Wolfram Language code: weights = Append[ConstantArray[1, Length[data] - 1], 300]; c = ClusterClassify[data, Weights -> weights]

使用分类器函数对相同点分类：

Wolfram Language code: c[{20, 90}]

应用  (3)

在小的正态分布数据集上训练某些分类器：

Wolfram Language code: SeedRandom[1234]; dataset = RandomReal[{-.5, .5}, {500, 2}]; dataset = Select[dataset, #[[1]] > #[[2]]&];
Wolfram Language code: classifiers = Table[ClusterClassify[dataset, n, Method -> "KMedoids"], {n, 16}];

通过使用大量正态分布随机点上的分类器，将三角形分成各个部分：

Wolfram Language code: data = RandomReal[{-.5, .5}, {10 ^ 4, 2}]; data = Select[data, #[[1]] > #[[2]]&];
Wolfram Language code: plots = Table[ListPlot[Pick[data, (classifiers[[n]])[data], #]& /@ Range[n], AspectRatio -> 1, Frame -> True, Axes -> False, FrameTicks -> None], {n, 16}];
Wolfram Language code: GraphicsGrid[Partition[plots, 4], ImageSize -> Medium]

产生某些正态分布数据：

Wolfram Language code: SeedRandom[1234]; 𝒟 = MixtureDistribution[{1, 1, 0.5}, { MultinormalDistribution[{-1, -5}, {{2, 0}, {0, 2}}], MultinormalDistribution[{-7, 1}, {{2, 0}, {0, 2}}], MultinormalDistribution[{2, 7}, {{2, 0}, {0, 2}}]}]; data = RandomVariate[𝒟, 2000]; ListPlot[data, PlotRange -> All]

不指定类的数目，对数据分群：

Wolfram Language code: cl = ClusterClassify[data]
Wolfram Language code: ListPlot[Pick[data, cl[data], #]& /@ {1, 2, 3}]

指定类的数目，对数据分群：

Wolfram Language code: c2 = ClusterClassify[data, 3]
Wolfram Language code: ListPlot[Pick[data, Flatten[c2[data]], #]& /@ {1, 2, 3}]

在图像中求主导颜色：

Wolfram Language code: image = [image]; imageData = Flatten[ImageData[ColorConvert[image, "LAB"]], 1];

对按照图像像素值的数组给出的数据分类：

Wolfram Language code: c = ClusterClassify[imageData, 4, Method -> "KMedoids"];

使用分类器对每个像素分群：

Wolfram Language code: decision = c[imageData];

使用分类器函数求四个主导颜色：

Wolfram Language code: LABColor@@@(Mean /@ (Pick[imageData, decision, #]& /@ Range[4]))

使用分类器获取每个主导颜色的二值掩模（mask）：

Wolfram Language code: Image /@ ComponentMeasurements[{image, Partition[decision, 426]}, "Mask"][[All, 2]]
Wolfram Research (2016)，ClusterClassify，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ClusterClassify.html （更新于 2020 年）.

文本

Wolfram Research (2016)，ClusterClassify，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ClusterClassify.html （更新于 2020 年）.

CMS

Wolfram 语言. 2016. "ClusterClassify." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2020. https://reference.wolfram.com/language/ref/ClusterClassify.html.

APA

Wolfram 语言. (2016). ClusterClassify. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ClusterClassify.html 年

BibTeX

@misc{reference.wolfram_2026_clusterclassify, author="Wolfram Research", title="{ClusterClassify}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/ClusterClassify.html}", note=[Accessed: 07-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_clusterclassify, organization={Wolfram Research}, title={ClusterClassify}, year={2020}, url={https://reference.wolfram.com/language/ref/ClusterClassify.html}, note=[Accessed: 07-September-2026]}