Wolfram 语言与系统参考资料中心

Volume

Volume[reg]

给出三维区域 reg 的体积.

Volume[{x₁,…,x_n},{s,s_min,s_max},{t,t_min,t_max},{u,u_min,u_max}]

给出参数化区域的体积，该区域的笛卡儿坐标 x_i 是 s, t, u 的函数.

Volume[{x₁,…,x_n},{s,s_min,s_max},{t,t_min,t_max},{u,u_min,u_max},chart]

把 x_i 理解为指定的坐标图表里的坐标.

范例

打开所有单元关闭所有单元

基本范例 (4)

三维空间中单位球的体积：

Wolfram Language code: Volume[Ball[]]

Wolfram Language code: Region[Ball[]]

三维空间中标准型的体积：

Wolfram Language code: Volume[Simplex[3]]

Wolfram Language code: Region[Simplex[3]]

矩形长方体的体积：

Wolfram Language code: Volume[{s, t, u}, {s, 0, a}, {t, 0, b}, {u, 0, c}]

圆柱体的体积，满足，（圆柱坐标系）：

Wolfram Language code: Volume[{r, t, z}, {r, 0, R}, {t, 0, 2Pi}, {z, 0, zMax}, "Cylindrical"]

范围 (23)

特殊区域 (7)

Cuboid 的体积：

Wolfram Language code: Volume[Cuboid[{Subscript[l, x], Subscript[l, y], Subscript[l, z]}, {Subscript[u, x], Subscript[u, y], Subscript[u, z]}]]

Wolfram Language code:

ℛ = Cuboid[{0, 0, 0}, {3, 2, 1}];
Volume[ℛ]

Wolfram Language code: Region[ℛ]

Parallelepiped:

Wolfram Language code:

ℛ = Parallelepiped[{0, 0, 0}, {{1, 0, 0}, {1, 1, 0}, {0, 1, 1}}];
Volume[ℛ]

Wolfram Language code: Region[ℛ]

三维空间中的 Simplex:

Wolfram Language code: Volume[Simplex[3]]

Wolfram Language code: Region[Simplex[3]]

四维空间中嵌入的体积标准型：

Wolfram Language code: Volume[Simplex[{{0, 0, 0, 0}, {0, 0, 1, 1}, {1, 1, 0, 0}, {0, 1, 1, 0}}]]

Ball:

Wolfram Language code: Volume[Ball[{Subscript[c, x], Subscript[c, y], Subscript[c, z]}, r]]

Wolfram Language code:

ℛ = Ball[{0, 0, 0}, 1];
Volume[ℛ]

Wolfram Language code: Region[ℛ]

Ellipsoid:

Wolfram Language code:

Volume[Ellipsoid[{Subscript[c, x], Subscript[c, y], Subscript[c, z]}, {Subscript[r, x], Subscript[r, y], Subscript[r, z]}]]

Wolfram Language code:

ℛ = Ellipsoid[{0, 0, 0}, {3, 2, 1}];
Volume[ℛ]

Wolfram Language code: Region[ℛ]

Cylinder:

Wolfram Language code:

Volume[Cylinder[{{Subscript[x, 1], Subscript[y, 1], Subscript[z, 1]}, {Subscript[x, 2], Subscript[y, 2], Subscript[z, 2]}}, r]]

Wolfram Language code:

ℛ = Cylinder[{{0, 0, 0}, {0, 0, 2}}, 1];
Volume[ℛ]

Wolfram Language code: Region[ℛ]

Cone:

Wolfram Language code:

Volume[Cone[{{Subscript[x, 1], Subscript[y, 1], Subscript[z, 1]}, {Subscript[x, 2], Subscript[y, 2], Subscript[z, 2]}}, r]]

Wolfram Language code:

ℛ = Cone[{{0, 0, 0}, {0, 0, 2}}, 1];
Volume[ℛ]

Wolfram Language code: Region[ℛ]

公式区域 (2)

表示为 ImplicitRegion 的球的体积：

Wolfram Language code: Volume[ImplicitRegion[x^2 + y^2 + z^2 ≤ 1, {x, y, z}]]

圆柱体：

Wolfram Language code: Volume[ImplicitRegion[x^2 + y^2 ≤ 1, {x, y, {z, 0, 2}}]]

球的体积表示为 ParametricRegion:

Wolfram Language code:

ℛ = ParametricRegion[{r Cos[θ]Cos[ϕ], r Sin[θ]Cos[ϕ], r Sin[ϕ]}, {{θ, 0, 2π}, {ϕ, -π / 2, π / 2}, {r, 0, 1}}];

Wolfram Language code: Volume[ℛ]

使用有理参数表示的圆柱体：

Wolfram Language code: Volume[ParametricRegion[{r(1 - t^2/1 + t^2), r(2t/1 + t^2), z}, {t, {r, 0, 1}, {z, 0, 2}}]]

网格区域 (2)

MeshRegion 的体积：

Wolfram Language code: DelaunayMesh[RandomReal[1, {20, 3}]]

Wolfram Language code: Volume[%]

BoundaryMeshRegion 的体积：

Wolfram Language code: ConvexHullMesh[RandomReal[1, {20, 3}]]

Wolfram Language code: Volume[%]

导出区域 (3)

RegionIntersection 的体积：

Wolfram Language code: ℛ = RegionIntersection[Ball[{0, 0, 0}, 1], Ball[{0, 0, 1}, 1]];

Wolfram Language code: Region[ℛ]

Wolfram Language code: Volume[ℛ]

TransformedRegion 的体积：

Wolfram Language code: ℛ = TransformedRegion[Ball[{0, 0, 0}, 1], ScalingTransform[{a, b, c}]];

Wolfram Language code: Region[ℛ /. Thread[{a, b, c} -> {3, 2, 1}]]

Wolfram Language code: Volume[ℛ]

RegionBoundary 的体积：

Wolfram Language code: RegionBoundary[Ball[{0, 0, 0, 0}, 1]]

Wolfram Language code: Volume[%]

参数化公式 (6)

半长轴为 3，2，1 的椭球的体积：

Wolfram Language code: Volume[{3r Cos[ψ], 2r Sin[θ]Sin[ψ], r Cos[θ]Sin[ψ]}, {r, 0, 1}, {θ, 0, 2Pi}, {ψ, 0, Pi}]

Wolfram Language code: ParametricPlot3D[{3 Cos[ψ], 2Sin[θ]Sin[ψ], Cos[θ]Sin[ψ]}, {θ, 0, 2Pi}, {ψ, 0, Pi}]

半球壳体的体积（球面坐标系）：

Wolfram Language code: Volume[{r, t, p}, {r, 1, 2}, {t, 0, Pi / 2} , {p, 0, 2Pi}, "Spherical"]

Wolfram Language code:

ParametricPlot3D[CoordinateTransform[ "Spherical" -> "Cartesian", {r, t, p}] /. {{r -> 1}, {r -> 2}}//Evaluate, {t, 0, Pi / 2}, {p, 0, 2Pi}, PlotTheme -> "Minimal", PlotStyle -> Opacity[.5]]

主半径为 5，次半径为 2 的环面的体积：

Wolfram Language code: Volume[{(5 + 2 r Sin[p])Cos[t], (5 + 2 r Sin[p])Sin[t], 5 Cos[p]}, {r, 0, 1}, {t, 0, 2Pi}, {p, 0, 2Pi} ]

Wolfram Language code: ParametricPlot3D[{(5 + 2Sin[p])Cos[t], (5 + 2Sin[p])Sin[t], 2Cos[p]}, {t, 0, 2Pi}, {p, 0, 2Pi} ]

嵌在四维空间内的圆盘与圆圈之积的体积：

Wolfram Language code: Volume[{3r Sin[t], 3r Cos[t], 2Sin[p], 2 Cos[p]}, {r, 0, 1}, {t, 0, 2Pi}, {p, 0, 2Pi}]

在矩形以上的抛物面的体积：

Wolfram Language code: Volume[w ^ 2 + x ^ 2 + y ^ 2, {w, -1, 1.}, {x, -2, 2.}, {y, -3, 3.}]

三球面的一个八分体的体积（用球极平面坐标）:

Wolfram Language code: Volume[{s, t, u}, {s, 0, ∞}, {t, 0, ∞}, {u, 0, ∞}, {"Stereographic", {"Sphere", 1}}]

CSG Regions (1)

线性 CSGRegion 的体积：

Wolfram Language code: CSGRegion["Difference", {Cube[2], Cube[{1, 0, 1}, 3]}]

Wolfram Language code: Volume[%]

非线性：

Wolfram Language code: CSGRegion["Intersection", {Ball[], Ball[{0, 0, 1}]}]

Wolfram Language code: SurfaceArea[%]

Subdivision Regions (2)

一个 SubdivisionRegion 的体积：

Wolfram Language code: SubdivisionRegion[Cube[]]

Wolfram Language code: Volume[%]

连续细分层次的体积收敛于极限区域的体积：

Wolfram Language code: levels = Table[SubdivisionRegion[Cube[], i], {i, 0, 3}]

Wolfram Language code: ListPlot[Volume /@ levels, ...]

选项 (6)

AccuracyGoal (1)

考虑一个体积难以精确计算的区域：

Wolfram Language code: ℛ = Region@ImplicitRegion[(x^2 + (9/4)y^2 + z^2 - 1)^3 - x^2z^3 - (9/80)y^2z^3 <= 0, {x, y, z}]

Wolfram Language code: volume1 = Volume[ℛ]

可以使用 AccuracyGoal 选项来更改默认的绝对容差. 在这里，一旦超过精度目标准则，体积计算就会停止：

Wolfram Language code: volume2 = Volume[ℛ, AccuracyGoal -> 3]

默认设置下得到的结果不同，因为默认只使用精度准则：

Wolfram Language code: volume1 - volume2

Assumptions (1)

任意半长轴为，半短轴为，且高为的椭圆锥的面积：

Wolfram Language code: Volume[{(1 - z / c) r a Cos[t], (1 - z / c) r b Sin[t], z}, {r, 0, 1}, {t, 0, 2Pi}, {z, 0, c}]

附加一个半轴为正数的假设将会简化结果：

Wolfram Language code:

Volume[{(1 - z / c) r a Cos[t], (1 - z / c) r b Sin[t], z}, {r, 0, 1}, {t, 0, 2Pi}, {z, 0, c}, Assumptions -> a > 0 && b > 0]

、、的区域：

Wolfram Language code:

Block[{a = 3, b = 2, c = 5}, RegionPlot3D[ParametricRegion[{(1 - z / c )r a Cos[t], (1 - z / c) r b Sin[t], z}, {{r, 0, 1}, {t, 0, 2Pi}, {z, 0, 5}}], Axes -> True, PlotPoints -> 51, PlotRange -> {{-a, a}, {-a, a}, {0, c}}]]

PrecisionGoal (1)

可以通过 PrecisionGoal 指定所寻求的有效精度位数：

Wolfram Language code:

Table[Volume[ImplicitRegion[(x^2 + (9/4)y^2 + z^2 - 1)^3 - x^2z^3 - (9/80)y^2z^3 <= 0, {x, y, z}], PrecisionGoal -> prec], {prec, 1, 5}]

绘制针对不同精度设置计算的体积：

Wolfram Language code: ListPlot[%, PlotRange -> All]

PerformanceGoal (1)

考虑一个体积难以精确计算的区域：

Wolfram Language code: ℛ = Region@ImplicitRegion[(x^2 + (9/4)y^2 + z^2 - 1)^3 - x^2z^3 - (9/80)y^2z^3 <= 0, {x, y, z}]

使用 PerformanceGoal"Speed" 以尝试快速计算体积：

Wolfram Language code: (volume1 = Volume[ℛ, PerformanceGoal -> "Speed"])//Timing

使用 PerformanceGoal"Performance" 以尝试计算出具有尽可能多正确数字的结果：

Wolfram Language code: (volume2 = Volume[ℛ, PerformanceGoal -> "Quality"])//Timing

WorkingPrecision (2)

用机器算术计算 Volume：

Wolfram Language code: Volume[ImplicitRegion[x ^ 4 + y ^ 4 + z ^ 4 - x y z <= 1, {x, y, z}], WorkingPrecision -> MachinePrecision]

有些情况下，无法算出精确的答案：

Wolfram Language code: Volume[ImplicitRegion[x ^ 4 + y ^ 4 + z ^ 4 - x y z <= 1, {x, y, z}], WorkingPrecision -> ∞]

用 30 位精度计算 Volume：

Wolfram Language code: Volume[{a Cos[t], a Sin[t], b Sin[t]}, {t, 0, 2Pi}, {a, 0, 1}, {b, 0, 1}, WorkingPrecision -> 30]

应用 (6)

函数区域：

Wolfram Language code: f[x_, y_, z_] := x y + z;

Wolfram Language code: ℛ = ParametricRegion[{x, y, z, f[x, y, z]}, {{x, 0, 1}, {y, 0, 1}, {z, 0, 1}}];

该区域的维度为 3：

Wolfram Language code: RegionDimension[ℛ]

该区域的的体积：

Wolfram Language code: Volume[ℛ]

相当于：

Wolfram Language code: Volume[f[x, y, z], {x, 0, 1}, {y, 0, 1}, {z, 0, 1}]

计算一个多面体的体积：

Wolfram Language code: ℛ = PolyhedronData["Tetrahedron", "Polyhedron"]

Wolfram Language code: Volume[ℛ]

地球的形状几乎是一个扁椭球体，其体积为：

Wolfram Language code: Volume[{ξ, η, φ}, {η, 0, Pi}, {φ, 0, 2Pi}, {ξ, 0, ArcTanh[b / a]}, {{"OblateSpheroidal", aSqrt[1 - (b^2/a^2)]}}]

带入半长轴和半短轴的值：

Wolfram Language code: % /. {a -> GeodesyData["ITRF00", "SemimajorAxis"], b -> GeodesyData["ITRF00", "SemiminorAxis"]}

求一个 Ball 内的甲醇的质量：

Wolfram Language code: ℛ = Ball[{0, 0, 0}, Quantity[3, "Centimeters"]];

Wolfram Language code: ChemicalData["Methanol", "Density"]Volume[ℛ]

求一个 Cone 的平均密度（其非均匀质量密度定义为）：

Wolfram Language code: ℛ = Cone[{{0, 0, 0}, {0, 0, h}}, r];

Wolfram Language code: Simplify[Integrate[x ^ 2 + y ^ 2 + z ^ 2, Element[{x, y, z}, ℛ]] / Volume[ℛ], h > 0 && r > 0]

计算一个装有个半径为 1.75 英寸的网球的罐子里的空余空间体积：

Wolfram Language code:

r = Quantity[1.75, "Inches"];
height = 2 n r;

Wolfram Language code:

can = Cylinder[{{0, 0, 0}, {0, 0, height}}, r];
ball = Ball[{0, 0, 0}, r];

Wolfram Language code: Volume[can] - n Volume[ball]

可视化装有三个球的罐:

Wolfram Language code:

n = 3;Graphics3D[{{Opacity[0.3], can}, Table[Ball[{0, 0, 2 r k - r}, r], {k, n}]} /. q_Quantity :> QuantityMagnitude[q], Boxed -> False]

属性和关系 (5)

Volume 是一个非负的量：

Wolfram Language code: Volume[{r Cos[φ] Sin[θ], r Sin[θ] Sin[φ], r Cos[θ]}, {r, 0, 1}, {θ, 0, π}, {φ, 0, 2Pi}]

Wolfram Language code: Volume[{r Cos[φ] Sin[θ], r Sin[θ] Sin[φ], r Cos[θ]}, {r, 0, 1}, {θ, 0, π}, {φ, 0, -2Pi}]

对于三维区域，Volume[r] 与 RegionMeasure[r] 相同：

Wolfram Language code: ℛ = Ball[3];

Wolfram Language code: {Volume[ℛ], RegionMeasure[ℛ]}

一般来说， Volume[r] 与 RegionMeasure[r,3] 等同：

Wolfram Language code: {Volume[Sphere[{0, 0, 0, 0}]], RegionMeasure[Sphere[{0, 0, 0, 0}], 3]}

Volume[x,s,t,u,c] 相当于 RegionMeasure[x,{s,t,u},c]:

Wolfram Language code: Volume[{s t ^ 2, Pi / 2, u, s t}, {s, 0, 1}, {t, 0, 2Pi}, {u, 0, 1}, "Hyperspherical"]

Wolfram Language code: RegionMeasure[{s t ^ 2, Pi / 2, u, s t}, {{s, 0, 1}, {t, 0, 2Pi}, {u, 0, 1}}, "Hyperspherical"]

对于一个三维区域，Volume 被定义为 1 在那个区域的积分：

Wolfram Language code:

ℛ = Ellipsoid[{1, 2, 3}, {4, 5, 6}];
{Volume[ℛ], Integrate[1, x∈ℛ]}

若要获取四维区域的曲面体积，可使用 RegionBoundary：

Wolfram Language code:

ℛ = Ball[4];
Volume[RegionBoundary[ℛ]]

可能存在的问题 (2)

Volume 的参数形式会计算可能的多个覆盖面的体积：

Wolfram Language code: Volume[{r Cos[φ] Sin[θ], r Sin[θ] Sin[φ], r Cos[θ]}, {r, 0, 1}, {θ, 0, π}, {φ, 0, 10Pi}]

区域版本的函数可计算图像的体积：

Wolfram Language code: Volume[ParametricRegion[{r Cos[φ] Sin[θ], r Sin[θ] Sin[φ], r Cos[θ]}, {{r, 0, 1}, {θ, 0, π}, {φ, 0, 10Pi}}]]

Wolfram Language code: Volume[Ball[{0, 0, 0}, 1]]

维度不是 3 的区域的体积是 Undefined:

Wolfram Language code: {Volume[Point[{0, 0}]], Volume[Circle[]], Volume[Ball[{0, 0, 0, 0}, 1]]}

Wolfram Language code: RegionDimension /@ {Point[{0, 0}], Circle[], Ball[{0, 0, 0, 0}, 1]}

Top

AccuracyGoal	Infinity	寻求绝对准确度的数字
Assumptions	$Assumptions	对于参数的假设
GenerateConditions	Automatic	是否产生参数的条件
PerformanceGoal	$PerformanceGoal	尝试优化的性能方面
PrecisionGoal	Automatic	寻求精度的数字
WorkingPrecision	Automatic	内部计算时使用的精度

更多学习资源

技术支持

Wolfram 解决方案

Wolfram 的教育解决方案

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

Volume

更多信息和选项

范例

基本范例 (4)

范围 (23)

特殊区域 (7)

公式区域 (2)

网格区域 (2)

导出区域 (3)

参数化公式 (6)

CSG Regions (1)

Subdivision Regions (2)

选项 (6)

AccuracyGoal (1)

Assumptions (1)

PrecisionGoal (1)

PerformanceGoal (1)

WorkingPrecision (2)

应用 (6)

属性和关系 (5)

可能存在的问题 (2)

文本

CMS

APA

BibTeX

BibLaTeX

Volume

更多信息和选项

范例

基本范例 (4)

范围 (23)

特殊区域 (7)

公式区域 (2)

网格区域 (2)

导出区域 (3)

参数化公式 (6)

CSG Regions (1)

Subdivision Regions (2)

选项 (6)

AccuracyGoal (1)

Assumptions (1)

PrecisionGoal (1)

PerformanceGoal (1)

WorkingPrecision (2)

应用 (6)

属性和关系 (5)

可能存在的问题 (2)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX