Wolfram言語＆システムドキュメントセンター

ArcLength

ArcLength[reg]

一次元の領域 reg の長さを与える．

ArcLength[{x₁,…,x_n},{t,t_min,t_max}]

デカルト座標 x_iが t の関数である，パラメータ化された曲線の長さを与える．

ArcLength[{x₁,…,x_n},{t,t_min,t_max},chart]

x_iを指定された座標チャートの座標として解釈する．

詳細とオプション

ArcLengthは，長さあるいは曲線長としても知られている．
一次元の領域を，1以上の任意の次元に埋め込むことができる．

デカルト座標における曲線のArcLengthはである．
一般的な座標チャートでは，パラメトリック曲線のArcLengthはで与えられる．ただし，は測定基準である．
ArcLength[x,{t,t_min,t_max}]では，x がスカラーの場合は，ArcLengthはパラメトリック曲線{t,x}の長さを返す．
ArcLengthの第3引数の座標チャートは，CoordinateChartDataの第1引数と同じように，3つの成分{coordsys,metric,dim}で指定することができる．dim を省略した短縮形を使うこともできる．
次は，使用可能なオプションである．

AccuracyGoal	Infinity	目標とする絶対確度の桁数
Assumptions	$Assumptions	パラメータについての仮定
GenerateConditions	Automatic	パラメータについての条件を生成するかどうか
PerformanceGoal	$PerformanceGoal	パフォーマンスのどの局面について最適化するか
PrecisionGoal	Automatic	目標とする精度の桁数
WorkingPrecision	Automatic	内部計算に使用する精度

積分の記号極限は，実数であり順序付けられているものとみなされる．記号座標チャートのパラメータは，CoordinateChartDataの"ParameterRangeAssumptions"特性によって与えられる範囲内であるとみなされる，
ArcLengthはGeometricSceneの記号領域と一緒に使うことができる．

例題

すべて開くすべて閉じる

例 (3)

点，，を繋ぐ線の長さ：

Wolfram Language code: ArcLength[Line[{{0, 0}, {1, 1}, {2, 0}}]]

半径の円の外周の長さ：

Wolfram Language code: ArcLength[Circle[{x, y}, r]]

パラメータ化された単位円の円周：

Wolfram Language code: ArcLength[{Sin[θ], Cos[θ]}, {θ, 0, 2Pi}]

円柱座標で表した，，の螺線一巡の長さ：

Wolfram Language code: ArcLength[{1, t, t}, {t, 0, 2Pi}, "Cylindrical"]

スコープ (16)

特別な領域 (3)

Line：

Wolfram Language code:

ℛ = Line[{{0, 0}, {1, 2}, {1, 0}, {2, 2}}];
ArcLength[ℛ]

Wolfram Language code: Region[ℛ]

線は任意の次元で使うことができる：

Wolfram Language code: ArcLength[Line[{{0}, {1}}]]

Wolfram Language code: ArcLength[Line[{{0, 0, 0}, {1, 1, 1}, {0, 0, 1}}]]

1DのSimplexのみが有意な弧長を有する：

Wolfram Language code:

ℛ = Simplex[{{0, 0}, {1, 1}}];
ArcLength[ℛ]

Wolfram Language code: Region[ℛ]

これは，任意次元に埋め込むことができる：

Wolfram Language code: ArcLength[Simplex[{{0}, {1}}]]

Wolfram Language code: ArcLength[Simplex[{{0, 0, 0}, {1, 1, 1}}]]

Circle：

Wolfram Language code: ArcLength[Circle[{Subscript[c, x], Subscript[c, y]}, r]]

Wolfram Language code: Region[Circle[{0, 0}, 1]]

Wolfram Language code: ArcLength[Circle[{Subscript[c, x], Subscript[c, y]}, {Subscript[r, x], Subscript[r, y]}]]

Wolfram Language code: Region[Circle[{0, 0}, {3, 2}]]

数式定義領域 (2)

ImplicitRegionとして表された円の弧長：

Wolfram Language code: ArcLength[ImplicitRegion[x^2 + y^2 == 1, {x, y}]]

楕円：

Wolfram Language code: ArcLength[ImplicitRegion[x^2 + 2y^2 == 1, {x, y}]]

ParametricRegionとして表された円の弧長：

Wolfram Language code: ArcLength[ParametricRegion[{Cos[θ], Sin[θ]}, {{θ, 0, 2π}}]]

円の有理パラメータ化を使う：

Wolfram Language code: ArcLength[ParametricRegion[{(1 - t^2/1 + t^2), (2t/1 + t^2)}, {t}]]

メッシュ領域 (2)

MeshRegionの弧長：

Wolfram Language code: MeshRegion[{{0, 0}, {1, 0}, {2, 1 / 2}, {2, -1 / 2}}, Line[{1, 2, 3, 4, 2}]]

Wolfram Language code: ArcLength[%]

3D：

Wolfram Language code: MeshRegion[{{0, 0, 0}, {0, 1, 1}, {1, 0, 0}, {1, 1, 1}}, Line[{1, 2, 3, 4, 1}]]

Wolfram Language code: ArcLength[%]

1DでのBoundaryMeshRegionの弧長：

Wolfram Language code: BoundaryMeshRegion[{{0}, {1}}, Point[{{1}, {2}}]]

Wolfram Language code: ArcLength[%]

派生領域 (4)

円の円板と交差する部分：

Wolfram Language code: ℛ = RegionIntersection[Circle[{1, 0}, 1], Disk[]];

Wolfram Language code: Show[Graphics[{LightBlue, EdgeForm[Gray], Disk[], Gray, Circle[{1, 0}, 1]}], HighlightMesh[DiscretizeRegion[ℛ], 1]]

Wolfram Language code: ArcLength[ℛ]

Triangleと交差するCircleの弧長：

Wolfram Language code:

Subscript[ℛ, 1] = Circle[];
Subscript[ℛ, 2] = Triangle[{{-3 / 2, 0}, {3 / 2, 0}, {0, 11 / 10}}];
Subscript[ℛ, 3] = RegionIntersection[Subscript[ℛ, 1], Subscript[ℛ, 2]];

Wolfram Language code:

Show[Graphics[{LightBlue, EdgeForm[Gray], Subscript[ℛ, 2], Gray, Subscript[ℛ, 1]}], HighlightMesh[DiscretizeRegion[Subscript[ℛ, 3]], 1]]

Wolfram Language code: ArcLength[Subscript[ℛ, 3]]

TransformedRegionの弧長：

Wolfram Language code: ℛ = TransformedRegion[Line[{{0, 0}, {1, 0}, {1, 1}, {0, 0}}], ShearingTransform[30Degree, {1, 0}, {0, 1}]];

Wolfram Language code: DiscretizeRegion[ℛ, {{0, 2}, {-1, 1}}]

Wolfram Language code: ArcLength[ℛ]

RegionBoundaryの大きさ：

Wolfram Language code: ℛ = RegionBoundary[Disk[{1, 2}, 3]]

Wolfram Language code: Region[ℛ]

Wolfram Language code: ArcLength[ℛ]

パラメトリック式 (5)

極座標における，有限長の無限曲線：

Wolfram Language code: ArcLength[{Exp[-t / 10], t}, {t, 0, ∞}, "Polar"]

Wolfram Language code: ParametricPlot[CoordinateTransform[ "Polar" -> "Cartesian", {Exp[-t / 10], t}]//Evaluate, {t, 0, 50}, PlotRange -> All]

からまでの放物線の長さ：

Wolfram Language code: ArcLength[x ^ 2, {x, a, b}]

測定基準，座標系，パラメータを指定する弧長：

Wolfram Language code: ArcLength[{1, t, 2t}, {t, 0, Pi}, {{"OblateSpheroidal", {2}}, "Euclidean"}]

より高次元のユークリッド空間における曲線の弧長：

Wolfram Language code: ArcLength[{t ^ 2, Pi / 2, Pi / 4, t}, {t, 0, 2Pi}, "Hyperspherical"]

ステレオ投影座標で表された2つの球の経線の長さ：

Wolfram Language code: ArcLength[{t, a t}, {t, 0, ∞}, {"Stereographic", "Sphere"}, Assumptions -> a∈Reals]

オプション (7)

AccuracyGoal (1)

弧長を厳密に計算することが難しい領域について考える：

Wolfram Language code: Region[ℛ = ImplicitRegion[x ^ 4 + y ^ 4 == 1, {x, y}]]

Wolfram Language code: s1 = ArcLength[ℛ]

The AccuracyGoalオプションを使ってデフォルトの絶対許容範囲を変えることができる．以下では，確度の目標基準を超えると弧長の計算が停止する：

Wolfram Language code: s2 = ArcLength[ℛ, AccuracyGoal -> 1]

Assumptions (1)

任意のパラメータ a によるカルジオイド（心臓形）の長さ：

Wolfram Language code: ArcLength[{2 a (1 + Cos[t]) Sin[t], -2 a Cos[t] (1 + Cos[t])}, {t, 0, 2Pi}]

a は正であるという仮定を加えると，答が簡約される：

Wolfram Language code: ArcLength[{2 a (1 + Cos[t]) Sin[t], -2 a Cos[t] (1 + Cos[t])}, {t, 0, 2Pi}, Assumptions -> a > 0]

GenerateConditions (1)

デフォルトで，答が有効であることを保証するためにパラメータを制限する条件が追加できる：

Wolfram Language code: ArcLength[Log[x], {x, a, b} ]

パラメータのいくつかの値についてしか有効ではない条件なしで結果を生成する：

Wolfram Language code: ArcLength[Log[x], {x, a, b} , GenerateConditions -> False]

PrecisionGoal (1)

目標とする精度の有効桁数はPrecisionGoalで指定できる：

Wolfram Language code: Table[ArcLength[ImplicitRegion[x ^ 4 + y ^ 4 == 1, {x, y}], PrecisionGoal -> prec], {prec, 1, 5}]

さまざまな精度設定で計算した弧長をプロットする：

Wolfram Language code: ListPlot[%, PlotRange -> All]

PerformanceGoal (1)

弧長の厳密計算が難しい領域について考える：

Wolfram Language code: Region[ℛ = ImplicitRegion[x ^ 4 + y ^ 4 == 1, {x, y}]]

PerformanceGoal"Speed"を使って素早く弧長を計算しようとする：

Wolfram Language code: (s1 = ArcLength[ℛ, PerformanceGoal -> "Speed"])//Timing

PerformanceGoal"Performance"を使って正しい精度の桁数ができるだけ多くなるように試みる：

Wolfram Language code: (s2 = ArcLength[ℛ, PerformanceGoal -> "Quality"])//Timing

厳密計算で求まった値と比較する：

Wolfram Language code:

sexact = -(3^1 / 4 MeijerG[{{(1/3), (2/3), (5/6), 1, (4/3)}, {}}, {{(1/12), (5/12), (7/12), (3/4), (13/12)}, {}}, 1]/16 Sqrt[2] π^7 / 2 Gamma[(5/4)]);

Wolfram Language code: s1 - sexact

Wolfram Language code: s2 - sexact

WorkingPrecision (2)

機械演算を使ってArcLengthを計算する：

Wolfram Language code: ArcLength[ImplicitRegion[x ^ 6 + y ^ 6 - x y == 1, {x, y}], WorkingPrecision -> MachinePrecision]

場合によっては厳密な答が計算できないことがある：

Wolfram Language code: ArcLength[ImplicitRegion[x ^ 6 + y ^ 6 - x y == 1, {x, y}]]

30桁精度でArcLengthを求める：

Wolfram Language code: ArcLength[{a Cos[t], a Sin[t], a Sin[t]}, {t, 0, 2Pi}, WorkingPrecision -> 30]

アプリケーション (8)

関数曲線の長さ：

Wolfram Language code: curve = ParametricRegion[{x, Sin[x]}, {{x, 0, 1}}];

Wolfram Language code: ArcLength[curve]

同様に：

Wolfram Language code: ArcLength[Sin[x], {x, 0, 1}]

結び目の長さを計算する：

Wolfram Language code: knot = KnotData["SolomonSeal", "SpaceCurve"]

Wolfram Language code: ArcLength[knot[t], {t, 0, 2Pi}]

木星軌道の長さをメートル単位で計算する：

Wolfram Language code: {a, e} = {"SemimajorAxis", "Eccentricity"} /. Entity["Planet", "Jupiter"]["OrbitRules"]//N

長さは楕円の極表現を使って計算することができる：

Wolfram Language code: ArcLength[{(a(1 - e^2)/1 + e Cos[θ]), θ}, {θ, 0, 2Pi}, "Polar"]

代りに，半焦点距離，定数の楕円座標を使う：

Wolfram Language code: ArcLength[{ArcCosh[1 / e], ν}, {ν, 0, 2Pi}, {{"Elliptic", a e}}]

グラフィックスから線を抽出し，その座標長を計算する：

Wolfram Language code: graphics = KnotData["SolomonSeal", "KnotDiagram"]

Wolfram Language code: ArcLength /@ Cases[graphics, _Line, -1]

Wolfram Language code: Total[%]

横断する距離に従って，リサージュ(Lissajous)曲線に彩色する：

Wolfram Language code:

c[t_] = {Cos[3t], Sin[5t]};
total = ArcLength[c[t], {t, 0., 2Pi}];
ParametricPlot[c[t], {t, 0, 2Pi}, PlotStyle -> Thick, ColorFunctionScaling -> False, ImageSize -> 300, ColorFunction -> (Hue[0.6ArcLength[c[t], {t, 0, #3}] / total]&), PlotLegends -> BarLegend[{Hue[0.6# / total]&, {0, total}}]]

横断距離の比によって，球面上のヴィヴィアーニ(Viviani)曲線に彩色する：

Wolfram Language code:

viv[t_] := {-(Sin[t]/2), -Sin[(t/2)], (1/2) (1 + Cos[t])};
fraclen[a_] = ArcLength[viv[t], {t, 0, 4Pi a}] / ArcLength[viv[t], {t, 0, 4Pi}];
Show[ParametricPlot3D[viv[t], {t, 0, 4Pi}, PlotStyle -> Thick, ColorFunction -> (Hue[0.6fraclen[#4]]&), PlotLegends -> BarLegend[{Hue[0.6#]&, {0, 1}}, LegendMarkerSize -> Small]], Graphics3D[{Gray, Opacity[.5], Sphere[]}], PlotRange -> All]

円形のワイヤーに沿った線形電荷密度の平均：

Wolfram Language code: r = Circle[{0, 0}, 1];

Wolfram Language code: Integrate[x^2y^2, {x, y}∈r] / ArcLength[r]

Polygonの外周の長さを計算する：

Wolfram Language code:

p = Polygon[Table[If[EvenQ[ii], 3, 2]{Cos[2π ii / 16], Sin[2π ii / 16]}, {ii, 0, 15}]];
Region[p]

Wolfram Language code: ArcLength[RegionBoundary[N@p]]

特性と関係 (6)

ArcLengthは非負の数量である：

Wolfram Language code: ArcLength[{Sin[θ], Cos[θ]}, {θ, 0, 2π}]

Wolfram Language code: ArcLength[{Sin[θ], Cos[θ]}, {θ, 0, -2π}]

ArcLength[r]は，任意の一次元領域については，RegionMeasure[r]と等しい：

Wolfram Language code: {ArcLength[Line[{{0, 0}, {1, 1}}]], RegionMeasure[Line[{{0, 0}, {1, 1}}]]}

Wolfram Language code: {ArcLength[Circle[]], RegionMeasure[Circle[]]}

パラメトリック形式についてのArcLengthは，積分として定義される：

Wolfram Language code: ArcLength[{Sin[θ], 2Cos[θ]}, {θ, 0, 2π}]

Wolfram Language code: Integrate[Sqrt[Sin'[θ]^2 + (2 Cos'[θ])^2], {θ, 0, 2π}]

ArcLength[x,t,c]はRegionMeasure[x,{t},c]に等しい：

Wolfram Language code: ArcLength[{t ^ 2, Pi / 2, Pi / 4, t}, {t, 0, 2Pi}, "Hyperspherical"]

Wolfram Language code: RegionMeasure[{t ^ 2, Pi / 2, Pi / 4, t}, {{t, 0, 2Pi}}, "Hyperspherical"]

Wolfram Language code: % == %%

1D領域については，ArcLengthはその領域上での1の積分として定義される：

Wolfram Language code: ℛ = Circle[{1, 2}, {3, 4}];

Wolfram Language code: {ArcLength[ℛ], Integrate[1, x∈ℛ]}

2D領域の外周は，そのRegionBoundaryのArcLengthである：

Wolfram Language code: ℛ = RegionBoundary[Disk[{0, 0}, 1]];

Wolfram Language code: ArcLength[ℛ]

考えられる問題 (2)

パラメトリック形式，すなわちArcLengthは，場合によっては，複数の被覆の長さを計算することができる：

Wolfram Language code: ArcLength[{Cos[θ], Sin[θ]}, {θ, 0, 4π}]

領域バージョンは画像の長さを計算する：

Wolfram Language code: ArcLength[ParametricRegion[{Cos[θ], Sin[θ]}, {{θ, 0, 4π}}]]

Wolfram Language code: ArcLength[Circle[{0, 0}, 1]]

一次元以外の次元の領域の長さはUndefinedである：

Wolfram Language code: {ArcLength[Point[{0, 0}]], ArcLength[Disk[]]}

Wolfram Language code: {RegionDimension[Point[{0, 0}]], RegionDimension[Disk[]]}

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

ArcLength

詳細とオプション

例題

例 (3)

スコープ (16)

特別な領域 (3)

数式定義領域 (2)

メッシュ領域 (2)

派生領域 (4)

パラメトリック式 (5)

オプション (7)

AccuracyGoal (1)

Assumptions (1)

GenerateConditions (1)

PrecisionGoal (1)

PerformanceGoal (1)

WorkingPrecision (2)

アプリケーション (8)

特性と関係 (6)

考えられる問題 (2)

テキスト

CMS

APA

BibTeX

BibLaTeX

ArcLength

詳細とオプション

例題

例 (3)

スコープ (16)

特別な領域 (3)

数式定義領域 (2)

メッシュ領域 (2)

派生領域 (4)

パラメトリック式 (5)

オプション (7)

AccuracyGoal (1)

Assumptions (1)

GenerateConditions (1)

PrecisionGoal (1)

PerformanceGoal (1)

WorkingPrecision (2)

アプリケーション (8)

特性と関係 (6)

考えられる問題 (2)

関連項目

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX