WOLFRAM

Wolfram 语言与系统参考资料中心

LowpassFilter[data,ωc]

用截止频率为 ωc 的低通滤波器对一组数据进行处理.

LowpassFilter[data,ωc,n]

使用核长度为 n 的滤波器.

LowpassFilter[data,ωc,n,wfun]

对滤波器核运用平滑窗 wfun.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
数据  
参数  
选项  
Padding  
SampleRate  
应用  
属性和关系  
可能存在的问题  
互动范例  
参见
相关指南
历史
按以下格式引用：

LowpassFilter

LowpassFilter[data,ωc]

用截止频率为 ωc 的低通滤波器对一组数据进行处理.

LowpassFilter[data,ωc,n]

使用核长度为 n 的滤波器.

LowpassFilter[data,ωc,n,wfun]

对滤波器核运用平滑窗 wfun.

更多信息和选项

  • 低通滤波通常用于通过减少数据中的高频内容来对数据进行平滑或去噪.
  • LowpassFilter 将数字信号与使用窗口方法创建的有限脉冲响应 (FIR) 内核进行卷积.
  • data 可以采用以下形式：
  • list任意维数的数值数组
    tseries暂态数据，如 TimeSeries 和 TemporalData
    image任意 Image 或 Image3D 对象
    audioAudio 或 Sound 对象
    videoVideo 对象
  • 截止频率越小通常会导致平滑度越大. 内核更长会使得频率分辨力更好. »
  • LowpassFilter[data,ωc] 根据输入 data 和截止频率 ωc，采用不同的滤波器内核长度和平滑窗.
  • 常用平滑窗函数 wfun 包括：
  • BlackmanWindow用 Blackman 窗平滑
    DirichletWindow不使用平滑窗
    HammingWindow用 Hamming 窗平滑
    {v1,v2,…}使用数值 vi 组成的平滑窗
    f通过对 f 在 和 之间抽样生成平滑窗
  • 当应用于图像和多维数组时，从级别 1 开始依次对每个维度应用过滤. LowpassFilter[data,{ωc1,ωc2,…}] 使用频率 ωci 作为第 维.
  • 可使用以下选项：
  • Padding "Fixed"采用的填充数值
    SampleRate Automatic预设的输入抽样率
  • 缺省情况下，对于图像和列表，假定 SampleRate->1. 对于音频信号和时间序列，则从输入数据中提取或算出采样率.
  • 如果设 SampleRatesr，截止频率 ωc 应在 0 和 之间. »

范例

打开所有单元 关闭所有单元

基本范例  (3)

对含有噪声的方波进行低通滤波：

Wolfram Language code: data = Table[SquareWave[i / 100], {i, 225}] + RandomReal[{-0.1, 0.1}, 225]; GraphicsRow[ListLinePlot /@ {data, LowpassFilter[data, 0.5]}]

对音频进行低通滤波：

Wolfram Language code: LowpassFilter[\!\(\*AudioBox["![Embedded Audio Player](audio://content-1323j)"]\), Quantity[1000, "Hertz"]]

对图像进行低通滤波：

Wolfram Language code: LowpassFilter[[image], 0.5, 15]//ImageAdjust

范围  (14)

数据  (9)

对一维脉冲序列进行滤波：

Wolfram Language code: data = BoxMatrix[5, {41}]; ListLinePlot[{data, LowpassFilter[data, 0.5, 15]}]

对二维脉冲序列进行滤波：

Wolfram Language code: data = Table[UnitBox[(n/7), (m/7)], {n, -7, 7}, {m, -7, 7}]; ListPlot3D[data]
Wolfram Language code: LowpassFilter[data, 0.5, 15]//ListPlot3D

对 TimeSeries 进行滤波：

Wolfram Language code: ts = TemporalData[TimeSeries, {{{0., -0.27267267057145633, -0.6672983789995302, -0.5338541947930846, -0.6117404489279314, -0.6755527076595494, -0.02125421294486496, -0.10792797291843935, -0.6138271235477938, -0.3248568606554575, -0.08843449054 ... 2053424, -0.49980440691873723, -0.5388679788215971, -0.4101602764645551}}, {{0, 1., 0.01}}, 1, {"Continuous", 1}, {"Continuous", 1}, 1, {ValueDimensions -> 1, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 10.1]; filtered = LowpassFilter[ts, Quantity[10, "Hertz"]];
Wolfram Language code: ListLinePlot[{ts, filtered}, PlotLegends -> {"original data", "filtered"}]

三角波 Audio 对象的平滑处理：

Wolfram Language code: a = AudioGenerator[{"Triangle", 440}]
Wolfram Language code: AudioPlot[a, PlotRange -> {{0, 0.01}, All}]

用较低的截止频率移除信号的大部分谐波：

Wolfram Language code: AudioPlot[LowpassFilter[a, Quantity[500, "Hertz"]], PlotRange -> {{0, 0.01}, All}]

对双音多频 (DTMF) 信号的 Sound 对象进行低通滤波：

Wolfram Language code: s = Sound[SampledSoundList[Table[Sin[2 π 697 t] + Sin[2 π 1209 t], {t, 0., 0.3, 1 / 8000.}], 8000]]

用两个拨号音的中间频率作为截止频率，长度为 99，同时使用布莱克曼窗：

Wolfram Language code: LowpassFilter[s, Quantity[953, "Hertz"], 99, BlackmanWindow]

对彩色图像进行低通滤波：

Wolfram Language code: LowpassFilter[[image], 0.5]

对视频进行滤波：

Wolfram Language code: LowpassFilter[Video["ExampleData/fish.mp4"], .5]

对三维图像进行低通滤波：

Wolfram Language code: LowpassFilter[[image], 0.5]

精确滤波：

Wolfram Language code: LowpassFilter[{0, 0, 0, 1, 1, 1, 0, 0, 0}, Pi / 2, 3]

参数  (5)

数值截止频率会被解释为以弧度每秒为单位的量：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-iz4x8)"]\);
Wolfram Language code: LowpassFilter[a, 2000 π] === LowpassFilter[a, Quantity[2000*Pi, "Radians"/"Seconds"]] === LowpassFilter[a, Quantity[1000, "Hertz"]]

用 的截止频率对白噪音信号进行滤波：

Wolfram Language code: noise = AudioGenerator["White", 0.2]; Periodogram[noise]
Wolfram Language code: Periodogram[LowpassFilter[noise, Quantity[5000, "Hertz"]]]

使用更高频的值：

Wolfram Language code: Periodogram[LowpassFilter[noise, Quantity[10000, "Hertz"]]]

默认情况下，滤波器的长度及其频率分辨率取决于截止频率：

Wolfram Language code: noise = AudioGenerator["White", 0.2]; Periodogram[LowpassFilter[noise, Quantity[2000, "Hertz"]]]

截止频率越高会导致滤波器内核更短、过渡带更宽且频率分辨力更差：

Wolfram Language code: Periodogram[LowpassFilter[noise, Quantity[5000, "Hertz"]]]

用更长的内核增加滤波器的锐度和频率识别：

Wolfram Language code: Periodogram[LowpassFilter[noise, Quantity[5000, "Hertz"], 55]]

通过使用不同的窗函数来改变阻带衰减量：

Wolfram Language code: a = AudioGenerator[Sin[11025 2 π #^2]&]; Periodogram[LowpassFilter[a, Quantity[10000, "Hertz"], 33, #]& /@ {DirichletWindow, HammingWindow, BlackmanWindow}, PlotLegends -> {"Dirichlet", "Hamming", "Blackman"}]

增加滤波器长度以改善频率分辨率：

Wolfram Language code: a = AudioGenerator[Sin[11025 2 π #^2]&]; n = 33; Periodogram[MapThread[LowpassFilter[a, Quantity[10000, "Hertz"], #1, #2]&, {{n, 2n, 3n}, {DirichletWindow, HammingWindow, BlackmanWindow}}], PlotLegends -> {"Dirichlet", "Hamming", "Blackman"}]

用可调整的 Kaiser 窗改变衰减量：

Wolfram Language code: Periodogram[Table[LowpassFilter[a, Quantity[10000, "Hertz"], 33, KaiserWindow[#, b]&], {b, {3, 5, 7}}], PlotLegends -> {3, 5, 7}]

用数值列表指定窗函数：

Wolfram Language code: Periodogram[LowpassFilter[a, Quantity[10000, "Hertz"], 33, ConstantArray[1, {33}]]]

在各维度使用不同的截止频率：

Wolfram Language code: LowpassFilter[[image], {.5, 1.5}]

选项  (4)

Padding  (2)

不进行填充以消除边界伪影：

Wolfram Language code: LowpassFilter[[image], 0.2, Padding -> #]& /@ {Automatic, None}

不同的填充方法导致边呈现不同的效果：

Wolfram Language code: ramp = Range[21] / 21. + RandomReal[.1, 21]; GraphicsRow@(ListLinePlot[{ramp, LowpassFilter[ramp, 0.5, Padding -> #]}, ...]& /@ {"Fixed", "Periodic", 0})

SampleRate  (2)

使用长度为 5 的半带低通滤波器，假定采样率为 :

Wolfram Language code: LowpassFilter[{0, 0, 0, 0, 0, 1, 1, 1, 1, 1}, π / 2., 5]

假定采样率为 ：

Wolfram Language code: LowpassFilter[{0, 0, 0, 0, 0, 1, 1, 1, 1, 1}, 3 π / 2., 5, SampleRate -> 3]

将低通半带滤波器应用于采样率为 TemplateBox[{44100, "Hz", hertz, "Hertz"}, QuantityTF] 的音频信号：

Wolfram Language code: noise = AudioGenerator["White", 0.2]; sr = QuantityMagnitude@AudioSampleRate[noise]
Wolfram Language code: LowpassFilter[noise, sr π / 2.]//Periodogram

应用  (6)

通过使用 1000 Hz 的截止频率减少音频噪声：

Wolfram Language code: input = ExampleData[{"Audio", "Apollo11ReturnSafely"}]; Spectrogram[input]
Wolfram Language code: LowpassFilter[input, Quantity[1000, "Hertz"]]//Spectrogram

用 LowpassFilter 使得音频对象听起来不那么刺耳：

Wolfram Language code: cello = \!\(\*AudioBox["![Embedded Audio Player](audio://content-4obok)"]\);
Wolfram Language code: LowpassFilter[cello, Quantity[800, "Hertz"]]

在现代 88 键钢琴上，55 键（ C5 音符）的基频约为 523 Hz. 使用 LowpassFilter 可有效去除该键的所有谐波，同时保留以下音频剪辑中的基波：

Wolfram Language code: key55 = \!\(\*AudioBox["![Embedded Audio Player](audio://content-sglcp)"]\);

使用长度为 59 的滤波器，其截止频率介于基波 (523 Hz) 和其第一次 1046 Hz 的谐波之间：

Wolfram Language code: f = 1.5 523; res = LowpassFilter[key55, 2 π f, 59]

比较两个音频片段的频谱：

Wolfram Language code: Periodogram[{key55, res}, PlotRange -> All, GridLines -> All, PlotLegends -> {"original", "filtered"}, Epilog -> {Red, InfiniteLine[{{f, 0}, {f, 1}}]}]

模糊一幅图像：

Wolfram Language code: image = [image]; LowpassFilter[image, .5]

去掉 moiré 图案和高空间频率：

Wolfram Language code: LowpassFilter[[image], 2]

模糊图像的掩模：

Wolfram Language code: i = [image];
Wolfram Language code: 2i - LowpassFilter[i, .5]

属性和关系  (8)

将截止频率设为 0，则返回一个全部为 0 的序列：

Wolfram Language code: LowpassFilter[{0, 0, 0, 0, 0, 1, 1, 1, 1, 1}, 0]

将截止频率设为 π 或更大，生成一个全通滤波器：

Wolfram Language code: LowpassFilter[{0, 0, 0, 0, 0, 1, 1, 1, 1, 1}, π]

利用 LeastSquaresFilterKernel 和 Hamming 窗函数生成一个低通滤波器：

Wolfram Language code: n = 5; ω = 1.; win = Array[HammingWindow, n, {-1 / 2, 1 / 2}]; ker = Normalize[win LeastSquaresFilterKernel[{"Lowpass", ω}, n], Total]
Wolfram Language code: ListConvolve[ker, {0, 0, 0, 0, 0, 1, 1, 1, 1, 1}, Ceiling[n / 2], 0]

与 LowpassFilter 的结果进行比较：

Wolfram Language code: LowpassFilter[{0, 0, 0, 0, 0, 1, 1, 1, 1, 1}, ω, n, win, Padding -> 0]

低通滤波器的冲激响应：

Wolfram Language code: h = LowpassFilter[ArrayPad[{1}, 10], π / 2., 21]
Wolfram Language code: ListPlot[h, PlotRange -> All, Filling -> 0]

滤波器的幅频响应：

Wolfram Language code: Plot[Abs[ListFourierSequenceTransform[h, ω]], {ω, 0, π}]

长度为 21 且没有平滑窗的半带低通滤波器的冲激响应：

Wolfram Language code: h = LowpassFilter[ArrayPad[{1}, 10], π / 2., 21, None]
Wolfram Language code: ListPlot[h, PlotRange -> All, Filling -> 0]

滤波器的幅值谱：

Wolfram Language code: Plot[Abs[ListFourierSequenceTransform[h, ω]], {ω, 0, π}]

长度为偶数的没有平滑窗的滤波器的冲激响应：

Wolfram Language code: h = LowpassFilter[ArrayPad[{1}, 10], π / 2., 20, None]
Wolfram Language code: ListPlot[h, PlotRange -> All, Filling -> 0]

滤波器的幅值谱：

Wolfram Language code: Plot[Abs[ListFourierSequenceTransform[h, ω]], {ω, 0, π}]

低通滤波器的频率分辨力随着其长度的增加而提高：

Wolfram Language code: Manipulate[ ListLinePlot[Abs[Fourier[LowpassFilter[ArrayPad[{1.}, 128], Pi / 2, n, DirichletWindow], FourierParameters -> {1, -1}]][[ ;; 129]], ...], {{n, 21}, 3, 63, 1}]

冲激响应的长度随着滤波器带宽的减小而增加：

Wolfram Language code: Manipulate[ListPlot[DeleteCases[LowpassFilter[ArrayPad[{1.}, 65], ω, Padding -> 0], 0.], Filling -> 0, Axes -> {True, False}, Ticks -> None], {{ω, 1., "SubscriptBox[ω, c]"}, 0.125, 1.0}]

可能存在的问题  (1)

用 PaddingNone 将导致输出的长度比输入的长度短：

Wolfram Language code: LowpassFilter[{0, 0, 0, 1, 0, 0, 0}, 1., 7, Padding -> None]

使用较长的内核可能会得到一个空列表：

Wolfram Language code: LowpassFilter[{0, 0, 0, 1, 0, 0, 0}, 1., 11, Padding -> None]

互动范例  (1)

通过改变截止频率 ωc 消除图像的环状伪影：

Wolfram Language code: Manipulate[LowpassFilter[[image], w, Padding -> None], {{w, 1.5, "SubscriptBox[ω, c]"}, 0.25, 1.5}]
Wolfram Research (2012)，LowpassFilter，Wolfram 语言函数，https://reference.wolfram.com/language/ref/LowpassFilter.html （更新于 2025 年）.

文本

Wolfram Research (2012)，LowpassFilter，Wolfram 语言函数，https://reference.wolfram.com/language/ref/LowpassFilter.html （更新于 2025 年）.

CMS

Wolfram 语言. 2012. "LowpassFilter." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2025. https://reference.wolfram.com/language/ref/LowpassFilter.html.

APA

Wolfram 语言. (2012). LowpassFilter. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/LowpassFilter.html 年

BibTeX

@misc{reference.wolfram_2026_lowpassfilter, author="Wolfram Research", title="{LowpassFilter}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/LowpassFilter.html}", note=[Accessed: 09-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_lowpassfilter, organization={Wolfram Research}, title={LowpassFilter}, year={2025}, url={https://reference.wolfram.com/language/ref/LowpassFilter.html}, note=[Accessed: 09-November-2026]}