WOLFRAM

Wolfram 语言与系统参考资料中心

Dendrogram[{e1,e2,…}]

构建元素 e1、e2、…等的分级聚类的树状图.

Dendrogram[{e1v1,e2v2,…}]

在构建的树状图中用 vi 表示 ei.

Dendrogram[{e1,e2,…}{v1,v2,…}]

在构建的树状图中用 vi 表示 ei.

Dendrogram[label1e1,label2e2,…]

在构建的树状图中用标签 labeli 表示 ei.

Dendrogram[data,orientation]

根据 orientation 构建有向树状图.

Dendrogram[tree]

根据权重树 tree 构建树状图.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
AspectRatio  
ClusterDissimilarityFunction  
DistanceFunction  
FeatureExtractor  
ImageSize  
应用  
参见
相关指南
历史
按以下格式引用：

Dendrogram

Dendrogram[{e1,e2,…}]

构建元素 e1、e2、…等的分级聚类的树状图.

Dendrogram[{e1v1,e2v2,…}]

在构建的树状图中用 vi 表示 ei.

Dendrogram[{e1,e2,…}{v1,v2,…}]

在构建的树状图中用 vi 表示 ei.

Dendrogram[label1e1,label2e2,…]

在构建的树状图中用标签 labeli 表示 ei.

Dendrogram[data,orientation]

根据 orientation 构建有向树状图.

Dendrogram[tree]

根据权重树 tree 构建树状图.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (4)

从数字列表中获取树状图：

Wolfram Language code: Dendrogram[{1, 2, 5}]

从加权树获取树状图：

Wolfram Language code: graph = Graph[{1, 2, 3}, {1 -> 2, 1 -> 3}, VertexWeight -> {10, 0, 0}, VertexLabels -> "Name"]
Wolfram Language code: Dendrogram[graph]

从城市列表中获取树状图，并将标签置于左边：

Wolfram Language code: Dendrogram[{Entity["City", {"Paris", "IleDeFrance", "France"}], Entity["City", {"Sydney", "NewSouthWales", "Australia"}], Entity["City", {"Boston", "Massachusetts", "UnitedStates"}], Entity["City", {"SanFrancisco", "California", "UnitedStates"}]}, Left]

从布尔项列表中获取一个层次聚类：

Wolfram Language code: Dendrogram[{{False, False, True}, {True, True, False}, {False, True, True}, {False, False, False}}]

范围  (7)

从颜色列表中获取树状图，并将其置于左边：

Wolfram Language code: Dendrogram[{RGBColor[0.3882530591983919, 0.2972372289203644, 0.14662872236042124], RGBColor[0.3134110772018093, 0.6577487501778145, 0.7061181487042973], RGBColor[0.31684543929904985, 0.32154575812724917, 0.8496239355766027], RGBColor[0.5443420548178017, 0.4583234220657759, 0.8094937667804043], RGBColor[0.4274650545373566, 0.9072941688093845, 0.898117681435409], RGBColor[0.9323469092538643, 0.8301659871869203, 0.4534352919547222], RGBColor[0.7518445360980579, 0.05631287374652039, 0.6430690822523268], RGBColor[0.5197739285846861, 0.5456615504221027, 0.8065756552586965], RGBColor[0.41433011753391313, 0.0998327927406264, 0.8070954046302512]}, Left]

与 Dendrogram 应用于 ClusteringTree 的结果的结果比较：

Wolfram Language code: c = ClusteringTree[{RGBColor[0.3882530591983919, 0.2972372289203644, 0.14662872236042124], RGBColor[0.3134110772018093, 0.6577487501778145, 0.7061181487042973], RGBColor[0.31684543929904985, 0.32154575812724917, 0.8496239355766027], RGBColor[0.5443420548178017, 0.4583234220657759, 0.8094937667804043], RGBColor[0.4274650545373566, 0.9072941688093845, 0.898117681435409], RGBColor[0.9323469092538643, 0.8301659871869203, 0.4534352919547222], RGBColor[0.7518445360980579, 0.05631287374652039, 0.6430690822523268], RGBColor[0.5197739285846861, 0.5456615504221027, 0.8065756552586965], RGBColor[0.41433011753391313, 0.0998327927406264, 0.8070954046302512]}];
Wolfram Language code: Dendrogram[c, Left]

从异构数据集中获取树形图：

Wolfram Language code: data = {{RGBColor[0.3882530591983919, 0.2972372289203644, 0.14662872236042124], "brown"}, {RGBColor[0.3134110772018093, 0.6577487501778145, 0.7061181487042973], "light blue"}, {RGBColor[0.31684543929904985, 0.32154575812724917, 0.8496239355766027], "blue"}, {RGBColor[0.5443420548178017, 0.4583234220657759, 0.8094937667804043], "violet"}, {RGBColor[0.4274650545373566, 0.9072941688093845, 0.898117681435409], "light blue"}, {RGBColor[0.9323469092538643, 0.8301659871869203, 0.4534352919547222], "yellow"}, {RGBColor[0.7518445360980579, 0.05631287374652039, 0.6430690822523268], "light violet"}};
Wolfram Language code: Dendrogram[data, Left]

与颜色的树形图相比较：

Wolfram Language code: Dendrogram[data[[All, 1]], Left]

生成一个随机实数的数列：

Wolfram Language code: r = RandomReal[1, 20];

根据舍入为整数的实数，获取一个带标签的树状图：

Wolfram Language code: Dendrogram[r -> Round[r, .1]]

从 Association 生成树状图：

Wolfram Language code: association = <|"this color is red" -> RGBColor[0.7355420127983632, 0.2464091158003272, 0.1318671396857256], "this color is blue" -> RGBColor[0.19595271830233885, 0.10998208611256777, 0.5195988419509086], "this color is pink" -> RGBColor[0.98714064424384, 0.4517971556938676, 0.7345757642205208], "this color is yellow" -> RGBColor[0.914802573832932, 0.9472567075421043, 0.19573643015491093]|>;
Wolfram Language code: Dendrogram[association, Left]

与根据其 Values 生成的树状图比较：

Wolfram Language code: Dendrogram[Values[association], Left]

与根据其 Keys 生成的树状图比较：

Wolfram Language code: Dendrogram[Keys[association], Left]

从数字列表中生成树状图：

Wolfram Language code: data = Round[RandomReal[{1, 30}, 10], .1];
Wolfram Language code: Dendrogram[data]

显示 轴，以便比较两个子聚类之间的距离：

Wolfram Language code: Dendrogram[data, Axes -> { False, True}, AxesOrigin -> {0, 0}]

从矢量列表中生成树状图：

Wolfram Language code: data = N@RandomInteger[{0, 20}, {10, 5}];
Wolfram Language code: Dendrogram[data]

使用垂直标签显示结果：

Wolfram Language code: Dendrogram[data -> (Rotate[ #, 3 Pi / 2]& /@ data)]

将矢量的 ArrayPlot 作为标签显示结果：

Wolfram Language code: Dendrogram[data -> (Rotate[ArrayPlot[{#}, ColorFunction -> "BlueGreenYellow"], 3 Pi / 2]& /@ data)]

从图像列表中获取树状图：

Wolfram Language code: l = {[image], [image], [image], [image], [image], [image], [image], [image]};
Wolfram Language code: Dendrogram[l, Right]

选项  (13)

AspectRatio  (3)

默认情况下，自动确定绘图的高宽比：

Wolfram Language code: Dendrogram[IconizedObject[«data»]]

设置 AspectRatio1 可使得宽和高一样：

Wolfram Language code: Dendrogram[IconizedObject[«data»], AspectRatio -> 1]

指定高宽比：

Wolfram Language code: Dendrogram[IconizedObject[«data»], AspectRatio -> 1 / 2]

ClusterDissimilarityFunction  (1)

生成随机颜色列表：

Wolfram Language code: data = RandomColor[30]

使用 "Centroid" 链接从列表中获取聚类层次结构：

Wolfram Language code: Dendrogram[data, ClusterDissimilarityFunction -> "Centroid"]

使用 "Single" 链接从列表中获取聚类层次结构：:

Wolfram Language code: Dendrogram[data, ClusterDissimilarityFunction -> "Single"]

使用不同的 "ClusterDissimilarityFunction" 从列表中获取聚类层次结构：

Wolfram Language code: Dendrogram[data, ClusterDissimilarityFunction -> (Max[#]&)]

DistanceFunction  (1)

生成随机矢量列表：

Wolfram Language code: data = RandomReal[{10, 20}, {10, 2}];

用自动选取的 DistanceFunction 获取树形图，并绘制 轴：

Wolfram Language code: Dendrogram[data, Axes -> {False, True}]

用 EuclideanDistance 获取树形图，并比较 轴的值：

Wolfram Language code: Dendrogram[data, DistanceFunction -> EuclideanDistance, Axes -> {False, True}]

用不同的 DistanceFunction 获取树形图：

Wolfram Language code: Dendrogram[data, DistanceFunction -> ManhattanDistance]
Wolfram Language code: Dendrogram[data, DistanceFunction -> ChessboardDistance]

FeatureExtractor  (1)

从图片列表中获取树形图：

Wolfram Language code: flowers = { [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image]};
Wolfram Language code: Dendrogram[flowers]

用不同的 FeatureExtractor 提取特征：

Wolfram Language code: fe = FeatureExtraction[flowers, "ImageFeatures"]
Wolfram Language code: Dendrogram[flowers, FeatureExtractor -> fe]

用 Identity FeatureExtractor 保持数据不变：

Wolfram Language code: Dendrogram[flowers, FeatureExtractor -> Identity]

ImageSize  (7)

使用命名尺寸，如 Tiny、Small、Medium 和 Large：

Wolfram Language code: {Dendrogram[IconizedObject[«data»], ImageSize -> Tiny], Dendrogram[IconizedObject[«data»], ImageSize -> Small]}

指定绘图的宽度：

Wolfram Language code: {Dendrogram[IconizedObject[«data»], ImageSize -> 150], Dendrogram[IconizedObject[«data»], AspectRatio -> 1.5, ImageSize -> 150]}

指定绘图的高度：

Wolfram Language code: {Dendrogram[IconizedObject[«data»], ImageSize -> {Automatic, 150}], Dendrogram[IconizedObject[«data»], AspectRatio -> 2, ImageSize -> {Automatic, 150}]}

允许宽度和高度达到一定尺寸：

Wolfram Language code: {Dendrogram[IconizedObject[«data»], ImageSize -> UpTo[200]], Dendrogram[IconizedObject[«data»], AspectRatio -> 2, ImageSize -> UpTo[200]]}

指定图形的宽度和高度，必要时用空白填充：

Wolfram Language code: Dendrogram[IconizedObject[«data»], ImageSize -> {200, 300}, Background -> LightBlue]

设置 AspectRatioFull 会填充可用空间：

Wolfram Language code: Dendrogram[IconizedObject[«data»], AspectRatio -> Full, ImageSize -> {200, 200}, Background -> LightBlue]

使用允许的最大宽度和高度：

Wolfram Language code: {Dendrogram[IconizedObject[«data»], ImageSize -> {UpTo[150], UpTo[100]}], Dendrogram[IconizedObject[«data»], AspectRatio -> 2, ImageSize -> {UpTo[150], UpTo[100]}]}

用 ImageSizeFull 填充对象中可用的空间：

Wolfram Language code: Framed[Pane[Dendrogram[IconizedObject[«data»], ImageSize -> Full, Background -> LightBlue], {200, 100}]]

将图像大小指定为可用空间的一定比例：

Wolfram Language code: Framed[Pane[Dendrogram[IconizedObject[«data»], AspectRatio -> Full, ImageSize -> {Scaled[0.5], Scaled[0.5]}, Background -> LightBlue], {200, 100}]]

应用  (1)

生成随机颜色列表，计算它的树状图，距离在 y 轴上：

Wolfram Language code: colors = {RGBColor[0.005205065918539198, 0.505430385626394, 0.5037170574409544], RGBColor[0.16523243233558582, 0.435798695033599, 0.006857194456336924], RGBColor[0.10448507405871288, 0.6798166859116166, 0.1566614433106035], RGBColor[0.22501876056775894, 0.2933626410500396, 0.11416198735334127], RGBColor[0.4222624701525557, 0.48149330236969345, 0.940230574165601], RGBColor[0.23162634358255763, 0.9202398461548127, 0.7752908257962525], RGBColor[0.5222836023306179, 0.20801120086103708, 0.5543480345610741], RGBColor[0.7501151268647552, 0.05746907232600429, 0.9059681239202162], RGBColor[0.6534431085562413, 0.5329943588860213, 0.9285215109733242], RGBColor[0.9143128324385004, 0.2569397145689536, 0.5777060976306343]};
Wolfram Language code: Dendrogram[colors, Axes -> {False, True}, AxesOrigin -> {0, 0}]

通过合并距离小于 0.65 的聚类计算同样数据的 ClusteringTree：

Wolfram Language code: g = ClusteringTree[colors, 0.65]

计算上面的图的 Dendrogram：

Wolfram Language code: Dendrogram[g]

构建一个 Manipulate，展示当距离阈值增加时聚类的合并情况：

Wolfram Language code: With[{colors = {RGBColor[0.005205065918539198, 0.505430385626394, 0.5037170574409544], RGBColor[0.16523243233558582, 0.435798695033599, 0.006857194456336924], RGBColor[0.10448507405871288, 0.6798166859116166, 0.1566614433106035], RGBColor[0.22501876056775894, 0.2933626410500396, 0.11416198735334127], RGBColor[0.4222624701525557, 0.48149330236969345, 0.940230574165601], RGBColor[0.23162634358255763, 0.9202398461548127, 0.7752908257962525], RGBColor[0.5222836023306179, 0.20801120086103708, 0.5543480345610741], RGBColor[0.7501151268647552, 0.05746907232600429, 0.9059681239202162], RGBColor[0.6534431085562413, 0.5329943588860213, 0.9285215109733242], RGBColor[0.9143128324385004, 0.2569397145689536, 0.5777060976306343]}}, Manipulate[Dendrogram[ClusteringTree[colors, h], Left], {h, 0, 1}] ]
Wolfram Research (2016)，Dendrogram，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Dendrogram.html （更新于 2017 年）.

文本

Wolfram Research (2016)，Dendrogram，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Dendrogram.html （更新于 2017 年）.

CMS

Wolfram 语言. 2016. "Dendrogram." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2017. https://reference.wolfram.com/language/ref/Dendrogram.html.

APA

Wolfram 语言. (2016). Dendrogram. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Dendrogram.html 年

BibTeX

@misc{reference.wolfram_2026_dendrogram, author="Wolfram Research", title="{Dendrogram}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/Dendrogram.html}", note=[Accessed: 04-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_dendrogram, organization={Wolfram Research}, title={Dendrogram}, year={2017}, url={https://reference.wolfram.com/language/ref/Dendrogram.html}, note=[Accessed: 04-September-2026]}