ArcSinDistribution

ArcSinDistribution[{x_min,x_max}]

x_minから x_maxまででサポートされている逆正弦分布を表す．

ArcSinDistribution[]

0から1の間でサポートされている逆正弦分布を表す．

詳細

逆正弦分布における値の確率密度は，ではに比例し，あるいはでは0である．
ArcSinDistributionでは，x_minと x_maxは x_min<x_maxの任意の実数でよい．
ArcSinDistributionでは，x_min と x_max は単位次元が等しい任意の数量でよい． »
ArcSinDistributionは，Mean，CDF，RandomVariate等の関数とともに使うことができる．

予備知識

ArcSinDistribution[{x_min,x_max}]は，x_minから x_maxまでの値について定義される特定の統計的分布を表す．名前は，その関数形である累積分布関数(CDF)に由来する．これは，正規化された逆正弦関数である．この確率密度関数(PDF)は下に凸であり，領域の中点でその絶対最小値に達し，また中点について鏡映対称となる．また x_minおよび x_max双方の近くで特異点（漸近的に無限大に近付く点）を持つ可能性がある．
逆正弦分布は，確率理論や整数論等を含む数多くの数学的文脈で自然に見られる．一次元ウィナー過程の全体的動作の多くは，レヴィによる，いわゆる逆正弦の3法則によって説明することができる．これらの法則は，過程が正である時間の割合，最後に0になった時点，過程が最大に達した時点のすべてが逆正弦分布に従っているとしている．エルデシュによる整数論的結果は，逆正弦分布を指定された整数の小さい素因子数と関連付けている．より最近になって，逆正弦分布は量子コイン投げの確率的モデルの極限分布であることが示された．
RandomVariateを使って，逆正弦分布から1つあるいは複数の機械精度あるいは任意精度の（後者はWorkingPrecision オプションによる）擬似乱数変量を与えることができる．Distributed[x,ArcSinDistribution[{x_minx_max}]]（より簡略な表記では xArcSinDistribution[{x_minx_max}]）を使って，確率変数 x が逆正弦分布に従って分布していると宣言することができる．このような宣言は，Probability，NProbability，Expectation，NExpectation等の関数で用いることができる．
確率密度関数および累積分布関数は，PDF[ArcSinDistribution[{x_min,x_max}],x]およびCDF[ArcSinDistribution[{x_min,x_max}],x]を使って得ることができる．平均，中央値，分散，原点の周りのモーメント，中心モーメントはそれぞれ，Mean，Median，Variance，Moment，CentralMomentを使って計算することができる．
DistributionFitTestを使って与えられたデータ集合が逆正弦分布と一致するかどうかを検定することが，EstimatedDistributionを使って与えられたデータから逆正弦パラメトリック分布を推定することが，FindDistributionParametersを使ってデータを逆正弦分布にフィットすることが可能である．ProbabilityPlotを使って記号逆正弦分布のCDFに対する与えられたデータのCDFプロットを生成することができ，QuantilePlotを使って記号逆正弦分布の変位値に対する与えられたデータの変位値プロットを生成することができる．
TransformedDistributionを使って変換された逆正弦分布を，CensoredDistributionを使って上限値と下限値の間で打ち切られた値の分布を，TruncatedDistributionを使って上限値と下限値の間で切断された値の分布を表すことができる．CopulaDistributionを使って逆正弦分布を含むより高次元の分布を構築することが，ProductDistributionを使って逆正弦分布を含む独立成分分布との結合分布を計算することができる．
逆正弦分布は多くの他の分布と密接に関係している．例えば，標準逆正弦分布ArcSinDistribution[{0,1}]は，ベータ分布BetaDistribution[1/2,1/2]と厳密に等しい．結果として，ArcSinDistributionはBetaDistributionの多くの関係を継承する．ArcSinDistributionは，同様に，PDF[ArcSinDistribution[{0,1}],x]がPDF[PearsonDistribution[1,1,-1/2,1,-1,0],x]と等しいという意味において，タイプ1のPearsonDistributionであると見ることができる．これは，UniformDistribution，PERTDistribution，ChiSquareDistribution，GammaDistribution，BetaPrimeDistributionとも密接に関係している．

例題

すべて開くすべて閉じる

例 (4)

確率密度関数：

Wolfram Language code: Plot[Table[PDF[ArcSinDistribution[{-1, max}], x], {max, {1, 2, 4}}]//Evaluate, {x, -1, 4}, Filling -> Axis]

Wolfram Language code: PDF[ArcSinDistribution[{min, max}], x]

累積分布関数：

Wolfram Language code:

Plot[Table[CDF[ArcSinDistribution[{-1, max}], x], {max, {1, 2, 4}}]//Evaluate, {x, -1, 4}, Filling -> Axis, Exclusions -> None]

Wolfram Language code: CDF[ArcSinDistribution[{min, max}], x]

平均と分散：

Wolfram Language code: Mean[ArcSinDistribution[{min, max}]]

Wolfram Language code: Variance[ArcSinDistribution[{min, max}]]

中央値：

Wolfram Language code: Median[ArcSinDistribution[{min, max}]]

スコープ (7)

逆正弦分布から擬似乱数のサンプルを生成する：

Wolfram Language code: data = RandomVariate[ArcSinDistribution[], 10 ^ 4];

そのヒストグラムを確率密度関数と比較する：

Wolfram Language code: Show[Histogram[data, 20, "PDF"], Plot[PDF[ArcSinDistribution[], x], {x, -.5, 1.5}, PlotStyle -> Thick]]

分布母数推定：

Wolfram Language code: sample = RandomVariate[ArcSinDistribution[{-2, 3}], 10 ^ 3];

サンプルデータから分布母数を推定する：

Wolfram Language code: edist = EstimatedDistribution[sample, ArcSinDistribution[{min, max}]]

サンプルの密度ヒストグラムを推定分布の確率密度関数と比較する：

Wolfram Language code: Show[Histogram[sample, 20, "PDF"], Plot[PDF[edist, x], {x, -3, 4}, PlotStyle -> Thick]]

尖度と歪度は一定である：

Wolfram Language code: Skewness[ArcSinDistribution[{min, max}]]

Wolfram Language code: Kurtosis[ArcSinDistribution[{min, max}]]

母数の関数としての閉じた形の種々のモーメント：

Wolfram Language code: FormulaGrid[list_, type_] := Grid[...]

Moment：

Wolfram Language code: FormulaGrid[Table[Moment[ArcSinDistribution[{min, max}], k]//Expand, {k, 5}], M]

CentralMoment：

Wolfram Language code: FormulaGrid[Table[CentralMoment[ArcSinDistribution[{min, max}], k], {k, 5}], CM]

記号次数についての閉じた形：

Wolfram Language code: CentralMoment[ArcSinDistribution[{min, max}], r]

FactorialMoment：

Wolfram Language code: FormulaGrid[Table[FactorialMoment[ArcSinDistribution[{min, max}], k], {k, 4}], FM]

Cumulant：

Wolfram Language code: FormulaGrid[Table[Cumulant[ArcSinDistribution[{min, max}], k], {k, 5}], C]

ハザード関数：

Wolfram Language code:

Plot[Table[HazardFunction[ArcSinDistribution[{-1, max}], x], {max, {1, 3, 5}}]//Evaluate, {x, -1, 5}, Filling -> Axis, AxesOrigin -> {0, 0}]

Wolfram Language code: HazardFunction[ArcSinDistribution[{min, max}], x]

分位関数：

Wolfram Language code: Plot[Table[Quantile[ArcSinDistribution[{0, max}], q], {max, {1, 3, 5}}]//Evaluate, {q, 0, 1}, Filling -> Axis]

Wolfram Language code: Quantile[ArcSinDistribution[{min, max}], q]

母数でQuantityを一貫して使うとQuantityDistributionが与えられる：

Wolfram Language code: rad𝒟 = ArcSinDistribution[{Quantity[0.99, "AstronomicalUnit"], Quantity[1.01, "AstronomicalUnit"]}]

平均半径：

Wolfram Language code: Mean[rad𝒟]

Wolfram Language code: UnitConvert[%, "LightMinutes"]

アプリケーション (5)

対称ランダムウォークによる正側滞在時間の割合のシミュレーションを行う：

Wolfram Language code: randomWalk[n_] := RandomFunction[RandomWalkProcess[1 / 2], {n}];

正側滞在時間の割合を計算する：

Wolfram Language code: ratio[n_] := Count[randomWalk[n]["Values"], _ ? Positive] / n

極限での比はArcSinDistributionに従う：

Wolfram Language code: sample[n_, walks_] := Table[ratio[n], {i, walks}]

Wolfram Language code:

Show[Histogram[sample[10 ^ 3, 10 ^ 3], {0, 1, 0.025}, "PDF"], Plot[PDF[ArcSinDistribution[{0, 1}], x], {x, 0, 1}, PlotStyle -> Thick, PlotRange -> 4]]

標準WienerProcessが正側滞在時間の割合のシミュレーションを行う：

Wolfram Language code: data[n_] := RandomFunction[WienerProcess[], {0, 1, 1 / n}];

Wolfram Language code: ratio[n_] := Count[data[n]["Values"], _ ? Positive] / n

極限での比はArcSinDistributionに従う：

Wolfram Language code: sample[n_, walks_] := Table[ratio[n], {i, walks}]

Wolfram Language code:

Show[Histogram[sample[10 ^ 3, 10 ^ 3], {0, 1, 0.025}, "PDF"], Plot[PDF[ArcSinDistribution[{0, 1}], x], {x, 0, 1}, PlotStyle -> Thick, PlotRange -> 4]]

時点0から1の間でWienerProcessの符号が最後に変わった時点の分布を求める：

Wolfram Language code: data = RandomFunction[WienerProcess[], {0, 1, .01}, 10 ^ 3];

符号の差を計算して符号の変化を求める：

Wolfram Language code: diff = Differences[Sign[data]];

経路を抽出し，各経路における最後の符号変化の時点を求める：

Wolfram Language code: paths = diff["Paths"];

Wolfram Language code: sample = Map[Last[Cases[#, {t_, Except[0]} :> t]]&, paths];

極限では，時点はArcSinDistributionに従う：

Wolfram Language code:

Show[Histogram[sample, {0, 1, 0.02}, "PDF"], Plot[PDF[ArcSinDistribution[{0, 1}], x], {x, 0, 1}, PlotStyle -> Thick, PlotRange -> 4]]

0から1までで，WienerProcessの最大値に対応する時点の分布を求める：

Wolfram Language code: data = RandomFunction[WienerProcess[], {0, 1, .001}, 10 ^ 4]["Paths"];

各経路から，その経路の最大値に対応する時点を抽出する：

Wolfram Language code: {null, {sample}} = Reap[Do[vmax = Max[path[[All, 2]]];Sow[FirstCase[path, {tmax_, vmax} :> tmax]], {path, data}]];

極限では，この時点はArcSinDistributionに従う：

Wolfram Language code:

Show[Histogram[Flatten[sample], {0, 1, 0.025}, "PDF"], Plot[PDF[ArcSinDistribution[{0, 1}], x], {x, 0, 1}, PlotStyle -> Thick, PlotRange -> 4]]

離散マルコフ連鎖（ただし，は独立同分布に従う標準一様確率変数では独立同分布に従う対称ベルヌーイ確率変数の列）は，である任意の初期条件について定常分布ArcSinDistribution[{0,1}] に収束する：

Wolfram Language code:

mcPath = Compile[{{x0, _Real}, {zvec, _Integer, 1}, {uvec, _Real, 1}}, 
	Module[{path = Table[x0, {Length[zvec]}], i = 1, x = x0}, 
	Do[path[[i]] = If[zvec[[i]] == 0, x *= uvec[[i]], x += uvec[[i]](1 - x)], {i, Length[zvec]}];path]];

マルコフ連鎖の実現からサンプルを取り，経路のバーンイン部分を削除する：

Wolfram Language code:

x0 = 0.2;len = 10 ^ 5 + 100;
path = mcPath[x0, RandomInteger[{0, 1}, len], RandomReal[1, len]];
pathTail = Drop[path, 100];

マルコフ連鎖からのサンプルは独立ではなく内部構造を示している：

Wolfram Language code:

iidSamples = RandomVariate[ArcSinDistribution[{0, 1}], Length[pathTail]];
vizopts = {ImageSize -> 200, PlotStyle -> PointSize[Tiny], AspectRatio -> 1, PlotTheme -> "Scientific"};
Row[{Legended[ListPlot[Partition[pathTail, 2, 2], vizopts], Placed[Style["MC samples", Bold], Below]], Legended[ListPlot[Partition[iidSamples, 2, 2], vizopts], Placed[Style["iid samples", Bold], Below]]}]

経路の値のヒストグラムとマルコフ連鎖の定常分布のPDFを比較する：

Wolfram Language code:

Show[Histogram[pathTail, {0, 1, 0.01}, "LogPDF"], LogPlot[PDF[ArcSinDistribution[{0, 1}], x], {x, 0, 1}, PlotRange -> All], ImageSize -> 250, PlotRange -> {-2, 3}]

経路の値を使って期待値を近似する：

Wolfram Language code: Mean[Log[PDF[ArcSinDistribution[{0, 1}], #]]&[pathTail]]

直角位相値と比較する：

Wolfram Language code: NExpectation[Log[PDF[ArcSinDistribution[{0, 1}], x]], xArcSinDistribution[{0, 1}]]

特性と関係 (9)

逆正弦分布は平行移動と正の因子によるスケーリングの下では閉じている：

Wolfram Language code: TransformedDistribution[k * u + loc, uArcSinDistribution[{min, max}]]

逆正弦分布の累積分布関数はArcSin関数に比例する：

Wolfram Language code: CDF[ArcSinDistribution[], x]//FunctionExpand

上での逆正弦分布の平方は上での逆正弦分布になる：

Wolfram Language code: 𝒟 = TransformedDistribution[u ^ 2, uArcSinDistribution[{-1, 1}]];

Wolfram Language code: CDF[𝒟, x]//FullSimplify

Wolfram Language code: CDF[ArcSinDistribution[], x]

Wolfram Language code: Simplify[% - %%]

他の分布との関係：

BetaDistributionは逆正弦分布の特別なケースである：

Wolfram Language code: CDF[ArcSinDistribution[], x]

Wolfram Language code: CDF[BetaDistribution[1 / 2, 1 / 2], x]//FunctionExpand

Wolfram Language code: Simplify[% - %%]

逆正弦分布はタイプ1のPearsonDistributionの特殊な型である：

Wolfram Language code: PDF[PearsonDistribution[1, 1, -1 / 2, 1, -1, 0], x]

Wolfram Language code: PDF[ArcSinDistribution[], x]

Wolfram Language code: Simplify[% - %%]

ArcSinDistributionはUniformDistributionを変換したものである：

Wolfram Language code: TransformedDistribution[Sin[U], UUniformDistribution[{-Pi, Pi}]]

Wolfram Language code: TransformedDistribution[Cos[U], UUniformDistribution[{-Pi, Pi}]]

ArcSinDistributionはTriangularDistributionを変換したものである：

Wolfram Language code: TransformedDistribution[Sin[U], UTriangularDistribution[{-Pi, Pi}]]

HoytDistributionはExponentialDistributionとArcSinDistributionから得ることができる：

Wolfram Language code:

𝒟 = TransformedDistribution[(2 q/1 + q^2) Sqrt[ω x y], {xArcSinDistribution[{(1/2) (1 + q^2), (1/2) (1 + (1/q^2))}], yExponentialDistribution[1]}];

Wolfram Language code:

Block[{q = .2, ω = 3}, Show[Histogram[RandomVariate[𝒟, 10 ^ 4], 20, "PDF"], Plot[PDF[HoytDistribution[q, ω], x], {x, 0, 6}, PlotStyle -> Thick]]]

おもしろい例題 (1)

累積分布関数の等高線を持つ xmax のさまざまな値についての確率密度関数：

Wolfram Language code:

dist = ArcSinDistribution[{-1, xmax}];cdf = Function[{x, xmax}, Evaluate[CDF[dist, x]]];
ql = {0.025, 0.10, 0.25, 0.5, 0.75, 0.90, 0.975};
cl = Table[ColorData["Rainbow"][q], {q, Join[{0.0}, ql]}];

Wolfram Language code:

Legended[Plot3D[PDF[dist, x], {x, -1, 3}, {xmax, 1, 3}, PlotTheme -> "Marketing", MeshFunctions -> {cdf}, Mesh -> {ql}, MeshStyle -> GrayLevel[0.8], MeshShading -> cl, AxesLabel -> Automatic, BaseStyle -> Opacity[0.9], ImageSize -> 400, PlotPoints -> 50], BarLegend["Rainbow", ql, LegendLabel -> "prob"]]

Top

その他のラーニングリソース

テクニカルサポート

Wolframソリューション

教育のためのWolframソリューション

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

ArcSinDistribution

詳細

予備知識

例題

例 (4)

スコープ (7)

アプリケーション (5)

特性と関係 (9)

おもしろい例題 (1)

テキスト

CMS

APA

BibTeX

BibLaTeX

ArcSinDistribution

詳細

予備知識

例題

例 (4)

スコープ (7)

アプリケーション (5)

特性と関係 (9)

おもしろい例題 (1)

関連項目

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX