WOLFRAM

Wolfram 语言与系统参考资料中心

DirichletCondition[beqn,pred]

表示由方程 beqn 给出的狄利克雷边界条件，在给予 NDSolve 的区域上的边界部分成立，其中 pred 为 True.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
1D 问题  
2D 问题  
3D 问题  
时间相关问题  
多边界条件  
耦合系统的边界条件  
属性和关系  
可能存在的问题  
参见
技术笔记
相关指南
历史
按以下格式引用：

DirichletCondition

DirichletCondition[beqn,pred]

表示由方程 beqn 给出的狄利克雷边界条件，在给予 NDSolve 的区域上的边界部分成立，其中 pred 为 True.

更多信息

  • DirichletCondition 在诸如 DSolve、NDSolve、DEigensystem、NDEigensystem 和 GreenFunction 这样的函数中和微分方程一起使用，描述边界条件.
  • 在 NDSolve[eqns,{u1,u2,…},{x1,x2,…}∈Ω] 中，xi 是自变量，uj 是因变量，而 Ω 是边界为 ∂Ω 的区域.
  • 可能需要指定狄利克雷条件的位置以蓝色显示. 它们出现在区域 Ω 的边界 ∂Ω 上（以浅蓝色表示），也可能出现在 Ω 的内部边界上（以深蓝色表示），并且指定在这些点上满足条件 beqn 的解的值.
  • DirichletCondition 表达式应包括在方程 eqns 中.
  • 独立变量 x1、… 的等式和不等式的的任何逻辑组合都可用作谓词 pred.
  • DirichletCondition[u1r,pred] 用于阐明边界 ∂Ω 上的 ui 的值应该为 r. 一般而言，边界方程 beqn 需要在因变量中呈仿射线性，即 h1 u1+…r，其中 hi 和 r 可依赖于任何独立变量 {x1,x2,…}.
  • 对于含时方程，beqn 和 pred 可能依赖于时间，只在空间边界时才考虑 pred.
  • 通常情况下，使微分方程具有唯一解，需要指定至少一个狄利克雷型边界条件. 狄氏条件也称为本质边界条件.
  • 狄利克雷条件在 ∂Ω 离散化的每一个点上强制成立，其中 pred 为 True.
  • DirichletCondition[{eqn1,eqn2,…},pred] 等价于 {DirichletCondition[eqn1,pred],DirichletCondition[eqn2,pred],…}.
  • DirichletCondition[eqn,{pred1,pred2,…}] 等价于 {DirichletCondition[eqn,pred1],DirichletCondition[eqn,pred2],…}.
  • 对于有限元近似法，DirichletCondition 始终在结点上进行操作，从不在边和面上进行操作.
  • 不应在边界的同一部分上同时指定 DirichletCondition 和 NeumannValue .
  • 多个 DirichletCondition 实例不能在边界上重叠.

范例

打开所有单元 关闭所有单元

基本范例  (2)

在单位圆盘上求解 ，其中狄利克雷边界条件为 ：

Wolfram Language code: NDSolveValue[{Subsuperscript[∇, {x, y}, 2]u[x, y] == 0, DirichletCondition[u[x, y] == Sin[x y], True]}, u, {x, y}∈Disk[]]
Wolfram Language code: Plot3D[%[x, y], {x, y}∈Disk[]]

指定多个狄利克雷条件，对于 ，有 ，对于 ，有 ：

Wolfram Language code: NDSolveValue[{Subsuperscript[∇, {x, y}, 2]u[x, y] == 0, DirichletCondition[u[x, y] == 0, x ≤ -0.3], DirichletCondition[u[x, y] == 1, x ≥ 0.35]}, u, {x, y}∈Disk[]]
Wolfram Language code: Plot3D[%[x, y], {x, y}∈Disk[]]

在单位圆盘上求解 ，其狄利克雷边界条件为 ：

Wolfram Language code: DSolveValue[{Subsuperscript[∇, {x, y}, 2]u[x, y] == 0, DirichletCondition[u[x, y] == Sin[4ArcTan[x, y]], True]}, u[x, y], {x, y}∈Disk[]]
Wolfram Language code: Plot3D[%, {x, y}∈Disk[], PlotRange -> All, PlotPoints -> 101, PlotStyle -> Hue[0.55]]

范围  (4)

指定有孔的区域：

Wolfram Language code: Ω = RegionDifference[Rectangle[{-1, -1}, {1, 1}], Rectangle[{-1 / 2, -1 / 2}, {1 / 2, 1 / 2}]]; RegionPlot[Ω]

设定多个狄利克雷条件，在内部边界上为 ，在外部边界上为 ，并在该区域上求解拉普拉斯方程 ：

Wolfram Language code: NDSolveValue[{Subsuperscript[∇, {x, y}, 2]u[x, y] == 0, DirichletCondition[u[x, y] == 100., Abs[x] == 1 / 2 && -1 / 2 ≤ y ≤ 1 / 2 || -1 / 2 ≤ x ≤ 1 / 2 && Abs[y] == 1 / 2], DirichletCondition[u[x, y] == 20., Abs[x] == 1 || Abs[y] == 1]}, u, {x, y}∈Ω]
Wolfram Language code: Plot3D[%[x, y], {x, y}∈Ω, Mesh -> None, PlotRange -> All]

在有孔和狄利克雷条件的区域上求解 TemplateBox[{{(, {{(, , {{2, , y}, ; , {x, , 3}}, , )}, , ., , TemplateBox[{{u, (, {x, ,, y}, )}, {{, {x, ,, y}, }}, InactiveTraditional}, InactiveGrad]}, )}, {{, {x, ,, y}, }}, InactiveTraditional}, InactiveDiv]=0，指定该区域：

Wolfram Language code: Ω = ImplicitRegion[x ^ 2 + y ^ 2 ≥ 1, {{x, -2, 2}, {y, -2, 2}}]; RegionPlot[Ω]

解方程：

Wolfram Language code: NDSolveValue[{Inactive[Div][{{2, y}, {x, 3}} . Inactive[Grad][u[x, y], {x, y}], {x, y}] == 0, DirichletCondition[u[x, y] == 0, x^2 + y^2 == 1], DirichletCondition[u[x, y] == 1, x == 2 || x == -2 || y == 2 || y == -2]}, u, {x, y}∈Ω]

绘制解的密度：

Wolfram Language code: DensityPlot[%[x, y], {x, y}∈Ω]

在长度为 d 的区间上求解波动方程格林函数，在两端约束为 0：

Wolfram Language code: gf = GreenFunction[{(1/c^2)Subscript[∂, {t, 2}]u[x, t] - Subscript[∂, {x, 2}]u[x, t], DirichletCondition[u[x, t] == 0, True]}, u[x, t], {x, 0, d}, t, {y, s}]

在区域内部分指定一个 DirichletCondition. 创建边界网格并使之可视化：

Wolfram Language code: Needs["NDSolve`FEM`"] bmesh = ToBoundaryMesh["Coordinates" -> {{0, 0}, {1 / 2, 0}, {1, 0}, {1, 1}, {0, 1}, {1 / 2, 2 / 5}}, "BoundaryElements" -> {LineElement[{{1, 2}, {2, 3}, {3, 4}, {4, 5}, {5, 1}, {2, 6}}]}]; bmesh["Wireframe"]

使用条件为 的 DirichletCondition 求解偏微分方程：

Wolfram Language code: mesh = ToElementMesh[bmesh]; solution = NDSolveValue[{Laplacian[u[x, y], {x, y}] == 0, u[x, 1] == 100, u[x, 0] == 0, u[1, y] == 100 y, u[0, y] == 100 y, DirichletCondition[u[x, y] == 0, x == 1 / 2 && y <= 2 / 5]}, u, {x, y}∈mesh]

可视化该解：

Wolfram Language code: Show[ContourPlot[solution[x, y], {x, y}∈mesh, Contours -> 20], Graphics[{Green, Line[{{1 / 2, 0}, {1 / 2, 2 / 5}}]}]]

应用  (11)

1D 问题  (1)

在从 到 的区域上指定微分方程 ，其中在 和 处有狄利克雷边界条件:

Wolfram Language code: NDSolveValue[{D[-2u[x], x, x] + 3 D[u[x], x] + 10u[x] == 1, DirichletCondition[2 * u[x] == -1, x == -1], DirichletCondition[3 * u[x] == 1 / 2, x == 2]}, u, {x, -1, 2}]

绘制解的图线：

Wolfram Language code: Plot[%[x], {x, -1, 2}]

2D 问题  (1)

在单位圆盘上指定泊松方程 ，在所有边界上具有狄利克雷边界值 0：

Wolfram Language code: NDSolveValue[{Subsuperscript[∇, {x, y}, 2]u[x, y] == 1, DirichletCondition[u[x, y] == 0, True]}, u, {x, y}∈Disk[]]
Wolfram Language code: Plot3D[%[x, y], {x, y}∈Disk[]]

3D 问题  (1)

在具有狄利克雷边界条件 的单位球上求解 ：

Wolfram Language code: NDSolveValue[{Subsuperscript[∇, {x, y, z}, 2]u[x, y, z] == 1, DirichletCondition[u[x, y, z] == Sin[x * y * z], True]}, u[x, y, z], {x, y, z}∈Ball[]]
Wolfram Language code: SliceContourPlot3D[%, {x, y, z}∈Ball[]]

时间相关问题  (4)

求解具有初始和和边界条件的时间相关问题：

Wolfram Language code: pde = D[u[t, x], t, t] == D[u[t, x], x, x]; ics = {u[0, x] == Exp[-20(x) ^ 2], Derivative[1, 0][u][0, x] == 0}; bcs = {u[t, -1] == 0, u[t, 1] == 0};
Wolfram Language code: NDSolveValue[{pde, ics, bcs}, u, {t, 0, 1}, {x, -1, 1}]
Wolfram Language code: Plot3D[%[t, x], {t, 0, 1}, {x, -1, 1}, PlotRange -> All]

求解时间相关的问题，其边界条件指定为狄利克雷边界条件：

Wolfram Language code: bcs = DirichletCondition[u[t, x] == 0, x == -1 || x == 1]
Wolfram Language code: NDSolveValue[{pde, ics, bcs}, u, {t, 0, 1}, {x, -1, 1}]
Wolfram Language code: Plot3D[%[t, x], {t, 0, 1}, {x, -1, 1}, PlotRange -> All]

求解具有初始和时间相关边界条件的时间相关问题：

Wolfram Language code: pde = D[u[t, x], t, t] == D[u[t, x], x, x]; ics = {u[0, x] == Exp[-20(x) ^ 2], Derivative[1, 0][u][0, x] == 0}; bcs = {DirichletCondition[u[t, x] == Sin[t], x == 1], DirichletCondition[u[t, x] == 0, x == -1]}
Wolfram Language code: NDSolveValue[{pde, ics, bcs}, u, {t, 0, π}, {x, -1, 1}, Method -> {"PDEDiscretization" -> {"MethodOfLines", {"SpatialDiscretization" -> "FiniteElement"}}}]
Wolfram Language code: Plot3D[%[t, x], {t, 0, π}, {x, -1, 1}]

求解具有初始和边界条件规范的二维时间相关问题：

Wolfram Language code: ufun = NDSolveValue[{D[u[t, x, y], t] == Subsuperscript[∇, {x, y}, 2]u[t, x, y], u[0, x, y] == Sin[Pi x] Sin[Pi y], DirichletCondition[u[t, x, y] == 0, True]}, u, {t, 0, 1}, {x, 0, 1}, {y, 0, 1}, Method -> {"PDEDiscretization" -> {"MethodOfLines", {"SpatialDiscretization" -> "FiniteElement"}}}]

在 t==0.5 时绘制时间分布：

Wolfram Language code: Plot3D[ufun[0.5, x, y], {x, 0, 1}, {y, 0, 1}]

观察随时间流逝，温度分布迅速平息为零：

Wolfram Language code: ListAnimate@Table[Plot3D[ufun[t, x, y], {x, 0, 1}, {y, 0, 1}, PlotRange -> 1], {t, 0, .25, .025}]

求边缘被夹住的圆鼓面的震动：

Wolfram Language code: NDSolveValue[{D[u[t, x, y], {t, 2}] == Subsuperscript[∇, {x, y}, 2]u[t, x, y], u[0, x, y] == x y Sin[Pi( x ^ 2 + y ^ 2)], Derivative[1, 0, 0][u][0, x, y] == 0, DirichletCondition[u[t, x, y] == 0, True]}, u, {t, 0, 2}, {x, y}∈Disk[]]

可视化震动：

Wolfram Language code: ListAnimate@Table[Plot3D[%[t, x, y], {x, y}∈Disk[], PlotRange -> 1], {t, 0, 2, .1}]

多边界条件  (1)

通过边界指定区域：

Wolfram Language code: boundaries = {-y, (1/25) - (-(3/2) + x)^2 - y^2, 1 - x^2 - y^2, x^2 + y^2 - 4, y - x * Tan[π / 8]}; Ω = ImplicitRegion[And@@(# ≤ 0& /@ boundaries), {x, y}];

显示区域和边界：

Wolfram Language code: Show[RegionPlot[Ω], ContourPlot[Evaluate[Thread[boundaries == 0]], {x, 0.8, 2.2}, {y, -0.2, 1.}, ContourStyle -> {Purple, Green, Red, Blue, Purple}], PlotRange -> {{0.8, 2.2}, {-0.2, 1.}}, AspectRatio -> Automatic]

求解拉普拉斯方程，其中温度设在红色和蓝色边界，助熔剂在绿色边界：

Wolfram Language code: NDSolveValue[{-10 Subsuperscript[∇, {x, y}, 2]u[x, y] == NeumannValue[-1000., boundaries[[2]] == 0.], {DirichletCondition[u[x, y] == 200., boundaries[[3]] == 0.], DirichletCondition[u[x, y] == 15., boundaries[[4]] == 0.]}}, u, {x, y}∈Ω]
Wolfram Language code: ContourPlot[%[x, y], {x, y}∈Ω, Mesh -> None, ColorFunction -> "TemperatureMap", Contours -> 21, AspectRatio -> Automatic]

耦合系统的边界条件  (3)

指定耦合微分方程：

Wolfram Language code: pde = {D[-2 u[x], {x, 2}] + D[4 v[x], {x, 2}] + 10 v[x] == 1, D[-3 u[x], {x, 2}] + D[-1 v[x], {x, 2}] == 0};

指定两个方程的狄利克雷边界条件：

Wolfram Language code: bcs = {DirichletCondition[2 u[x] == 1, x == 0], DirichletCondition[u[x] == 0, x == 1], DirichletCondition[v[x] == 1., x == 0], DirichletCondition[v[x] == 0, x == 1]};

求解方程组：

Wolfram Language code: NDSolveValue[{pde, bcs}, {u[x], v[x]}, {x, 0, 1}]

绘制解的图线：

Wolfram Language code: Plot[Evaluate[%], {x, 0, 1}]

指定耦合方程 和 ：

Wolfram Language code: pde = {-Subsuperscript[∇, {x, y}, 2]u[x, y] + v[x, y] == 0, -Subsuperscript[∇, {x, y}, 2]v[x, y] + u[x, y] == 0}

指定每个因变量的两个狄利克雷边界条件：

Wolfram Language code: bcs = {DirichletCondition[u[x, y] == 1., x ≥ 0.9], DirichletCondition[u[x, y] == 0., x ≤ -0.9], DirichletCondition[v[x, y] == 2., y ≥ 0.8], DirichletCondition[v[x, y] == 3., y ≤ -0.7]};

求解圆盘上的耦合方程：

Wolfram Language code: NDSolveValue[{pde, bcs}, {u[x, y], v[x, y]}, {x, y}∈Disk[]]
Wolfram Language code: Plot3D[#, {x, y}∈Disk[]]& /@ %

指定一个平面应力运算符，其中杨氏模量 Y 和泊松比 ν 在一个条上：

Wolfram Language code: ps = {Inactive[Div][{{0, -(Y ν/1 - ν^2)}, {-(Y (1 - ν)/2 (1 - ν^2)), 0}}.Inactive[Grad][v[x, y], {x, y}], {x, y}] + Inactive[Div][{{-(Y/1 - ν^2), 0}, {0, -(Y (1 - ν)/2 (1 - ν^2))}}.Inactive[Grad][u[x, y], {x, y}], {x, y}], Inactive[Div][{{0, -(Y (1 - ν)/2 (1 - ν^2))}, {-(Y ν/1 - ν^2), 0}}.Inactive[Grad][u[x, y], {x, y}], {x, y}] + Inactive[Div][{{-(Y (1 - ν)/2 (1 - ν^2)), 0}, {0, -(Y/1 - ν^2)}}.Inactive[Grad][v[x, y], {x, y}], {x, y}]} /. {Y -> 10 ^ 3, ν -> 33 / 100};

计算一个杆的形变，其中左侧边缘固定，从右侧边缘移动到 方向的相反位置上，但保持其 方向：

Wolfram Language code: {uif, vif} = NDSolveValue[{ps == {0, 0}, DirichletCondition[{u[x, y] == 0., v[x, y] == 0.}, x == 0], DirichletCondition[v[x, y] == -0.2, x == 5], DirichletCondition[u[x, y] == 0, x == 5] }, {u, v}, {x, 0, 5}, {y, 0, 1}]

在 方向绘制条形变的等值线图：

Wolfram Language code: ContourPlot[uif[x, y], {x, 0, 5}, {y, 0, 1}, ColorFunction -> "TemperatureMap", AspectRatio -> Automatic]

在 方向绘制条形变的等值线图：

Wolfram Language code: ContourPlot[vif[x, y], {x, 0, 5}, {y, 0, 1}, ColorFunction -> "TemperatureMap", AspectRatio -> Automatic]

可视化条的形变：

Wolfram Language code: mr = MeshRegion[uif["ElementMesh"]]; c = MeshCoordinates[mr]; Show[ BoundaryMesh[mr], HighlightMesh[MeshRegion[c + Transpose[{uif@@@c, vif@@@c}], MeshCells[mr, {2, All}]], Style[1, Red]] ]

属性和关系  (1)

通过追赶法满足边界条件：

Wolfram Language code: NDSolveValue[{u''[x] == -x * u[x], u[0] == 0, u[4] == 1 / 2}, u[x], {x, 0, 4}, Method -> {"Shooting"}]
Wolfram Language code: Plot[%, {x, 0, 4}]

用有限元方法求解同样的方程：

Wolfram Language code: NDSolveValue[{u''[x] == -x * u[x], u[0] == 0, u[4] == 1 / 2}, u[x], {x, 0, 4}, Method -> {"FiniteElement"}]
Wolfram Language code: Plot[%, {x, 0, 4}]

指定 Dirichlet 条件作为边界条件：

Wolfram Language code: NDSolveValue[{u''[x] == -x * u[x], DirichletCondition[u[x] == 0, x == 0], DirichletCondition[u[x] == 1 / 2, x == 4]}, u[x], {x, 0, 4}]
Wolfram Language code: Plot[%, {x, 0, 4}]

可能存在的问题  (6)

指定至少一个狄利克雷边界条件是必要的：

Wolfram Language code: NDSolveValue[{Subsuperscript[∇, {x, y}, 2]u[x, y] == 1}, u[x, y], {x, y}∈Disk[]]

指定狄利克雷条件给出预期的结果：

Wolfram Language code: NDSolveValue[{Subsuperscript[∇, {x, y}, 2]u[x, y] == 1, DirichletCondition[u[x, y] == 0, True]}, u[x, y], {x, y}∈Disk[]]
Wolfram Language code: Plot3D[%, {x, y}∈Disk[]]

指定罗宾边界条件作为必要条件是充分的：

Wolfram Language code: NDSolveValue[Subsuperscript[∇, {x, y}, 2]u[x, y] == 1 + NeumannValue[3 u[x, y] + Sin[x y], True], u[x, y], {x, y}∈Disk[]]
Wolfram Language code: Plot3D[%, {x, y}∈Disk[]]

当边界条件与边界不相交时，将会产生一个警告，并在可能时忽略非相交边界：

Wolfram Language code: NDSolveValue[{D[-2u[x], x, x] + 3 D[u[x], x] + 10u[x] == 1, DirichletCondition[2 * u[x] == -1, x == -1], DirichletCondition[3 * u[x] == 1 / 2, x == 3]}, u, {x, -1, 2}, Method -> "FiniteElement"]

调整边界将纠正这个问题：

Wolfram Language code: NDSolveValue[{D[-2u[x], x, x] + 3 D[u[x], x] + 10u[x] == 1, DirichletCondition[2 * u[x] == -1, x == -1], DirichletCondition[3 * u[x] == 1 / 2, x == 2]}, u, {x, -1, 2}, Method -> "FiniteElement"]

如果指定 True 作为谓词，将会把 DirichletCondition 的值应用于所有边界，包括内部材料的边界.

用内部边界生成并可视化网格：

Wolfram Language code: mesh = NDSolve`FEM`ToElementMesh[Annulus[{0, 0}, {1, 2}], "RegionHoles" -> None]; mesh["Wireframe"]

设置多种材料组成的区域的方程：

Wolfram Language code: eqn = Inactive[Div][(If[x ^ 2 + y ^ 2 ≤ 1, -1, -5]) Inactive[Grad][u[x, y], {x, y}], {x, y}] == 1;

在所有边界处将因变量 设为零，求解方程：

Wolfram Language code: sol = NDSolveValue[{eqn, DirichletCondition[u[x, y] == 0, True]}, u, {x, y}∈mesh];

可视化解：

Wolfram Language code: Plot3D[sol[x, y], {x, y}∈Disk[{0, 0}, 2], PlotRange -> All]

在外边界处将因变量 设为零，求解方程：

Wolfram Language code: sol = NDSolveValue[{eqn, DirichletCondition[u[x, y] == 0, x ^ 2 + y ^ 2 == 2 ^ 2]}, u, {x, y}∈mesh];

可视化解：

Wolfram Language code: Plot3D[sol[x, y], {x, y}∈Disk[{0, 0}, 2], PlotRange -> All]

如果指定 True 作为谓词，将在所有空间边界上应用 DirichletCondition 的值：

Wolfram Language code: sol = NDSolveValue[{D[u[t, x], {t, 1}] - Laplacian[u[t, x], {x}] == 1, DirichletCondition[u[t, x] == 0, True], u[0, x] == 0}, u, {t, 0, 1}, {x, 0, 1}]

两端满足边界条件，初始条件也得到满足. 在 时没有边界条件，因为时域不被视为空间边界：

Wolfram Language code: GraphicsGrid[{{Plot[sol[t, 0], {t, 0, 1}], Plot[sol[t, 1], {t, 0, 1}]}, {Plot[sol[0, x], {x, 0, 1}], Plot[sol[1, x], {x, 0, 1}]}}, ImageSize -> Medium]

默认情况下，NDSolve 将 PDE 视为含时问题. 可用 Method->{"PDEDiscretization"->"FiniteElement"} 指定纯空间离散化：

Wolfram Language code: sol = NDSolveValue[{D[u[t, x], {t, 1}] - Laplacian[u[t, x], {x}] == 1, DirichletCondition[u[t, x] == 0, True], u[0, x] == 0}, u, {t, 0, 1}, {x, 0, 1}, Method -> {"PDEDiscretization" -> "FiniteElement"}]

如果将同一个 PDE 作为纯空间问题求解，则已在所有边界处应用了 DirichletCondition：

Wolfram Language code: GraphicsGrid[{{Plot[sol[t, 0], {t, 0, 1}], Plot[sol[t, 1], {t, 0, 1}]}, {Plot[sol[0, x], {x, 0, 1}], Plot[sol[1, x], {x, 0, 1}]}}, ImageSize -> Medium]

有时，导入的网格或甚至生成的网格都可能存在数值上的不精确. 例如，目标区域是一个矩形 ，但该区域的离散化版本存在不精确性，实际上是 . 在这种情况下，如果指定了 形式的谓词，就会产生一条错误信息，因为 并不存在. 请看这个构造的例子：

Wolfram Language code: Ω = Rectangle[{10 ^ -6, 0}, {1, 1}]; NDSolveValue[{-Laplacian[u[x, y], {x, y}] == 1, DirichletCondition[u[x, y] == 0, x == 0]}, u, {x, y}∈Ω]

处理这种情况的一种方法是将谓词表述为一个界限：，其中 是界限的粗细：

Wolfram Language code: NDSolveValue[{-Laplacian[u[x, y], {x, y}] == 1, DirichletCondition[u[x, y] == 0, x ^ 2 <= 10 ^ -6]}, u, {x, y}∈Ω]

这种技巧也可用于更复杂的谓词，如边界的圆形部分，在这种情况下，数字精度问题更有可能出现.

Wolfram Research (2014)，DirichletCondition，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DirichletCondition.html （更新于 2022 年）.

文本

Wolfram Research (2014)，DirichletCondition，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DirichletCondition.html （更新于 2022 年）.

CMS

Wolfram 语言. 2014. "DirichletCondition." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2022. https://reference.wolfram.com/language/ref/DirichletCondition.html.

APA

Wolfram 语言. (2014). DirichletCondition. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/DirichletCondition.html 年

BibTeX

@misc{reference.wolfram_2026_dirichletcondition, author="Wolfram Research", title="{DirichletCondition}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/DirichletCondition.html}", note=[Accessed: 10-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_dirichletcondition, organization={Wolfram Research}, title={DirichletCondition}, year={2022}, url={https://reference.wolfram.com/language/ref/DirichletCondition.html}, note=[Accessed: 10-September-2026]}