WOLFRAM

Wolfram 语言与系统参考资料中心

AnnotationDelete[obj]

删除对象 obj 的所有注释.

AnnotationDelete[{obj,itemspec}]

删除由 itemspec 指定的 obj 项的所有注释.

AnnotationDelete[spec,key]

删除由 spec 指定的注释 key.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
图与网络  
图注释  
顶点注释  
边注释  
区域  
应用  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

AnnotationDelete

AnnotationDelete[obj]

删除对象 obj 的所有注释.

AnnotationDelete[{obj,itemspec}]

删除由 itemspec 指定的 obj 项的所有注释.

AnnotationDelete[spec,key]

删除由 spec 指定的注释 key.

更多信息

  • 通常用于删除对象和对象中特定项的注释.
  • AnnotationDelete[spec,key] 返回 spec 中指定的对象，其中注释 key 已被删除.
  • 对于标准注释，AnnotationDelete 有效地将值重置为注释默认值.
  • 带有可注释项的可能对象：
  • Audio时间点和时间间隔
    BoundaryMeshRegion网格单元
    CSGRegion几何区域
    Graph顶点和边
    MeshRegion网格单元
  • 每种对象类型的项规范 itemspec 在其参考页中给出.

范例

打开所有单元 关闭所有单元

基本范例  (3)

删除顶点或边注释：

Wolfram Language code: g = CompleteGraph[4, VertexLabels -> {1 -> "here"}, EdgeStyle -> {12 -> Red}]
Wolfram Language code: {AnnotationDelete[{g, 1}, VertexLabels], AnnotationDelete[{g, 12}, EdgeStyle]}

删除样式或标签注释：

Wolfram Language code: mr = MengerMesh[1, MeshCellStyle -> {{1, All} -> Red}, MeshCellLabel -> {0 -> "Index"}]
Wolfram Language code: {AnnotationDelete[{mr, {1, All}}, MeshCellStyle], AnnotationDelete[{mr, 0}, MeshCellLabel]}

为 Audio 对象添加注释：

Wolfram Language code: a = Import["ExampleData/rule30.wav"];res = AudioAnnotate[a, {"tag1" -> {.5 -> "v11", {1, 1.5} -> "v12"}, "tag2" -> {.1 -> "v21", {.7, 1.5} -> "v22"}}];

删除带有特定标签的注释：

Wolfram Language code: AnnotationDelete[res, "tag1"]//AudioAnnotationLookup

范围  (11)

图与网络  (7)

图注释  (5)

从顶点删除一个注释：

Wolfram Language code: g = CompleteGraph[4, VertexStyle -> {1 -> Red}, VertexSize -> {1 -> Small}, EdgeStyle -> {12 -> Brown}, EdgeLabels -> {12 -> "hello"}]
Wolfram Language code: AnnotationDelete[{g, 1}, VertexStyle]

从边：

Wolfram Language code: AnnotationDelete[{g, 12}, EdgeLabels]

从顶点删除所有注释：

Wolfram Language code: AnnotationDelete[{g, 1}]

从边：

Wolfram Language code: AnnotationDelete[{g, 12}]

从顶点删除多个注释：

Wolfram Language code: CompleteGraph[4, VertexStyle -> {1 -> Red}, VertexSize -> {1 -> Small}, VertexLabels -> {1 -> "vertex"}];
Wolfram Language code: AnnotationDelete[{[image], 1}, {VertexLabels, VertexStyle}]

从边：

Wolfram Language code: WheelGraph[4, DirectedEdges -> True, EdgeStyle -> {_ -> Arrowheads[0.08], 12 -> Directive[Brown, Arrowheads[0.08]]}, EdgeLabels -> {12 -> "edge"}];
Wolfram Language code: AnnotationDelete[{[image], 12}, {EdgeStyle, EdgeLabels}]

AnnotationDelete 适用于无向图：

Wolfram Language code: CycleGraph[3, EdgeStyle -> {12 -> Brown}, EdgeLabels -> {12 -> "edge"}];
Wolfram Language code: AnnotationDelete[{[image], 12}, EdgeStyle]

有向图：

Wolfram Language code: CycleGraph[3, DirectedEdges -> True, EdgeStyle -> {12 -> Directive[Arrowheads[Small], Brown], Arrowheads[Small]}, EdgeLabels -> {12 -> "edge"}];
Wolfram Language code: AnnotationDelete[{[image], 12}, EdgeStyle]

加权图：

Wolfram Language code: With[{g = CycleGraph[3], w = 0.3Range[3], pl = {Above, Right, Right} /. {Right -> {1 / 2, {-0.4, 1 / 2}}, Above -> {1 / 2, {1 / 2, 0}}}}, Graph[VertexList[g], EdgeList[g], EdgeWeight -> w, VertexShapeFunction -> "Name", EdgeLabels -> Thread[EdgeList[g] -> MapThread[Placed, {w, pl}]], VertexCoordinates -> GraphEmbedding[g]]];
Wolfram Language code: AnnotationDelete[{[image], 12}, EdgeLabels]

顶点注释  (1)

为图设置多个注释：

Wolfram Language code: g = CompleteGraph[4, VertexSize -> Small]
Wolfram Language code: AnnotationValue[{g, 4}, VertexStyle] = Red; AnnotationValue[{g, 1}, VertexLabels] = "hello"; AnnotationValue[{g, 1}, VertexShape] = [image]; AnnotationValue[{g, 1}, VertexSize] = Large; AnnotationValue[{g, 2}, VertexShapeFunction] = "Square";AnnotationValue[{g, 1}, VertexWeight] = 100;AnnotationValue[{g, 2}, "Material"] = "Wood";
Wolfram Language code: g

删除包括 VertexStyle 的顶点注释：

Wolfram Language code: AnnotationDelete[{g, 4}, VertexStyle]

VertexLabels：

Wolfram Language code: AnnotationDelete[{g, 1}, VertexLabels]

VertexSize：

Wolfram Language code: AnnotationDelete[{g, 1}, VertexSize]

VertexShape：

Wolfram Language code: AnnotationDelete[{g, 1}, VertexShape]

VertexShapeFunction：

Wolfram Language code: AnnotationDelete[{g, 2}, VertexShapeFunction]

VertexCoordinates：

Wolfram Language code: AnnotationDelete[{g, 1}, VertexCoordinates]

自定义注释：

Wolfram Language code: MemberQ[PropertyList[{g, 2}], "Material"]
Wolfram Language code: AnnotationDelete[{g, 2}, "Material"];
Wolfram Language code: MemberQ[PropertyList[{%, 2}], "Material"]

边注释  (1)

为图设置多个注释：

Wolfram Language code: g = CompleteGraph[4]
Wolfram Language code: AnnotationValue[{g, 12}, EdgeStyle] = Brown; AnnotationValue[{g, 12}, EdgeLabels] = "hello"; AnnotationValue[{g, 34}, EdgeShapeFunction] = "HalfFilledDoubleArrow"; AnnotationValue[{g, 12}, EdgeWeight] = 42; AnnotationValue[{g, 24}, "Resistance"] = 50.;
Wolfram Language code: g

删除包括 EdgeStyle 的边注释：

Wolfram Language code: AnnotationDelete[{g, 12}, EdgeStyle]

EdgeLabels：

Wolfram Language code: AnnotationDelete[{g, 12}, EdgeLabels]

EdgeShapeFunction：

Wolfram Language code: AnnotationDelete[{g, 34}, EdgeShapeFunction]

自定义注释：

Wolfram Language code: MemberQ[AnnotationKeys[{g, 24}], "Resistance"]
Wolfram Language code: AnnotationDelete[{g, 24}, "Resistance"];
Wolfram Language code: MemberQ[AnnotationKeys[{%, 24}], "Resistance"]

区域  (4)

从子区域中删除一个注释：

Wolfram Language code: CSGRegion["Union", {Style[Ball[], Red], Style[Cuboid[], Blue]}]
Wolfram Language code: AnnotationDelete[{%, {1}}, "CSGRegionStyle"]

删除子区域的所有注释：

Wolfram Language code: CSGRegion["Union", {Style[Annotation[Ball[], "Material" -> "Metal"], Red], Cuboid[]}]
Wolfram Language code: AnnotationDelete[{%, {1}}]

从所有子区域中删除注释：

Wolfram Language code: CSGRegion["Union", {Style[Annotation[Ball[], "Material" -> "Wood"], Red], Style[Cuboid[], Blue]}]
Wolfram Language code: AnnotationDelete[%, "CSGRegionStyle"]
Wolfram Language code: AnnotationKeys[{%, {1}}]

删除 CSGRegion 对象中的所有注释：

Wolfram Language code: CSGRegion["Union", {Style[Annotation[Ball[], "Material" -> "Wood"], Red], Style[Cuboid[], Blue]}]
Wolfram Language code: AnnotationDelete[%]
Wolfram Language code: AnnotationKeys[{%, {1}}]

应用  (2)

Linda 希望在家庭聚会的介绍中保持匿名. 隐藏她的顶点标签：

Wolfram Language code: ExampleData[{"NetworkGraph", "FamilyGathering"}]
Wolfram Language code: AnnotationDelete[{%, "Linda"}, VertexLabels]

使用 Fold 重复应用 AnnotationDelete：

Wolfram Language code: g = CycleGraph[8, VertexStyle -> Table[i -> RandomChoice[{Red, Green, Blue}], {i, 8}], VertexSize -> Large]
Wolfram Language code: Fold[AnnotationDelete[{#1, #2}, VertexStyle]&, g, Range[1, 7]]

查看所有部分结果：

Wolfram Language code: FoldList[AnnotationDelete[{#1, #2}, VertexStyle]&, g, Range[1, 7]]

属性和关系  (6)

使用 Annotation 作为包装器在 Graph 之类的函数中指定注释：

Wolfram Language code: Graph[{Annotation[1, {VertexSize -> Medium, VertexStyle -> Red}], 2, 3}, {12, 23, 31}]

使用 AnnotationValue 提取值：

Wolfram Language code: g = CompleteGraph[4, VertexStyle -> {1 -> Red}, VertexSize -> Small]
Wolfram Language code: AnnotationValue[{g, 1}, VertexStyle]

对于未定义的注释，返回值 $Failed：

Wolfram Language code: AnnotationValue[{g, 1}, "foo"]
Wolfram Language code: MemberQ[AnnotationKeys[{g, 1}], "foo"]

使用 AnnotationValue 在图中设置注释：

Wolfram Language code: g = CompleteGraph[4]
Wolfram Language code: AnnotationValue[{g, 1}, VertexSize] = Small;

原始图已更改：

Wolfram Language code: g

使用 AnnotationValue 取消图形中的注释：

Wolfram Language code: g = CompleteGraph[4, VertexSize -> {1 -> Small}]
Wolfram Language code: AnnotationValue[{g, 1}, VertexSize]=.;

原始图已更改：

Wolfram Language code: g

使用 AnnotationKeys 来测试注释的存在：

Wolfram Language code: g = CompleteGraph[4, VertexLabels -> {1 -> one, 4 -> four}]
Wolfram Language code: MemberQ[AnnotationKeys[{g, 1}], VertexLabels]

生成顶点标签规则列表：

Wolfram Language code: Cases[VertexList[g], v_ /; MemberQ[AnnotationKeys[{g, v}], VertexLabels] :> v -> AnnotationValue[{g, v}, VertexLabels]]

使用 Annotate 设置注释而不更改原图：

Wolfram Language code: g = CompleteGraph[4]
Wolfram Language code: Annotate[{g, 1}, VertexSize -> Medium]

原始图不变：

Wolfram Language code: g

可能存在的问题  (1)

AnnotationValue 通常比 AnnotationDelete 更快：

Wolfram Language code: g = Graph[Annotation[#, VertexWeight -> 10.]& /@ Range[1000], {}];
Wolfram Language code: Timing@Do[AnnotationValue[{g, v}, VertexWeight]=., {v, VertexList[g]}]
Wolfram Language code: g = Graph[Annotation[#, VertexWeight -> 10.]& /@ Range[1000], {}];
Wolfram Language code: Timing@Do[g = AnnotationDelete[{g, v}, VertexWeight], {v, VertexList[g]}]
Wolfram Research (2019)，AnnotationDelete，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AnnotationDelete.html （更新于 2025 年）.

文本

Wolfram Research (2019)，AnnotationDelete，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AnnotationDelete.html （更新于 2025 年）.

CMS

Wolfram 语言. 2019. "AnnotationDelete." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2025. https://reference.wolfram.com/language/ref/AnnotationDelete.html.

APA

Wolfram 语言. (2019). AnnotationDelete. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/AnnotationDelete.html 年

BibTeX

@misc{reference.wolfram_2026_annotationdelete, author="Wolfram Research", title="{AnnotationDelete}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/AnnotationDelete.html}", note=[Accessed: 16-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_annotationdelete, organization={Wolfram Research}, title={AnnotationDelete}, year={2025}, url={https://reference.wolfram.com/language/ref/AnnotationDelete.html}, note=[Accessed: 16-August-2026]}