Wolfram 语言与系统参考资料中心

EstimatedDistribution

EstimatedDistribution[data,dist]

估计 data 的参数分布 dist.

EstimatedDistribution[data,dist,{{p,p₀},{q,q₀},…}]

估计参数 p、q、…，起始值为 p₀、q₀、….

EstimatedDistribution[data,dist,idist]

估计分布 dist，其中起始值选自于实体化分布 idist.

范例

打开所有单元关闭所有单元

基本范例 (3)

得到伽玛分布时的最大似然参数估计：

Wolfram Language code: data = RandomVariate[𝒟 = GammaDistribution[1, 2], 10 ^ 3];

Wolfram Language code: e𝒟 = EstimatedDistribution[data, GammaDistribution[α, β]]

可视化比较原分布和估计分布的概率密度函数：

Wolfram Language code: Plot[{PDF[𝒟, x], PDF[e𝒟, x]}, {x, 0, 10}, PlotLegends -> {"𝒟", "e𝒟"}]

得到矩法的估计量：

Wolfram Language code: EstimatedDistribution[data, GammaDistribution[α, β], ParameterEstimator -> "MethodOfMoments"]

估计多元分布的参数：

Wolfram Language code: data = RandomVariate[MultivariatePoissonDistribution[5, {4, 3, 10}], 20];

Wolfram Language code: EstimatedDistribution[data, MultivariatePoissonDistribution[μ, {Subscript[μ, 1], Subscript[μ, 2], Subscript[μ, 3]}]]

数量数据的估计参数：

Wolfram Language code: data = RandomVariate[NormalDistribution[Quantity[200, "Centimeters"], Quantity[7, "Centimeters"]], 20]

Wolfram Language code: EstimatedDistribution[data, NormalDistribution[m, s]]

范围 (15)

基本用途 (5)

估计二次分布的两个参数：

Wolfram Language code: bdata = {23, 16, 24, 17, 16, 17, 18, 17, 19, 23, 19, 13, 19, 18, 22, 21, 19, 22, 19, 23};

Wolfram Language code: EstimatedDistribution[bdata, BinomialDistribution[n, p]]

假设 n 已知，估计 p：

Wolfram Language code: EstimatedDistribution[bdata, BinomialDistribution[50, p]]

假设 p 已知，估计 n：

Wolfram Language code: EstimatedDistribution[bdata, BinomialDistribution[n, 2 / 5]]

获取对于特定分布族，具有最大似然参数估计的分布：

Wolfram Language code: vals = RandomReal[ChiSquareDistribution[20], 1000];

Wolfram Language code: dist = EstimatedDistribution[vals, ChiSquareDistribution[n]]

通过比较数据的直方图和估计概率密度函数，检测拟合优度：

Wolfram Language code: Show[Histogram[vals, Automatic, "ProbabilityDensity"], Plot[PDF[dist, x], {x, 0, 50}]]

用零分布 dist 执行拟合优度检验:

Wolfram Language code: DistributionFitTest[vals, dist, {"TestDataTable", All}]

执行参数估计校正的检验：

Wolfram Language code: DistributionFitTest[vals, ChiSquareDistribution[n], {"TestDataTable", All}]

通过最大化对数似然值，估计参数：

Wolfram Language code: data = RandomVariate[GeometricDistribution[.4], 100];

Wolfram Language code: dist = EstimatedDistribution[data, GeometricDistribution[p]]

Wolfram Language code: phat = dist[[1]]

绘制对数似然函数来可视化检查该解是否最优：

Wolfram Language code:

Show[Plot[LogLikelihood[GeometricDistribution[p], data], {p, 0, 1}], Graphics[{PointSize[Large], Red, Point[{phat, LogLikelihood[GeometricDistribution[phat], data]}]}]]

可视化对数似然曲面来求得参数的粗略值：

Wolfram Language code: data = BlockRandom[SeedRandom[100];RandomVariate[WeibullDistribution[4, 5], 50]];

Wolfram Language code: ContourPlot[LogLikelihood[WeibullDistribution[α, β], data], {α, 2, 6}, {β, 3, 8}]

将原始值作为初始值来估计：

Wolfram Language code: EstimatedDistribution[data, WeibullDistribution[α, β], WeibullDistribution[3, 5.5]]

估计泊松数据的正态逼近：

Wolfram Language code: data = RandomVariate[PoissonDistribution[20], 100];

Wolfram Language code: EstimatedDistribution[data, NormalDistribution[μ, σ]]

获取估计直到20个数位：

Wolfram Language code: EstimatedDistribution[data, NormalDistribution[μ, σ], WorkingPrecision -> 20]

单变量参数分布 (2)

估计连续分布的参数：

Wolfram Language code:

data = {0.8, 0.98, 0.66, 0.09, 0.03, 0.16, 0.88, 0.32, 0.56, 0.3, 0.82, 0.34, 0.93, 0.33, 0.25, 0.74, 0.3, 0.74, 0.16, 0.02};

Wolfram Language code: EstimatedDistribution[data, BetaDistribution[α, β]]

比较实验得到的分位数和分布分位数：

Wolfram Language code: QuantilePlot[data, %]

估计离散分布的参数：

Wolfram Language code: data = {16, 1, 2, 5, 3, 5, 1, 6, 4, 14, 2, 9, 1, 1, 2, 2, 8, 1, 3, 1};

Wolfram Language code: EstimatedDistribution[data, LogSeriesDistribution[θ]]

多变量参数分布 (2)

估计离散多变量分布的参数：

Wolfram Language code: mdata = RandomVariate[MultinomialDistribution[20, {1 / 3, 1 / 6, 1 / 10, 2 / 5}], 1000];

Wolfram Language code:

EstimatedDistribution[mdata, MultinomialDistribution[n, {Subscript[p, 1], Subscript[p, 2], Subscript[p, 3], Subscript[p, 4]}]]

估计连续多变量分布的参数：

Wolfram Language code: bndata = RandomVariate[BinormalDistribution[{1, 2}, {1 / 3, 4}, 3 / 4], 1000];

Wolfram Language code:

dist = EstimatedDistribution[bndata, BinormalDistribution[{Subscript[μ, 1], Subscript[μ, 2]}, {Subscript[σ, 1], Subscript[σ, 2]}, ρ]]

比较原概率密度函数和估计概率密度函数之间的不同：

Wolfram Language code:

Plot3D[PDF[BinormalDistribution[{1, 2}, {1 / 3, 4}, 3 / 4], {x, y}] - PDF[dist, {x, y}], {x, 0, 2}, {y, -10, 16}, PlotRange -> All]

导出分布 (6)

估计截断正态分布的参数：

Wolfram Language code: 𝒟o = TruncatedDistribution[{-1, 2}, NormalDistribution[1, 1 / 3]];

Wolfram Language code:

SeedRandom[1];
data = RandomVariate[𝒟o, 100];

Wolfram Language code: 𝒟e = EstimatedDistribution[data, TruncatedDistribution[{-1, 2}, NormalDistribution[μ, σ]]]

比较原分布和估计分布：

Wolfram Language code: Plot[{PDF[𝒟o, x], PDF[𝒟e, x]}, {x, -1, 3}, Filling -> Axis, PlotLegends -> {"𝒟o", "𝒟e"}]

估计一种构造分布的参数：

Wolfram Language code: dist = ProbabilityDistribution[λ Exp[λ(1 - x)], {x, 1, Infinity}, Assumptions -> λ > 0]

Wolfram Language code: EstimatedDistribution[{1.4, 5.1, 1.7, 1.6, 1.1, 3.9, 2.2, 1.3, 2., 1.5}, dist]

估计一种乘积分布的参数：

Wolfram Language code: data = RandomVariate[ProductDistribution[BetaDistribution[2, 3], LaplaceDistribution[10, 1]], 100];

Wolfram Language code: EstimatedDistribution[data, ProductDistribution[BetaDistribution[α, β], LaplaceDistribution[μ, σ]]]

估计一种 copula 分布的参数：

Wolfram Language code: 𝒟o = CopulaDistribution[{"Frank", 1 / 2}, {GammaDistribution[2, 3], ChiSquareDistribution[10]}];

Wolfram Language code: data = RandomVariate[𝒟o, 100];

Wolfram Language code:

𝒟e = EstimatedDistribution[data, CopulaDistribution[{"Frank", c}, {GammaDistribution[α, β], ChiSquareDistribution[n]}]]

比较原分布和估计累积分布函数：

Wolfram Language code: Plot3D[CDF[𝒟o, {x, y}] - CDF[𝒟e, {x, y}], {x, 0, 25}, {y, 0, 35}, PlotRange -> All]

