WOLFRAM

Wolfram 语言与系统参考资料中心

ArcLength[reg]

给出一维区域 reg 的长度.

ArcLength[{x1,…,xn},{t,tmin,tmax}]

给出参数化曲线的长度，其中该参数化曲线的笛卡儿坐标 xi 为 t 的函数.

ArcLength[{x1,…,xn},{t,tmin,tmax},chart]

将 xi 诠释为指定坐标图中的坐标.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
特殊区域  
公式区域  
网格区域  
派生区域  
参数化公式  
选项  
AccuracyGoal  
Assumptions  
GenerateConditions  
PrecisionGoal  
PerformanceGoal  
WorkingPrecision  
应用  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

ArcLength

ArcLength[reg]

给出一维区域 reg 的长度.

ArcLength[{x1,…,xn},{t,tmin,tmax}]

给出参数化曲线的长度，其中该参数化曲线的笛卡儿坐标 xi 为 t 的函数.

ArcLength[{x1,…,xn},{t,tmin,tmax},chart]

将 xi 诠释为指定坐标图中的坐标.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (3)

连接点 、 和 的直线的长度：

Wolfram Language code: ArcLength[Line[{{0, 0}, {1, 1}, {2, 0}}]]

半径为 的圆环的长度：

Wolfram Language code: ArcLength[Circle[{x, y}, r]]

参数化单位圆的周长：

Wolfram Language code: ArcLength[{Sin[θ], Cos[θ]}, {θ, 0, 2Pi}]

螺旋 ， 一圈的长度，用圆柱坐标表示：

Wolfram Language code: ArcLength[{1, t, t}, {t, 0, 2Pi}, "Cylindrical"]

范围  (16)

特殊区域  (3)

Line：

Wolfram Language code: ℛ = Line[{{0, 0}, {1, 2}, {1, 0}, {2, 2}}]; ArcLength[ℛ]
Wolfram Language code: Region[ℛ]

线可以在任意维数中使用：

Wolfram Language code: ArcLength[Line[{{0}, {1}}]]
Wolfram Language code: ArcLength[Line[{{0, 0, 0}, {1, 1, 1}, {0, 0, 1}}]]

只有一维 Simplex 有有意义的弧长：

Wolfram Language code: ℛ = Simplex[{{0, 0}, {1, 1}}]; ArcLength[ℛ]
Wolfram Language code: Region[ℛ]

它可以嵌入到任何维度：

Wolfram Language code: ArcLength[Simplex[{{0}, {1}}]]
Wolfram Language code: ArcLength[Simplex[{{0, 0, 0}, {1, 1, 1}}]]

Circle:

Wolfram Language code: ArcLength[Circle[{Subscript[c, x], Subscript[c, y]}, r]]
Wolfram Language code: Region[Circle[{0, 0}, 1]]
Wolfram Language code: ArcLength[Circle[{Subscript[c, x], Subscript[c, y]}, {Subscript[r, x], Subscript[r, y]}]]
Wolfram Language code: Region[Circle[{0, 0}, {3, 2}]]

公式区域  (2)

用 ImplicitRegion 表示的圆的弧长：

Wolfram Language code: ArcLength[ImplicitRegion[x^2 + y^2 == 1, {x, y}]]

椭圆：

Wolfram Language code: ArcLength[ImplicitRegion[x^2 + 2y^2 == 1, {x, y}]]

用 ParametricRegion 表示的圆的弧长：

Wolfram Language code: ArcLength[ParametricRegion[{Cos[θ], Sin[θ]}, {{θ, 0, 2π}}]]

使用圆的有理参数：

Wolfram Language code: ArcLength[ParametricRegion[{(1 - t^2/1 + t^2), (2t/1 + t^2)}, {t}]]

网格区域  (2)

MeshRegion 的弧长：

Wolfram Language code: MeshRegion[{{0, 0}, {1, 0}, {2, 1 / 2}, {2, -1 / 2}}, Line[{1, 2, 3, 4, 2}]]
Wolfram Language code: ArcLength[%]

在三维中：

Wolfram Language code: MeshRegion[{{0, 0, 0}, {0, 1, 1}, {1, 0, 0}, {1, 1, 1}}, Line[{1, 2, 3, 4, 1}]]
Wolfram Language code: ArcLength[%]

一维 BoundaryMeshRegion 的弧长：

Wolfram Language code: BoundaryMeshRegion[{{0}, {1}}, Point[{{1}, {2}}]]
Wolfram Language code: ArcLength[%]

派生区域  (4)

与圆盘相交的圆的部分：

Wolfram Language code: ℛ = RegionIntersection[Circle[{1, 0}, 1], Disk[]];
Wolfram Language code: Show[Graphics[{LightBlue, EdgeForm[Gray], Disk[], Gray, Circle[{1, 0}, 1]}], HighlightMesh[DiscretizeRegion[ℛ], 1]]
Wolfram Language code: ArcLength[ℛ]

与 Triangle 相交的 Circle 的弧长：

Wolfram Language code: Subscript[ℛ, 1] = Circle[]; Subscript[ℛ, 2] = Triangle[{{-3 / 2, 0}, {3 / 2, 0}, {0, 11 / 10}}]; Subscript[ℛ, 3] = RegionIntersection[Subscript[ℛ, 1], Subscript[ℛ, 2]];
Wolfram Language code: Show[Graphics[{LightBlue, EdgeForm[Gray], Subscript[ℛ, 2], Gray, Subscript[ℛ, 1]}], HighlightMesh[DiscretizeRegion[Subscript[ℛ, 3]], 1]]
Wolfram Language code: ArcLength[Subscript[ℛ, 3]]

TransformedRegion 的弧长：

Wolfram Language code: ℛ = TransformedRegion[Line[{{0, 0}, {1, 0}, {1, 1}, {0, 0}}], ShearingTransform[30Degree, {1, 0}, {0, 1}]];
Wolfram Language code: DiscretizeRegion[ℛ, {{0, 2}, {-1, 1}}]
Wolfram Language code: ArcLength[ℛ]

RegionBoundary 度量：

Wolfram Language code: ℛ = RegionBoundary[Disk[{1, 2}, 3]]
Wolfram Language code: Region[ℛ]
Wolfram Language code: ArcLength[ℛ]

参数化公式  (5)

在极坐标系下有限长度的无限曲线：

Wolfram Language code: ArcLength[{Exp[-t / 10], t}, {t, 0, ∞}, "Polar"]
Wolfram Language code: ParametricPlot[CoordinateTransform[ "Polar" -> "Cartesian", {Exp[-t / 10], t}]//Evaluate, {t, 0, 50}, PlotRange -> All]

抛物线 在 和 之间的长度：

Wolfram Language code: ArcLength[x ^ 2, {x, a, b}]

指定度量、坐标系与参数的弧长：

Wolfram Language code: ArcLength[{1, t, 2t}, {t, 0, Pi}, {{"OblateSpheroidal", {2}}, "Euclidean"}]

在高维欧氏空间中的曲线弧长：

Wolfram Language code: ArcLength[{t ^ 2, Pi / 2, Pi / 4, t}, {t, 0, 2Pi}, "Hyperspherical"]

用立体坐标表示的双球经线的长度：

Wolfram Language code: ArcLength[{t, a t}, {t, 0, ∞}, {"Stereographic", "Sphere"}, Assumptions -> a∈Reals]

选项  (7)

AccuracyGoal  (1)

下面是一个其弧长难以精确计算的区域：

Wolfram Language code: Region[ℛ = ImplicitRegion[x ^ 4 + y ^ 4 == 1, {x, y}]]
Wolfram Language code: s1 = ArcLength[ℛ]

可通过 AccuracyGoal 选项来修改默认的绝对容差. 此处，当精度目标条件被满足时，弧长计算便会停止：

Wolfram Language code: s2 = ArcLength[ℛ, AccuracyGoal -> 1]

Assumptions  (1)

具有任意参数 a 的心形的长度：

Wolfram Language code: ArcLength[{2 a (1 + Cos[t]) Sin[t], -2 a Cos[t] (1 + Cos[t])}, {t, 0, 2Pi}]

添加一个 a 为正数的假设，使答案得到简化：

Wolfram Language code: ArcLength[{2 a (1 + Cos[t]) Sin[t], -2 a Cos[t] (1 + Cos[t])}, {t, 0, 2Pi}, Assumptions -> a > 0]

GenerateConditions  (1)

默认情况下，可以添加限制参数的条件以确保答案有效：

Wolfram Language code: ArcLength[Log[x], {x, a, b} ]

生成一个无条件的、仅对某些参数值有效的结果：

Wolfram Language code: ArcLength[Log[x], {x, a, b} , GenerateConditions -> False]

PrecisionGoal  (1)

可通过 PrecisionGoal 指定需要达到的有效精度位数：

Wolfram Language code: Table[ArcLength[ImplicitRegion[x ^ 4 + y ^ 4 == 1, {x, y}], PrecisionGoal -> prec], {prec, 1, 5}]

绘制针对不同精度设置计算出的弧长：

Wolfram Language code: ListPlot[%, PlotRange -> All]

PerformanceGoal  (1)

下面是一个弧长难以精确计算的区域：

Wolfram Language code: Region[ℛ = ImplicitRegion[x ^ 4 + y ^ 4 == 1, {x, y}]]

用 PerformanceGoal"Speed" 来尝试快速计算弧长：

Wolfram Language code: (s1 = ArcLength[ℛ, PerformanceGoal -> "Speed"])//Timing

用 PerformanceGoal"Performance" 来尝试计算可给出尽可能多正确位数的结果：

Wolfram Language code: (s2 = ArcLength[ℛ, PerformanceGoal -> "Quality"])//Timing

与精确计算得出的数值进行比较：

Wolfram Language code: sexact = -(3^1 / 4 MeijerG[{{(1/3), (2/3), (5/6), 1, (4/3)}, {}}, {{(1/12), (5/12), (7/12), (3/4), (13/12)}, {}}, 1]/16 Sqrt[2] π^7 / 2 Gamma[(5/4)]);
Wolfram Language code: s1 - sexact
Wolfram Language code: s2 - sexact

WorkingPrecision  (2)

使用机器算法计算 ArcLength：

Wolfram Language code: ArcLength[ImplicitRegion[x ^ 6 + y ^ 6 - x y == 1, {x, y}], WorkingPrecision -> MachinePrecision]

在某些情况下，不能计算得到确切的答案：

Wolfram Language code: ArcLength[ImplicitRegion[x ^ 6 + y ^ 6 - x y == 1, {x, y}]]

使用30位精度求 ArcLength：

Wolfram Language code: ArcLength[{a Cos[t], a Sin[t], a Sin[t]}, {t, 0, 2Pi}, WorkingPrecision -> 30]

应用  (8)

函数曲线 的长度：

Wolfram Language code: curve = ParametricRegion[{x, Sin[x]}, {{x, 0, 1}}];
Wolfram Language code: ArcLength[curve]

等效地：

Wolfram Language code: ArcLength[Sin[x], {x, 0, 1}]

计算结的长度：

Wolfram Language code: knot = KnotData["SolomonSeal", "SpaceCurve"]
Wolfram Language code: ArcLength[knot[t], {t, 0, 2Pi}]

计算木星轨道长度，以米为单位：

Wolfram Language code: {a, e} = {"SemimajorAxis", "Eccentricity"} /. Entity["Planet", "Jupiter"]["OrbitRules"]//N

长度可以使用椭圆的极坐标表示计算：

Wolfram Language code: ArcLength[{(a(1 - e^2)/1 + e Cos[θ]), θ}, {θ, 0, 2Pi}, "Polar"]

也使用使用半焦距为 、常数为 的椭圆坐标 :

Wolfram Language code: ArcLength[{ArcCosh[1 / e], ν}, {ν, 0, 2Pi}, {{"Elliptic", a e}}]

从图形中提取线，并计算它们的坐标长度：

Wolfram Language code: graphics = KnotData["SolomonSeal", "KnotDiagram"]
Wolfram Language code: ArcLength /@ Cases[graphics, _Line, -1]
Wolfram Language code: Total[%]

根据遍历距离对利萨茹曲线进行着色：

Wolfram Language code: c[t_] = {Cos[3t], Sin[5t]}; total = ArcLength[c[t], {t, 0., 2Pi}]; ParametricPlot[c[t], {t, 0, 2Pi}, PlotStyle -> Thick, ColorFunctionScaling -> False, ImageSize -> 300, ColorFunction -> (Hue[0.6ArcLength[c[t], {t, 0, #3}] / total]&), PlotLegends -> BarLegend[{Hue[0.6# / total]&, {0, total}}]]

根据遍历距离的分数在球面上对 Viviani 曲线进行着色：

Wolfram Language code: viv[t_] := {-(Sin[t]/2), -Sin[(t/2)], (1/2) (1 + Cos[t])}; fraclen[a_] = ArcLength[viv[t], {t, 0, 4Pi a}] / ArcLength[viv[t], {t, 0, 4Pi}]; Show[ParametricPlot3D[viv[t], {t, 0, 4Pi}, PlotStyle -> Thick, ColorFunction -> (Hue[0.6fraclen[#4]]&), PlotLegends -> BarLegend[{Hue[0.6#]&, {0, 1}}, LegendMarkerSize -> Small]], Graphics3D[{Gray, Opacity[.5], Sphere[]}], PlotRange -> All]

求沿圆形导线的平均线电荷密度：

Wolfram Language code: r = Circle[{0, 0}, 1];
Wolfram Language code: Integrate[x^2y^2, {x, y}∈r] / ArcLength[r]

计算 Polygon 的周长：

Wolfram Language code: p = Polygon[Table[If[EvenQ[ii], 3, 2]{Cos[2π ii / 16], Sin[2π ii / 16]}, {ii, 0, 15}]]; Region[p]
Wolfram Language code: ArcLength[RegionBoundary[N@p]]

属性和关系  (6)

ArcLength 是一个非负的量：

Wolfram Language code: ArcLength[{Sin[θ], Cos[θ]}, {θ, 0, 2π}]
Wolfram Language code: ArcLength[{Sin[θ], Cos[θ]}, {θ, 0, -2π}]

对于任何一维区域，ArcLength[r] 与 RegionMeasure[r] 相同：

Wolfram Language code: {ArcLength[Line[{{0, 0}, {1, 1}}]], RegionMeasure[Line[{{0, 0}, {1, 1}}]]}
Wolfram Language code: {ArcLength[Circle[]], RegionMeasure[Circle[]]}

参数形式的 ArcLength 作为积分定义：

Wolfram Language code: ArcLength[{Sin[θ], 2Cos[θ]}, {θ, 0, 2π}]
Wolfram Language code: Integrate[Sqrt[Sin'[θ]^2 + (2 Cos'[θ])^2], {θ, 0, 2π}]

ArcLength[x,t,c] 等价于 RegionMeasure[x,{t},c]:

Wolfram Language code: ArcLength[{t ^ 2, Pi / 2, Pi / 4, t}, {t, 0, 2Pi}, "Hyperspherical"]
Wolfram Language code: RegionMeasure[{t ^ 2, Pi / 2, Pi / 4, t}, {{t, 0, 2Pi}}, "Hyperspherical"]
Wolfram Language code: % == %%

对于一维区域，ArcLength 定义为1在该区域上的积分：

Wolfram Language code: ℛ = Circle[{1, 2}, {3, 4}];
Wolfram Language code: {ArcLength[ℛ], Integrate[1, x∈ℛ]}

二维区域的周长是其 RegionBoundary 的 ArcLength：

Wolfram Language code: ℛ = RegionBoundary[Disk[{0, 0}, 1]];
Wolfram Language code: ArcLength[ℛ]

可能存在的问题  (2)

参数形式或 ArcLength 计算可能的多个覆盖层的长度：

Wolfram Language code: ArcLength[{Cos[θ], Sin[θ]}, {θ, 0, 4π}]

区域版本计算图像的长度：

Wolfram Language code: ArcLength[ParametricRegion[{Cos[θ], Sin[θ]}, {{θ, 0, 4π}}]]
Wolfram Language code: ArcLength[Circle[{0, 0}, 1]]

不是1的维度区域的长度是 Undefined:

Wolfram Language code: {ArcLength[Point[{0, 0}]], ArcLength[Disk[]]}
Wolfram Language code: {RegionDimension[Point[{0, 0}]], RegionDimension[Disk[]]}
Wolfram Research (2014)，ArcLength，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ArcLength.html （更新于 2019 年）.

文本

Wolfram Research (2014)，ArcLength，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ArcLength.html （更新于 2019 年）.

CMS

Wolfram 语言. 2014. "ArcLength." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2019. https://reference.wolfram.com/language/ref/ArcLength.html.

APA

Wolfram 语言. (2014). ArcLength. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ArcLength.html 年

BibTeX

@misc{reference.wolfram_2026_arclength, author="Wolfram Research", title="{ArcLength}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/ArcLength.html}", note=[Accessed: 12-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_arclength, organization={Wolfram Research}, title={ArcLength}, year={2019}, url={https://reference.wolfram.com/language/ref/ArcLength.html}, note=[Accessed: 12-September-2026]}