WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Dendrogram[{e1,e2,…}]

要素 e1, e2, …の階層的クラスタ化から系統樹を構築する．

Dendrogram[{e1v1,e2v2,…}]

構築された系統樹の viを伴う eiを表す．

Dendrogram[{e1,e2,…}{v1,v2,…}]

構築された系統樹の viを伴う eiを表す．

Dendrogram[label1e1,label2e2,…]

構築された系統樹の中でラベル labeliを使って eiを表す．

Dendrogram[data,orientation]

orientation に従って方向性のある系統樹を構築する．

Dendrogram[tree]

重み付きツリー tree に対応する系統樹を構築する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
AspectRatio  
ClusterDissimilarityFunction  
DistanceFunction  
FeatureExtractor  
ImageSize  
アプリケーション  
関連項目
関連するガイド
履歴
引用書式

Dendrogram

Dendrogram[{e1,e2,…}]

要素 e1, e2, …の階層的クラスタ化から系統樹を構築する．

Dendrogram[{e1v1,e2v2,…}]

構築された系統樹の viを伴う eiを表す．

Dendrogram[{e1,e2,…}{v1,v2,…}]

構築された系統樹の viを伴う eiを表す．

Dendrogram[label1e1,label2e2,…]

構築された系統樹の中でラベル labeliを使って eiを表す．

Dendrogram[data,orientation]

orientation に従って方向性のある系統樹を構築する．

Dendrogram[tree]

重み付きツリー tree に対応する系統樹を構築する．

詳細とオプション

例題

すべて開く すべて閉じる

例  (4)

数のリストから系統樹を得る：

Wolfram Language code: Dendrogram[{1, 2, 5}]

重み付きツリーの系統樹を得る：

Wolfram Language code: graph = Graph[{1, 2, 3}, {1 -> 2, 1 -> 3}, VertexWeight -> {10, 0, 0}, VertexLabels -> "Name"]
Wolfram Language code: Dendrogram[graph]

都市のリストから系統樹を得，左側にラベルを置く：

Wolfram Language code: Dendrogram[{Entity["City", {"Paris", "IleDeFrance", "France"}], Entity["City", {"Sydney", "NewSouthWales", "Australia"}], Entity["City", {"Boston", "Massachusetts", "UnitedStates"}], Entity["City", {"SanFrancisco", "California", "UnitedStates"}]}, Left]

ブール値のリストからクラスタ階層を得る：

Wolfram Language code: Dendrogram[{{False, False, True}, {True, True, False}, {False, True, True}, {False, False, False}}]

スコープ  (7)

色のリストから系統樹を得，左に表示する：

Wolfram Language code: Dendrogram[{RGBColor[0.3882530591983919, 0.2972372289203644, 0.14662872236042124], RGBColor[0.3134110772018093, 0.6577487501778145, 0.7061181487042973], RGBColor[0.31684543929904985, 0.32154575812724917, 0.8496239355766027], RGBColor[0.5443420548178017, 0.4583234220657759, 0.8094937667804043], RGBColor[0.4274650545373566, 0.9072941688093845, 0.898117681435409], RGBColor[0.9323469092538643, 0.8301659871869203, 0.4534352919547222], RGBColor[0.7518445360980579, 0.05631287374652039, 0.6430690822523268], RGBColor[0.5197739285846861, 0.5456615504221027, 0.8065756552586965], RGBColor[0.41433011753391313, 0.0998327927406264, 0.8070954046302512]}, Left]

DendrogramをClusteringTreeの結果に適用した結果と比較する：

Wolfram Language code: c = ClusteringTree[{RGBColor[0.3882530591983919, 0.2972372289203644, 0.14662872236042124], RGBColor[0.3134110772018093, 0.6577487501778145, 0.7061181487042973], RGBColor[0.31684543929904985, 0.32154575812724917, 0.8496239355766027], RGBColor[0.5443420548178017, 0.4583234220657759, 0.8094937667804043], RGBColor[0.4274650545373566, 0.9072941688093845, 0.898117681435409], RGBColor[0.9323469092538643, 0.8301659871869203, 0.4534352919547222], RGBColor[0.7518445360980579, 0.05631287374652039, 0.6430690822523268], RGBColor[0.5197739285846861, 0.5456615504221027, 0.8065756552586965], RGBColor[0.41433011753391313, 0.0998327927406264, 0.8070954046302512]}];
Wolfram Language code: Dendrogram[c, Left]

非同次データ集合から系統樹を得る：

Wolfram Language code: data = {{RGBColor[0.3882530591983919, 0.2972372289203644, 0.14662872236042124], "brown"}, {RGBColor[0.3134110772018093, 0.6577487501778145, 0.7061181487042973], "light blue"}, {RGBColor[0.31684543929904985, 0.32154575812724917, 0.8496239355766027], "blue"}, {RGBColor[0.5443420548178017, 0.4583234220657759, 0.8094937667804043], "violet"}, {RGBColor[0.4274650545373566, 0.9072941688093845, 0.898117681435409], "light blue"}, {RGBColor[0.9323469092538643, 0.8301659871869203, 0.4534352919547222], "yellow"}, {RGBColor[0.7518445360980579, 0.05631287374652039, 0.6430690822523268], "light violet"}};
Wolfram Language code: Dendrogram[data, Left]

この系統樹を色の系統樹と比較する：

Wolfram Language code: Dendrogram[data[[All, 1]], Left]

一連の実数乱数を生成する：

Wolfram Language code: r = RandomReal[1, 20];

丸められた実数によってラベルが与えられた系統樹を得る：

Wolfram Language code: Dendrogram[r -> Round[r, .1]]

Associationから系統樹を計算する：

Wolfram Language code: association = <|"this color is red" -> RGBColor[0.7355420127983632, 0.2464091158003272, 0.1318671396857256], "this color is blue" -> RGBColor[0.19595271830233885, 0.10998208611256777, 0.5195988419509086], "this color is pink" -> RGBColor[0.98714064424384, 0.4517971556938676, 0.7345757642205208], "this color is yellow" -> RGBColor[0.914802573832932, 0.9472567075421043, 0.19573643015491093]|>;
Wolfram Language code: Dendrogram[association, Left]

これを，そのValuesの系統樹と比較する：

Wolfram Language code: Dendrogram[Values[association], Left]

そのKeysの系統樹と比較する：

Wolfram Language code: Dendrogram[Keys[association], Left]

数のリストから系統樹を生成する：

Wolfram Language code: data = Round[RandomReal[{1, 30}, 10], .1];
Wolfram Language code: Dendrogram[data]

軸を示してサブクラスタ間の距離を比較する：

Wolfram Language code: Dendrogram[data, Axes -> { False, True}, AxesOrigin -> {0, 0}]

ベクトルのリストから系統樹を生成する：

Wolfram Language code: data = N@RandomInteger[{0, 20}, {10, 5}];
Wolfram Language code: Dendrogram[data]

垂直ラベルを使って結果を表示する：

Wolfram Language code: Dendrogram[data -> (Rotate[ #, 3 Pi / 2]& /@ data)]

ベクトルをラベルに使ったArrayPlotで結果を表示する：

Wolfram Language code: Dendrogram[data -> (Rotate[ArrayPlot[{#}, ColorFunction -> "BlueGreenYellow"], 3 Pi / 2]& /@ data)]

画像のリストから系統樹を得る：

Wolfram Language code: l = {[image], [image], [image], [image], [image], [image], [image], [image]};
Wolfram Language code: Dendrogram[l, Right]

オプション  (13)

AspectRatio  (3)

デフォルトで，プロットの縦横比は自動的に決定される：

Wolfram Language code: Dendrogram[IconizedObject[«data»]]

AspectRatio1を使って縦と横を等しくする：

Wolfram Language code: Dendrogram[IconizedObject[«data»], AspectRatio -> 1]

縦横比を指定する：

Wolfram Language code: Dendrogram[IconizedObject[«data»], AspectRatio -> 1 / 2]

ClusterDissimilarityFunction  (1)

ランダムな色のリストを生成する：

Wolfram Language code: data = RandomColor[30]

"Centroid"結合を使ってリストからクラスタ階層を得る：

Wolfram Language code: Dendrogram[data, ClusterDissimilarityFunction -> "Centroid"]

"Single"結合を使ってリストからクラスタ階層を得る：

Wolfram Language code: Dendrogram[data, ClusterDissimilarityFunction -> "Single"]

別の"ClusterDissimilarityFunction"を使ってリストからクラスタ階層を得る：

Wolfram Language code: Dendrogram[data, ClusterDissimilarityFunction -> (Max[#]&)]

DistanceFunction  (1)

ランダムなベクトルのリストを生成する：

Wolfram Language code: data = RandomReal[{10, 20}, {10, 2}];

自動的に選ばれたDistanceFunctionを使って系統樹を得， 軸をプロットする：

Wolfram Language code: Dendrogram[data, Axes -> {False, True}]

EuclideanDistanceを使って系統樹を得， 軸上の値を比較する：

Wolfram Language code: Dendrogram[data, DistanceFunction -> EuclideanDistance, Axes -> {False, True}]

別のDistanceFunctionを使って系統樹を得る：

Wolfram Language code: Dendrogram[data, DistanceFunction -> ManhattanDistance]
Wolfram Language code: Dendrogram[data, DistanceFunction -> ChessboardDistance]

FeatureExtractor  (1)

絵のリストの系統樹を得る：

Wolfram Language code: flowers = { [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image]};
Wolfram Language code: Dendrogram[flowers]

別のFeatureExtractorを使って特徴を抽出する：

Wolfram Language code: fe = FeatureExtraction[flowers, "ImageFeatures"]
Wolfram Language code: Dendrogram[flowers, FeatureExtractor -> fe]

Identity FeatureExtractorを使ってデータを変化させずにおく：

Wolfram Language code: Dendrogram[flowers, FeatureExtractor -> Identity]

ImageSize  (7)

Tiny，Small，Medium，Largeのような名前付きのサイズを使う：

Wolfram Language code: {Dendrogram[IconizedObject[«data»], ImageSize -> Tiny], Dendrogram[IconizedObject[«data»], ImageSize -> Small]}

プロットの幅を指定する：

Wolfram Language code: {Dendrogram[IconizedObject[«data»], ImageSize -> 150], Dendrogram[IconizedObject[«data»], AspectRatio -> 1.5, ImageSize -> 150]}

プロットの高さを指定する：

Wolfram Language code: {Dendrogram[IconizedObject[«data»], ImageSize -> {Automatic, 150}], Dendrogram[IconizedObject[«data»], AspectRatio -> 2, ImageSize -> {Automatic, 150}]}

特定のサイズまでの幅と高さを許容する：

Wolfram Language code: {Dendrogram[IconizedObject[«data»], ImageSize -> UpTo[200]], Dendrogram[IconizedObject[«data»], AspectRatio -> 2, ImageSize -> UpTo[200]]}

グラフィックスの幅と高さを指定して，必要であればスペースで充填する：

Wolfram Language code: Dendrogram[IconizedObject[«data»], ImageSize -> {200, 300}, Background -> LightBlue]

AspectRatioFullと設定すると，使用可能なスペースが塗り潰される：

Wolfram Language code: Dendrogram[IconizedObject[«data»], AspectRatio -> Full, ImageSize -> {200, 200}, Background -> LightBlue]

幅と高さに最大サイズを使う：

Wolfram Language code: {Dendrogram[IconizedObject[«data»], ImageSize -> {UpTo[150], UpTo[100]}], Dendrogram[IconizedObject[«data»], AspectRatio -> 2, ImageSize -> {UpTo[150], UpTo[100]}]}

ImageSizeFullを使ってオブジェクト内の使用可能なスペースを塗り潰す：

Wolfram Language code: Framed[Pane[Dendrogram[IconizedObject[«data»], ImageSize -> Full, Background -> LightBlue], {200, 100}]]

画像サイズを使用可能なスペースとの割合で指定する：

Wolfram Language code: Framed[Pane[Dendrogram[IconizedObject[«data»], AspectRatio -> Full, ImageSize -> {Scaled[0.5], Scaled[0.5]}, Background -> LightBlue], {200, 100}]]

アプリケーション  (1)

ランダムな色のリストを生成し，y 軸上の距離を使ってその系統樹を計算する：

Wolfram Language code: colors = {RGBColor[0.005205065918539198, 0.505430385626394, 0.5037170574409544], RGBColor[0.16523243233558582, 0.435798695033599, 0.006857194456336924], RGBColor[0.10448507405871288, 0.6798166859116166, 0.1566614433106035], RGBColor[0.22501876056775894, 0.2933626410500396, 0.11416198735334127], RGBColor[0.4222624701525557, 0.48149330236969345, 0.940230574165601], RGBColor[0.23162634358255763, 0.9202398461548127, 0.7752908257962525], RGBColor[0.5222836023306179, 0.20801120086103708, 0.5543480345610741], RGBColor[0.7501151268647552, 0.05746907232600429, 0.9059681239202162], RGBColor[0.6534431085562413, 0.5329943588860213, 0.9285215109733242], RGBColor[0.9143128324385004, 0.2569397145689536, 0.5777060976306343]};
Wolfram Language code: Dendrogram[colors, Axes -> {False, True}, AxesOrigin -> {0, 0}]

同じデータについて，距離が0.65未満のクラスタを統合することでClusteringTreeを計算する：

Wolfram Language code: g = ClusteringTree[colors, 0.65]

上のグラフのDendrogramを計算する：

Wolfram Language code: Dendrogram[g]

距離の閾値が上昇するとクラスタの統合がどのようになるかを可視化するManipulateを構築する：

Wolfram Language code: With[{colors = {RGBColor[0.005205065918539198, 0.505430385626394, 0.5037170574409544], RGBColor[0.16523243233558582, 0.435798695033599, 0.006857194456336924], RGBColor[0.10448507405871288, 0.6798166859116166, 0.1566614433106035], RGBColor[0.22501876056775894, 0.2933626410500396, 0.11416198735334127], RGBColor[0.4222624701525557, 0.48149330236969345, 0.940230574165601], RGBColor[0.23162634358255763, 0.9202398461548127, 0.7752908257962525], RGBColor[0.5222836023306179, 0.20801120086103708, 0.5543480345610741], RGBColor[0.7501151268647552, 0.05746907232600429, 0.9059681239202162], RGBColor[0.6534431085562413, 0.5329943588860213, 0.9285215109733242], RGBColor[0.9143128324385004, 0.2569397145689536, 0.5777060976306343]}}, Manipulate[Dendrogram[ClusteringTree[colors, h], Left], {h, 0, 1}] ]
Wolfram Research (2016), Dendrogram, Wolfram言語関数， https://reference.wolfram.com/language/ref/Dendrogram.html （2017年に更新）.

テキスト

Wolfram Research (2016), Dendrogram, Wolfram言語関数， https://reference.wolfram.com/language/ref/Dendrogram.html （2017年に更新）.

CMS

Wolfram Language. 2016. "Dendrogram." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2017. https://reference.wolfram.com/language/ref/Dendrogram.html.

APA

Wolfram Language. (2016). Dendrogram. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Dendrogram.html

BibTeX

@misc{reference.wolfram_2026_dendrogram, author="Wolfram Research", title="{Dendrogram}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/Dendrogram.html}", note=[Accessed: 10-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_dendrogram, organization={Wolfram Research}, title={Dendrogram}, year={2017}, url={https://reference.wolfram.com/language/ref/Dendrogram.html}, note=[Accessed: 10-September-2026]}