Sin

Sin[z]

z の正弦を与える．

詳細

数値操作と記号操作の両方に適した数学関数である．
明示的にQuantityオブジェクトとして与えられていない限り，Sinの引数はラジアン単位であるとみなされる（Degreeをかけて度から変換することができる）． »
Sinは，引数がの単純有理数倍である場合は自動的に評価されるが，より複雑な有理数倍の場合はFunctionExpandが使用されることもある． »
特別な引数の場合，Sinは，自動的に厳密値を計算する．
Sinは，任意の数値精度で評価できる．
Sinは，自動的にリストに縫い込まれる． »
SinはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

予備知識

Sinは，正弦関数であり，三角法における基本関数の一つである．これは，を単位円の円周に沿って軸から反時計回りに測定されたラジアン角度とすることによって，実数について定義される．Sin[x]は，弧の端点の垂直座標を与える．教科書的な定義では，直角三角形における角度の正弦は，の向かい側の辺の長さと斜辺の長さの比である．
Sinは，その引数がの単純な有理倍数のときは，自動的に厳密値に評価される．より複雑な有理倍数については，FunctionExpandを使って明示的な厳密値を得ることができることがある．度で測られた角を使って引数を指定するときは，記号Degreeを乗数として使うことができる（例：Sin[30 Degree]）．引数として厳密な数式が与えられると，Sinは任意の数値精度に評価できることがある．Sinを含む記号式の操作に便利なその他の演算には，TrigToExp，TrigExpand，Simplify，FullSimplify等がある．
Sinは要素単位でリストおよび行列に縫い込まれる．これとは対照的に，MatrixFunctionを使って，平方行列の正弦（つまり，通常のベキが行列のベキで置き換えられた正弦関数のベキ級数）を与えることができる．
Sinは，FunctionPeriodにあるように，を周期として周期的である．Sinは恒等式を満足する．これは，ピタゴラス(Pythagoras)の定理に等しい．正弦関数の定義は，定義を使って，複素数の引数にまで拡張される．ここでは，自然対数の底である．正弦関数は完全，つまり複素平面のすべての有限点において複素微分することが可能である．Sin[z]は原点周囲で級数展開を持つ．
Sinの逆関数は，ArcSinである．双曲線正弦はSinhによって与えられる．他の関連する数学関数にはCos，Tan，Csc等がある．

例題

すべて開くすべて閉じる

例 (5)

引数はラジアンで与えられる：

Wolfram Language code: Sin[Pi / 3]

Degreeを用いて引数を度数で指定する：

Wolfram Language code: Sin[60Degree]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[Sin[x], {x, 0, 2Pi}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[Sin[z], {z, -2 π - 2 I, 2 π + 2 I}, PlotLegends -> Automatic]

0における級数展開：

Wolfram Language code: Series[Sin[x], {x, 0, 10}]

スコープ (52)

数値評価 (6)

数値的に評価する：

Wolfram Language code: Sin[1.2]

高精度で評価する：

Wolfram Language code: N[Sin[12 / 10], 50]

出力精度は入力精度に従う：

Wolfram Language code: Sin[1.20000000000000000000000]

Sinは複素数を入力として取ることができる：

Wolfram Language code: Sin[2.5 + I]

Sinを効率よく高精度で評価する：

Wolfram Language code: Sin[1.2`500]//Timing

Wolfram Language code: Sin[1.2`100000];//Timing

自動縫込みを使って配列の要素ごとの値を計算する：

Wolfram Language code: Sin[ {{5π / 6, 0}, {3π / 2, -π / 2}}]

MatrixFunctionを使って行列のSin関数を計算することもできる：

Wolfram Language code: MatrixFunction[Sin[#]&, {{5π / 6, 0}, {3π / 2, -π / 2}}]

IntervalオブジェクトおよびCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: Sin[Interval[{-Pi / 6, Pi / 6}]]

Wolfram Language code: Sin[Interval[{-Infinity, Infinity}]]

Wolfram Language code: Sin[CenteredInterval[1, 1 / 100]]

Wolfram Language code: Sin[CenteredInterval[2 + 3I, (1 + I) / 100]]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: Sin[Around[2, 0.01]]

特定の値 (6)

固定点におけるSinの値：

Wolfram Language code: Table[Sin[n (π/6)], {n, 0, 6}]

Sinは π の有理数倍で厳密値となる：

Wolfram Language code: Table[Sin[n (π/6)], {n, 0, 6}]

無限大における値：

Wolfram Language code: Sin[Infinity]

Wolfram Language code: Sin[ComplexInfinity]

簡単な厳密値は自動的に生成される：

Wolfram Language code: Sin[Pi / 5]

より複雑な場合にはFunctionExpandを明示的に使う：

Wolfram Language code: Sin[Pi / 24]

Wolfram Language code: FunctionExpand[%]

Sinの零点：

Wolfram Language code: Assuming[m∈Integers, Refine[Sin[π m]]]

Sinの極値：

Wolfram Language code: Assuming[m∈Integers, FullSimplify[Sin[π ((1/2) + m)]]]

最初の正の極値をの根として求める：

Wolfram Language code: sol = Solve[D[Sin[x], x] == 0 && 0 < x < π, x]

結果を代入する：

Wolfram Language code: xmax = x /. First[sol]

結果を可視化する：

Wolfram Language code: Plot[Sin[x], {x, 0, 2π}, Epilog -> Style[Point[{xmax, Sin[xmax]}], PointSize[Large], Red]]

可視化 (3)

Sin関数をプロットする：

Wolfram Language code: Plot[Sin[x], {x, 0, 4π}]

の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[Sin[z]], {z, -2π - 2I, 2π + 2I}, IconizedObject[«PlotOptions»]]

の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[Sin[z]], {z, -2π - 2I, 2π + 2I}, IconizedObject[«PlotOptions»]]

による極プロット：

Wolfram Language code:

Table[PolarPlot[Sin[k ϕ], {ϕ, 0, 2 π}, Sequence[Frame -> True, FrameTicks -> {{{-1, -0.5, 0, 0.5, 1}, None}, {{-1, -0.5, 0, 0.5, 1}, None}}, PlotLabel -> "k=" <> ToString[k]]], {k, 1, 8}]

関数の特性 (13)

Sinは，すべての実数値および虚数値について定義される：

Wolfram Language code: FunctionDomain[Sin[x], x]

Wolfram Language code: FunctionDomain[Sin[z], z, Complexes]

Sinは，から1までのすべての実数値に達する：

Wolfram Language code: FunctionRange[Sin[x], x, y]

複素値の範囲は平面全体である：

Wolfram Language code: FunctionRange[Sin[z], z, y, Complexes]

Sinは周期がの周期関数である：

Wolfram Language code: FunctionPeriod[Sin[x], x]

Sinは奇関数である：

Wolfram Language code: Sin[-x]

Sinは鏡映特性を有する：

Wolfram Language code: FullSimplify[Sin[Conjugate[z]] == Conjugate[Sin[z]]]

Sinは x についての解析関数である：

Wolfram Language code: FunctionAnalytic[Sin[x], x]

Sinは特定の値域で単調である：

Wolfram Language code: FunctionMonotonicity[Sin[x], x]

Wolfram Language code: FunctionMonotonicity[{Sin[x], 0 < x < π / 2}, x]

Sinは単射ではない：

Wolfram Language code: FunctionInjective[Sin[x], x]

Wolfram Language code: Plot[{Sin[x], 1 / 2}, {x, -2π, 2π}]

Sinは全射ではない：

Wolfram Language code: FunctionSurjective[Sin[x], x]

Wolfram Language code: Plot[{Sin[x], 1.5}, {x, -2π, 2π}]

Sinは非負でも非正でもない：

Wolfram Language code: FunctionSign[Sin[x], x]

Sinは特異点も不連続点も持たない：

Wolfram Language code: FunctionSingularities[Sin[x], x]

Wolfram Language code: FunctionDiscontinuities[Sin[x], x]

Sinは凸でも凹でもない：

Wolfram Language code: FunctionConvexity[Sin[x], x]

Sinは[0,π]において x について凹である：

Wolfram Language code: FunctionConvexity[{Sin[x], 0 < x < π}, x]

Wolfram Language code: Plot[Sin[x], {x, 0, π}]

TraditionalForm による表示：

Wolfram Language code: Sin[α]//TraditionalForm

微分 (3)

一次導関数：

Wolfram Language code: D[Sin[x], x]

高次導関数：

Wolfram Language code: Table[D[Sin[x], {x, n}], {n, 1, 4}]

Wolfram Language code:

Plot[Evaluate[%], {x, -2π, 2π}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

次導関数の式：

Wolfram Language code: D[Sin[x], {x, n}]

積分 (3)

Integrateを使って不定積分を計算する：

Wolfram Language code: Integrate[Sin[x], x]

Sinの一定周期の定積分は0である：

Wolfram Language code: Integrate[Sin[x], {x, 0, 2 π}]

その他の積分例：

Wolfram Language code: Integrate[Sin[x]Cos[x], x]

Wolfram Language code: Integrate[Sin[z] ^ a, z]

級数展開 (4)

Seriesを使ってテイラー(Taylor)展開を求める：

Wolfram Language code: Series[Sin[x], {x, 0, 7}]

の周りのSinの最初の3つの近似をプロットする：

Wolfram Language code:

terms = Normal@Table[Series[Sin[x], {x, 0, m}], {m, 1, 5, 2}];
Plot[{Sin[x], terms}, {x, -2π, 2π}, PlotRange -> {-1.5, 1.5}]

SeriesCoefficientを使った級数展開における一般項：

Wolfram Language code: SeriesCoefficient[Sin[x], {x, 0, n}]

フーリエ級数：

Wolfram Language code: FourierSeries[Sin[z], z, 1]

Sinはベキ級数に適用できる：

Wolfram Language code: Sin[(π/2) + x + (x^2/2) + (x^3/3) + O[x]^4]

積分変換 (3)

FourierTransformを使ってフーリエ(Fourier)変換を計算する：

Wolfram Language code: FourierTransform[Sin[t], t, ω ]

LaplaceTransform：

Wolfram Language code: LaplaceTransform[Sin[t], t, s ]

MellinTransform：

Wolfram Language code: MellinTransform[Sin[x], x, s ]

関数の恒等式と簡約 (6)

TrigExpandを使ったニ倍角の公式：

Wolfram Language code: TrigExpand[Sin[2x]]

加算公式：

Wolfram Language code: TrigExpand[Sin[x + y]]

マルチアングルの式：

Wolfram Language code: TrigExpand[Sin[4x]]

TrigReduceを使ってもとの式を回復する：

Wolfram Language code: TrigReduce[%]

TrigFactorを使って和を積に変換する：

Wolfram Language code: TrigFactor[Sin[x] + Sin[y]]

x と y が実数であると仮定して，ComplexExpandを使って展開する：

Wolfram Language code: ComplexExpand[Sin[x + I y]]

TrigToExpを使って指数関数に変換する：

Wolfram Language code: TrigToExp[Sin[z]]

関数表現 (5)

Simplifyを使ってCosからの表現を求める：

Wolfram Language code: Simplify[Cos[(Pi/2) - x]]

ベッセル(Bessel)関数からの表現：

Wolfram Language code: Simplify[Sqrt[( π x/2)]BesselJ[(1/2), x]]

Wolfram Language code: Simplify[-I Sqrt[( π I x/2)]BesselI[(1/2), I x]]

SphericalHarmonicYからの表現：

Wolfram Language code: Simplify[Sqrt[8 π / 3]SphericalHarmonicY[1, -1, θ, 0]]

MeijerGに関する表現：

Wolfram Language code: MeijerGReduce[Sin[x], x]

Wolfram Language code: Activate[%]

Sinは，DifferentialRootとして表すことができる：

Wolfram Language code: DifferentialRootReduce[Sin[x], x]

アプリケーション (15)

円の描画：

Wolfram Language code: ParametricPlot[{Sin[t], Cos[t]}, {t, 0, 2Pi}]

リサージュ(Lissajous)の図形：

Wolfram Language code: ParametricPlot[{Sin[t], Sin[2t]}, {t, 0, 2Pi}]

等角（対数の）螺線：

Wolfram Language code: ParametricPlot[Exp[t / 10]{Sin[t], Cos[t]}, {t, 0, 10Pi}, PlotRange -> All]

円内の動き：

Wolfram Language code: Animate[Graphics[Line[{{0, 0}, {Sin[t], Cos[t]}}], PlotRange -> 1.2], {t, 0, 10Pi}]

440Hzで純音を生成する：

Wolfram Language code: Play[Sin[2 Pi 440 t], {t, 0, 1}]

調和運動の方程式を解く：

Wolfram Language code: DSolve[x''[t] + ω^2x[t] == 0, x[t], t]

回転行列：

Wolfram Language code: RotationMatrix[θ]

ベクトルを回転させる：

Wolfram Language code: %.{x, y}

球をプロットする：

Wolfram Language code: ParametricPlot3D[{Cos[ϕ] Sin[θ], Sin[θ] Sin[ϕ], Cos[θ]}, {ϕ, -π, π}, {θ, 0, π}]

トーラスをプロットする：

Wolfram Language code:

ParametricPlot3D[{Cos[ϕ] + 1 / 2 Cos[θ] Cos[ϕ], Sin[ϕ] + 1 / 2 Cos[θ] Sin[ϕ], Sin[θ] / 2}, {ϕ, -π, π}, {θ, 0, 2 π}]

波：

Wolfram Language code: Plot3D[Sin[x]Sin[y], {x, 0, 10Pi}, {y, 0, 10Pi}]

3重周期曲面：

Wolfram Language code:

ContourPlot3D[Sin[x] + Sin[y] + Sin[z], {x, -2Pi, 2Pi}, {y, -2Pi, 2Pi}, {z, -2Pi, 2Pi}, Contours -> {0}, Mesh -> False, BoundaryStyle -> None, 
	ContourStyle -> Opacity[0.8]]

微分可能なところがほとんどどこにもないRiemann–Weierstrass関数を近似する：

Wolfram Language code: Plot[Sum[N[Sin[j ^ 2 x] / j ^ 2], {j, 1, 12}], {x, 0, 2Pi}]

円形開口対回折角のフラウンホーファー(Fraunhofer)回析パターンの強度：

Wolfram Language code: Plot[2(BesselJ[2, 10Sin[θ]] / (10Sin[θ])) ^ 2, {θ, 0, π / 2}]

QRコードでグラフィックスを符号化する：

Wolfram Language code: str = ToString[HoldForm[Plot[Sin[x], {x, 0, 20}]]]

Wolfram Language code: i = BarcodeImage[str, "QR"]

式を複合化して評価する：

Wolfram Language code: ToExpression[BarcodeRecognize[i]]

Cos関数とSin関数を使って単位円上の点を求める：

Wolfram Language code:

ContourPlot[x ^ 2 + y ^ 2 == 1, {x, -1.5, 1.5}, {y, -1.5, 1.5}, Epilog -> Style[Point[{Cos[π / 4], Sin[π / 4]}], PointSize[Large], Red], Axes -> True, Frame -> False, AxesLabel -> {x, y}]

特性と関係 (13)

基本的なパリティと周期性の性質は自動的に適用される：

Wolfram Language code: Sin[x + 2Pi]

Wolfram Language code: Sin[-x]

Wolfram Language code: Sin[I x]

Wolfram Language code: 1 / Sin[x]

三角関数を含む複雑な式は自動的には簡約されない：

Wolfram Language code: Sin[3z]^2 + (2 Cos[z] Cos[2 z] - Cos[z])^2

Wolfram Language code: Simplify[%]

Wolfram Language code: Sin[x] - Sin[y] - 2Cos[(x + y/2)]Sin[(x - y/2)]

Wolfram Language code: Simplify[%]

逆関数を用いて構築する：

Wolfram Language code: {Sin[ArcSin[z]], Sin[2ArcSin[z]], Sin[3ArcSin[z]]}

Wolfram Language code: FunctionExpand[%]

1ラジアンは度である：

Wolfram Language code: Sin[1] == SinDegrees[180 / π]//Simplify

三角方程式を解く：

Wolfram Language code: Reduce[Sin[z]^2 + 3 Sin[z + Pi / 6] == 4, z]

超越方程式の根を数値的に求める：

Wolfram Language code: FindRoot[Sin[z]^2 + 3 Sin[z + Pi / 6] == z, {z, 2}]

三角方程式を簡約する：

Wolfram Language code: Reduce[Sin[α x + β] == 0, x]

フーリエ変換：

Wolfram Language code: FourierTransform[Sin[t], t, s]

Wolfram Language code: LaplaceTransform[Sin[t], t, s]

Sinは多くの数学関数の特殊形に現れる：

Wolfram Language code:

{BesselJ[(1/2), z], MathieuS[1, 0, z], JacobiSN[z, 0], HypergeometricPFQ[{}, {(3/2)}, -z], MeijerG[{{}, {}}, {{(1/2)}, {0}}, z]}

Sinは数値関数である：

Wolfram Language code: NumericQ[Sin[2 + E]]

SinはDifferentialRootとして表すことができる：

Wolfram Language code: DifferentialRootReduce[Sin[x], x]

Sinの母関数：

Wolfram Language code: GeneratingFunction[Sin[n], n, x]

Wolfram Language code: Series[%, {x, 0, 5}]//FullSimplify

Sinの指数母関数：

Wolfram Language code: ExponentialGeneratingFunction[Sin[n], n, x]

考えられる問題 (6)

機械精度の入力では正解を出すのに不十分である：

Wolfram Language code: Sin[10. ^ 30]

厳密な入力を与えると正しい答が得られる：

Wolfram Language code: N[Sin[10 ^ 30], 20]

$MaxExtraPrecisionの設定値を大きくする必要があるかもしれない：

Wolfram Language code: N[Sin[10 ^ 100], 20]

Wolfram Language code: Block[{$MaxExtraPrecision = 200}, N[Sin[10 ^ 100], 20]]

機械数の入力で高精度の結果が得られることがある：

Wolfram Language code: Sin[10. ^ 3I]

Wolfram Language code: MachineNumberQ[%]

FunctionExpandを使い，有理数にを掛けた正弦を根基で表す：

Wolfram Language code: {Sin[Pi / 8], Sin[Pi / 12], Sin[Pi / 15]}

Wolfram Language code: FunctionExpand[%]

Sin[x]を含む連続関数が不連続な不定積分を返すことがある：

Wolfram Language code: Integrate[(1/2 + Sin[x]), x]

Wolfram Language code: Plot[%, {x, 0, 2Pi}]

TraditionalFormでは，引数の周りにカッコが必要である：

Wolfram Language code: sin x

Wolfram Language code: sin(x)

おもしろい例題 (5)

不均衡波（準周期関数）：

Wolfram Language code: Plot[Sin[x] + Sin[Sqrt[2]x], {x, 0, 40Pi}]

引数の中には，ネストした累乗根の有限列として表せるものもある：

Wolfram Language code: Sin[(π/2^12)]//FunctionExpand

の不定積分：

Wolfram Language code: Integrate[Sin[x ^ n], x]

クラドニ(Chladni)図形：

Wolfram Language code: DensityPlot[Sin[3x]Sin[5y] + 1 / 2Sin[5x]Sin[3y], {x, 0, 2Pi}, {y, 0, 2Pi}]

整数点でSinをプロットする：

Wolfram Language code: ArrayPlot[Table[Sin[x y], {x, -20, 20}, {y, -20, 20}]]

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

Sin

詳細

予備知識

例題

例 (5)

スコープ (52)

数値評価 (6)

特定の値 (6)

可視化 (3)

関数の特性 (13)

微分 (3)

積分 (3)

級数展開 (4)

積分変換 (3)

関数の恒等式と簡約 (6)

関数表現 (5)

アプリケーション (15)

特性と関係 (13)

考えられる問題 (6)

おもしろい例題 (5)

テキスト

CMS

APA

BibTeX

BibLaTeX

Sin

詳細

予備知識

例題

例 (5)

スコープ (52)

数値評価 (6)

特定の値 (6)

可視化 (3)

関数の特性 (13)

微分 (3)

積分 (3)

級数展開 (4)

積分変換 (3)

関数の恒等式と簡約 (6)

関数表現 (5)

アプリケーション (15)

特性と関係 (13)

考えられる問題 (6)

おもしろい例題 (5)

関連項目

テクニカルノート

関連するガイド

関連リンク

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX