WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

TableView[{{expr11,expr12,…},{expr21,expr22,…},…}]

exprijの表示と編集のためにスプレッドシートのような表形式ビューとして表示する．

TableView[Dynamic[x]]

表形式ビューのコンテンツが動的に更新された x の値を取るとみなす．x の値は表形式ビューのインタラクティブな編集によってリセットされる．

TableView[table,type]

デフォルトの指定タイプを使って，表形式ビュー中の新たに編集されたあるいは作成された項目を表す．

TableView[]

空白の表形式ビューを表示する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
構造  
型  
オプション  
Alignment  
AllowedDimensions  
AppearanceElements  
Show More Show More
Background  
BaselinePosition  
HeaderSize  
ImageSize  
Scrollbars  
ScrollPosition  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

TableView

TableView[{{expr11,expr12,…},{expr21,expr22,…},…}]

exprijの表示と編集のためにスプレッドシートのような表形式ビューとして表示する．

TableView[Dynamic[x]]

表形式ビューのコンテンツが動的に更新された x の値を取るとみなす．x の値は表形式ビューのインタラクティブな編集によってリセットされる．

TableView[table,type]

デフォルトの指定タイプを使って，表形式ビュー中の新たに編集されたあるいは作成された項目を表す．

TableView[]

空白の表形式ビューを表示する．

詳細とオプション

  • TableViewは一般的なスプレッドシートのインターフェースと同じように使えるインターフェースを作成する．列の大きさは変更することができる．行全体，列全体あるいはブロックを選択してカットしたりペーストしたりすることができる．文字列や数は編集の際に自動的に識別される．項目数が多い場合はビューをスクロールすることができる．
  • 次は，type の可能な値である．
  • Number数
    String文字列
    Expression式
    Hold[Expression]ホールドされた式
    Boxes未加工のボックス
    {Number,String}可能な場合は数を使い，不可能な場合は文字列を使う
  • type が指定されていなければ，TableViewはデフォルトの{Number,String}を使う．
  • 次は，使用可能なオプションである．
  • Alignment {Center,Baseline}項目の水平および垂直の整列
    AllowedDimensions Automatic行数と列数の制限
    AppearanceElements Automatic表示したビューに含める要素
    Background None使用する背景色
    BaselinePosition Automatic周囲のテキストのベースラインと何を揃えるか
    BaseStyle{}格子のベーススタイル指定
    EnabledTrue個々の項目が編集可かどうか
    HeaderSize Automaticヘッダの幅と高さ
    HeadersAutomatic行と列のラベル
    ImageSize Automatic表形式ビューの全体的な大きさ
    ItemSizeAutomatic各項目の幅と高さ
    ItemStyleNone列と行のスタイル
    Scrollbars Automaticスクロールバーを含むかどうか
    ScrollPosition {0,0}スクロールが使用可能な際のスクロール位置
  • オプションAlignment，Background，ItemSize，ItemStyleの設定値は次のようにして，個々の項目に別々に適用することができる．
  • specspec をすべての項目に適用する
    {specx}specx を連続する水平位置に適用する
    {specx,specy}speck を連続する水平位置および垂直位置に適用する
    {specx,specy,rules}また，個別的な i, j 要素に明示的な規則を使う
  • 次は，speckの取り得る形である．
  • {s1,s2,…,sn}s1から snまでを使い，次にデフォルトを使う
    {{c}}すべての場合に c を使う
    {{c1,c2}}c1と c2を交替で使う
    {{c1,c2,…}}すべての ciを循環的に使う
    {s,{c}}s を使い，次に繰り返し c を使う
    {s1,s2,…,{c1, c2,…},sm,…,sn}最初に siの最初の一連なりを使い，次に ciを繰り返し使って，最後に siの最後の一連なりを使う
    {i1->v1,i2->v2,…}位置 ikに何を使うかを指定する
    {spec,rules}rules を使って spec の指定を無効にする
  • TableViewは，データの不規則な表を見ること，またその作成をサポートしている．
  • TableView中の空白項目は，表の右辺から切り取れる場合は，評価の際に取り除かれる．空白項目が表の中にある場合は，指定された type にふさわしい空白文字列あるいはNullで表される．
  • SettingをTableViewと一緒に使ってもとになっているデータが抽出できることがある．
  • TableViewは，ノートブック中の大規模データの表を効率的に表示，編集，保存できるように特に設計されている．
  • AppearanceElementsの可能な要素には，"RowHeaders"，"CollapsedRowHeaders"，"ColumnHeaders"，"CollapsedColumnHeaders"，"Frame"，"ResizeArea"がある．

例題

すべて開く すべて閉じる

例  (2)

TableViewにした数値データ：

Wolfram Language code: TableView[RandomReal[1, {4, 4}]]

数と文字列：

Wolfram Language code: TableView[{{"Paris", "France", 2200000}, {"New York", "US", 8500000}, {"Beijing", "China", 21700000}}]

スコープ  (11)

構造  (5)

空白のTableView：

Wolfram Language code: TableView[]

データの規則的配列構造：

Wolfram Language code: TableView[Table[i j, {i, 5}, {j, 5}]]

データの不規則配列：

Wolfram Language code: TableView[{{1}, {2, 2}, {3, 3, 3}, {4, 4}, {5, 5}}]

空白フィールドがある配列：

Wolfram Language code: TableView[{{1, 2, "", 4, 5}}]

空白の行と列：

Wolfram Language code: TableView[{{""}, {""}, {"", 1, 2, 3}}]

型  (6)

数：

Wolfram Language code: TableView[{{1.23, 3.592, 4.613}}]

文字列：

Wolfram Language code: TableView[{{"lions", "bears", "tigers"}}]

混合データ：

Wolfram Language code: TableView[{{"fish", 10}, {"fowl", 5}}]

式：

Wolfram Language code: TableView[Table[{Expand[(x + y) ^ n]}, {n, 5}], Expression, ItemSize -> {20, 1}]

画像とグラフィックス：

Wolfram Language code: TableView[{{RandomImage[1, {50, 50}], Graphics[Disk[]]}}, Expression, ItemSize -> {20, 4}]

ボックス：

Wolfram Language code: TableView[{{RowBox[{"a", "+"}], MakeBoxes[Integrate[x / 2, {x, 0, 1}], StandardForm]}}, Boxes, ItemSize -> {Automatic, 3}]

オプション  (20)

Alignment  (1)

中央揃え：

Wolfram Language code: TableView[{{"abc", 2, 3}}, Alignment -> Center]

AllowedDimensions  (2)

次元を厳密に4列 x 3行に設定する：

Wolfram Language code: TableView[{}, AllowedDimensions -> {4, 3}]

許される次元全体が一度に表示的ないときは，スクロールバーが自動的に現れる：

Wolfram Language code: TableView[{}, AllowedDimensions -> {10, 25}]

無制限の次元を使うと，スクロール位置が任意の高さに設定できる：

Wolfram Language code: TableView[{}, Scrollbars -> True, ScrollPosition -> {2000, 2000}]

制限がある次元では，スクロール位置は制限を超えては動かない：

Wolfram Language code: TableView[{}, Scrollbars -> True, ScrollPosition -> {2000, 2000}, AllowedDimensions -> {10, 10}]

AppearanceElements  (2)

折りたたんだヘッダと列を表示する：

Wolfram Language code: TableView[ConstantArray["c", {3, 4}], AppearanceElements -> {"CollapsedRowHeaders", "CollapsedColumnHeaders"}]

"Frame"要素は常に小さい灰色の枠として表示される：

Wolfram Language code: TableView[ConstantArray[123, {3, 4}], AppearanceElements -> {"Frame"}]

カスタマイズした枠を使用する場合は，"Frame"要素を削除してFramedを使う：

Wolfram Language code: Framed[TableView[ConstantArray[123, {3, 4}], AppearanceElements -> {}], FrameStyle -> {AbsoluteThickness[3], Brown}, FrameMargins -> None]

Background  (7)

ピンクの背景のビューを描画する：

Wolfram Language code: TableView[Table["x", {4}, {7}], Background -> Pink]

ピンクと灰色の背景を最初と2番目の水平位置に使う：

Wolfram Language code: TableView[Table["x", {4}, {7}], Background -> {{Pink, Gray}, None}]

等価の構文：

Wolfram Language code: TableView[Table["x", {4}, {7}], Background -> {{1 -> Pink, 2 -> Gray}, None}]

ピンクと灰色の背景を最初と2番目の垂直位置の行に使う：

Wolfram Language code: TableView[Table["x", {4}, {7}], Background -> {None, {Pink, Gray}}]

ピンクと灰色の背景を交互に使う：

Wolfram Language code: TableView[Table["x", {4}, {7}], Background -> {{{Pink, Gray}}, None}]

背景を交互に使い，最初と最後の位置に黄色を重ねる：

Wolfram Language code: TableView[Table["x", {4}, {7}], Background -> {{{{Pink, Gray}}, {1 -> Orange, -1 -> Orange}}, None}]

色の混合：

Wolfram Language code: TableView[Table["x", {4}, {7}], Background -> {{{Orange, None}}, {{StandardPurple, None}}}]

特定の項目の背景を設定する：

Wolfram Language code: TableView[Table["x", {4}, {7}], Background -> {None, None, {{1, 1} -> Pink, {3, 3} -> Red}}]

格子の部分領域の背景を設定する：

Wolfram Language code: TableView[Table["x", {4}, {7}], Background -> {None, None, {{{1, 3}, {1, 3}} -> Pink}}]

BaselinePosition  (2)

格子の中心を周囲のテキストのベースラインと合わせる：

Wolfram Language code: {x, y, TableView[{}, ImageSize -> Tiny], z}

格子の底辺をベースラインと合わせる：

Wolfram Language code: {x, y, TableView[{}, ImageSize -> Tiny, BaselinePosition -> Bottom], z}

HeaderSize  (1)

第1列を広くする：

Wolfram Language code: TableView[{{"abc", 2, 3}}, HeaderSize -> 10]

ImageSize  (1)

さまざまな大きさのビューを表示する：

Wolfram Language code: Magnify[Table[TableView[{}, ImageSize -> size], {size, {Tiny, Small, Medium, Large}}], .25]

Scrollbars  (3)

デフォルトで，TableViewが全データを一度に表示できる場合はスクロールバーは表示されない：

Wolfram Language code: TableView[{{"a"}}]

しかし，データが切り取られてしまうような場合にはスクロールバーが現れる：

Wolfram Language code: TableView[ConstantArray[123, {30, 30}]]

たとえデータがビューに収まる場合でも，常にスクロールバーを表示するようにする：

Wolfram Language code: TableView[{{"a"}}, Scrollbars -> True]

現行のImageSizeではデータが切り取られる場合でもスクロールバーを表示しないようにする：

Wolfram Language code: TableView[ConstantArray[123, {10, 10}], ImageSize -> {200, 100}, Scrollbars -> False]

ScrollPosition  (1)

ビューの初期位置を指定する：

Wolfram Language code: TableView[{}, ScrollPosition -> {500, 500}]

特性と関係  (1)

TableViewはGridと同じオプションを同じような設定でたくさん取る：

Wolfram Language code: Table[n[ConstantArray[10, {3, 4}], Background -> {{{None, StandardBlue}}, {2 -> Orange}}], {n, {TableView, Grid}}]

TableViewは，Gridとは異なり，右端や底を持たない．右端や底を指定しても何も起こらない：

Wolfram Language code: Table[n[ConstantArray[10, {3, 4}], Background -> {{-1 -> StandardGreen}, {{None}, Pink}}], {n, {TableView, Grid}}]

おもしろい例題  (1)

Magnifyを使って多くのセルを一度に見る：

Wolfram Language code: Magnify[TableView[DiskMatrix[7], ImageSize -> {1200, 500}], .4]
Wolfram Research (2020), TableView, Wolfram言語関数， https://reference.wolfram.com/language/ref/TableView.html.

テキスト

Wolfram Research (2020), TableView, Wolfram言語関数， https://reference.wolfram.com/language/ref/TableView.html.

CMS

Wolfram Language. 2020. "TableView." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/TableView.html.

APA

Wolfram Language. (2020). TableView. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/TableView.html

BibTeX

@misc{reference.wolfram_2026_tableview, author="Wolfram Research", title="{TableView}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/TableView.html}", note=[Accessed: 03-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_tableview, organization={Wolfram Research}, title={TableView}, year={2020}, url={https://reference.wolfram.com/language/ref/TableView.html}, note=[Accessed: 03-November-2026]}