估计一种混合分布的参数：

Wolfram Language code: data = RandomVariate[MixtureDistribution[{1 / 3, 2 / 3}, {GammaDistribution[2, 3], NormalDistribution[1, 1 / 4]}], 100];

Wolfram Language code:

EstimatedDistribution[data, MixtureDistribution[{p, 1 - p}, {GammaDistribution[α, β], NormalDistribution[μ, σ]}]]//Quiet

估计混合概率，假定混合分布中各组成分布已知：

Wolfram Language code:

EstimatedDistribution[data, MixtureDistribution[{p, 1 - p}, {GammaDistribution[2, 3], NormalDistribution[1, 1 / 4]}]]//Quiet

指定单位中数量分布的估计参数：

Wolfram Language code: data = RandomVariate[NormalDistribution[Quantity[200, "Centimeters"], Quantity[7, "Centimeters"]], 100]

Wolfram Language code: EstimatedDistribution[data, QuantityDistribution[NormalDistribution[m, s], "Meters"]]

选项 (4)

ParameterEstimator (3)

通过匹配中心矩来估计参数：

Wolfram Language code: data = RandomVariate[ParetoDistribution[2, 8, 5], 1000];

Wolfram Language code: EstimatedDistribution[data, ParetoDistribution[α, β, μ], ParameterEstimator -> "MethodOfCentralMoments"]

其它基于矩的方法通常给出相似的结果：

Wolfram Language code: EstimatedDistribution[data, ParetoDistribution[α, β, μ], ParameterEstimator -> "MethodOfCentralMoments"]

Wolfram Language code: EstimatedDistribution[data, ParetoDistribution[α, β, μ], ParameterEstimator -> "MethodOfFactorialMoments"]

基于默认矩来估计参数：

Wolfram Language code: data = RandomVariate[NormalDistribution[2, 3], 1000];

Wolfram Language code: EstimatedDistribution[data, NormalDistribution[μ, σ], ParameterEstimator -> "MethodOfMoments"]

根据第一阶和第四阶矩来估计参数：

Wolfram Language code:

EstimatedDistribution[data, NormalDistribution[μ, σ], ParameterEstimator -> {"MethodOfMoments", "MomentOrders" -> {1, 4}}]

利用默认的方法得到最大似然估计量：

Wolfram Language code: data = RandomVariate[BetaDistribution[2, 3], 1000];

Wolfram Language code: EstimatedDistribution[data, BetaDistribution[α, β]]

利用 FindMaximum 得到估计量：

Wolfram Language code:

EstimatedDistribution[data, BetaDistribution[α, β], ParameterEstimator -> {"MaximumLikelihood", Method -> "FindMaximum"}]

利用 EvaluationMonitor 提取所采样的点：

Wolfram Language code:

{params, {points}} = Reap[EstimatedDistribution[data, BetaDistribution[α, β], ParameterEstimator -> {"MaximumLikelihood", Method -> {"FindMaximum", EvaluationMonitor :> Sow[{α, β}]}}]];

可视化所采样的和值的序列：

Wolfram Language code: ListLogPlot[Transpose[points], PlotLegends -> {"α", "β"}]

WorkingPrecision (1)

默认情况下，对于连续参数使用机器精度：

Wolfram Language code: data = RandomVariate[GumbelDistribution[2, 5], 100, WorkingPrecision -> 50];

Wolfram Language code: EstimatedDistribution[data, GumbelDistribution[α, β]]

获取高精度结果：

Wolfram Language code: EstimatedDistribution[data, GumbelDistribution[α, β], WorkingPrecision -> 25]

应用 (14)

估计具有相似形状的分布 (1)

使用伽玛分布对对数正态分布数据进行建模：

Wolfram Language code: lnorm = LogNormalDistribution[2, 0.3];

Wolfram Language code: sample = RandomVariate[lnorm, 10 ^ 4];

Wolfram Language code: edist = EstimatedDistribution[sample, GammaDistribution[α, β]]

Wolfram Language code: Show[Histogram[sample, 20, "ProbabilityDensity"], Plot[PDF[edist, x], {x, 0, 20}, PlotStyle -> Thick]]

比较模拟分布和估计分布：

Wolfram Language code: Plot[{PDF[lnorm, x], PDF[edist, x]}, {x, 0, 25}]

保险索赔 (1)

在一个保险公司里，每年每份保单的事故索赔数目：

Wolfram Language code: accidentsPerPolicyCounts = {81714, 11306, 1618, 250, 40, 7};;

Wolfram Language code: accidentsPerPolicy = WeightedData[Range[0, 5], accidentsPerPolicyCounts]

由于大多数保单具有至多一个索赔，我们使用对数级数分布对数据进行建模：

Wolfram Language code: edist = EstimatedDistribution[WeightedData[Range[0, 5] + 1, accidentsPerPolicyCounts], LogSeriesDistribution[θ]]

Wolfram Language code:

Show[Histogram[accidentsPerPolicy, {-0.5, 5.5, 1}, "PDF"], DiscretePlot[PDF[edist, x + 1], {x, 0, 5}, PlotStyle -> PointSize[Medium]]]

不同语言中单词的长度 (1)

获取一些语言的单词长度数据：

Wolfram Language code: languages = {"Arabic", "English", "Finnish", "French", "Hebrew", "Hindi", "Italian", "Russian", "Spanish"};

Wolfram Language code: worddata = Table[StringLength /@ DictionaryLookup[{l, All}], {l, languages}];

把每种语言的单词长度使用二次分布进行建模：

Wolfram Language code:

binom = Table[EstimatedDistribution[i, BinomialDistribution[n, p], ParameterEstimator -> {"MaximumLikelihood", Method -> {"FindRoot", MaxIterations -> 1000}}], {i, worddata}]

比较实际和估计分布：

Wolfram Language code:

Partition[Table[Show[Histogram[worddata[[i]], {Range[25] - 1 / 2}, "ProbabilityDensity", PlotLabel -> languages[[i]]], DiscretePlot[PDF[binom[[i]], x], {x, 0, 25}, PlotRange -> All, PlotStyle -> PointSize[.025]]], {i, Length[languages]}], 3]//Grid

文本频率 (1)

在一个文本中的单词数目服从齐夫分布：

Wolfram Language code: text = ExampleData[{"Text", "OriginOfSpecies"}, "Words"];

Wolfram Language code: wordCount = Tally[text][[All, 2]];

对单词频率数据进行 ZipfDistribution 拟合：

Wolfram Language code: edist = EstimatedDistribution[wordCount, ZipfDistribution[ρ]]

比较频率直方图和估计分布：

Wolfram Language code:

Show[Histogram[wordCount, {0.5, 20.5, 1}, "ProbabilityDensity"], DiscretePlot[PDF[edist, x], {x, 0, 20}, PlotStyle -> PointSize[Medium]]]

地震幅度 (1)

EstimatedDistribution 可以与诸如 MixtureDistribution 的结构体一起使用，以创建多态模型：

Wolfram Language code: magnitudes = Select[ExampleData[{"Statistics", "USEarthquakes"}], #[[1]] ≥ 1935&][[All, 7]];

在选定年份中的美国地震震级有两种模式：

Wolfram Language code: h = Histogram[magnitudes, 20, "ProbabilityDensity"]

从一个 NormalDistribution 与另一个的可能混合进行分布拟合：

Wolfram Language code:

edist = EstimatedDistribution[magnitudes, MixtureDistribution[{p, 1 - p}, {NormalDistribution[a, b], NormalDistribution[c, d]}]]//Quiet

比较直方图和估计分布的概率密度函数：

Wolfram Language code: Show[h, Plot[PDF[edist, x], {x, 0, 10}, PlotStyle -> Thick, PlotRange -> All]]

求一个地震具有7或更高的震级的概率：

Wolfram Language code: Probability[x ≥ 7, xedist]

求平均地震震级：

Wolfram Language code: Mean[edist]

模拟接下来30次地震的震级：

Wolfram Language code: ListPlot[RandomVariate[edist, 30], Filling -> Axis]

风速分析 (1)

对波士顿的月最大风速建模：

Wolfram Language code: maxWinds = WeatherData["Boston", "MaxWindSpeed", {{1950, 1, 1}, {2009, 12, 31}, "Month"}, "Value"]//QuantityMagnitude;

对数据进行 RayleighDistribution 拟合：

Wolfram Language code: edist1 = EstimatedDistribution[maxWinds, RayleighDistribution[θ]]

一个 ExtremeValueDistribution：

Wolfram Language code: edist2 = EstimatedDistribution[maxWinds, ExtremeValueDistribution[a, b]]

通过比较经验分位数和拟合分布的分位数，查看模型从数据偏离的位置：

Wolfram Language code: Row[Table[QuantilePlot[maxWinds, i, PlotLabel -> Head[i]], {i, {edist1, edist2}}]]

收入分布 (1)

对大型州立大型的收入建模：

Wolfram Language code: ExampleData[{"Statistics", "UniversitySalaries"}, "ColumnDescriptions"]

Wolfram Language code:

universityA = Cases[ExampleData[{"Statistics", "UniversitySalaries"}], {dept_, perc_, salary_, campus : "A"} :> {perc, salary}];

Wolfram Language code: salaries = Cases[universityA, {p_ ? Positive, s_ ? Positive} :> s / p];

假设工资服从 Dagum 分布：

Wolfram Language code: edist = EstimatedDistribution[salaries, DagumDistribution[p, a, b]]

假设它们服从广义 Pareto 分布：

Wolfram Language code:

edist2 = EstimatedDistribution[salaries, ParetoDistribution[k, α, γ, μ], ParameterEstimator -> {"MaximumLikelihood", "Method" -> "SimulatedAnnealing"}]

比较估计分布的细微差别：

Wolfram Language code:

Show[Histogram[salaries, {0, 200000, 10000}, "PDF"], Plot[{PDF[edist, x], PDF[edist2, x]}, {x, 0, 200000}, PlotStyle -> Thick, PlotLegends -> {DagumDistribution, ParetoDistribution}]]

机动车辆的汽油使用效率 (1)

中型小汽车的平均城市和高速里程数服从二次分布：

Wolfram Language code:

midsizeMPG2009 = {{16, 22}, {18, 26}, {17, 25}, {16, 23}, {16, 23}, {14, 19}, {13, 19}, {10, 14}, {10, 17}, {18, 28}, {18, 27}, {17, 25}, {17, 25}, {17, 26}, {17, 26}, {16, 25}, {17, 25}, {15, 22}, {15, 23}, {11, 17}, {11, 17}, {17, 28}, {16, 24}, {16, 25}, {16, 25}, {17, 26}, {18, 26}, {17, 26}, {17, 25}, {17, 26}, {13, 19}, {15, 24}, {17, 26}, {15, 22}, {22, 33}, {22, 30}, {18, 29}, {17, 26}, {26, 34}, {21, 30}, {13, 20}, {19, 27}, {16, 27}, {21, 30}, {13, 20}, {19, 27}, {16, 27}, {24, 30}, {23, 27}, {23, 29}, {21, 25}, {19, 27}, {10, 15}, {9, 16}, {17, 25}, {20, 29}, {20, 28}, {18, 26}, {24, 33}, {25, 33}, {16, 25}, {15, 23}, {22, 32}, {22, 32}, {20, 28}, {23, 30}, {24, 32}, {19, 27}, {19, 26}, {18, 25}, {17, 24}, {16, 24}, {16, 23}, {16, 24}, {16, 23}, {20, 22}, {17, 25}, {20, 29}, {20, 28}, {18, 26}, {17, 24}, {18, 28}, {20, 29}, {21, 30}, {17, 25}, {18, 25}, {23, 32}, {17, 24}, {16, 22}, {15, 22}, {13, 19}, {13, 20}, {20, 27}, {16, 25}, {23, 32}, {23, 31}, {18, 27}, {19, 26}, {35, 33}, {19, 26}, {24, 30}, {21, 29}, {26, 31}, {27, 33}, {24, 32}, {11, 18}, {24, 30}, {24, 32}, {22, 33}, {17, 26}, {26, 34}, {21, 31}, {21, 31}, {19, 28}, {33, 34}, {48, 45}, {19, 29}, {15, 23}, {15, 22}, {16, 25}};

假设每加仑的城市和高速里程数服从二次分布，并且具有相关关系：

Wolfram Language code: edist = EstimatedDistribution[midsizeMPG2009, BinormalDistribution[{μ1, μ2}, {σ1, σ2}, ρ]]

显示城市和高速里程数的分布：

Wolfram Language code:

Plot[Evaluate[PDF[MarginalDistribution[edist, #], x]& /@ {1, 2}], {x, 5, 40}, Filling -> Axis, PlotLegends -> {"city", "highway"}]

使用对数幅度的等高线可视化联合密度：

Wolfram Language code: ContourPlot[Log[PDF[edist, {x, y}]], {x, 0, 50}, {y, 0, 50}, Contours -> 50]

地震间隔时间 (1)

数据包含从1902年12月16日至1977年3月4日，在世界范围内的大地震（震级至少7.5或者超过1000人死亡）的等待时间（以天数为单位）：

Wolfram Language code: earthquakesWaitingTimes = ExampleData[{"Statistics", "EarthquakeWaitingTimes"}];

通过 ExponentialDistribution 对等待时间进行建模：

Wolfram Language code: edist = EstimatedDistribution[earthquakesWaitingTimes, ExponentialDistribution[λ]]

估计主要地震之间的天数的平均值和中位数：

Wolfram Language code: {Mean[edist], Median[edist]}

地震频率 (1)

每年的地震数目可以使用 SinghMaddalaDistribution 建模：

Wolfram Language code: ExampleData[{"Statistics", "USEarthquakes"}, "ColumnDescriptions"]

Wolfram Language code: earthquakes = Tally[Select[ExampleData[{"Statistics", "USEarthquakes"}], #[[1]] ≥ 1935&][[All, 1]]][[All, 2]]

对数据分布进行拟合：

Wolfram Language code: edist = EstimatedDistribution[earthquakes, SinghMaddalaDistribution[q, a, b]]

比较数据直方图和估计分布的概率密度函数：

Wolfram Language code: Show[Histogram[earthquakes, 15, "ProbabilityDensity"], Plot[PDF[edist, x], {x, 0, 140}, PlotStyle -> Thick]]

求一年内美国至少60次地震的概率：

Wolfram Language code: NProbability[x ≥ 60, xedist]

喷泉喷发的时间间隔 (1)

混合分布可以用来对多态数据进行建模：

Wolfram Language code: ExampleData[{"Statistics", "OldFaithful"}, "ColumnDescriptions"]

Wolfram Language code: waiting = ExampleData[{"Statistics", "OldFaithful"}][[All, 2]];

Old Faithful 泉喷发的等待时间的直方图呈现出两种模式：

Wolfram Language code: h = Histogram[waiting, 20, "ProbabilityDensity"]

对数据进行 MixtureDistribution 拟合：

Wolfram Language code: mdist = MixtureDistribution[{1 / 3, 2 / 3}, {GammaDistribution[a, b], GammaDistribution[c, d]}];

Wolfram Language code: edist = Quiet@EstimatedDistribution[waiting, mdist, {{a, 85}, {b, .5}, {c, 195}, {d, .4}}]

比较直方图和估计分布的概率密度函数：

Wolfram Language code: Show[h, Plot[PDF[edist, x], {x, 0, 100}, PlotStyle -> Thick]]

求等待时间超过 80 分钟的概率：

Wolfram Language code: NProbability[x > 80, xedist]

模拟未来60次喷发的等待时间：

Wolfram Language code: times = RandomVariate[edist, 60];

Wolfram Language code:

ListPlot[{times, {{1, m1}, {60, m1}}, {{1, m2}, {60, m2}}}, Joined -> {False, True, True}, Filling -> {1 -> Axis}, AxesOrigin -> {0, 40}]

股票价格的分布 (1)

对数正态分布可以用来对股票价格进行建模：

Wolfram Language code: stocks = FinancialData["SBUX", {{2010, 1, 1}, {2014, 1, 1}, "Day"}, "Value"];

对数据分布进行拟合：

Wolfram Language code: edist = EstimatedDistribution[stocks, LogNormalDistribution[μ, σ]]

观察到数据和分布的分位数匹配良好，除了最大的一些值以外：

Wolfram Language code: QuantilePlot[stocks, QuantityMagnitude[edist]]

水流速率 (1)

考虑马哈那迪河年平均最小日流量（以每秒立方米数为单位）：

Wolfram Language code: minFlow = ExampleData[{"Statistics", "MahanadiRiverFlow"}];

把年平均最小日流量作为 MinStableDistribution 建模：

Wolfram Language code: edist = EstimatedDistribution[minFlow, MinStableDistribution[a, b, c]]

比较数据直方图和估计分布的概率密度函数：

Wolfram Language code: Show[Histogram[minFlow, 10, "ProbabilityDensity"], Plot[PDF[edist, x], {x, 0, 7}, PlotStyle -> Thick]]

模拟未来30年的年平均最小日流量：

Wolfram Language code: ListLinePlot[RandomVariate[edist, 30]]

人口规模 (1)

使用帕累托分布对澳大利亚的城市人口规模进行建模：

Wolfram Language code: cities = CityData[{All, "Australia"}];

Wolfram Language code: populations = QuantityMagnitude[CityData[#, "Population"]& /@ cities];

Wolfram Language code: edist = EstimatedDistribution[populations, ParetoDistribution[k, α, γ, μ]]

估计城市具有至少 10,000 人口的概率：

Wolfram Language code: Probability[x ≥ 10000, xedist]

基于原始数据计算概率：

Wolfram Language code: Probability[x ≥ 10000, xpopulations]//N

属性和关系 (8)

EstimatedDistribution 给出插入参数估计的分布：

Wolfram Language code: EstimatedDistribution[{5, 8, 3, 4, 9, 6}, PoissonDistribution[μ]]

FindDistributionParameters 把参数估计作为替换规则给出：

Wolfram Language code: FindDistributionParameters[{5, 8, 3, 4, 9, 6}, PoissonDistribution[μ]]

EstimatedProcess 估计参数过程

Wolfram Language code: data = RandomFunction[BernoulliProcess[0.4], {0, 10 ^ 5}];

Wolfram Language code: EstimatedProcess[data, BernoulliProcess[p]]

EstimatedDistribution 估计参数分布：

Wolfram Language code: data = RandomVariate[BernoulliDistribution[0.4], 10 ^ 5];

Wolfram Language code: EstimatedDistribution[data, BernoulliDistribution[p]]

通过最大似然法估计分布参数：

Wolfram Language code: data = RandomVariate[ExponentialDistribution[3], 1000];

Wolfram Language code: EstimatedDistribution[data, ExponentialDistribution[λ]]

使用 DistributionFitTest 测试拟合质量：

Wolfram Language code: ℋ = DistributionFitTest[data, ExponentialDistribution[λ], "HypothesisTestData"]

提取拟合分布：

Wolfram Language code: ℋ["FittedDistribution"]

获取相关测试统计量和值组成的表格：

Wolfram Language code: ℋ[{"TestDataTable", All}]

EstimatedDistribution 在一个参数分布中估计参数：

Wolfram Language code: data = RandomVariate[NormalDistribution[0, 1], 50];

Wolfram Language code: edist = EstimatedDistribution[data, NormalDistribution[μ, σ]]

SmoothKernelDistribution 给出一个非参数化的内核密度估计：

Wolfram Language code: skdist = SmoothKernelDistribution[data]

比较非参数分布和参数分布的概率密度函数：

Wolfram Language code: Plot[{PDF[skdist, x], PDF[edist, x]}, {x, -3, 3}, PlotStyle -> Thick]

使用 SmoothHistogram 可视化非参数密度：

Wolfram Language code: SmoothHistogram[data, PlotStyle -> Thick]

EstimatedDistribution 给出参数的最大似然估计：

Wolfram Language code: data = RandomVariate[GammaDistribution[4, 10], 25];

Wolfram Language code: edist = EstimatedDistribution[data, GammaDistribution[α, β]]

使用 Likelihood 计算似然值：

Wolfram Language code: Likelihood[edist, data]

使用 LogLikelihood 计算对数似然值：

Wolfram Language code: LogLikelihood[edist, data]

通过匹配原始矩，估计参数：

Wolfram Language code: data = RandomVariate[BetaDistribution[2, 5], 100];

Wolfram Language code: edist = EstimatedDistribution[data, BetaDistribution[α, β], ParameterEstimator -> "MethodOfMoments"]

使用 Moment 从数据计算原始矩：

Wolfram Language code: {Moment[data, 1], Moment[data, 2]}

从估计分布计算同样的矩：

Wolfram Language code: {Moment[edist, 1], Moment[edist, 2]}

估计一个威布尔分布的参数：

Wolfram Language code: data = RandomVariate[WeibullDistribution[3, 15], 100];

Wolfram Language code: edist = EstimatedDistribution[data, WeibullDistribution[α, β]]

使用 QuantilePlot 可视化实际分位数比拟合分布分位数：

Wolfram Language code: QuantilePlot[data, edist]

当估计在 QuantilePlot 中实现时，获取同样的可视化：

Wolfram Language code: QuantilePlot[data, WeibullDistribution[α, β]]

EstimatedDistribution 忽略 TimeSeries 和 EventSeries 中的时间戳：

Wolfram Language code:

ts = TemporalData[TimeSeries, {{{1, 0, 1, 0, 0, 1, 0, 1, 1, 0, 0, 0, 0, 1, 0, 0, 0, 0, 1, 0, 1, 0, 0, 1, 
    0, 1, 0, 1, 0, 0, 0, 1, 0, 1, 0, 1, 0, 0, 1, 0, 0, 1, 1, 0, 0, 1, 0, 1, 1, 1, 0, 1, 1, 1, 0, 0, 
    0, 0, 0, 1, 0, 0, 0, 1, 0, 1, 1, 0, 1, 0, 0, 1, 1, 0, 0, 0, 0, 0, 0, 1, 0, 1, 0, 1, 1, 1, 0, 0, 
    1, 0, 0, 0, 1, 1, 1, 0, 1, 1, 1, 1}}, {{0, 99, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, 
  {ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 10.1];

Wolfram Language code: EstimatedDistribution[ts, BernoulliDistribution[p]]

与下面相同：

Wolfram Language code: EstimatedDistribution[ts["Values"], BernoulliDistribution[p]]

对于 TemporalData，忽略所有路径结构：

Wolfram Language code: td = TemporalData[«4»];

Wolfram Language code: EstimatedDistribution[td, NormalDistribution[a, b]]

与下面相同：

Wolfram Language code: EstimatedDistribution[td["ValueList"]//Flatten, NormalDistribution[a, b]]

可能存在的问题 (3)

矩方程方法的解可能给出无效的参数：

Wolfram Language code: EstimatedDistribution[{10, 12, 8, 15}, BinomialDistribution[n, p], ParameterEstimator -> "MethodOfMoments"]

Wolfram Language code: DistributionParameterQ[%]

对于连续分布：

Wolfram Language code: data = RandomVariate[NormalDistribution[-1, .1], 10 ^ 3];

Wolfram Language code: EstimatedDistribution[data, NormalDistribution[m, m], ParameterEstimator -> "MethodOfMoments"]

Wolfram Language code: DistributionParameterQ[%]

可能需要良好的初始值才能得到好的解：

Wolfram Language code: data = {4.1, 5.8, 4.3, 5.6, 3.8, 2.5, 3.1, 5.3, 5.4, 3.3};

Wolfram Language code: EstimatedDistribution[data, RiceDistribution[.01, α, β], ParameterEstimator -> "MethodOfMoments"]

Wolfram Language code:

EstimatedDistribution[data, RiceDistribution[.01, α, β], {{α, 4}, {β, .02}}, ParameterEstimator -> "MethodOfMoments"]

起始值选得好，可以较快地得到结果：

Wolfram Language code: data = RandomVariate[DirichletDistribution[Range[25]], 10 ^ 4];

Wolfram Language code: EstimatedDistribution[data, DirichletDistribution[Array[g, 25]]]//Timing

Wolfram Language code: EstimatedDistribution[data, DirichletDistribution[Array[g, 25]], Transpose[{Array[g, 25], Range[25]}]]//Timing

Top

	"MaximumLikelihood"	对数似然函数最大化
	"MethodOfMoments"	原始矩匹配
	"MethodOfCentralMoments"	中心矩匹配
	"MethodOfCumulants"	累积量匹配
	"MethodOfFactorialMoments"	阶乘矩匹配

AccuracyGoal	Automatic	要达到的准确度
ParameterEstimator	"MaximumLikelihood"	应该使用何种参数估计量
PrecisionGoal	Automatic	要达到的精度
WorkingPrecision	Automatic	内部计算所用的精度

EstimatedDistribution

更多信息和选项

范例

基本范例 (3)

范围 (15)

基本用途 (5)

单变量参数分布 (2)

多变量参数分布 (2)

导出分布 (6)

选项 (4)

ParameterEstimator (3)

WorkingPrecision (1)

应用 (14)

估计具有相似形状的分布 (1)

保险索赔 (1)

不同语言中单词的长度 (1)

文本频率 (1)

地震幅度 (1)

风速分析 (1)

收入分布 (1)

机动车辆的汽油使用效率 (1)

地震间隔时间 (1)

地震频率 (1)

喷泉喷发的时间间隔 (1)

股票价格的分布 (1)

水流速率 (1)

人口规模 (1)

属性和关系 (8)

可能存在的问题 (3)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX