WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Animate[expr,{u,umin,umax}]

u が uminから umaxまで連続的に変化する expr のアニメーションを生成する．

Animate[expr,{u,umin,umax,du}]

u をステップ du で変化させる．

Animate[expr,{u,{u1,u2,…}}]

u が離散的な値 u1, u2, … を取るようにする．

Animate[expr,{u,…},{v,…},…]

すべての変数 u, v, … を変化させる．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
Animateのコンテンツ  
Animateのコントロール  
オプション  
Alignment  
AnimationDirection  
AnimationRate  
Show More Show More
AnimationRepetitions  
AnimationRunning  
AppearanceElements  
BaselinePosition  
ControlPlacement  
DefaultDuration  
Deinitialization  
Deployed  
DisplayAllSteps  
Exclusions  
FrameMargins  
ImageMargins  
Initialization  
RefreshRate  
TrackedSymbols  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連するワークフロー
履歴
引用書式

Animate

Animate[expr,{u,umin,umax}]

u が uminから umaxまで連続的に変化する expr のアニメーションを生成する．

Animate[expr,{u,umin,umax,du}]

u をステップ du で変化させる．

Animate[expr,{u,{u1,u2,…}}]

u が離散的な値 u1, u2, … を取るようにする．

Animate[expr,{u,…},{v,…},…]

すべての変数 u, v, … を変化させる．

詳細とオプション

例題

すべて開く すべて閉じる

例  (3)

aの値を継続的に変化させてアニメーションにする：

Wolfram Language code: Animate[Plot[Sin[x + a], {x, 0, 10}], {a, 0, 5}, AnimationRunning -> False]

離散的ステップでnを変化させてアニメーションにする：

Wolfram Language code: Animate[ArrayPlot[CellularAutomaton[n, {{1}, 0}, {40, All}]], {n, 0, 255, 1}, AnimationRunning -> False]

2つのパラメータaとbを連続的に変化させることでアニメーションにする：

Wolfram Language code: Animate[Plot[Sin[a x] + Sin[b x], {x, 0, 10}, PlotRange -> 2], {a, 1, 5}, {b, 1, 5}, AnimationRunning -> False]

スコープ  (8)

Animateのコンテンツ  (2)

プロットをアニメーションにする：

Wolfram Language code: Animate[Plot[Sin[x + a], {x, 0, 10}], {a, 0, 5}]

グラフィックスだけでなく，任意の式をアニメーションにする：

Wolfram Language code: Animate[FactorInteger[n], {n, 1, 2000, 1}, AnimationRunning -> False]
Wolfram Language code: Animate[Nest[Subsuperscript[#, #, #]&, x, n], {n, 1, 5, 1}, AnimationRunning -> False]

Animateのコントロール  (6)

アニメーションの範囲を指定する：

Wolfram Language code: Animate[Plot[Sin[x + a], {x, 0, 10}], {a, 0, 5}, AnimationRunning -> False]

AppearanceElementsを使ってアニメータのコントロールを指定する：

Wolfram Language code: Table[Animate[FactorInteger[n], {n, 1, 2000, 1, AppearanceElements -> a}], {a, {"ProgressSlider", "StepLeftButton", "StepRightButton", "PlayPauseButton", "FasterSlowerButtons", "DirectionButton", "ResetButton", "PlayButton", "ResetPlayButton"}}]

アニメーションのステップを指定する：

Wolfram Language code: Animate[Plot[BesselJ[n, x], {x, 0, 20}, PlotRange -> 1], {n, 1, 5, 1}, AnimationRunning -> False]

無限のアニメーションを指定する．ここでは，アニメーション変数が単位速度で増加する：

Wolfram Language code: Animate[Plot[Sin[x + a], {x, 0, 10}, PlotLabel -> a], {a, 0, Infinity}, AnimationRunning -> False]

離散的な一連の値を使ってアニメーションにする：

Wolfram Language code: Animate[Plot[Sin[x + a], {x, 0, 10}], {a, {0, π, 2π, 3π}}, AnimationRunning -> False]
Wolfram Language code: Animate[Graphics[p], {p, {Rectangle[], Line[{{0, 0}, {1, 1}}], Disk[]}}, AnimationRunning -> False]

複数の変数を一度にアニメーションにする：

Wolfram Language code: Animate[Plot3D[Sin[x + a]Sin[y + b], {x, 0, 2Pi}, {y, 0, 2Pi}, PlotRange -> 1], {a, 0, Pi}, {b, 0, Pi}, AnimationRunning -> False]

オプション  (23)

Alignment  (1)

設定値を使う：

Wolfram Language code: Table[Animate[Graphics[Disk[{u, 0}], PlotRange -> {{-1, 2}, {-1, 1}}, ImageSize -> 30], {u, 0, 1}, AnimationRunning -> False, Alignment -> a], {a, {Left, Center, Right}}]

AnimationDirection  (1)

アニメーションの方向を制御する：

Wolfram Language code: Table[Animate[u, {u, 0, 1}, AnimationDirection -> a, AnimationRunning -> False], {a, {Forward, Backward, ForwardBackward}}]

AnimationRate  (1)

アニメーションの速度を制御する：

Wolfram Language code: Table[Animate[u, {u, 0, 1}, AnimationRate -> a, AnimationRunning -> False], {a, {Automatic, 0.5, 1, 1.5}}]

AnimationRepetitions  (1)

アニメーションサイクルの回数を制御する：

Wolfram Language code: Table[Animate[u, {u, 0, 1}, AnimationRepetitions -> a, AnimationRunning -> False], {a, 1, 3}]

AnimationRunning  (2)

デフォルトで，Animateは評価されたときに実行される：

Wolfram Language code: Animate[u, {u, 0, 1}]

AnimationRunning->Falseと設定すると，Animateは静止状態で始まる：

Wolfram Language code: Animate[u, {u, 0, 1}, AnimationRunning -> False]

AppearanceElements  (2)

デフォルトで，Animateは1つのAnimatorしか含まない：

Wolfram Language code: Animate[u, {u, 0, 1}, AnimationRunning -> False]

AppearanceElementsを使って追加的なコントロールを持たせることができる：

Wolfram Language code: Table[Animate[u, {u, 0, 1}, AnimationRunning -> False, AppearanceElements -> a], {a, {"HideControlsButton", "SnapshotButton", "ResetButton", "UpdateButton", All}}]

BaselinePosition  (1)

周囲のテキストに揃える：

Wolfram Language code: Row[Table[Animate[u, {u, 0, 1}, ControlType -> None, AnimationRunning -> False, BaselinePosition -> p], {p, {Top, Center, Bottom}}], "xxx"]

ControlPlacement  (1)

コントロールの位置を指定する：

Wolfram Language code: Table[Animate[u, {u, 0, 1}, AnimationRunning -> False, ControlPlacement -> p], {p, {Left, Right, Bottom, Top}}]

DefaultDuration  (1)

1回のアニメーションサイクルの持続時間を制御する：

Wolfram Language code: Table[Animate[u, {u, 0, 10}, DefaultDuration -> a, AnimationRunning -> False], {a, 1, 3}]

Deinitialization  (1)

Animateが表示されなくなったときに，評価される式を指定する：

Wolfram Language code: CreateDialog[Animate[f[x], {x, 0, 1}, Initialization :> {f[c_] := Graphics[{Hue[c], Disk[]}, ImageSize -> Tiny]}, Deinitialization :> CreateDialog[f[x]]]];

Deployed  (2)

デフォルトで，コンテンツは選択・編集できる：

Wolfram Language code: Animate[Graphics[Disk[], ImageSize -> 50], {u, 0, 1}, AnimationRunning -> False]

Deployedを使ってコンテンツのインタラクティビティを制限することができる：

Wolfram Language code: Animate[Graphics[Disk[], ImageSize -> 50], {u, 0, 1}, AnimationRunning -> False, Deployed -> True]

DisplayAllSteps  (1)

デフォルト設定では，ステップが省略されることがある：

Wolfram Language code: Animate[Graphics[{Point[{Sin[x], Cos[x]Sin[x]}]}, PlotRange -> 1, ImageSize -> Tiny], {x, 0, 20 Pi, .1}, AnimationRunning -> False]

DisplayAllStepsを使って省略を防ぐ：

Wolfram Language code: Animate[Graphics[{Point[{Sin[x], Cos[x]Sin[x]}]}, PlotRange -> 1, ImageSize -> Tiny], {x, 0, 20 Pi, .1}, DisplayAllSteps -> True, AnimationRunning -> False]

Exclusions  (1)

範囲から値を除く：

Wolfram Language code: Animate[u, {u, 0, 1, 0.2}, Exclusions -> {0.4, 0.8}, AnimationRunning -> False]

FrameMargins  (2)

設定値を使う：

Wolfram Language code: Table[Animate[Framed@u, {u, 0, 1}, AnimationRunning -> False, FrameMargins -> f], {f, {Tiny, Small, Medium, Large}}]

あるいは，任意の値を使う：

Wolfram Language code: Animate[Framed@u, {u, 0, 1}, AnimationRunning -> False, FrameMargins -> 20]

ImageMargins  (2)

設定値を使う：

Wolfram Language code: Table[Framed@Animate[u, {u, 0, 1}, ImageMargins -> f], {f, {Tiny, Small, Medium, Large}}]

あるいは，任意の値を使う：

Wolfram Language code: Framed@Animate[u, {u, 0, 1}, ImageMargins -> 20]

Initialization  (1)

アニメーションを表示する前に評価されるべき式を指定する：

Wolfram Language code: Animate[f[x], {x, 0, 1}, Initialization :> {f[z_] := {z}}, AnimationRunning -> False]

RefreshRate  (1)

アニメーションの更新速度を制御する：

Wolfram Language code: Table[Animate[u, {u, 0, 1}, RefreshRate -> r, AnimationRunning -> False], {r, 1, 2}]

TrackedSymbols  (1)

アニメーションの更新の誘因となる記号を指定する：

Wolfram Language code: Animate[{u, v}, {u, 0, 1, AnimationRunning -> False}, {v, 1, 2}, TrackedSymbols -> {u}]

アプリケーション  (9)

転がる円のアニメーションを作る：

Wolfram Language code: Animate[Graphics[Translate[Rotate[{Circle[], Point[{0, 1}]}, -t], {t , 0}], PlotRange -> {{-2, 10}, {-2, 2}}, ImageSize -> {Large, Tiny}], {t, 0, 2π}, AnimationRunning -> False]

のテイラー(Taylor)級数をアニメーションにする：

Wolfram Language code: Animate[Series[Sin[x], {x, 0, n}], {n, 1, 20, 2}, AnimationDirection -> ForwardBackward, AnimationRunning -> False]

級数をアニメーションにする：

Wolfram Language code: Animate[Plot[Evaluate[{Sin[x], Normal[Series[Sin[x], {x, 0, n}]]}], {x, -10, 10}, PlotRange -> 3], {n, 1, 20, 2}, AnimationDirection -> ForwardBackward, AnimationRunning -> False]

セルオートマトンの大きいスペースを通してスキャンする：

Wolfram Language code: Animate[ArrayPlot[CellularAutomaton[{i, 2, 2}, {{1}, 0}, {40, All}]], {i, 0, Infinity, 2}, AnimationRate -> 4, AnimationRunning -> False]

直線的ではないスライダーの動きをアニメーションにする：

Wolfram Language code: Animate[{Slider[u ^ 2], Slider[1 - Sqrt[u]]}, {u, 0, 1}, AnimationRunning -> False]

2つの波の重ね合せを表示する：

Wolfram Language code: Animate[Column[{Plot[{Sin[f1 x + t], Sin[f2 x - t]}, {x, -2 π, 2 π}, PlotRange -> 1.1], Plot[Sin[f2 x - t] + Sin[f1 x + t], {x, -2 π, 2 π}, PlotRange -> 2]}], {f1, 1, 10}, {f2, 1, 10}, {t, 0, 2 π}, AnimationRunning -> False]

の異なる値についての平面の複合写像 をアニメーションにする：

Wolfram Language code: Animate[ParametricPlot[Through[{Re, Im}[(x + I y) ^ s]], {x, -2, 2}, {y, -2, 2}, PerformanceGoal -> "Quality", PlotLabel -> z^s, PlotRange -> {{-2, 2}, {-2, 2}}], {s, 0, 1}, AnimationRunning -> False]

球からトーラスへのモーフィングを表示する：

Wolfram Language code: sphere[θ_, ϕ_] := {Cos[θ]Sin[ϕ / 2], Sin[θ]Sin[ϕ / 2], Cos[ϕ / 2]};
Wolfram Language code: torus[θ_, ϕ_] := {-Sin[ϕ] / 3, (2 - Cos[ϕ]) Sin[θ] / 3, (2 - Cos[ϕ])Cos[θ] / 3};
Wolfram Language code: Animate[ParametricPlot3D[(1 - λ)sphere[θ, ϕ] + λ torus[θ, ϕ], {θ, 0, 2π}, {ϕ, 0, 2π}, PlotRange -> 1, Mesh -> True], {λ, 0, 1}, AnimationDirection -> ForwardBackward, SaveDefinitions -> True, AnimationRunning -> False]

の根をアニメーションにする：

Wolfram Language code: roots[n_, c_] := Module[{r, x, l}, r = Flatten@Table[x /. NSolve[x ^ n + l.x ^ Range[1, n - 1] + c == 0, x], {l, Tuples[{-1, 1}, n - 1]}]; Transpose[{Re[r], Im[r]}]]
Wolfram Language code: Animate[Graphics[Point[roots[n, a + I b]], PlotRange -> 2, Frame -> True], {{n, 7, "degree n"}, 2, 8, 1}, {{a, 1, "real constant a"}, -3, 3}, {{b, 0, "imaginary constant b"}, -3, 3}, SaveDefinitions -> True, AnimationRunning -> False]

点光源の位置をアニメーションにする：

Wolfram Language code: p1[θ_] := RotationTransform[θ, {0, 0, 1}][{0, 2, 0}]; p2[θ_] := RotationTransform[θ + Pi / 2, {1, 0, 1}][{0, 2, 0}]; p3[θ_] := RotationTransform[θ + Pi, {1, 0, 0}][{0, 2, 0}]; p4[θ_] := RotationTransform[θ + 3Pi / 2, {1, 0, -1}][{0, 2, 0}];
Wolfram Language code: Animate[Graphics3D[Sphere[], Lighting -> {{"Point", Red, p1[θ]}, {"Point", Green, p2[θ]}, {"Point", Blue, p3[θ]}, {"Point", Yellow, p4[θ]}}], {θ, 0, 2Pi}, AnimationDirection -> ForwardBackward, SaveDefinitions -> True, AnimationRunning -> False]

特性と関係  (2)

アニメーションの動作はAnimatorを基礎単位として使っても構築することができる：

Wolfram Language code: DynamicModule[{x = 0, xlis = {{0, 0}}}, {Animator[Dynamic[x, (x = #;AppendTo[xlis, {#, #}])&]], Graphics[Line[Dynamic@xlis], Axes -> True, PlotRange -> {{0, 1}, {0, 1}}]}]

式の固定リストのアニメーションはListAnimateを使って直接作ることもできる：

Wolfram Language code: ListAnimate[Table[Graphics[Line[{{0, 0}, {x, x}}], Axes -> True, PlotRange -> {{0, 1}, {0, 1}}], {x, 0, 1, 0.01}]]

考えられる問題  (2)

アニメーションが揺れるのを止めるようにPlotRangeを修正する：

Wolfram Language code: Animate[Plot[Sinc[x t], {x, 0, 10}], {t, 0, 2}]
Wolfram Language code: Animate[Plot[Sinc[x t], {x, 0, 10}, PlotRange -> {-1, 1}], {t, 0, 2}]

ImagePaddingを使って異なるラベルが画像サイズを変更しないようにする：

Wolfram Language code: Animate[Plot[x ^ n Sin[x], {x, 0, 10}], {n, 1, 4}]
Wolfram Language code: Animate[Plot[x ^ n Sin[x], {x, 0, 10}, ImagePadding -> 25], {n, 1, 4}]

おもしろい例題  (2)

円の周りを移動する点のアニメーション作成する：

Wolfram Language code: Animate[Graphics[{Circle[], AbsolutePointSize[8], Point[{Cos[t], Sin[t]}]}], {t, 0, 2π}, AnimationRunning -> False]

しかめ面がスマイリーへ変形していく様子のアニメーションを作成する：

Wolfram Language code: Animate[Plot[t(x^2 - 1) + (1 - t)(-x^2), {x, -1, 1}, Axes -> False, Epilog -> {Circle[{0, 1}, 3], Disk[{1, 2}, .3], Disk[{-1, 2}, .3], Line[{{0, 0.6}, {0, 1.6}}]}, PlotRange -> {{-3, 4}, {-3, 4}}, AspectRatio -> 1], {t, 0, 1}, AnimationRunning -> False]
Wolfram Research (2007), Animate, Wolfram言語関数， https://reference.wolfram.com/language/ref/Animate.html （2014年に更新）.

テキスト

Wolfram Research (2007), Animate, Wolfram言語関数， https://reference.wolfram.com/language/ref/Animate.html （2014年に更新）.

CMS

Wolfram Language. 2007. "Animate." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2014. https://reference.wolfram.com/language/ref/Animate.html.

APA

Wolfram Language. (2007). Animate. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Animate.html

BibTeX

@misc{reference.wolfram_2026_animate, author="Wolfram Research", title="{Animate}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/Animate.html}", note=[Accessed: 19-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_animate, organization={Wolfram Research}, title={Animate}, year={2014}, url={https://reference.wolfram.com/language/ref/Animate.html}, note=[Accessed: 19-August-2026]}