Wolfram 语言与系统参考资料中心

NMaxValue

NMaxValue[f,x]

给出关于 x 的 f 的全局最大值.

NMaxValue[f,{x,y,…}]

给出关于 x、y、 … 的 f 的全局最大值.

NMaxValue[{f,cons},{x,y,…}]

给出约束条件 cons 限制下 f 的全局最大值.

NMaxValue[…,x∈reg]

将 x 限制在区域 reg 内.

范例

打开所有单元关闭所有单元

基本范例 (5)

求一元函数的最大值：

Wolfram Language code: NMaxValue[-2x ^ 2 - 3x + 5, x]

求多元函数的最大值：

Wolfram Language code: NMaxValue[1 - (x y - 3) ^ 2, {x, y}]

求受约束条件限制的函数的最大值：

Wolfram Language code: NMaxValue[{x - 2y, x ^ 2 + y ^ 2 ≤ 1}, {x, y}]

求函数在几何区域上的全局最大值：

Wolfram Language code: MaxValue[x + y, {x, y}∈Disk[]]

求函数在几何区域上的全局最大值：

Wolfram Language code: NMaxValue[x + y, {x, y}∈Disk[]]

范围 (34)

基本用法 (12)

最大化受约束条件限制的：

Wolfram Language code: NMaxValue[{x + 2y, x^2 + 2y^2 ≤ 3, x + y == 2, x ≥ 1}, {x, y}]

可用 VectorGreaterEqual 表示几个线性不等式约束条件：

Wolfram Language code: NMaxValue[{-x - y, VectorGreaterEqual[{{x + 2y, x}, {3, -1}}]}, {x, y}]

用 v>= 或 \[VectorGreaterEqual] 输入向量不等式符号 ：

Wolfram Language code: NMaxValue[{-x - y, {x + 2y, x}{3, -1}}, {x, y}]

用标量不等式给出的等价形式：

Wolfram Language code: NMaxValue[{-x - y, x + 2y ≥ 3, x ≥ -1}, {x, y}]

使用向量变量：

Wolfram Language code: NMaxValue[{{-1, -1}.v, {{1, 2}, {1, 0}}.v{3, -1}}, v]

由于中可能存在的逐项运算，不等式不一定和一样：

Wolfram Language code: NMaxValue[{{-1, -1}.x, {{1, 2}, {1, 0}}.x + {-3, 1}0}, x]

Wolfram Language code: NMaxValue[{{-1, -1}.x, {{1, 2}, {1, 0}}.x{3, -1}}, x]

如果想要避免中不想要的逐项运算，可使用 Inactive[Plus]：

Wolfram Language code: NMaxValue[{{-1, -1}.x, {{1, 2}, {1, 0}}.x + {-3, 1}0}, x]

用常参数方程来避免中不想要的逐项运算：

Wolfram Language code: parEqs = {a == {{1, 2}, {1, 0}}, b == {3, -1}};

Wolfram Language code: NMaxValue[{{-1, -1}.x, {parEqs, a.x + b0}}, x]

VectorGreaterEqual 表示关于 "NonNegativeCone" 的锥不等式：

Wolfram Language code: constraint = VectorGreaterEqual[{{{1, 2}, {1, 0}}.v, {3, -1}}, "NonNegativeCone"]

如果想明确指定锥体的尺寸，可使用 {"NonNegativeCone",n}：

Wolfram Language code: constraint = VectorGreaterEqual[{{{1, 2}, {1, 0}}.v, {3, -1}}, {"NonNegativeCone", 2}]

求解：

Wolfram Language code: NMaxValue[{{-1, -1}.v, constraint}, v]

最大化受约束条件限制的：

Wolfram Language code: NMaxValue[{x + 2y, x^2 + y^2 ≤ 9}, {x, y}]

用含有 "NormCone" 的锥不等式指定约束条件：

Wolfram Language code: constraint = VectorGreaterEqual[{{x, y, 3}, 0}, {"NormCone", 3}]

求解：

Wolfram Language code: NMaxValue[{x + 2y, constraint}, {x, y}]

最大化受约束条件限制的函数：

Wolfram Language code: {a, b} = {-{{1, 1, 0}, {0, 1, 1}, {1, 1, 1}}, {2, 2, -1}};

用 Indexed 访问向量变量的分量，如：

Wolfram Language code: NMaxValue[{Total[x], a.xb, Indexed[x, 1] ≥ 1}, x]

当向量变量不明确时，用 Vectors[n,dom] 指定维度和域：

Wolfram Language code:

NMaxValue[{Indexed[x, {1}] + 2Indexed[x, {2}], (⁠|                  |                  |
| ---------------- | ---------------- |
| Indexed[-x, {1}] | 1                |
| 1                | Indexed[-x, {2}] |)Underscript[, {"SemidefiniteCone", 2}]0}, x]

Wolfram Language code:

NMaxValue[{Indexed[x, {1}] + Indexed[2x, {2}], (⁠|                  |                  |
| ---------------- | ---------------- |
| Indexed[-x, {1}] | 1                |
| 1                | Indexed[-x, {2}] |)Underscript[, {"SemidefiniteCone", 2}]0}, x∈Vectors[2, Reals]]

用 NonNegativeReals () 指定非负约束条件：

Wolfram Language code:

NMaxValue[{{1, 1}.x, {Indexed[x, {1}], Indexed[x, {2}], 1}Underscript[, {"NormCone", 3}]0}, x∈Vectors[2, NonNegativeReals]]

用向量不等式表示的等价格式：

Wolfram Language code: NMaxValue[{{1, 1}.x, {Indexed[x, {1}], Indexed[x, {2}], 1}Underscript[, {"NormCone", 3}]0, x0}, x]

用 NonPositiveReals () 指定非正约束条件：

Wolfram Language code: NMaxValue[{Total[v], {1, 2}.v-3}, v∈Vectors[2, NonPositiveReals]]

用向量不等式表示的等价格式：

Wolfram Language code: NMaxValue[{Total[v], {1, 2}.v-3, v0}, v]

可以指定 Or 约束条件：

Wolfram Language code: NMaxValue[{x + y, x ^ 2 + y ^ 2 ≤ 1 || (x + 2) ^ 2 + (y + 2) ^ 2 ≤ 1}, {x, y}]//Quiet

域约束条件 (4)

用 Integers 指定整数域约束条件：

Wolfram Language code: NMaxValue[{x + y, x + 2y ≤ 3, x ≤ 1}, {x, y∈Integers}]

用 Vectors[n,Integers] 指定向量变量的整数域约束条件：

Wolfram Language code:

NMaxValue[{Total[x], a == {{1, 2}, {1, 0}}, b == {-3, 2}, 
	a.xb}, x∈Vectors[2, Integers]]

用 NonNegativeIntegers () 指定非负整数域约束条件：

Wolfram Language code: NMaxValue[{x + 2y, x^2 + 2y^2 ≤ 3, x + y == 2, x∈NonNegativeIntegers}, {x, y}]

用 NonPositiveIntegers () 指定非正整数域约束条件：

Wolfram Language code: NMaxValue[{x - y, x + 2y ≥ 3, x∈NonPositiveIntegers}, {x, y}]

区域约束条件 (3)

求向量线性函数的最大值，是中的一个向量，且：

Wolfram Language code: NMaxValue[x.{1, 2, 3}, x∈Ball[]]

求区域上的最大值：

Wolfram Language code:

t = RotationTransform[{{0, 0, 1}, {1, 1, 1}}];
ℛ = TransformedRegion[Ellipsoid[{0, 0, 0}, {1, 2, 3}], t];

Wolfram Language code: NMaxValue[z, {x, y, z}∈ℛ]

求被限制在两个不同区域的两点之间可能的最大距离：

Wolfram Language code:

Subscript[ℛ, 1] = Disk[];
Subscript[ℛ, 2] = Line[{{-2, 0}, {0, 2}}];

Wolfram Language code: NMaxValue[EuclideanDistance[{x, y}, {u, v}], {{x, y}∈Subscript[ℛ, 1], {u, v}∈Subscript[ℛ, 2]}]

线性问题 (5)

如果目标函数和约束条件是线性的，最大值即是全局最大值：

Wolfram Language code: NMaxValue[{x + y, 3x + 2y ≤ 7 && x + 2y ≤ 6 && x ≥ 0 && y ≥ 0}, {x, y}]

约束条件可以是等式和不等式约束条件：

Wolfram Language code: NMaxValue[{y - x, x + y + z == 1 / 2, x - 2z == 1, 2x - y ≥ 1}, {x, y, z}]

用 Equal 一次表示几个等式约束条件：

Wolfram Language code: NMaxValue[{y - x, {x + y, x - y} == {1 / 2, 1}}, {x, y}]

用几个标量等式表示的等价形式：

Wolfram Language code: NMaxValue[{y - x, x + y == 1 / 2, x - y == 1}, {x, y}]

用 VectorLessEqual 一次表示几个 LessEqual 不等式约束条件：

Wolfram Language code: NMaxValue[{x + y, VectorGreaterEqual[{{x - 2y, -x + y}, {3, 2}}]}, {x, y}]

用 v<= 以紧凑格式输入向量不等式：

Wolfram Language code: NMaxValue[{x + y, {x - 2y, -x + y}{3, 2}}, {x, y}]

用标量不等式给出的等价形式：

Wolfram Language code: NMaxValue[{x + y, {x - 2y ≥ 3, -x + y ≥ 2}}, {x, y}]

用 Interval 指定变量的范围：

Wolfram Language code: NMaxValue[{x + y, x + 2y ≥ 3}, {x∈Interval[{-1, 2}], y∈Interval[{-1, 1}]}]

凸问题 (4)

用 "NonNegativeCone" 指定形如的线性函数：

Wolfram Language code:

NMaxValue[{Total[x], 
	VectorGreaterEqual[{{{-1, -1 / 2}, {1, -1 / 2}, {0, 1}}.x, {-1 / 2, -1 / 2, -1 / 2}}, {"NonNegativeCone", 3}]}, x]

用 v>= 以紧凑格式输入向量不等式：

Wolfram Language code: NMaxValue[{Total[x], {{-1, -(1/2)}, {1, -(1/2)}, {0, 1}}.x-(1/2)}, x]

求受一组凸二次约束条件限制的凹二次函数的最大值：

Wolfram Language code: res = NMaxValue[{-((x - 1)^2 + y^2), x^2 + (y^2/2) ≤ (1/2), 2x^2 ≤ 3y}, {x, y}]

绘制区域：

Wolfram Language code: Plot3D[-((x - 1)^2 + y^2), {x, -1, 1}, {y, 0, 1}, ...]

求的使得为半正定的最大值：

Wolfram Language code:

NMaxValue[{-(10x + 11 y), (⁠|   |   |
| - | - |
| x | 1 |
| 1 | y |⁠)Underscript[, {"SemidefiniteCone", 2}]0}, {x, y}]

显示目标函数图：

Wolfram Language code: Plot3D[-(10x + 11y), {x, 0, 5}, {y, 0, 5}, ...]

求凹目标函数的使得为半正定且的最大值：

Wolfram Language code:

res = NMaxValue[{Log[x + y], (⁠|       |       |
| ----- | ----- |
| x + y | 1     |
| 1     | x - y |⁠)Underscript[, {"SemidefiniteCone", 2}]0, 1 ≤ x ≤ 10, -1 ≤ y ≤ 1}, {x, y}]

绘制区域和最大化点：

Wolfram Language code: Show[Plot3D[Log[x + y], {x, 1, 10}, {y, -1, 1}, ...], Graphics3D[{Red, PointSize[0.05], Point[{10, 1, res}]}]]

可转化为凸问题的问题 (3)

最大化受不等式和范数约束条件限制的拟凹函数 . 目标函数是拟凹的，因为它是两个非负仿射函数的乘积：

Wolfram Language code: NMaxValue[{x y, x ≥ 0, y ≥ 0, Norm[{x - 1, y - 2}] ≤ 1}, {x, y}]

最大化是通过最小化目标函数的负值（拟凸函数）来解决的. 可将拟凸问题作为参数的参数凸优化问题求解：

Wolfram Language code:

pfun = ParametricConvexOptimization[0, {-x y ≤ α, x ≥ 0, y ≥ 0, 
	Norm[{x - 1, y - 2}] ≤ 1}, {x, y}, α, "PrimalMinimizerRules"]

绘制作为水平子集的函数的目标函数：

Wolfram Language code:

fun[α_ ? NumericQ] := -x * y /. pfun[α];
Plot[fun[α], {α, -4.68, 0}, PlotRange -> All]

对于水平子集在区间内的值，找到最小的值：

Wolfram Language code: pfun[-4.68]

当水平集值增加时，问题变得不可行：

Wolfram Language code: pfun[-4.69]

根据约束条件最大化 . 目标是非凸但可通过凸差函数表示，其中和为凸函数：

Wolfram Language code: res = NMaxValue[{x ^ 2 - y ^ 2, Norm[{x, y}] <= 2}, {x, y}]

绘制该区域和最小化点：

Wolfram Language code:

Show[Plot3D[x ^ 2 - y ^ 2, {x, -2, 2}, {y, -2, 2}, ...], Graphics3D[
	{PointSize[0.04], Point[{2, 0, res}]}]]

根据约束条件最大化 . 约束条件为非凸但可通过凸差约束条件表示，其中和为凸函数：

Wolfram Language code: res = NMaxValue[{x ^ 2 + y ^ 2 + x + y, 1 <= Norm[{x, y}] <= 2}, {x, y}]

绘制该区域和最小化点：

Wolfram Language code:

Show[Plot3D[x ^ 2 + y ^ 2 + x + y, {x, -2, 2}, {y, -2, 2}, ...], Graphics3D[
	{PointSize[0.04], Point[{Sqrt[2], Sqrt[2], res}]}]]

普通问题 (3)

最大化受非线性约束条件限制的线性目标函数：

Wolfram Language code: res = NMaxValue[{x + y, Sin[2x] + Cos[3y] ≤ 1, Norm[{x, y}] ≤ 2}, {x, y}]

绘制这些值：

Wolfram Language code: Show[Plot3D[x + y, {x, -2, 2}, {y, -2, 2}, ...], Graphics3D[{Blue, PointSize[0.03], Point[{1.414, 1.414, res}]}]]

最大化受线性约束条件限制的非线性目标函数：

Wolfram Language code: res = NMaxValue[{Sin[2x] + Cos[x], -2 ≤ x ≤ 3}, x]

绘制目标函数和最大化点：

Wolfram Language code: Plot[Sin[2x] + Cos[x], {x, -2, 3}, Rule[...]]

最大化受非线性约束条件限制的非线性目标函数：

Wolfram Language code: res = NMaxValue[{Sin[x^2 + y], Sin[2x] + Cos[3y] ≤ 1, Norm[{x^2, y}] ≤ 2}, {x, y}]

绘制这些值：

Wolfram Language code: Show[Plot3D[Sin[x^2 + y], {x, -2, 2}, {y, -2, 2}, ...], Graphics3D[{Blue, PointSize[0.03], Point[{0.719, 1.054, res}]}]]

选项 (7)

AccuracyGoal & PrecisionGoal (2)

强调收敛标准和：

Wolfram Language code: NMaxValue[-Sin[Tan[x] / 2], x, AccuracyGoal -> 9, PrecisionGoal -> 8]

强调收敛标准和，这在使用默认机器精度的计算中是无法实现的：

Wolfram Language code: NMaxValue[-Sin[Tan[x] / 2], x, AccuracyGoal -> 20, PrecisionGoal -> 18]

设置一个较高的 WorkingPrecision，使过程收敛：

Wolfram Language code: NMaxValue[-Sin[Tan[x] / 2], x, AccuracyGoal -> 20, PrecisionGoal -> 18, WorkingPrecision -> 40]

EvaluationMonitor (1)

记录所有在求解有极小值环的函数过程中计算过的点：

Wolfram Language code:

f[x_, y_] := -(x ^ 2 + y ^ 2 - 16) ^ 2;
{sol, pts} = Reap[
	NMaxValue[f[x, y], {{x, -5, 5}, {y, -5, 5}},   Method -> "DifferentialEvolution", EvaluationMonitor :> Sow[{x, y}]]];

绘制目标函数值接近最终答案的所有访问过的点：

Wolfram Language code:

ContourPlot[f[x, y], {x, -5, 5}, {y, -5, 5}, 
	Epilog -> Map[Point, Cases[First[pts], x_ /; Abs[f@@x - sol] ≤ .05]], Contours -> -4Range[0, 10] ^ 2]

Method (2)

对于某些问题，某些方法可能会给出次优结果：

Wolfram Language code:

objective[x_] := Sin[.4 x ^ 2] + .7Cos[.6 x] x; NMaxValue[{objective[x], -11 < x < 11}, {x}, Method -> #]& /@ {"NelderMead", "SimulatedAnnealing"}

自动选择的方法给出了该问题的最优解：

Wolfram Language code: NMaxValue[{objective[x], -11 < x < 11}, {x}]

为下面的非凸问题自动选择的方法为 "Couenne"：

Wolfram Language code: maxVal = NMaxValue[{objective[x], -11 < x < 11}, {x}, Method -> "Couenne"]

绘制目标函数和全局最大值：

Wolfram Language code: Plot[{objective[x], maxVal}, {x, -11, 11}]

当速度至关重要时，请使用方法 "NelderMead" 来求解有多个变量的问题：

Wolfram Language code:

n = 50;AbsoluteTiming[NMaxValue[Sum[-i * (x[i] - i) ^ 2 + Sin[x[i]], {i, 1, n}], Table[x[i], {i, 1, n}], Method -> "NelderMead"]]

StepMonitor (1)

NMaxValue 在求函数最大值的过程中采取的步骤：

Wolfram Language code:

pts = Reap[NMaxValue[-(1 - x) ^ 2 - 100(-x ^ 2 - y) ^ 2, {x, y}, Method -> "NelderMead", StepMonitor :> Sow[{x, y}]]][[2, 1]];
pts  = Join[{{-1.2, 1}}, pts];

Wolfram Language code:

ContourPlot[-(1 - x) ^ 2 - 100(-x ^ 2 - y) ^ 2, {x, -1.3, 1.5}, {y, -1.5, 1.4}, Epilog -> {Arrow[pts], Point[pts]}, Contours -> Table[-10 ^ -i, {i, -2, 10}], ColorFunction -> (Hue[0.5 * (Log[10, -#] + 11) / 13]&), ColorFunctionScaling -> False]

WorkingPrecision (1)

工作精度设为时，AccuracyGoal 和 PrecisionGoal 默认值为：

Wolfram Language code: NMaxValue[Cos[x ^ 2 - 3 y] + Sin[x ^ 2 + y ^ 2], {x, y}, WorkingPrecision -> 20]

应用 (4)

几何问题 (2)

求使得三角形和椭圆仍然相交的最大的：

Wolfram Language code:

Subscript[ℛ, 1] = Triangle[{{0, 0}, {1, 0}, {0, 1}}];
Subscript[ℛ, 2] = Circle[{1, 1}, {2r, r}];

Wolfram Language code: Subscript[r, opt] = NMaxValue[{r, {x, y}∈Subscript[ℛ, 1] && {x, y}∈Subscript[ℛ, 2]}, {r, x, y}]

绘制所得区域：

Wolfram Language code: Graphics[{Blue, Subscript[ℛ, 1], Subscript[ℛ, 2] /. r -> Subscript[r, opt]}]

求圆的最大半径，使得个非重叠圆和其中心都包含在一个正方形内. 边界约束条件可表达为：

Wolfram Language code:

n = 3;
boxConstraint = Table[-1 <= Norm[c[i], Infinity] + r <= 1, {i, n}];

圆不可重叠：

Wolfram Language code:

nonOverlapConstraint = Table[Norm[c[i] - c[j]] >= 2r, 
	{i, 1, n}, {j, i + 1, n}];

组合这些变量：

Wolfram Language code: vars = Append[Table[Element[c[i], Vectors[2, Reals]], {i, n}], Element[r, Reals]];

求最大半径：

Wolfram Language code: NMaxValue[{r, boxConstraint, nonOverlapConstraint, r >= 0}, vars]

投资问题 (1)

求如何在两只股票和债券之间分配最多可达 $250,000 的资金，使得投资回报最大化. 令为投资在两只股票上的金额，为投资在债券上的金额：

Wolfram Language code: capitalConstraint = Subscript[x, 1] + Subscript[x, 2] + Subscript[x, 3] ≤ 250000;

投资于公用事业股票的金额不得超过 $40,000：

Wolfram Language code: utilityStockConstraint = 0 ≤ Subscript[x, 1] ≤ 40000;

投资于债券的金额不能少于 $70,000：

Wolfram Language code: bondConstraint = Subscript[x, 3] ≥ 70000;

投资于两只股票的总金额必须至少是投资总额的一半：

Wolfram Language code: investmentConstraint = Subscript[x, 1] + Subscript[x, 2] ≥ (Subscript[x, 1] + Subscript[x, 2] + Subscript[x, 3]) / 2;

股票每年分别支付 9% 和 4% 的股息. 债券的股息为 5%. 总投资回报为：

Wolfram Language code: totalProfit = (0.09Subscript[x, 1] + 0.04Subscript[x, 2] + 0.05Subscript[x, 3]);

执行交易的成本为，不能超过 $1000：

Wolfram Language code: costConstraint = Sum[Abs[Subscript[x, i]]^0.5, {i, 3}] ≤ 1000;

在指定约束条件下可获得的最大利润为：

Wolfram Language code:

NMaxValue[{totalProfit, 
	capitalConstraint, utilityStockConstraint, bondConstraint, investmentConstraint, costConstraint}, {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}]

迭代优化 (1)

求与椭圆相关的参数的值，使得的最大值被最小化：

Wolfram Language code:

pfun[α_ ? NumericQ] := NMaxValue[{(x - 1)(y - 2), 
	 Norm[{x / α, α y}] ≤ 1}, {x, y}]

显示距离随变化的情况：

Wolfram Language code: Plot[pfun[α], {α, 0.1, 2}, PlotPoints -> 2, PlotRange -> All]

求最小化目标函数的最大值的最佳参数：

Wolfram Language code: FindMinimum[{pfun[α], 0.1 ≤ α ≤ 1}, {α, .5}, AccuracyGoal -> 3]

属性和关系 (7)

NMaximize 给出最大值，并以规则形式给出使结果最大化的变量值：

Wolfram Language code: NMaximize[{y - x.x , Norm[x + y] ≤ 1}, {Element[x, Vectors[2, Reals]], y}]

NArgMax 给出使结果最大化的值的列表：

Wolfram Language code: NArgMax[{y - x.x , Norm[x + y] ≤ 1}, {Element[x, Vectors[2, Reals]], y}]

NMaxValue 只给出最大值：

Wolfram Language code: NMaxValue[{y - x.x , Norm[x + y] ≤ 1}, {Element[x, Vectors[2, Reals]], y}]

最大化函数 f 相当于最小化 -f：

Wolfram Language code: NMinValue[{x ^ 2 + y ^ 2, x + 2 y ≥ 3}, {x, y}]

Wolfram Language code: -NMaxValue[{-(x ^ 2 + y ^ 2), x + 2 y ≥ 3}, {x, y}]

对于凸问题，可用 ConvexOptimization 获取解的其他属性：

Wolfram Language code: NMaxValue[{-(x ^ 2 + y ^ 2), x + 2 y ≥ 3}, {x, y}]

Wolfram Language code: ConvexOptimization[x ^ 2 + y ^ 2, x + 2 y ≥ 3, {x, y}, "PrimalMinimumValue"]

获取对偶问题的解：

Wolfram Language code: ConvexOptimization[x ^ 2 + y ^ 2, x + 2 y ≥ 3, {x, y}, "DualMaximizer"]

对于含有参数的凸问题，用 ParametricConvexOptimization 给出 ParametricFunction：

Wolfram Language code:

pfun = ParametricConvexOptimization[-(x + 2 y), (x - α) ^ 2 + (y - β) ^ 2 ≤ 1, {x, y}, {α, β}, "PrimalMinimumValue"]

可通过计算 ParametricFunction 求得参数的值：

Wolfram Language code: {pfun[0., 0.], pfun[.5, 1.], pfun[2., 1.]}

用 NMaxValue 定义参数化问题的函数：

Wolfram Language code:

fun[α_ ? NumericQ, β_ ? NumericQ]  := NMaxValue[{x + 2 y, (x - α) ^ 2 + (y - β) ^ 2 ≤ 1}, {x, y}];
{fun[0., 0.], fun[.5, 1.], fun[2., 1.]}

比较两种方法的速度：

Wolfram Language code:

testData = RandomReal[{0, 4}, {1000, 2}];
{First[AbsoluteTiming[pfun @@@testData]], First[AbsoluteTiming[fun @@@ testData]]}

也可以计算 ParametricFunction 的导数：

Wolfram Language code: D[pfun[α, β], {{α, β}}] /. {α -> 2., β -> 1.}

对于含有参数化约束条件的凸问题，RobustConvexOptimization 将找到适用于所有可能参数值的最优值：

Wolfram Language code:

{rMinValue, rOptimizer} = RobustConvexOptimization[-(2x + 3y), x + y ≤ α && x - y ≥ β && -1 ≤ α ≤ 1 && 0 ≤ β ≤ 1, {x, y}, {α, β}, {"PrimalMinimumValue", "PrimalMinimizerRules"}];
rMaxValue = -rMinValue;
{rMaxValue, rOptimizer}

对于特定参数值，NMaxValue 可能会找到更大的最大值：

Wolfram Language code: NMaxValue[{2x + 3y, x + y ≤ α && x - y ≥ β && α == 0 && β == 0}, {x, y}]

对于和允许的所有值，该最大化点不满足约束条件：

Wolfram Language code: maximizer = Last[NMaximize[{2x + 3y, x + y ≤ α && x - y ≥ β && α == 0 && β == 0}, {x, y}]]

Wolfram Language code: (x + y ≤ α && x - y ≥ β /. maximizer) /. {α -> 1, β -> 1}

为特定参数值找到的最大值大于或等于稳健最大值：

Wolfram Language code:

fun[α_, β_] /; (-1 ≤ α ≤ 1 && 0 ≤ β ≤ 1)  := 
	NMaxValue[{2x + 3y, x + y ≤ α && x - y ≥ β}, {x, y}];

Wolfram Language code:

testValues = RandomVariate[UniformDistribution[{{-1, 1}, {0, 1}}], 100];
AllTrue[testValues, ((fun@@#) ≥ rMaxValue)&]

NMaxValue 可以求解线性规划问题：

Wolfram Language code: NMaxValue[{2x + 3y - z, 1 ≤ x + y + z ≤ 2 && 1 ≤ x - y + z ≤ 2 && x - y - z == 3}, {x, y, z}]

LinearProgramming 可以求解用矩阵表示的相同问题：

Wolfram Language code:

c = {2., 3., -1.};
m = {{1, 1, 1}, {1, 1, 1}, {1, -1, 1}, {1, -1, 1}, {1, -1, -1}};
b = {{1, 1}, {2, -1}, {1, 1}, {2, -1}, {3, 0}};

Wolfram Language code: c.LinearProgramming[-c, m, b, -Infinity]

用 RegionBounds 计算边界框：

Wolfram Language code:

f = x^4 + 3. x^2 y + 2. x^2 y^2 - y^3 + y^4 ≤ 0;
ℛ = ImplicitRegion@@{f, {x, y}}

Wolfram Language code: RegionBounds[ℛ]

用 NMaxValue 和 NMinValue 计算相同的边界：

Wolfram Language code: {{x1, x2}, {y1, y2}} = {NMinValue[#, {x, y}∈ℛ], NMaxValue[#, {x, y}∈ℛ]}& /@ {x, y}

Wolfram Language code: Show[{Graphics[{LightBlue, Rectangle[{x1, y1}, {x2, y2}]}], RegionPlot[f, {x, x1 - 1, x2 + 1}, {y, y1 - 1, y2 + 1}]}]

Top

	lhs==rhs	等式
	lhs>rhs, lhs≥rhs, lhs<rhs, lhs≤rhs	不等式 (LessEqual、…)
	lhsrhs, lhsrhs, lhsrhs, lhsrhs	向量不等式 (VectorLessEqual、…)
	{x,y,…}∈rdom	区域或域的指定

	Reals	实标量变量
	Integers	整数标量变量
	Vectors[n,dom]	中的向量变量
	Matrices[{m,n},dom]	中的矩阵变量
	ℛ	限制在几何区域中的向量变量

AccuracyGoal	Automatic	追求多少位的准确度
EvaluationMonitor	None	计算 f 时要计算的表达式
MaxIterations	Automatic	使用的最大迭代次数
Method	Automatic	使用的方法
PrecisionGoal	Automatic	追求多少位的精度
StepMonitor	None	每次迭代时要计算的表达式
WorkingPrecision	MachinePrecision	内部计算使用的精度

	"Convex"	只使用凸方法
	"MOSEK"	对于凸问题，使用商用 MOSEK 库
	"Gurobi"	对于凸问题，使用商用 Gurobi 库
	"Xpress"	对于凸问题，使用商用 Xpress 库

	"NelderMead"	Nelder 和 Mead 的单纯形法
	"DifferentialEvolution"	使用差分进化
	"SimulatedAnnealing"	使用模拟退火
	"RandomSearch"	使用从多个随机起始点中找到的最佳局部最大值
	"Couenne"	使用 Couenne 库处理非凸混合整数非线性问题

NMaxValue

更多信息和选项

范例

基本范例 (5)

范围 (34)

基本用法 (12)

域约束条件 (4)

区域约束条件 (3)

线性问题 (5)

凸问题 (4)

可转化为凸问题的问题 (3)

普通问题 (3)

选项 (7)

AccuracyGoal & PrecisionGoal (2)

EvaluationMonitor (1)

Method (2)

StepMonitor (1)

WorkingPrecision (1)

应用 (4)

几何问题 (2)

投资问题 (1)

迭代优化 (1)

属性和关系 (7)

参见

技术笔记

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX