Wolfram 语言与系统参考资料中心

NDSolveValue

NDSolveValue[eqns,expr,{x,x_min,x_max}]

根据含有独立变量 x 的常微分方程 eqns 的数值解，给出函数表达式 expr 的值，其范围为 x_min 到 x_max.

NDSolveValue[eqns,expr,{x,x_min,x_max},{y,y_min,y_max}]

在矩形区域内求解偏微分方程 eqns.

NDSolveValue[eqns,expr,{x,y}∈Ω]

在区域 Ω 内求解偏微分方程 eqns.

NDSolveValue[eqns,u,{t,t_min,t_max},{x,y}∈Ω]

在区域 Ω 内求解时变偏微分方程 eqns.

NDSolveValue

NDSolveValue[eqns,expr,{x,x_min,x_max}]

根据含有独立变量 x 的常微分方程 eqns 的数值解，给出函数表达式 expr 的值，其范围为 x_min 到 x_max.

NDSolveValue[eqns,expr,{x,x_min,x_max},{y,y_min,y_max}]

在矩形区域内求解偏微分方程 eqns.

NDSolveValue[eqns,expr,{x,y}∈Ω]

在区域 Ω 内求解偏微分方程 eqns.

NDSolveValue[eqns,u,{t,t_min,t_max},{x,y}∈Ω]

在区域 Ω 内求解时变偏微分方程 eqns.

范例

打开所有单元关闭所有单元

基本范例 (7)

求解一阶常微分方程：

Wolfram Language code: ysol = NDSolveValue[{y'[x] == y[x]Cos[x + y[x]], y[0] == 1}, y, {x, 0, 30}]

在图中使用解：

Wolfram Language code: Plot[ysol[x], {x, 0, 30}, PlotRange -> All]

在图中使用函数和它的导数：

Wolfram Language code: ParametricPlot[{ysol[x], ysol'[x]}, {x, 0, 20}]

求指定值：

Wolfram Language code: {ysol[10.5], ysol'[12.5]}

NDSolveValue 也可以直接给出上述数值：

Wolfram Language code: NDSolveValue[{y'[x] == y[x]Cos[x + y[x]], y[0] == 1}, {y[10.5], y'[12.5]}, {x, 0, 30}]

二阶非线性常微分方程：

Wolfram Language code: ysol = NDSolveValue[{y''[x] + Sin[y[x]]y[x] == 0, y[0] == 1, y'[0] == 0}, y, {x, 0, 30}]

绘制函数和它的两个导数：

Wolfram Language code: Plot[{ysol[x], ysol'[x], ysol''[x]}, {x, 0, 30}]

或者将要绘制的函数直接代入 NDSolveValue：

Wolfram Language code:

Plot[Evaluate[NDSolveValue[{y''[x] + Sin[y[x]]y[x] == 0, y[0] == 1, y'[0] == 0}, {y[x], y'[x], y''[x]}, {x, 0, 30}]], {x, 0, 30}]

常微分方程组：

Wolfram Language code: {xsol, ysol} = NDSolveValue[{x'[t] == -y[t] - x[t] ^ 2, y'[t] == 2x[t] - y[t] ^ 3, x[0] == y[0] == 1}, {x, y}, {t, 20}]

Wolfram Language code: ParametricPlot[{xsol[t], ysol[t]}, {t, 0, 20}]

以下求解一维热方程：

Wolfram Language code:

usol = NDSolveValue[{D[u[t, x], t] == D[u[t, x], x, x], u[0, x] == 0, u[t, 0] == Sin[t], u[t, 5] == 0}, u, {t, 0, 10}, {x, 0, 5}]

Wolfram Language code: Plot3D[usol[t, x], {t, 0, 10}, {x, 0, 5}, PlotRange -> All]

方程的其他形式：

Wolfram Language code:

NDSolveValue[{Subscript[∂, t]u[t, x] == Subscript[∂, x, x]u[t, x], u[0, x] == 0, u[t, 0] == Sin[t], u[t, 5] == 0}, u, {t, 0, 10}, {x, 0, 5}]

求解 Disk 上的泊松方程：

Wolfram Language code: NDSolveValue[{-Laplacian[u[x, y], {x, y}] == 1, DirichletCondition[u[x, y] == 0, True]}, u[x, y], {x, y}∈Disk[]]

Wolfram Language code: Plot3D[%, {x, y}∈Disk[]]

求带有正弦边界条件 Disk 上的最小曲面：

Wolfram Language code:

NDSolveValue[{-Inactive[Div][(1/Sqrt[1 + Grad[u[x, y], {x, y}] . Grad[u[x, y], {x, y}]])*
  Inactive[Grad][u[x, y], {x, y}], {x, y}] == 0, DirichletCondition[u[x, y] == Sin[2π * (x + y)], True]}, u[x, y], {x, y}∈Disk[]]

Wolfram Language code: Plot3D[%, {x, y}∈Disk[]]

求区域上耦合的非线性正弦-戈登方程：

Wolfram Language code:

Ω = Polygon[2{{-Pi, -E}, {0, -1}, {0, 0}, {Pi, 0}, {Pi, E}, {-Pi, E}}];
NDSolveValue[{Laplacian[u[x, y], {x, y}] + λ Cos[v[x, y]]Sin[u[x, y]] == 0, Laplacian[v[x, y], {x, y}] + λ Sin[u[x, y]]Sin[v[x, y]] == 0, DirichletCondition[{u[x, y] == 1 / 10, v[x, y] == 1 / 20}, True]} /. λ -> 5, {u[x, y], v[x, y]}, {x, y}∈Ω]

Wolfram Language code: Plot3D[%, {x, y}∈Ω]

范围 (25)

常微分方程组 (7)

指定任意阶方程；自动简化为正常形式：

Wolfram Language code: xsol = NDSolveValue[{x''[t] + 1 / 10x'[t] + Sin[x[t]] == 1 / 2Cos[t], x[0] == x'[0] == 0}, x, {t, 0, 100}]

直接对解求导数，绘制相位图：

Wolfram Language code: ParametricPlot[{xsol[t], xsol'[t]}, {t, 0, 100}, ColorFunction -> Hue]

直接指定方程组：

Wolfram Language code:

{xsol, ysol, zsol} = NDSolveValue[{Derivative[1][x][t] == -3(x[t] - y[t]), Derivative[1][y][t] == -x[t]z[t] + 26.5x[t] - y[t], Derivative[1][z][t] == x[t]y[t] - z[t], x[0] == z[0] == 0, y[0] == 1}, {x, y, z}, {t, 0, 5}]

Wolfram Language code: Plot[{xsol[t], ysol[t], zsol[t]}, {t, 0, 5}]

求解一个向量值函数：

Wolfram Language code:

ysol = NDSolveValue[{Derivative[2][y][x] + (|   |   |   |   |
| :- | :- | :- | :- |
| 1 | 1 | 1 | 1 |
| 1 | 2 | 1 | 2 |
| 1 | 1 | 3 | 1 |
| 1 | 2 | 1 | 4 |).y[x] == 0, y[0] == Derivative[1][y][0] == {1, 1, 1, 1}}, y, {x, 0, 8}]

Wolfram Language code: ysol[5]

绘制解的四个分量：

Wolfram Language code: Plot[ysol[x], {x, 0, 8}]

指定谐波振荡器为一个二阶方程的不同的方法：

Wolfram Language code: xsol = NDSolveValue[{x''[t] + x[t] == 0, x[0] == 1, x'[0] == 0}, x, {t, 10}]

Wolfram Language code: Plot[Evaluate[{xsol[t], xsol'[t]}], {t, 0, 10}]

作为一个一阶方程组：

Wolfram Language code: {xsol, ysol} = NDSolveValue[{x'[t] == y[t], y'[t] == -x[t], x[0] == 1, y[0] == 0}, {x, y}, {t, 0, 10}]

Wolfram Language code: Plot[Evaluate[{xsol[t], ysol[t]}], {t, 0, 10}]

使用一个向量变量，维数从初始条件中导出：

Wolfram Language code: zsol = NDSolveValue[{z'[t] == {{0, 1}, {-1, 0}}.z[t], z[0] == {1, 0}}, z, {t, 0, 10}]

Wolfram Language code: Plot[zsol[t], {t, 0, 10}]

使用矩阵值变量计算基本的矩阵解：

Wolfram Language code: A = RandomReal[{0, 1}, {5, 5}];

Wolfram Language code: fs = NDSolveValue[{x'[t] == A.x[t], x[0] == IdentityMatrix[5]}, x, {t, 0, 1}]

比较精确解：

Wolfram Language code: Plot[Norm[Flatten[fs[t] - MatrixExp[A t]]], {t, 0, 1}]

定义一个 Van der Pol 方程：

Wolfram Language code: vdp = {x'[t] == y[t], y'[t] == -x[t] + 1000(1 - x[t] ^ 2)y[t], x[0] == 2, y[0] == 0};

默认求解器会自动处理解的“僵硬”行为：

Wolfram Language code: {xsol, ysol} = NDSolveValue[vdp, {x, y}, {t, 2000}]

Wolfram Language code: Plot[Evaluate[xsol[t]], {t, 0, 2000}, PlotRange -> All]

其他方法可能不能求解该方程组：

Wolfram Language code:

NDSolveValue[{Derivative[1][x][t] == y[t], Derivative[1][y][t] == -x[t] + 1000(1 - x[t]^2)y[t], x[0] == 2, y[0] == 0}, {x, y}, {t, 2000}, Method -> "ExplicitRungeKutta"]

解 ysol[x] 是连续的，因为它对分段函数只进行一次积分：

Wolfram Language code: ysol = NDSolveValue[{y'[x] + Cos[y[x]] == Floor[x], y[0] == 1}, y, {x, 0, 3}]

Wolfram Language code: Plot[ysol[x], {x, 0, 3}]

解 ysol[x] 是可微的，然而 ysol'[x] 只是连续的：

Wolfram Language code: ysol = NDSolveValue[{y''[x] + y[x] == Floor[x], y[0] == y'[0] == 1}, y, {x, 0, 5}]

Wolfram Language code: Plot[{ysol[x], ysol'[x]}, {x, 0, 5}]

偏微分方程组 (5)

一维非线性对流扩散方程：

Wolfram Language code:

usol = NDSolveValue[{D[u[t, x], t] == 0.5D[u[t, x], x, x] + u[t, x]D[u[t, x], x], u[t, -Pi] == u[t, Pi] == 0, u[0, x] == Sin[x]}, u, {t, 0, 2}, {x, -Pi, Pi}]

Wolfram Language code: Plot3D[usol[t, x], {t, 0, 2}, {x, -Pi, Pi}, PlotRange -> All]

定义混合抛物-双曲型的偏微分方程组：

Wolfram Language code:

pde = {Subscript[∂, t]u[t, x] == Subscript[∂, x]((v[t, x] - 1)Subscript[∂, x]u[t, x]) + (16x t - 2t - 16(v[t, x] - 1))(u[t, x] - 1) + 10x E^-4x, Subscript[∂, t]v[t, x] == Subscript[∂, {x, 2}]v[t, x] + Subscript[∂, x]u[t, x] + 4u[t, x] - 4 + x^2 - 2t - 10t E^-4x};

Wolfram Language code:

bc = {u[0, x] == 1, v[0, x] == 1, u[t, 0] == 1, v[t, 0] == 1, 3u[t, 1] + u^(0, 1)[t, 1] == 3, 5v^(0, 1)[t, 1] == E^4(u[t, 1] - 1)};

Wolfram Language code: {usol, vsol} = NDSolveValue[{pde, bc}, {u, v}, {x, 0, 1}, {t, 0, 2}]

Wolfram Language code:

Plot3D[{usol[t, x], vsol[t, x]}, {x, 0, 1}, {t, 0, 2}, PlotStyle -> {Directive[Opacity[0.7], Red], Directive[Opacity[0.7], Blue]}]

具有周期性边界条件的两个空间维度的非线性正弦-Gordon 方程：

Wolfram Language code:

L = 4;
usol = NDSolveValue[{D[u[t, x, y], t, t] == D[u[t, x, y], x, x] + D[u[t, x, y], y, y] + Sin[u[t, x, y]], u[t, -L, y] == u[t, L, y], u[t, x, -L] == u[t, x, L], u[0, x, y] == Exp[-(x ^ 2 + y ^ 2)], Derivative[1, 0, 0][u][0, x, y] == 0}, u, {t, 0, L / 2}, {x, -L, L}, {y, -L, L}]

绘制最终时间的解：

Wolfram Language code: Plot3D[usol[L / 2, x, y], {x, -L, L}, {y, -L, L}]

绘制解的径向截面的时间演化：

Wolfram Language code: Plot3D[usol[t, x, 0], {t, 0, L / 2}, {x, 0, L}]

求带有狭缝区域上的波动方程：

Wolfram Language code:

Ω = RegionDifference[RegionDifference[Rectangle[{0, 0}, {2, 1}], Rectangle[{9 / 10, 0}, {11 / 10, 4 / 10}]], Rectangle[{9 / 10, 6 / 10}, {11 / 10, 1}]];
sol = NDSolveValue[{D[u[t, x, y], {t, 2}] - Laplacian[u[t, x, y], {x, y}] == 0, DirichletCondition[u[t, x, y] == 0, True], u[0, x, y] == 2 * Exp[-125((x - 0.25) ^ 2 + (y - 0.5) ^ 2)], Derivative[1, 0, 0][u][0, x, y] == 0}, u, {t, 0, 2}, {x, y}∈Ω]

Wolfram Language code:

ListAnimate[Table[Rasterize[Plot3D[sol[t, x, y], {x, y}∈Ω, PlotRange -> {-0.75, 2}, AspectRatio -> Automatic]], {t, 0, 2, 1 / 25}], SaveDefinitions -> True]

求解曲线边界上带有周期边界条件的泊松方程：

Wolfram Language code: Ω = RegionDifference[RegionUnion[Disk[], Rectangle[{0, -1}, {2, 1}]], Disk[{2, 0}]];

Wolfram Language code:

ufun = NDSolveValue[{-Subsuperscript[∇, {x, y}, 2]u[x, y] == 1., PeriodicBoundaryCondition[u[x, y], (x - 2) ^ 2 + y ^ 2 == 1, Function[x, x - {2, 0}]], DirichletCondition[u[x, y] == 0, (0 < x < (2 - 10 ^ -6) && (y ≤ -1 || y ≥ 1))]}, u, {x, y}∈Ω];

可视化结果：

Wolfram Language code: ContourPlot[ufun[x, y], {x, y}∈Ω, ColorFunction -> "TemperatureMap", AspectRatio -> Automatic]

边界值问题 (5)

非线性多点边界值问题：

Wolfram Language code: {xsol, ysol} = NDSolveValue[{x''[t] == y[t]x[t], y'[t] == 2 - x[t], x[0] == x[4] == 1, y[1] == 1}, {x, y}, t]

Wolfram Language code: Plot[{xsol[t], ysol[t]}, {t, 0, 4}, Epilog -> {Point[{0, 1}], Point[{4, 1}], Red, Point[{1, 1}]}]

求解非线性扩散方程，其中狄利克雷和诺伊曼条件开始于的初始种子：

Wolfram Language code:

sol = NDSolveValue[{Inactive[Div][(-u[x]^2)*Inactive[Grad][u[x], {x}], {x}] == 4 + NeumannValue[2., x == 1], DirichletCondition[u[x] == 1., x == 0]}, u, {x}∈Line[{{0}, {1}}], InitialSeeding -> {u[x] == 1}]

可视化结果：

Wolfram Language code: Plot[sol[x], {x, 0, 1}]

求解非线性方程，其中狄利克雷和诺伊曼条件开始于的初始种子：

Wolfram Language code:

sol = NDSolveValue[{Subsuperscript[∇, {x}, 2]u[x] + 4u[x]D[u[x], x] == 2, DirichletCondition[u[x] == 1., True]}, u, {x}∈Line[{{0}, {1}}], InitialSeeding -> {u[x] == 1}]

可视化结果：

Wolfram Language code: Plot[sol[x], {x, 0, 1}]

求解带有狄利克雷边界条件的复值非线性反应方程：

Wolfram Language code:

sol = NDSolveValue[{-Subsuperscript[∇, {x}, 2]u[x] + I u[x] ^ 2 == 10, DirichletCondition[u[x] == -6I, x == 0], DirichletCondition[u[x] == -Sqrt[2]I, x == 1]}, u, {x}∈Line[{{0}, {1}}]]

可视化结果：

Wolfram Language code: ReImPlot[sol[x], {x, 0, 1}]

求解带有非线性负荷项的边界值问题：

Wolfram Language code:

sol = NDSolveValue[{Subsuperscript[∇, {x}, 2]u[x] == Sin[u[x]], DirichletCondition[u[x] == 5., x == 0], DirichletCondition[u[x] == 5.1, x == π / 2]}, u, {x}∈Line[{{0}, {π / 2}}]]

可视化结果：

Wolfram Language code: Plot[sol[x], {x, 0, π / 2}]

时滞微分方程 (2)

求解具有两个常量时滞和初始历史函数的时滞微分：

Wolfram Language code: xsol = NDSolveValue[{x'[t] == x[t](x[t - Pi] - x'[t - 1]), x[t /; t ≤ 0] == Cos[t]}, x, {t, 0, 8}]

不连续性在以等于时滞的间隔传播：

Wolfram Language code: Plot[Evaluate[{xsol[t], xsol'[t]}], {t, 0, 8}, PlotRange -> All]

研究线性时滞微分方程的稳定性：

Wolfram Language code:

Manipulate[
	Module[{sol, y, t}, 
	sol = NDSolveValue[{y'[t] == λ y[t] + μ y[t - 1], y[t /; t ≤ 0] == 1 - t}, y, 
	{t, 0, 10}];
	If[pp, ParametricPlot[{sol[t], sol[t - 1]}, {t, 1, 10}, PlotRange -> {{-3, 3}, {-3, 3}}], 
	Plot[sol[t], {t, 0, 10}, PlotRange -> {{0, 10}, {-3, 3}}]]], {{pp, False, "Plot in phase plane"}, {True, False}}, {{λ, -1}, -5, 5}, {{μ, 1}, -5, 5}, FrameLabel -> ToString[y'[t] == λ y[t] + μ y[t - 1], TraditionalForm]]

混合及不连续系统 (5)

等式右边不连续的差分方程：

Wolfram Language code: ifun = NDSolveValue[{y'[t] == -Sign[y[t]], y[0] == 1}, y[t], {t, 0, 2}];

Wolfram Language code: Plot[ifun, {t, 0, 2}, PlotRange -> All]

等式右边的值分为多段的差分方程：

Wolfram Language code:

ifun = NDSolveValue[{y'[t] == Piecewise[{{.5, 0 ≤ y[t] ≤ 1}, {1, 1 < y[t] ≤ 2}}, 0], y[0] == 0.5}, y[t], {t, 0, 3}];

Wolfram Language code: Plot[ifun, {t, 0, 3}]

等式右边在规则时间间隔时变化的微分方程：

Wolfram Language code:

ifun = NDSolveValue[{y'[t] == a[t], y[0] == 0, a[0] == 1, WhenEvent[Mod[t, 1] == 0, a[t] -> -a[t]]}, y[t], {t, 0, 5}, DiscreteVariables -> a[t]];

Wolfram Language code: Plot[ifun, {t, 0, 5}]

每次当解穿过负轴时，对其做关于轴的映射：

Wolfram Language code:

de = {x'[t] == y[t], y'[t] == -x[t] + .2y[t] + 1};
ic = {x[0] == .5, y[0] == .5};

Wolfram Language code: ifun = NDSolveValue[{de, ic, WhenEvent[And[y[t] == 0, x[t] < 0], x[t] -> -x[t]]}, {x[t], y[t]}, {t, 0, 1000}];

Wolfram Language code: ParametricPlot[ifun, {t, 0, 200}, PlotPoints -> 200]

具有滑动模式的周期解：

Wolfram Language code:

Manipulate[Module[{x0, y0, xsol, ysol}, 
	{x0, y0} = p;{xsol, ysol} = NDSolveValue[{x'[t] == y[t], y'[t] == If[y[t] - 1 > 0, -1, .1y[t] - x[t]], x[0] == x0, y[0] == y0}, {x, y}, {t, 0, 20}];
	ParametricPlot[{xsol[t], ysol[t]}, {t, 0, 20}, PlotRange -> {{-1.5, 1.5}, {-1.5, 1.5}}]], 
	{{p, {-1.5, 1.5}}, Locator}]

微分代数方程 (1)

具有代数约束的微分方程：

Wolfram Language code: {xsol, ysol} = NDSolveValue[{x'[t] == y[t] ^ 2 + x[t]y[t], 2x[t] ^ 2 + y[t] ^ 2 == 1, x[0] == 0}, {x, y}, {t, 0, 10}]

Wolfram Language code: ParametricPlot[{xsol[t], ysol[t]}, {t, 0, 10}, PlotRange -> All, AspectRatio -> 1]

推广和延伸 (1)

函数名称不必是符号：

Wolfram Language code:

eqns = {Table[Derivative[1][y[i]][x] == y[i - 1][x] - y[i][x], {i, 2, 4}], {Derivative[1][y[1]][x] == -y[1][x], Derivative[1][y[5]][x] == y[4][x], y[1][0] == 1}, Table[y[i][0] == 0, {i, 2, 5}]}

Wolfram Language code: sol = NDSolveValue[eqns, Table[y[i], {i, 5}], {x, 10}]

Wolfram Language code: Plot[Evaluate[Table[sol[[i]][x], {i, 5}]], {x, 0, 10}]

选项 (29)

AccuracyGoal 与 PrecisionGoal (1)

使用默认设置求解对初始条件具有敏感依赖性的天体力学方程：

Wolfram Language code: eqn = z''[t] == -z[t] / (z[t]^2 + ((1 + Sin[2π t] / 2) / 2)^2)^3 / 2;

Wolfram Language code: Plot[Evaluate[NDSolveValue[{eqn, z[0] == 1, z'[0] == 0}, z[t], {t, 0, 40}]], {t, 0, 40}]

设定更高的准确度和精度给出不同的计算结果：

Wolfram Language code:

Plot[Evaluate[NDSolveValue[{eqn, z[0] == 1, z'[0] == 0}, z[t], {t, 0, 40}, AccuracyGoal -> 10, PrecisionGoal -> 10]], {t, 0, 40}]

进一步提高准确度和精度以便更接近正确的解：

Wolfram Language code:

Plot[Evaluate[NDSolveValue[{eqn, z[0] == 1, z'[0] == 0}, z[t], {t, 0, 40}, AccuracyGoal -> 20, PrecisionGoal -> 20, WorkingPrecision -> 35, MaxSteps -> Infinity]], {t, 0, 40}]

DependentVariables (1)

设置一个很大的方程组：

Wolfram Language code:

n = 1000;
vars = Table[Subscript[x, i][t], {i, n}];
eqns = Table[j = Mod[i, n] + 1;{Subscript[x, i]'[t] == 1 / (Subscript[x, i][t] + Subscript[x, j][t])^2, Subscript[x, i][0] == 1 / i}, {i, n}];

Wolfram Language code: Short[eqns, 3]

求解所有相关变量，但只保存 x₁ 的解：

Wolfram Language code: x1sol = NDSolveValue[eqns, Subscript[x, 1], {t, 0, 100}, DependentVariables -> vars]

Wolfram Language code: Plot[x1sol[t], {t, 0, 100}, PlotRange -> All]

EvaluationMonitor (2)

总计算次数：

Wolfram Language code: Module[{c = 0}, NDSolveValue[{y'[x] == y[x]Cos[x + y[x]], y[0] == 1}, y, {x, 0, 30}, EvaluationMonitor :> c++];c]

连续计算间的距离；负距离意味被拒绝的步骤：

Wolfram Language code:

ListLinePlot[Differences[Reap[NDSolveValue[{y'[x] == y[x]Cos[x + y[x]], y[0] == 1}, y, {x, 0, 30}, EvaluationMonitor :> Sow[x]]][[2, 1]]]]

InitialSeedings (2)

为边界值问题指定 0 的初始化种子：

Wolfram Language code:

NDSolveValue[{-2u[x]Derivative[1][u][x] - Derivative[2][u][x] == 1, DirichletCondition[u[x] == 0, x == 0], DirichletCondition[u[x] == 0, x == 1]}, u, {x}∈Line[{{0}, {1}}], InitialSeeding -> {u[x] == 0}]

指定依赖于空间坐标的初始化种子：

Wolfram Language code:

NDSolveValue[{-2u[x]Derivative[1][u][x] - Derivative[2][u][x] == 0, DirichletCondition[u[x] == 0, x == 0], DirichletCondition[u[x] == 1, x == 1]}, u, {x}∈Line[{{0}, {1}}], InitialSeeding -> {u[x] == x}]

InterpolationOrder (1)

使用 InterpolationOrder->All 获取与方法同样阶数的插值：

Wolfram Language code:

Timing[{xa, ya} = NDSolveValue[{x'[t] == y[t], y'[t] == -x[t], x[0] == 1, y[0] == 0}, {x, y}, {t, 0, 1000}, InterpolationOrder -> All]]

这比使用默认插值阶数更耗时：

Wolfram Language code: Timing[{xd, yd} = NDSolveValue[{x'[t] == y[t], y'[t] == -x[t], x[0] == 1, y[0] == 0}, {x, y}, {t, 0, 1000}]]

步骤间更好：

Wolfram Language code: Plot[Evaluate[{xa[t], xd[t]} - Cos[t]], {t, 0, 10}, PlotRange -> All, PlotStyle -> {Directive[Thick, Blue], Red}]

MaxStepFraction (1)

有可能错过积分区间中相对较小的特征：

Wolfram Language code:

Table[Plot[Evaluate[NDSolveValue[{y''[x] + y[x] == Exp[-(1000(x / L - 1 / 3)) ^ 2], y[0] == y'[0] == 0}, y[x], {x, L}]], {x, L / 4, L / 2}, PlotRange -> All], {L, {1, 10, 100, 1000}}]

使用 MaxStepFraction 确保不错过特征，和区间大小无关：

Wolfram Language code:

Table[Plot[Evaluate[NDSolveValue[{y''[x] + y[x] == Exp[-(1000(x / L - 1 / 3)) ^ 2], y[0] == y'[0] == 0}, y[x], {x, L}, MaxStepFraction -> 0.001]], {x, L / 4, L / 2}, PlotRange -> All], {L, {1, 10, 100, 1000}}]

MaxSteps (1)

由于所需区间不能满足，停止进行积分计算：

Wolfram Language code: NDSolveValue[{y''[x] + x y[x] == 0, y[0] == 1, y'[0] == 0}, y, {x, 0, 200}]

需要更多的步骤才能解得答案：

Wolfram Language code: ysol = NDSolveValue[{y''[x] + x y[x] == 0, y[0] == 1, y'[0] == 0}, y, {x, 0, 200}, MaxSteps -> 10 ^ 6]

在相位平面绘制解：

Wolfram Language code: ParametricPlot[Evaluate[{ysol[x], ysol'[x]}], {x, 0, 200}, ColorFunction -> Function[Hue[#3]], AspectRatio -> 1]

MaxStepSize (2)

默认步骤控制可能错过突然变化的特征：

Wolfram Language code: NDSolveValue[{y''[x] + (1 + Sech[1000(x - Pi)])y[x] == 0, y[0] == 1, y'[0] == 0}, y, {x, 0, 10}][x]

Wolfram Language code:

Plot[Evaluate[NDSolveValue[{y''[x] + (1 + Sech[1000(x - Pi)])y[x] == 0, y[0] == 1, y'[0] == 0}, y, {x, 0, 10}][x] - Cos[x]], {x, 0, 10}]

更小的 MaxStepSize 设置保证 NDSolveValue 获取特征：

Wolfram Language code:

Plot[Evaluate[NDSolveValue[{y''[x] + (1 + Sech[1000(x - Pi)])y[x] == 0, y[0] == 1, y'[0] == 0}, y, {x, 0, 10}, MaxStepSize -> 0.01][x] - Cos[x]], {x, 0, 10}]

试图计算正整数小于的数目会错过多个事件：

Wolfram Language code: Block[{n = 0}, NDSolveValue[{y'[t] == y[t], y[-1] == E^-1, WhenEvent[Sin[π y[t]] == 0, n++]}, y, {t, 5}];n]

设置足够小的 MaxStepSize 保证不会错过任何事件：

Wolfram Language code:

Block[{n = 0}, NDSolveValue[{y'[t]  == y[t], y[-1] == E^-1, WhenEvent[Sin[π y[t]] == 0, n++]}, y, {t, 5}, MaxStepSize -> 0.001];n]

Method (12)

TimeIntegration (5)

使用默认求解方法时，相邻步骤间值的差异：

Wolfram Language code:

ListLinePlot[Differences[Reap[NDSolveValue[{y'[x] == y[x]Cos[x + y[x]], y[0] == 1}, y, {x, 0, 30}, StepMonitor :> Sow[x]]][[2, 1]]]]

在显式龙格库塔法中，步骤大小改变的很频繁：

Wolfram Language code:

ListLinePlot[Differences[Reap[NDSolveValue[{y'[x] == y[x]Cos[x + y[x]], y[0] == 1}, y, {x, 0, 30}, StepMonitor :> Sow[x], Method -> "ExplicitRungeKutta"]][[2, 1]]]]

差分阶数为 8：

Wolfram Language code:

ListLinePlot[Differences[Reap[NDSolveValue[{y'[x] == y[x]Cos[x + y[x]], y[0] == 1}, y, {x, 0, 30}, StepMonitor :> Sow[x], Method -> {"ExplicitRungeKutta", "DifferenceOrder" -> 8}]][[2, 1]]]]

差分阶数为 3，步骤更小：

Wolfram Language code:

ListLinePlot[Differences[Reap[NDSolveValue[{y'[x] == y[x]Cos[x + y[x]], y[0] == 1}, y, {x, 0, 30}, StepMonitor :> Sow[x], Method -> {"ExplicitRungeKutta", "DifferenceOrder" -> 3}]][[2, 1]]]]

外推法（Extrapolation）趋向于采取很大的步骤：

Wolfram Language code:

ListLinePlot[Differences[Reap[NDSolveValue[{y'[x] == y[x]Cos[x + y[x]], y[0] == 1}, y, {x, 0, 30}, StepMonitor :> Sow[x], Method -> "Extrapolation"]][[2, 1]]]]

BoundaryValues (1)

求解边界值问题：

Wolfram Language code: xsol0 = NDSolveValue[{x''[t] + Sin[x[t]] == 0, x[0] == x[10] == 0}, x, t]

采用默认选项设置，得出的是平凡解：

Wolfram Language code: Table[xsol0[t], {t, 0, 10}]

为 "Shooting" 解法指定不同的起始条件来求出不同的解：

Wolfram Language code:

xsols = Map[NDSolveValue[{x''[t] + Sin[x[t]] == 0, x[0] == x[10] == 0}, x, t, Method -> {"Shooting", "StartingInitialConditions" -> {x[0] == 0, x'[0] == #}}]&, 
	{1.5, 1.75, 2}];
Plot[Evaluate[Through[xsols[t]]], {t, 0, 10}, PlotStyle -> {StandardGray, Blue, Green}]

DiscontinuityProcessing (1)

NDSolveValue 会自动处理像 Sign 这样的不连续函数：

Wolfram Language code: xsol1 = NDSolveValue[{x'[t] == Sign[1 - x[t]], x[0] == 0}, x, {t, 0, 2}]

如果相应的选项被设置为无效的话，碰到断点，NDSolveValue 可能会无法继续进行计算：

Wolfram Language code: NDSolveValue[{x'[t] == Sign[1 - x[t]], x[0] == 0}, x, {t, 0, 2}, Method -> {"DiscontinuityProcessing" -> False}]

对于有些时间积分方法，求得的解会很不准确：

Wolfram Language code:

xsol2 = NDSolveValue[{x'[t] == Sign[1 - x[t]], x[0] == 0}, x, {t, 0, 2}, Method -> {"DiscontinuityProcessing" -> False, "TimeIntegration" -> "Extrapolation"}]

Wolfram Language code: Plot[{xsol1[t], xsol2[t]}, {t, 0, 2}]

另一个办法是利用 "DiscontinuitySignature" 求解：

Wolfram Language code:

xsol3 = NDSolveValue[{Derivative[1][x][t] == v[t], WhenEvent[1 == x[t], v[t] -> "DiscontinuitySignature"], x[0] == 0, v[0] == 1}, x, {t, 0, 2}, DiscreteVariables -> {Element[v, {-1, 0, 1}]}]

解实际上是一样的：

Wolfram Language code: Table[(xsol1[t]) - (xsol3[t]), {t, 0, 2, .25}]

EquationSimplification (1)

由于平方根函数不够平滑，无法求得全部的解：

Wolfram Language code: NDSolveValue[{Derivative[1][x][t] ^ 2 + x[t] ^ 2 == 1, x[0] == 1 / 2}, x, {t, 0, 10Pi}]

通过形成残差，作为 DAE 求解，可以得到一个解：

Wolfram Language code:

xsol1 = NDSolveValue[{Derivative[1][x][t] ^ 2 + x[t] ^ 2 == 1, x[0] == 1 / 2}, x, {t, 0, 10Pi}, Method -> {"EquationSimplification" -> "Residual"}]

通过指定一个统一的的值，可以求得其它解：

Wolfram Language code:

xsol2 = NDSolveValue[{Derivative[1][x][t] ^ 2 + x[t] ^ 2 == 1, x[0] == 1 / 2, x'[0] == -Sqrt[3 / 4]}, x, {t, 0, 10Pi}, Method -> {"EquationSimplification" -> "Residual"}]

Wolfram Language code: Plot[{xsol1[t], xsol2[t]}, {t, 0, 10Pi}]

IndexReduction (1)

一个指数 3 的约束摆问题表述方程，需要用降指数方法：

Wolfram Language code:

eqns = {x''[t] == T[t]x[t], y''[t] == T[t]y[t] - 1, x[t] ^ 2 + y[t] ^ 2 == 1};
init = {x[0] == 1, y[0] == 0, y'[0] == -14 / 10};

默认解法只能求解指数 1 问题：

Wolfram Language code: NDSolveValue[{eqns, init}, {T, x, y}, {t, 0, 10}]

经过符号指数降阶处理的问题是可解的：

Wolfram Language code:

s1 = NDSolveValue[{x''[t] == T[t]x[t], y''[t] == T[t]y[t] - 1, x[t] ^ 2 + y[t] ^ 2 == 1, x[0] == 1, y[0] == 0, y'[0] == -14 / 10}, {T, x, y}, {t, 0, 10}, Method -> {"IndexReduction" -> True}]

降阶为指数 0 并使用投影法以满足约束条件：

Wolfram Language code:

s2 = NDSolveValue[{x''[t] == T[t]x[t], y''[t] == T[t]y[t] - 1, x[t] ^ 2 + y[t] ^ 2 == 1, x[0] == 1, y[0] == 0, y'[0] == -14 / 10}, {T, x, y}, {t, 0, 10}, Method -> {"IndexReduction" -> {True, "ConstraintMethod" -> "Projection"}}]

绘制两个解在时间步长上的隐式能量约束条件：

Wolfram Language code:

energy[sol_] := Module[{T, x, y, times, es}, 
	{T, x, y} = sol;times = Part[x, 3, 1];es[t_] = 1 + y[t] + (1/2)(-y[t]Derivative[1][x][t] + x[t]Derivative[1][y][t])^2;Transpose[{times, es[times] - es[0]}]];

Wolfram Language code: ListPlot[{energy[s1], energy[s2]}]

DAEInitialization (1)

用前向配置法来初始化以避免在 0 点处有 Abs 项的问题：

Wolfram Language code:

NDSolveValue[{x'[t] == Abs[u[t]], u[t] == Sin[t], y[t] == x[t], y[0] == 10}, {x, y, u}, {t, 0, 10}, Method -> {"DAEInitialization" -> {"Collocation", "CollocationDirection" -> "Forward"}}]

PDEDiscretization (2)

Bergers 方程的解可能会变陡，出现数值不稳定性问题：

Wolfram Language code:

usol1 = NDSolveValue[{Subscript[∂, t]u[t, x] == (1/1000)Subscript[∂, x, x]u[t, x] - u[t, x]Subscript[∂, x]u[t, x], u[0, x] == Sin[2π x], u[t, 0] == u[t, 1]}, u, {t, 0, 2}, {x, 0, 1}]

Wolfram Language code:

end = Part[usol1, 1, 1, -1];
Plot[usol1[end, x], {x, 0, 1}]

指定足够精细的空间离散，求出前端：

Wolfram Language code:

usol2 = NDSolveValue[{Subscript[∂, t]u[t, x] == (1/1000)Subscript[∂, x, x]u[t, x] - u[t, x]Subscript[∂, x]u[t, x], u[0, x] == Sin[2π x], u[t, 0] == u[t, 1]}, u, {t, 0, 2}, {x, 0, 1}, Method -> {"PDEDiscretization" -> {"MethodOfLines", "SpatialDiscretization" -> {"TensorProductGrid", "MinPoints" -> 1000}}}]

Wolfram Language code:

end = Part[usol2, 1, 1, -1];
Plot[usol2[end, x], {x, 0, 1}]

前端形成之后，方程的解开始相对快速的衰减：

Wolfram Language code:

X = Part[usol2, 3, 2];
Plot[Max[usol2[t, X]], {t, 0, 2}]

在细化网格上求解瞬态薛定谔方程：

Wolfram Language code:

solution = NDSolveValue[{Inactive[Div][{{-(1/2)}} . Inactive[Grad][u[t, x], {x}], {x}] == I u^(1, 0)[t, x], u[0, x] == E^(-3I  x - (1/20) x^2), DirichletCondition[u[t, x] == 0, True]}, u, {t, 0, 5}, {x, -10, 10}, Method -> {"PDEDiscretization" -> {"MethodOfLines", "SpatialDiscretization" -> {"FiniteElement", "MeshOptions" -> {"MaxCellMeasure" -> 0.1}}}}]

绘制更高精度的解：

Wolfram Language code: Plot3D[Evaluate[Abs[solution[t, x]]], {x, -10, 10}, {t, 0, 5}, PlotPoints -> 50, AxesLabel -> {x, t}]

NormFunction (1)

绘制使用不同误差估计范数情况下，实际解的误差：

Wolfram Language code:

L = 5;Table[usol[p] = NDSolveValue[{D[u[t, x], t, t] == D[u[t, x], x, x], u[0, x] == Exp[-x ^ 2], Derivative[1, 0][u][0, x] == -Exp[-x ^ 2], u[t, -L] == u[t, L]}, u, {t, 0, 4L}, {x, -L, L}, NormFunction -> (Norm[#, p]&)];
Plot[Evaluate[(usol[p][4L, x]) - (Exp[-x ^ 2] - 2Sqrt[π])], {x, -L, L}, PlotRange -> All], {p, {1, 2, 3, ∞}}]

最佳解的图：

Wolfram Language code: Plot3D[usol[1][t, x], {t, 0, 4L}, {x, -10, 10}, Mesh -> False, PlotPoints -> 20]

StartingStepSize (1)

对于很大的间隔，接近始端的短暂特征可能错过：

Wolfram Language code:

feature[t_ ? NumberQ] := If[t < 1, t Sin[10Pi t], 0];xsol = NDSolveValue[{x''[t] + 10 ^ -4x[t] == feature[t], x[0] == x'[0] == 0}, x, {t, 0, 10000}]

Wolfram Language code: Max[Abs[xsol[RandomReal[{0, 10000}, 10000]]]]

设置足够小的步骤尺寸来开始以保证不会错过输入：

Wolfram Language code: xsol = NDSolveValue[{x''[t] + 10 ^ -4x[t] == feature[t], x[0] == x'[0] == 0}, x, {t, 0, 10000}, StartingStepSize -> 0.1]

Wolfram Language code: {Plot[xsol[t], {t, 0, 2}], Plot[xsol[t], {t, 0, 10000}]}

StepMonitor (3)

在解的过程中接受步骤的每个点上绘制解：

Wolfram Language code:

ListLinePlot[Reap[NDSolveValue[{y'[x] == y[x]Cos[x + y[x]], y[0] == 1}, y, {x, 0, 30}, StepMonitor :> Sow[{x, y[x]}]]][[2, 1]]]

步骤总数包含在求解过程中：

Wolfram Language code: Module[{c = 0}, NDSolveValue[{y'[x] == y[x]Cos[x + y[x]], y[0] == 1}, y, {x, 0, 30}, StepMonitor :> c++];c]

连续步骤上值间的差分：

Wolfram Language code:

ListLinePlot[Differences[Reap[NDSolveValue[{y'[x] == y[x]Cos[x + y[x]], y[0] == 1}, y, {x, 0, 30}, StepMonitor :> Sow[x]]][[2, 1]]]]

WorkingPrecision (1)

100 个周期的谐波振荡器的解的误差：

Wolfram Language code:

T = 200Pi;
Timing[NDSolveValue[{y''[x] + y[x] == 0, y[0] == 0, y'[0] == 1}, y, {x, 0, T}, MaxSteps -> Infinity][T]]

当增加工作精度，局部公差相应增加：

Wolfram Language code:

Timing[NDSolveValue[{y''[x] + y[x] == 0, y[0] == 0, y'[0] == 1}, y, {x, 0, T}, WorkingPrecision -> 32, MaxSteps -> 10 ^ 6][T]]

具有大的工作精度，有时，"Extrapolation" 方法相当有效：

Wolfram Language code:

Timing[NDSolveValue[{y''[x] + y[x] == 0, y[0] == 0, y'[0] == 1}, y, {x, 0, T}, WorkingPrecision -> 32, Method -> "Extrapolation"][T]]

应用 (22)

Duffing 方程 (2)

模拟双势阱中粒子的 Duffing 方程：

Wolfram Language code: xsol = NDSolveValue[{x''[t] + 0.15x'[t] - x[t] + x[t] ^ 3 == 0.3Cos[t], x[0] == -1, x'[0] == 1}, x, {t, 0, 50}]

Wolfram Language code: Plot[xsol[t], {t, 0, 50}]

解强烈依赖于初始条件：

Wolfram Language code:

xsol = NDSolveValue[{x''[t] + 0.15x'[t] - x[t] + x[t] ^ 3 == 0.3Cos[t], 
x[0] == -1, x'[0] == 1.001}, x, {t, 0, 50}]

Wolfram Language code: Plot[xsol[t], {t, 0, 50}]

Lotka–Volterra 方程组 (1)

Lotka–Volterra 猎物捕食方程 [更多信息]：

Wolfram Language code:

{xsol, ysol} = NDSolveValue[{y'[t] == y[t](x[t] - 1), x'[t] == x[t](2 - y[t]), x[0] == 1, y[0] == 2.7}, {x, y}, {t, 0, 10}]

相位平面图：

Wolfram Language code: ParametricPlot[{xsol[t], ysol[t]}, {t, 0, 10}]

Lorenz 方程组 (1)

Lorenz 方程组 [更多信息]:

Wolfram Language code:

{xsol, ysol, zsol} = NDSolveValue[{Derivative[1][x][t] == -3(x[t] - y[t]), Derivative[1][y][t] == -x[t]z[t] + 26.5x[t] - y[t], Derivative[1][z][t] == x[t]y[t] - z[t], x[0] == z[0] == 0, y[0] == 1}, {x, y, z}, {t, 0, 200}, MaxSteps -> ∞]

Wolfram Language code: ParametricPlot3D[{xsol[t], ysol[t], zsol[t]}, {t, 0, 200}, PlotPoints -> 1000, ColorFunction -> (Hue[#4]&)]

Gavrilov–Shilnikov 模型 (1)

看蓝天灾变轨道的外观：

Wolfram Language code:

eqns = {
	x'[t] == x[t](2 + μ - 10(x[t] ^ 2 + y[t] ^ 2)) + z[t] ^ 2 + y[t] ^ 2 + 2y[t], 
	y'[t] == -z[t] ^ 3 - (1 + y[t])(z[t] ^ 2 + y[t] ^ 2 + 2y[t]) - 4x[t] + μ y[t], 
	z'[t] == (1 + y[t])z[t] ^ 2 + x[t] ^ 2 - ϵ};

Wolfram Language code:

Table[Block[{ϵ = 0.0357, T = 1000}, 
	{xsol, ysol, zsol} = NDSolveValue[{eqns, x[0] == y[0] == z[0] == 1}, {x, y, z}, {t, 0, T}, MaxSteps -> ∞];
	ParametricPlot3D[{xsol[t], ysol[t], zsol[t]}, {t, T / 4, T}, BoxRatios -> 1, PlotPoints -> 1000, PlotRange -> All]], {μ, .455, .456, .001}]

热方程 (2)

在具有定期表面加热，深度为处的土壤温度的简单模型：

Wolfram Language code:

usol = NDSolveValue[{D[u[t, x], t] == D[u[t, x], x, x], u[0, x] == 0, u[t, 0] == Sin[t], u[t, 5] == 0}, u, {t, 0, 10}, {x, 0, 5}]

Wolfram Language code: Plot3D[Evaluate[usol[t, x]], {t, 0, 10}, {x, 0, 5}, PlotRange -> All]

热源位于棒中，模拟温度场：

Wolfram Language code:

vars = {Θ[x], {x}};
pars = <|"ThermalConductivity" -> 0.026, "HeatSource" -> 1|>;
Ω = Line[{{0}, {1}}];
eqn = HeatTransferPDEComponent[vars, pars] == 0

解 PDE：

Wolfram Language code: Tfun = NDSolveValue[{eqn, HeatTemperatureCondition[x == 0, vars, pars, <|"SurfaceTemperature" -> 0|>]}, Θ, x∈Ω];

可视化解：

Wolfram Language code: Plot[Tfun[x], {x}∈Ω]

有关热方程和适用的边界条件的更多信息，请参见 Heat Transfer 教程和 Heat Transfer PDE models 指南页面.

波方程 (1)

具有周期边界条件的简单波演化：

Wolfram Language code:

usol = NDSolveValue[{Subscript[∂, t, t]u[t, x] == Subscript[∂, x, x]u[t, x], u[0, x] == E^-x^2, u^(1, 0)[0, x] == 0, u[t, -10] == u[t, 10]}, u, {t, 0, 40}, {x, -10, 10}]

绘制解：

Wolfram Language code: DensityPlot[usol[t, x], {t, 0, 40}, {x, -10, 10}, PlotPoints -> 30]

Wolfram 非线性波方程 (3)

Wolfram 非线性波方程 [更多信息]：

Wolfram Language code:

usol = NDSolveValue[{Subscript[∂, t, t]u[t, x] == Subscript[∂, x, x]u[t, x] + (1 - u[t, x]^2)(1 + 2u[t, x]), u[0, x] == E^-x^2, u^(1, 0)[0, x] == 0, u[t, -10] == u[t, 10]}, u, {t, 0, 10}, {x, -10, 10}]

Wolfram Language code: Plot3D[usol[t, x], {t, 0, 10}, {x, -10, 10}]

Wolfram Language code: DensityPlot[usol[-t, x], {x, -10, 10}, {t, 0, -10}]

使用 Wolfram 的非线性波动方程进行建模 [更多信息]，并采用狄里克雷条件.

定义初始和边界条件：

Wolfram Language code: ics = {u[0, x] == Exp[-x ^ 2], Derivative[1, 0][u][0, x] == 0};

Wolfram Language code: bcs = DirichletCondition[u[t, x] == 0, True];

解方程：

Wolfram Language code:

sol = NDSolveValue[{(1 + 2 u[t, x]) (-1 + u[t, x]^2) + Inactive[Div][-Inactive[Grad][u[t, x], {x}], {x}] + u^(2, 0)[t, x] == 0, ics, bcs}, u, {t, 0, 10}, {x, -10, 10}]

可视化结果：

Wolfram Language code: Plot3D[sol[t, x], {x, -10, 10}, {t, 0, 10}, ...]

以下求解方程的 2+1-维度的版本：

Wolfram Language code:

usol = NDSolveValue[{D[u[t, x, y], t, t] == D[u[t, x, y], x, x] + D[u[t, x, y], y, y] / 2 + (1 - u[t, x, y] ^ 2)(1 + 2u[t, x, y]), u[0, x, y] == E^-(x^2 + y^2), u[t, -5, y] == u[t, 5, y], u[t, x, -5] == u[t, x, 5], u^(1, 0, 0)[0, x, y] == 0}, u, {t, 0, 4}, {x, -5, 5}, {y, -5, 5}]

Wolfram Language code: Table[Plot3D[usol[t, x, y], {x, -5, 5}, {y, -5, 5}, PlotRange -> All], {t, 1, 4}]

n-体问题 (1)

简化的 3-体问题 [更多信息]：

Wolfram Language code: eqn = z''[t] == -(z[t]/(z[t]^2 + ((1/2)(1 + 0.1Sin[2Pi t]))^2)^3 / 2);

Wolfram Language code: zsol = NDSolveValue[{eqn, z[0] == 1, z'[0] == 0}, z, {t, 0, 30}]

Wolfram Language code: Plot[zsol[t], {t, 0, 30}]

公式化适于不同的初始条件数目：

Wolfram Language code: eqn = D[z[t, s], t, t] == -(z[t, s]/(z[t, s]^2 + ((1/2)(1 + 0.1Sin[2Pi t]))^2)^3 / 2);

Wolfram Language code: zsol = NDSolveValue[{eqn, z[0, s] == s, Derivative[1, 0][z][0, s] == 0}, z, {t, 0, 10}, {s, 1, 2}]

Wolfram Language code: Plot3D[zsol[tp, z0], {tp, 0, 10}, {z0, 1, 2}]

非线性薛定谔方程 (2)

由周期源项驱动的移动孤子：

Wolfram Language code:

L = 50;
usol = NDSolveValue[{I D[u[t, x], t] + D[u[t, x], x, x] + 2Abs[u[t, x]] ^ 2u[t, x] == 0.1(1 - Cos[Pi x / L]), u[0, x] == Sech[x]Exp[I x], u[t, -L] == u[t, L]}, u, {t, 0, 10}, {x, -L, L}]

Wolfram Language code: Plot3D[Abs[usol[t, x]], {t, 0, 10}, {x, -L, L}, PlotPoints -> 60, MaxRecursion -> 3, Mesh -> None]

周期势场下的运动孤子：

Wolfram Language code:

L = 20;
usol = NDSolveValue[{I D[u[t, x], t] + D[u[t, x], x, x] + 2 Abs[u[t, x]] ^ 2 u[t, x] + 0.1 (1 - Cos[Pi x / L]) u[t, x] == 0, u[0, x] == Sech[x]Exp[I x], u[t, -L] == u[t, L]}, u, {t, 0, 15}, {x, -L, L}]

Wolfram Language code: Plot3D[Abs[usol[t, x]], {t, 0, 15}, {x, -L, L}, PlotPoints -> 60, PlotRange -> All, MaxRecursion -> 3]

Korteweg-de Vries (KdV) 方程 (2)

定义标准形式的 KdV 方程：

Wolfram Language code: KdV = {D[u[x, t], t] + D[u[x, t], {x, 3}] + 6u[x, t]D[u[x, t], x] == 0}

求解具有周期边界条件的行波孤子解：

Wolfram Language code: sol = NDSolveValue[{KdV, u[x, 0] == 2 - 2 Tanh[(1/4) + x]^2, u[-50, t] == u[50, t]}, u, {x, -50, 50}, {t, 0, 10}]

Wolfram Language code:

Plot[Evaluate[Table[sol[x, t], {t, 1, 12, 3}]], {x, -5, 50}, PlotRange -> All, Filling -> Axis, Epilog -> {Arrow[{{5, 1.6}, {9, 1.6}}], Arrow[{{17, 1.6}, {21, 1.6}}], Arrow[{{29, 1.6}, {33, 1.6}}], Arrow[{{41, 1.6}, {45, 1.6}}]}]

定义 KdV 方程的另一种形式：

Wolfram Language code: KdV = {D[u[x, t], t] + D[u[x, t], {x, 3}] - 6u[x, t]D[u[x, t], x] == 0}

从双曲正割平方初始条件分裂成两个孤子：

Wolfram Language code:

sol = NDSolveValue[{KdV, u[x, 0] == -6 Sech[x]^2, u[-50, t] == u[50, t]}, u, {x, -50, 50}, {t, 0, 10}, Method -> {"MethodOfLines", "SpatialDiscretization" -> {"TensorProductGrid", "MaxPoints" -> 5000, "MinPoints" -> 5000}, Method -> "StiffnessSwitching"}]

Wolfram Language code: ListAnimate[Plot[#, {x, -50, 50}, PlotRange -> All]& /@ Table[sol[x, t], {t, 0, 10, 0.1}], SaveDefinitions -> True]

Mackey–Glass 方程 (1)

查看 Mackey–Glass 时滞微分方程的解：

Wolfram Language code:

Manipulate[
	Module[{xsol, x, t}, 
	xsol = NDSolveValue[{x'[t] == a x[t - τ] / (1 + x[t - τ] ^ 10) - b x[t], x[t /; t ≤ 0] == 1 / 2}, x, {t, 0, 500}];
	ParametricPlot[{xsol[t], xsol[t - τ]}, {t, 300, 500}, PlotRange -> {{0, 2}, {0, 2}}]], {{a, .2}, 0, 1}, {{b, .1}, 0, 1}, 
	{{τ, 17}, 1, 20}]

声学方程 (1)

定义瞬态声压场的模型变量 vars，模型参数为 pars：

Wolfram Language code:

vars = {p[t, x], t, {x}};
pars = <|"SoundSpeed" -> 343, "MassDensity" -> 1.2|>;

定义向右传播的声波的初始条件 ics：

Wolfram Language code:

p0 = D[0.125 Erf[(x - 0.5) / 0.15], x];
ics = {p[0, x] == p0, Derivative[1, 0][p][0, x] == -343 * D[p0, x]};

设置方程，右侧为声硬边界条件：

Wolfram Language code: eqn = AcousticPDEComponent[vars, pars] == AcousticSoundHardValue[x == 1, vars, pars]

解 PDE：

Wolfram Language code: pfun = NDSolveValue[{eqn, ics}, p, {t, 0, 0.003}, x∈Line[{{0}, {1}}]];

可视化时域中的声场：

Wolfram Language code: Manipulate[Plot[pfun[t, x], {x, 0, 1}, ...], {{t, 0}, 0, 0.003, 10 ^ -4}, Rule[...]]

有关波方程和声学边界条件的更多信息，请参见 Acoustics in the Time Domain 教程和 Acoustics PDE models 指南页面.

物质输运 (1)

给定化学物种在一种材料内的反应速率，模拟一维化学物种穿过不同材料的过程. 右侧和左侧分别受到质量浓度和流入条件的影响：

设置稳态传质模型变量 vars：

Wolfram Language code: vars = {c[x], {x}};

设置区域：

Wolfram Language code: Ω = Line[{{0}, {1}}];

指定传质模型参数物质扩散率和在区域中的反应速率：

Wolfram Language code: pars = <|"DiffusionCoefficient" -> 0.01, "MassReactionRate" -> If[x > 1 / 2, 1, 0]|>;

指定物种通量边界条件：

Wolfram Language code: Subscript[Γ, flux] = MassFluxValue[x == 0, vars, pars, <|"MassFlux" -> 1|>]

指定质量浓度边界条件：

Wolfram Language code: Subscript[Γ, C] = MassConcentrationCondition[x == 1, vars, pars, <|"MassConcentration" -> 0|>]

设置方程：

Wolfram Language code: eqn = MassTransportPDEComponent[vars, pars] == Subscript[Γ, flux]

解 PDE：

Wolfram Language code: cfun = NDSolveValue[{eqn, Subscript[Γ, C]}, c, x∈Ω];

可视化解：

Wolfram Language code: Show[Plot[cfun[x], x∈Ω, Rule[...]], Graphics[...]]

有关物质输运方程和边界条件的更多信息，请参见 Mass Transport 教程和 MassTransport PDE models 指南页面.

瞬态 Gray–Scott (1) 方程

设置方程并指定系数：

Wolfram Language code:

eqn = {u[t, x, y] (f + v[t, x, y]^2) + Inactive[Div][(-c1)*Inactive[Grad][u[t, x, y], {x, y}], {x, y}] + u^(1, 0, 0)[t, x, y] == f, v[t, x, y] (f + k - u[t, x, y] v[t, x, y]) + Inactive[Div][(-c2)*Inactive[Grad][v[t, x, y], {x, y}], {x, y}] + v^(1, 0, 0)[t, x, y] == 0} //. {c1 -> 2 * 10 ^ -5, c2 -> c1 / 4, f -> 1 / 25, k -> 3 / 50};

作为初始条件，若，则设且，否则为 0：

Wolfram Language code: ics = {u[0, x, y] == 1 / 2, v[0, x, y] == If[x ^ 2 + y ^ 2 <= 1 / 40, 1, 0]};

在边界上将和都设为零：

Wolfram Language code: bcs = DirichletCondition[{u[t, x, y] == 0, v[t, x, y] == 0}, True];

在细化的有限元网格上求解方程组：

Wolfram Language code:

{ufun, vfun} = NDSolveValue[{eqn, bcs, ics}, {u, v}, {x, y}∈Disk[], {t, 0, 3000}, Method -> {"PDEDiscretization" -> {"MethodOfLines", "SpatialDiscretization" -> {"FiniteElement", "MeshOptions" -> {"MaxCellMeasure" -> 0.003}}}}];

可视化结果：

Wolfram Language code:

frames = Table[ContourPlot[vfun[t, x, y], {x, -1, 1}, {y, -1, 1}, ...], {t, 100, 2000, 25}];
ListAnimate[frames, Rule[...]]

瞬态朗道-金兹堡方程 (1)

建立方程：

Wolfram Language code:

eqn = {u^(1, 0)[t, x] + Inactive[Div][-Inactive[Grad][u[t, x], {x}], {x}] + Inactive[Div][-Inactive[Grad][v[t, x], {x}], {x}] - u[t, x] + (u[t, x] - 2 v[t, x]) (u[t, x]^2 + v[t, x]^2) == 0, v^(1, 0)[t, x] + Inactive[Div][Inactive[Grad][u[t, x], {x}], {x}] + Inactive[Div][-Inactive[Grad][v[t, x], {x}], {x}] - v[t, x] + (2 u[t, x] + v[t, x]) (u[t, x]^2 + v[t, x]^2) == 0};

设置初始条件，以避免机器下溢：

Wolfram Language code:

exp[x_] := If[x < Log[$MinMachineNumber], 0., Exp[x]]
ics = {u[0, x] == 1 - exp[-x ^ 2], v[0, x] == exp[-(10 - x) ^ 2]};

指定边界条件：

Wolfram Language code: bcs = {u[t, -50] == 1, u[t, 50] == 1, v[t, -50] == 0, v[t, 50] == 0};

在具有指定间距的网格上求解方程：

Wolfram Language code:

{ufun, vfun} = NDSolveValue[{eqn, ics, bcs}, {u, v}, {t, 0, 40}, {x, -50, 50}, Method -> {"MethodOfLines", "SpatialDiscretization" -> {"FiniteElement", "MeshOptions" -> {"MaxCellMeasure" -> 0.4}}}];

可视化结果：

Wolfram Language code: DensityPlot[Evaluate[Sqrt[ufun[t, x] ^ 2 + vfun[t, x] ^ 2]], {x, -50, 50}, {t, 0, 40}, ...]

布莱克-舒尔斯方程 (1)

目标是使用布莱克-舒尔斯模型确定欧式普通看涨期权的价格，已知标的资产价格与执行价格均为，无风险利率为，资产的波动率为，并且该期权的到期期限为一年.

定义参数：

Wolfram Language code: pars = {tEnd -> 1, k -> 100, σ -> 0.2, r -> 0.05}

定义资产价格的取值范围：

Wolfram Language code: {lower, upper} = {0, 3k} /. pars

定义偏微分方程并替换参数：

Wolfram Language code: BSPDE = -r V[t, s] + r s V^(0, 1)[t, s] + (1/2) s^2 σ^2 V^(0, 2)[t, s] + V^(1, 0)[t, s] == 0 /. pars

设置终端条件：

Wolfram Language code: terminalBC = V[tEnd, s] == Max[0, s - k] /. pars

边界条件的选择方式如下：在下界处，当资产价格非常低时，期权价值为零. 上界处的条件来自于看涨-看跌期权平价关系.

指定边界条件：

Wolfram Language code:

bcs = {DirichletCondition[V[t, s] == upper - k E^-r(tEnd - t), s == upper], DirichletCondition[V[t, s] == 0, s == lower]} /. pars

在细化网格上求解该偏微分方程：

Wolfram Language code:

sol = NDSolveValue[{BSPDE, terminalBC, bcs}, V, {t, 0, tEnd} /. pars, {s, lower, upper}, Method -> {"MethodOfLines", "SpatialDiscretization" -> {"FiniteElement", "MeshOptions" -> {"MaxCellMeasure" -> 0.1}}}]

在时间，资产价格为时，检查期权的价值：

Wolfram Language code: sol[0, 100]

绘制整个时间范围内获得的数值解：

Wolfram Language code: Plot3D[sol[t, s], {s, 50, 150}, {t, 0, 1}, ...]

定义一个函数，使用 FinancialDerivative 函数来获取期权的价格：

Wolfram Language code:

optionPrice[s0_] := FinancialDerivative@@ReplaceAll[{{"European", "Call"}, {"StrikePrice" -> k, "Expiration" -> tEnd}, {"InterestRate" -> r, "Volatility" -> σ, "CurrentPrice" -> s0}}, pars]

检查由 FinancialDerivative 给出的通常为真的值：

Wolfram Language code: optionPrice[100]

计算这两个值之间的误差：

Wolfram Language code:

trueVal = optionPrice[100];
numericalVal = sol[0, 100];
PercentForm[(Abs[trueVal - numericalVal]/trueVal)]

绘制在时刻的数值解与传统上真实解之间的差异：

Wolfram Language code: Plot[optionPrice[s0] - sol[0, s0], {s0, k - 100, k + 100} /. pars, ...]

属性和关系 (9)

NDSolveValue 给出解的函数，而 NDSolve 返回的结果是一个规则：

Wolfram Language code: ysol = NDSolveValue[{y'[x] == y[x]Cos[x + y[x]], y[0] == 1}, y, {x, 0, 30}]

Wolfram Language code: sol = NDSolve[{y'[x] == y[x]Cos[x + y[x]], y[0] == 1}, y, {x, 0, 30}]

下述两个解是等价的：

Wolfram Language code: ysol === First[y /. sol]

Wolfram Language code: {Plot[ysol[x], {x, 0, 30}], Plot[y[x] /. sol, {x, 0, 30}]}

NDSolveValue 可直接返回在指定点的解的函数：

Wolfram Language code: NDSolveValue[{y'[x] == y[x]Cos[x + y[x]], y[0] == 1}, y[1.], {x, 0, 30}]

来看 NDSolve：

Wolfram Language code: y[1.] /. First@NDSolve[{y'[x] == y[x]Cos[x + y[x]], y[0] == 1}, y, {x, 0, 30}]

NDSolveValue 可直接返回解在几个点的值：

Wolfram Language code: NDSolveValue[{y'[x] == y[x]Cos[x + y[x]], y[0] == 1}, Table[y[i], {i, 10, 30, 10}], {x, 0, 30}]

来看 NDSolve：

Wolfram Language code: Table[y[i], {i, 10, 30, 10}] /. First@NDSolve[{y'[x] == y[x]Cos[x + y[x]], y[0] == 1}, y, {x, 0, 30}]

NDSolveValue 可直接返回涉及解的任意表达式的结果：

Wolfram Language code: f[x_] = NDSolveValue[{y'[x] == y[x]Cos[x + y[x]], y[0] == 1}, y''[x]Cos[x + y[x]], {x, 0, 30}]

Wolfram Language code: Plot[f[x], {x, 0, 30}]

Wolfram Language code: NDSolveValue[{y'[x] == y[x]Cos[x + y[x]], y[0] == 1}, y''[25]Cos[25 + y[25]], {x, 0, 30}]

来看 NDSolve：

Wolfram Language code: sol = First@NDSolve[{y'[x] == y[x]Cos[x + y[x]], y[0] == 1}, y, {x, 0, 30}];

Wolfram Language code: y''[x]Cos[x + y[x]] /. sol

Wolfram Language code: y''[25]Cos[25 + y[25]] /. sol

如果一个方程有多个解，NDSolveValue 会选取其中一个：

Wolfram Language code: ysol = NDSolveValue[{y'[x] ^ 2 == (1 - y[x] ^ 2)(1 - y[x] ^ 2 / 2), y[0] == 0}, y, {x, 0, 1.5}]

Wolfram Language code: Plot[ysol[x], {x, 0, 1.5}]

NDSolve 则会同时求出两个解：

Wolfram Language code:

sol = NDSolve[{y'[x] ^ 2 == (1 - y[x] ^ 2)(1 - y[x] ^ 2 / 2), y[0] == 0}, y[x], {x, 0, 1.5}];
Plot[Evaluate[y[x] /. sol], {x, 0, 1.5}]

数值计算在一区间不同点的积分值：

Wolfram Language code: iv = Table[{x, NIntegrate[Sin[Exp[s]], {s, 0, x}]}, {x, 0, 3, .25}]

具有独立变量的函数，NDSolve 有效地给出不定积分：

Wolfram Language code: ysol = NDSolveValue[{y'[x] == Sin[Exp[x]], y[0] == 0}, y, {x, 0, 3}]

Wolfram Language code: Plot[ysol[x], {x, 0, 3}, Epilog -> Map[Point, iv]]

求事件与求解的函数的根相关：

Wolfram Language code: ev[t_ ? NumberQ] := NDSolveValue[{y''[x] + y[x] == 0, y[0] == 1, y'[0] == 0}, y, {x, t}][t]

Wolfram Language code: Plot[ev[t], {t, 0, 3}]

Wolfram Language code: FindRoot[ev[t], {t, 1}]

事件位置准确和有效地找到根：

Wolfram Language code: NDSolveValue[{y''[x] + y[x] == 0, y[0] == 1, y'[0] == 0, WhenEvent[y[x] == 0, "StopIntegration"]}, y, {x, ∞}]

以下给出作为微分方程的函数：

Wolfram Language code: Subscript[y, 10][yp0_ ? NumberQ] := NDSolveValue[{y''[x] + Sin[y[x]] == 0, y[0] == 1, y'[0] == yp0}, y, {x, 10}][10]

Wolfram Language code: Plot[Subscript[y, 10][Subsuperscript[y, 0, ′]], {Subsuperscript[y, 0, ′], -2, 2}]

求的根：

Wolfram Language code: FindRoot[Subscript[y, 10][Subsuperscript[y, 0, ′]] == 0, {Subsuperscript[y, 0, ′], -1.5}]

求等边界值问题：

Wolfram Language code: ysol = NDSolveValue[{y''[x] + Sin[y[x]] == 0, y[0] == 1, y[10] == 0}, y, x];Plot[{ysol[x], ysol'[x]}, {x, 0, 10}]

Wolfram Language code: SystemModel["DocumentationExamples.Basic.DiffEq"]

使用 NDSolve 作为 SystemModel 的一个求解器：

Wolfram Language code: sim = SystemModelSimulate[[image], Method -> "NDSolve"]

根据仿真结果绘制变量：

Wolfram Language code: SystemModelPlot[sim, {"y", "z"}]

Wolfram Language code: SystemModel["DocumentationExamples.Simulation.Tanks.TankSystem"]

使用 SystemModel 模拟更大型的分层模型：

Wolfram Language code: sim = SystemModelSimulate[[image]]

绘制随着时间的推移储罐系统中的储罐液位：

Wolfram Language code: SystemModelPlot[sim, {"tank1.h", "tank2.h", "tank3.h"}, PlotRange -> All]

可能存在的问题 (12)

针对许多 NDSolveValue 消息，有特定的消息参考页面. 请到理解出错消息工作流程中了解怎样访问这些页面.

有多个解 (1)

对于有多个解的方程，NDSolveValue 只会返回一个解：

Wolfram Language code: NDSolveValue[{Derivative[1][y][x]^2 - y[x]^2 == 0, y[0]^2 == 4}, y[x], {x, 1}]

用 NDSolve 求得所有的解：

Wolfram Language code: NDSolve[{Derivative[1][y][x]^2 - y[x]^2 == 0, y[0]^2 == 4}, y[x], {x, 1}]

Wolfram Language code: Plot[Evaluate[y[x] /. %], {x, 0, 1}]

数值误差 (3)

当远离初始条件，误差趋于增长：

Wolfram Language code: ysol = NDSolveValue[{y''[x] + y[x] == 0, y[0] == 1, y'[0] == 0}, y, {x, 0, 100}]

求数值和精确解间的不同：

Wolfram Language code: Plot[ysol[x] - Cos[x], {x, 0, 100}]

非线性方程的误差：

Wolfram Language code: ysol = NDSolveValue[{y''[x] == y[x](y[x] ^ 2 - 3 / 2), y[0] == 0, y'[0] == 1}, y, {x, 0, 10}]

Wolfram Language code: Plot[ysol[x] - JacobiSN[x, 1 / 2], {x, 0, 10}]

对于高阶方法，默认插值在步骤间可能具有大的误差：

Wolfram Language code:

ysol = NDSolveValue[{y''[x] == y[x](y[x] ^ 2 - 3 / 2), y[0] == 0, y'[0] == 1}, y, {x, 0, 10}, Method -> {"ExplicitRungeKutta", "DifferenceOrder" -> 8}]

Wolfram Language code: Plot[(ysol''[x] - ysol[x](ysol[x] ^ 2 - 3 / 2)), {x, 0, 10}, PlotRange -> All]

具有对应于方法的阶数的插值减少步骤间的误差：

Wolfram Language code:

ysol2 = NDSolveValue[{y''[x] == y[x](y[x] ^ 2 - 3 / 2), y[0] == 0, y'[0] == 1}, y, {x, 0, 10}, Method -> {"ExplicitRungeKutta", "DifferenceOrder" -> 8}, InterpolationOrder -> All]

Wolfram Language code: Plot[(ysol2''[x] - ysol2[x](ysol2[x] ^ 2 - 3 / 2)), {x, 0, 10}, PlotRange -> All]

微分代数方程 (2)

微分代数方程组：

Wolfram Language code:

DAE = {Derivative[1][Subscript[x, 1]][t] == Subscript[x, 3][t], Subscript[x, 2][t](1 - Subscript[x, 2][t]) == 0, Subscript[x, 1][t]Subscript[x, 2][t] + Subscript[x, 3][t](1 - Subscript[x, 2][t]) == t};

，求方程的解：

Wolfram Language code: NDSolveValue[{DAE, Subscript[x, 1]'[0] == 1}, {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}, {t, 0, 1}]

设，如果还不能求出方程的解，NDSolveValue 可能会改变给定的初始条件：

Wolfram Language code: NDSolveValue[{DAE, Subscript[x, 1]'[0] == 0}, {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}, {t, 0, 1}]

NDSolveValue 只能求解指数1的方程，但是时方程指数为2：

Wolfram Language code:

NDSolveValue[{DAE, Subscript[x, 1][0] == 0, Subscript[x, 2][0] == 1, Subscript[x, 3][0] == 0}, {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}, {t, 0, 1}]

默认方法可能无法收敛于缺省容差：

Wolfram Language code:

s = 100;
dae = {x'[t] == -(xs[t] - ys[t]), y'[t] == (xs[t] - ys[t]), xs[t] == s x[t], ys[t] == s y[t], x[0] == 1, y[0] == 0, xs[0] == s, ys[0] == 0};

Wolfram Language code: NDSolveValue[dae, {x, y}, {t, 0, 1}]

把 AccuracyGoal 和 PrecisionGoal 设为较小的值以后，求出了一个解：

Wolfram Language code: NDSolveValue[dae, {x, y}, {t, 0, 1}, AccuracyGoal -> 6, PrecisionGoal -> 6]

"StateSpace" 时间积分法可以在设置为缺省容差的情况下求出方程的解：

Wolfram Language code: NDSolveValue[dae, {x, y}, {t, 0, 1}, Method -> {"TimeIntegration" -> "StateSpace"}]

偏微分方程 (4)

在 PDE models overview 中可以找到各个领域的大量 PDE 模型以及详细的说明.

定义一个非线性 PDE：

Wolfram Language code:

L = 25;
wpde = {Subscript[∂, t, t]u[t, x] == Subscript[∂, x, x]u[t, x] + (1 - u[t, x]^2)(1 + 2u[t, x]), u[0, x] == E^-x^2, u^(1, 0)[0, x] == 0, u[t, -L] == u[t, L]};

空间离散化是基于初始值，它变化小于最终值：

Wolfram Language code: usol1 = NDSolveValue[wpde, u, {t, 0, L}, {x, -L, L}]

通过增加空间网格点的最小数，你可以精确计算最终值：

Wolfram Language code:

usol2 = NDSolveValue[wpde, u, {t, 0, L}, {x, -L, L}, Method -> {"MethodOfLines", "SpatialDiscretization" -> {"TensorProductGrid", "MinPoints" -> 1000}}]

图演示了一个空间更复杂解的开端：

Wolfram Language code: DensityPlot[usol2[-t, x], {x, -L, L}, {t, 0, -L}, PlotPoints -> 50]

定义一个热方程，初始值是一个阶跃函数：

Wolfram Language code: hpde = {D[u[t, x], t] == D[u[t, x], x, x], u[0, x] == UnitStep[1 / 2 - x], u[t, 0] == 1, u[t, 1] == 0};

初始值的不连续性可能导致太多的空间网格点：

Wolfram Language code: Plot3D[Evaluate[NDSolveValue[hpde, u[t, x], {t, 0, .01}, {x, 0, 1}]], {x, 0, 1}, {t, 0, .01}]

设置更小的空间网格点基本上是一个好的解决方法：

Wolfram Language code:

Plot3D[Evaluate[NDSolveValue[hpde, u[t, x], {t, 0, .01}, {x, 0, 1}]], {x, 0, 1}, {t, 0, .01}, Method -> {"MethodOfLines", "SpatialDiscretization" -> {"TensorProductGrid", "MaxPoints" -> 100}}]

定义具有初始值的拉普拉斯方程：

Wolfram Language code:

lpde = {D[u[x, y], x, x] + D[u[x, y], y, y] == 0, u[x, 0] == Sin[Pi x], Derivative[0, 1][u][x, 0] == 0, u[0, y] == u[1, y] == 0};

求解器只适用于具有良好初始值（柯西）问题的方程组：

Wolfram Language code: usol = NDSolveValue[lpde, u, {x, 0, 1}, {y, 0, 1}]

不适定性显示为数值不稳定性：

Wolfram Language code: Plot3D[Evaluate[usol[x, y]], {x, 0, 1}, {y, 0, 1}, PlotRange -> All]

边界值问题 (1)

以下求解边界值问题的平常解：

Wolfram Language code: ysol = NDSolveValue[{y''[x] + Sin[y[x]] == 0, y[0] == 0, y[10] == 0}, y, x];Plot[{ysol[x], ysol'[x]}, {x, 0, 10}]

通过给出解搜索的起始条件，可以找到其它解：

Wolfram Language code:

Table[
	ysol = NDSolveValue[{y''[x] + Sin[y[x]] == 0, y[0] == 0, y[10] == 0}, y, x, Method -> {"Shooting", "StartingInitialConditions" -> {y[0] == 0, y'[0] == i}}];
	Plot[{ysol[x], ysol'[x]}, {x, 0, 10}], {i, 1, 2}]

巧妙范例 (1)

通过求解拉普拉斯方程并计算该解的梯度解开迷宫问题：

Wolfram Language code:

mesh = ImageMesh[[image]];
if = NDSolveValue[{Laplacian[u[x, y], {x, y}] == 0, DirichletCondition[u[x, y] == 1, x <= 6], DirichletCondition[u[x, y] == 0, x >= 595]}, u, {x, y}∈mesh];
ContourPlot[Evaluate[Sqrt[Total[Grad[if[x, y], {x, y}] ^ 2]]], {x, y}∈mesh, Contours -> 2, PlotPoints -> 30]

Top

	"TimeIntegration"	微分方程组的时间积分
	"BoundaryValues"	常微分方程边界值解
	"DiscontinuityProcessing"	处理不连续微分方程的符号式处理
	"EquationSimplification"	数值计算的方程形式化简
	"IndexReduction"	微分代数方程的符号索引化简
	"DAEInitialization"	微分代数方程的一致初始化
	"PDEDiscretization"	偏微分方程的离散化

	"Adams"	预测-校正亚当斯法，阶数从 1 至 12
	"BDF"	隐式向后差分公式，阶数为 1 至 5
	"ExplicitRungeKutta"	2(1) 至 9(8) 自适应嵌入对龙格库塔法
	"ImplicitRungeKutta"	任意阶数隐式龙格库塔法系列
	"SymplecticPartitionedRungeKutta"	可分哈密顿系统的交错龙格库塔法

	"Composition"	构成子方法的列表
	"DoubleStep"	双步法自适应步骤尺寸
	"EventLocator"	响应指定的事件
	"Extrapolation"	使用多项式外推自适应阶数和步骤大小
	"FixedStep"	使用常量步骤大小
	"OrthogonalProjection"	满足正交约束的投影解
	"Projection"	满足一般约束的投影解
	"Splitting"	分开方程组和是哦那个不同的子方法
	"StiffnessSwitching"	如果检测到刚度从显式切换到隐式

	"ExplicitEuler"	向前欧拉方法
	"ExplicitMidpoint"	中点规则方法
	"ExplicitModifiedMidpoint"	具有 Gragg 平滑的中点规则法
	"LinearlyImplicitEuler"	线性隐式欧拉方法
	"LinearlyImplicitMidpoint"	线性隐式中点规则法
	"LinearlyImplicitModifiedMidpoint"	线性隐式 Bader 平滑中点规则法
	"LocallyExact"	数值近似到本地精确符号式解

AccuracyGoal	Automatic	寻求的绝对精确数字
Compiled	Automatic	表达式是否应该自动编译
DependentVariables	Automatic	所有相关变量的列表
EvaluationMonitor	None	当计算函数时计算的的表达式
InitialSeeding	{}	用于某些算法的播种方程
InterpolationOrder	Automatic	最终输出的连续度
MaxStepFraction	1/10	每个步骤中最大的范围比例
MaxSteps	Automatic	采用的最大步骤数
MaxStepSize	Automatic	每一步的最大尺寸
Method	Automatic	使用的方法
NormFunction	Automatic	误差估计使用的范数
PrecisionGoal	Automatic	寻求的精确数字
StartingStepSize	Automatic	使用的初始步骤大小
StepMonitor	None	每采取步骤时计算的表达式
WorkingPrecision	MachinePrecision	内部计算使用的精度

NDSolveValue

更多信息和选项

范例

基本范例 (7)

范围 (25)

常微分方程组 (7)

偏微分方程组 (5)

边界值问题 (5)

时滞微分方程 (2)

混合及不连续系统 (5)

微分代数方程 (1)

推广和延伸 (1)

选项 (29)

AccuracyGoal 与 PrecisionGoal (1)

DependentVariables (1)

EvaluationMonitor (2)

InitialSeedings (2)

InterpolationOrder (1)

MaxStepFraction (1)

MaxSteps (1)

MaxStepSize (2)

Method (12)

TimeIntegration (5)

BoundaryValues (1)

DiscontinuityProcessing (1)

EquationSimplification (1)

IndexReduction (1)

DAEInitialization (1)

PDEDiscretization (2)

NormFunction (1)

StartingStepSize (1)

StepMonitor (3)

WorkingPrecision (1)

应用 (22)

Duffing 方程 (2)

Lotka–Volterra 方程组 (1)

Lorenz 方程组 (1)

Gavrilov–Shilnikov 模型 (1)

热方程 (2)

波方程 (1)

Wolfram 非线性波方程 (3)

n-体问题 (1)

非线性薛定谔方程 (2)

Korteweg-de Vries (KdV) 方程 (2)

Mackey–Glass 方程 (1)

声学方程 (1)

物质输运 (1)

瞬态 Gray–Scott (1) 方程

瞬态朗道-金兹堡方程 (1)

布莱克-舒尔斯方程 (1)

属性和关系 (9)

可能存在的问题 (12)

有多个解 (1)

数值误差 (3)

微分代数方程 (2)

偏微分方程 (4)

边界值问题 (1)

巧妙范例 (1)

参见

技术笔记

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX