Wolfram 语言与系统参考资料中心

ArcSinDistribution

ArcSinDistribution[{x_min,x_max}]

表示在 x_min 和 x_max 之间支持的反正弦分布.

ArcSinDistribution[]

表示在0和1之间支持的反正弦分布.

背景

ArcSinDistribution[{x_min,x_max}] 表示值在 x_min 和 x_max 之间的一个特定的统计分布. 它是以其累积分布函数（CDF）的函数形式，即归一化的反正弦函数命名的. 它的概率分布函数（PDF）是上凹函数，在定义域的中点处取得全局最小值且关于这个中点呈轴对称形状，而在两端 x_min 和 x_max 附近的点处则有潜在的奇点（渐进趋向于无穷）.
在许多数学场合，包括概率论和数论中都自然出现了反正弦分布. 一维维纳过程的大量整体行为都可以用莱维提出的三条所谓反正弦定律来描述. 这些定律说一维维纳过程为正的时间比例，上次到达零的时间以及达到最大值的时间都是反正弦分布的. Erdős 的一个数论结果把反正弦分布与给定整数的小素数因子的数目联系了起来. 最近，反正弦分布也被证明是量子硬币翻转的概率模型的极限分布.
RandomVariate 可被用于给出反正弦分布的一个或多个机器精度或任意精度（后者可用 WorkingPrecision 选项指定）的伪随机变量. Distributed[x,ArcSinDistribution[{x_minx_max}]]，更简洁的写法是 xArcSinDistribution[{x_minx_max}]，可被用于声明随机变量 x 是反正弦分布的. 这样一个声明之后可用在如 Probability、NProbability、Expectation 以及 NExpectation 这样的函数中.
概率密度函数和累积分布函数可用 PDF[ArcSinDistribution[{x_min,x_max}],x] 和 CDF[ArcSinDistribution[{x_min,x_max}],x] 求得. 平均数、中位数、方差、原点矩及中心矩可分别用 Mean、Median、Variance、Moment 和 CentralMoment 计算.
DistributionFitTest 可被用于测试给定的数据集是否与反正弦分布一致，EstimatedDistribution 可被用于根据给定数据估算反正弦参数化分布，FindDistributionParameters 可拟合数据和反正弦分布. ProbabilityPlot 可被用于生成给定数据的 CDF 相对于符号反正弦分布的 CDF 的图线，而 QuantilePlot 可被用于生成给定数据的分位数相对于符号反正弦分布的分位数的图线.
TransformedDistribution 可被用于表示转换的反正弦分布，CensoredDistribution 可被用于表示删截后位于上限值和下限值之间的值分布，而 TruncatedDistribution 可被用于表示截断后位于上限值和下限值之间的值分布. CopulaDistribution 可被用于建立包含了反正弦分布的高维分布，而 ProductDistribution 可被用于计算包括反正弦分布在内的，若干个独立分量分布的联合分布.
反正弦分布与许多其它分布密切相关. 例如，标准反正弦分布 ArcSinDistribution[{0,1}] 精确等于贝塔分布 BetaDistribution[1/2,1/2]. 因此 ArcSinDistribution 继承了许多 BetaDistribution 的关系. ArcSinDistribution 同样可被视为1-型 PearsonDistribution 因为 PDF[ArcSinDistribution[{0,1}],x] 等于 PDF[PearsonDistribution[1,1,-1/2,1,-1,0],x]. 它也和 UniformDistribution、PERTDistribution、ChiSquareDistribution、GammaDistribution 及 BetaPrimeDistribution 密切相关.

范例

打开所有单元关闭所有单元

基本范例 (4)

概率密度函数：

Wolfram Language code: Plot[Table[PDF[ArcSinDistribution[{-1, max}], x], {max, {1, 2, 4}}]//Evaluate, {x, -1, 4}, Filling -> Axis]

Wolfram Language code: PDF[ArcSinDistribution[{min, max}], x]

累积分布函数：

Wolfram Language code:

Plot[Table[CDF[ArcSinDistribution[{-1, max}], x], {max, {1, 2, 4}}]//Evaluate, {x, -1, 4}, Filling -> Axis, Exclusions -> None]

Wolfram Language code: CDF[ArcSinDistribution[{min, max}], x]

均值和方差：

Wolfram Language code: Mean[ArcSinDistribution[{min, max}]]

Wolfram Language code: Variance[ArcSinDistribution[{min, max}]]

中位数：

Wolfram Language code: Median[ArcSinDistribution[{min, max}]]

范围 (7)

生成一组服从反正弦分布的伪随机数样本：

Wolfram Language code: data = RandomVariate[ArcSinDistribution[], 10 ^ 4];

比较其直方图与概率密度函数：

Wolfram Language code: Show[Histogram[data, 20, "PDF"], Plot[PDF[ArcSinDistribution[], x], {x, -.5, 1.5}, PlotStyle -> Thick]]

分布参数估计：

Wolfram Language code: sample = RandomVariate[ArcSinDistribution[{-2, 3}], 10 ^ 3];

从样本数据中估计分布参数：

Wolfram Language code: edist = EstimatedDistribution[sample, ArcSinDistribution[{min, max}]]

比较样本的密度直方图和估计分布的概率密度函数：

Wolfram Language code: Show[Histogram[sample, 20, "PDF"], Plot[PDF[edist, x], {x, -3, 4}, PlotStyle -> Thick]]

偏度和峰度为常数：

Wolfram Language code: Skewness[ArcSinDistribution[{min, max}]]

Wolfram Language code: Kurtosis[ArcSinDistribution[{min, max}]]

以参数的函数形式表示不同矩的解析式：

Wolfram Language code: FormulaGrid[list_, type_] := Grid[...]

Moment:

Wolfram Language code: FormulaGrid[Table[Moment[ArcSinDistribution[{min, max}], k]//Expand, {k, 5}], M]

CentralMoment:

Wolfram Language code: FormulaGrid[Table[CentralMoment[ArcSinDistribution[{min, max}], k], {k, 5}], CM]

具有符号式阶数的解析式：

Wolfram Language code: CentralMoment[ArcSinDistribution[{min, max}], r]

FactorialMoment：

Wolfram Language code: FormulaGrid[Table[FactorialMoment[ArcSinDistribution[{min, max}], k], {k, 4}], FM]

Cumulant：

Wolfram Language code: FormulaGrid[Table[Cumulant[ArcSinDistribution[{min, max}], k], {k, 5}], C]

风险函数：

Wolfram Language code:

Plot[Table[HazardFunction[ArcSinDistribution[{-1, max}], x], {max, {1, 3, 5}}]//Evaluate, {x, -1, 5}, Filling -> Axis, AxesOrigin -> {0, 0}]

Wolfram Language code: HazardFunction[ArcSinDistribution[{min, max}], x]

分位数函数：

Wolfram Language code: Plot[Table[Quantile[ArcSinDistribution[{0, max}], q], {max, {1, 3, 5}}]//Evaluate, {q, 0, 1}, Filling -> Axis]

Wolfram Language code: Quantile[ArcSinDistribution[{min, max}], q]

在参数中使用一致的 Quantity 生成 QuantityDistribution：

Wolfram Language code: rad𝒟 = ArcSinDistribution[{Quantity[0.99, "AstronomicalUnit"], Quantity[1.01, "AstronomicalUnit"]}]

平均半径：

Wolfram Language code: Mean[rad𝒟]

Wolfram Language code: UnitConvert[%, "LightMinutes"]

应用 (5)

模拟一个对称式随机游走在正向所用时间的比例：

Wolfram Language code: randomWalk[n_] := RandomFunction[RandomWalkProcess[1 / 2], {n}];

计算正向游走所用时间的比值：

Wolfram Language code: ratio[n_] := Count[randomWalk[n]["Values"], _ ? Positive] / n

在极限时，该比值服从 ArcSinDistribution：

Wolfram Language code: sample[n_, walks_] := Table[ratio[n], {i, walks}]

Wolfram Language code:

Show[Histogram[sample[10 ^ 3, 10 ^ 3], {0, 1, 0.025}, "PDF"], Plot[PDF[ArcSinDistribution[{0, 1}], x], {x, 0, 1}, PlotStyle -> Thick, PlotRange -> 4]]

模拟标准 WienerProcess 在正向所用时间的比例：

Wolfram Language code: data[n_] := RandomFunction[WienerProcess[], {0, 1, 1 / n}];

Wolfram Language code: ratio[n_] := Count[data[n]["Values"], _ ? Positive] / n

在极限时，该比值服从 ArcSinDistribution:

Wolfram Language code: sample[n_, walks_] := Table[ratio[n], {i, walks}]

Wolfram Language code:

Show[Histogram[sample[10 ^ 3, 10 ^ 3], {0, 1, 0.025}, "PDF"], Plot[PDF[ArcSinDistribution[{0, 1}], x], {x, 0, 1}, PlotStyle -> Thick, PlotRange -> 4]]

求 WienerProcess 在0和1之间最后一次变化符号的分布：

Wolfram Language code: data = RandomFunction[WienerProcess[], {0, 1, .01}, 10 ^ 3];

计算符号的差值，以得到符号的变化：

Wolfram Language code: diff = Differences[Sign[data]];

提取路径，找到每个路径最后一个符号改变的时刻：

Wolfram Language code: paths = diff["Paths"];

Wolfram Language code: sample = Map[Last[Cases[#, {t_, Except[0]} :> t]]&, paths];

在极限时，时刻服从 ArcSinDistribution：

Wolfram Language code:

Show[Histogram[sample, {0, 1, 0.02}, "PDF"], Plot[PDF[ArcSinDistribution[{0, 1}], x], {x, 0, 1}, PlotStyle -> Thick, PlotRange -> 4]]

求在0和1之间与 WienerProcess 的最大值相对应的时刻的分布：

Wolfram Language code: data = RandomFunction[WienerProcess[], {0, 1, .001}, 10 ^ 4]["Paths"];

从每个路径中，提取与路径最大值对应的时刻：

Wolfram Language code: {null, {sample}} = Reap[Do[vmax = Max[path[[All, 2]]];Sow[FirstCase[path, {tmax_, vmax} :> tmax]], {path, data}]];

在极限时，时刻服从 ArcSinDistribution：

Wolfram Language code:

Show[Histogram[Flatten[sample], {0, 1, 0.025}, "PDF"], Plot[PDF[ArcSinDistribution[{0, 1}], x], {x, 0, 1}, PlotStyle -> Thick, PlotRange -> 4]]

离散马科夫链，其中是独立同分布 (iid) 标准均匀随机变量，是独立同分布的对称伯努力随机变量，对于任意满足的初始条件收敛于平稳分布 ArcSinDistribution[{0,1}]：

Wolfram Language code:

mcPath = Compile[{{x0, _Real}, {zvec, _Integer, 1}, {uvec, _Real, 1}}, 
	Module[{path = Table[x0, {Length[zvec]}], i = 1, x = x0}, 
	Do[path[[i]] = If[zvec[[i]] == 0, x *= uvec[[i]], x += uvec[[i]](1 - x)], {i, Length[zvec]}];path]];

对马科夫链的实现进行采样，并丢弃路径的老化部分：

Wolfram Language code:

x0 = 0.2;len = 10 ^ 5 + 100;
path = mcPath[x0, RandomInteger[{0, 1}, len], RandomReal[1, len]];
pathTail = Drop[path, 100];

来自马科夫链的样本不是独立的，表现出内部结构：

Wolfram Language code:

iidSamples = RandomVariate[ArcSinDistribution[{0, 1}], Length[pathTail]];
vizopts = {ImageSize -> 200, PlotStyle -> PointSize[Tiny], AspectRatio -> 1, PlotTheme -> "Scientific"};
Row[{Legended[ListPlot[Partition[pathTail, 2, 2], vizopts], Placed[Style["MC samples", Bold], Below]], Legended[ListPlot[Partition[iidSamples, 2, 2], vizopts], Placed[Style["iid samples", Bold], Below]]}]

比较路径值的直方图与马科夫链平稳分布的 PDF：

Wolfram Language code:

Show[Histogram[pathTail, {0, 1, 0.01}, "LogPDF"], LogPlot[PDF[ArcSinDistribution[{0, 1}], x], {x, 0, 1}, PlotRange -> All], ImageSize -> 250, PlotRange -> {-2, 3}]

使用路径值近似期望：

Wolfram Language code: Mean[Log[PDF[ArcSinDistribution[{0, 1}], #]]&[pathTail]]

与正交值比较：

Wolfram Language code: NExpectation[Log[PDF[ArcSinDistribution[{0, 1}], x]], xArcSinDistribution[{0, 1}]]

属性和关系 (9)

当平移并且使用一个正因子为比例进行缩放时，新生成的分布仍然是反正弦分布：

Wolfram Language code: TransformedDistribution[k * u + loc, uArcSinDistribution[{min, max}]]

反正弦分布的累积分布函数与 ArcSin 函数成比例：

Wolfram Language code: CDF[ArcSinDistribution[], x]//FunctionExpand

在上，反正弦分布的平方服从上的反正弦分布：

Wolfram Language code: 𝒟 = TransformedDistribution[u ^ 2, uArcSinDistribution[{-1, 1}]];

Wolfram Language code: CDF[𝒟, x]//FullSimplify

Wolfram Language code: CDF[ArcSinDistribution[], x]

Wolfram Language code: Simplify[% - %%]

与其它分布的关系：

BetaDistribution 是反正弦分布的一种特殊情况：

Wolfram Language code: CDF[ArcSinDistribution[], x]

Wolfram Language code: CDF[BetaDistribution[1 / 2, 1 / 2], x]//FunctionExpand

Wolfram Language code: Simplify[% - %%]

反正弦分布是第一类 PearsonDistribution 的特殊情形：

Wolfram Language code: PDF[PearsonDistribution[1, 1, -1 / 2, 1, -1, 0], x]

Wolfram Language code: PDF[ArcSinDistribution[], x]

Wolfram Language code: Simplify[% - %%]

ArcSinDistribution 是 UniformDistribution 的一个变形：

Wolfram Language code: TransformedDistribution[Sin[U], UUniformDistribution[{-Pi, Pi}]]

Wolfram Language code: TransformedDistribution[Cos[U], UUniformDistribution[{-Pi, Pi}]]

ArcSinDistribution 是 TriangularDistribution 的一个变形：

Wolfram Language code: TransformedDistribution[Sin[U], UTriangularDistribution[{-Pi, Pi}]]

HoytDistribution 可由 ExponentialDistribution 和 ArcSinDistribution 得到：

Wolfram Language code:

𝒟 = TransformedDistribution[(2 q/1 + q^2) Sqrt[ω x y], {xArcSinDistribution[{(1/2) (1 + q^2), (1/2) (1 + (1/q^2))}], yExponentialDistribution[1]}];

Wolfram Language code:

Block[{q = .2, ω = 3}, Show[Histogram[RandomVariate[𝒟, 10 ^ 4], 20, "PDF"], Plot[PDF[HoytDistribution[q, ω], x], {x, 0, 6}, PlotStyle -> Thick]]]

巧妙范例 (1)

不同 xmax 值的概率密度函数，具有累积分布函数等值线：

Wolfram Language code:

dist = ArcSinDistribution[{-1, xmax}];cdf = Function[{x, xmax}, Evaluate[CDF[dist, x]]];
ql = {0.025, 0.10, 0.25, 0.5, 0.75, 0.90, 0.975};
cl = Table[ColorData["Rainbow"][q], {q, Join[{0.0}, ql]}];

Wolfram Language code:

Legended[Plot3D[PDF[dist, x], {x, -1, 3}, {xmax, 1, 3}, PlotTheme -> "Marketing", MeshFunctions -> {cdf}, Mesh -> {ql}, MeshStyle -> GrayLevel[0.8], MeshShading -> cl, AxesLabel -> Automatic, BaseStyle -> Opacity[0.9], ImageSize -> 400, PlotPoints -> 50], BarLegend["Rainbow", ql, LegendLabel -> "prob"]]

Top

更多学习资源

技术支持

Wolfram 解决方案

Wolfram 的教育解决方案

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

ArcSinDistribution

更多信息

背景

范例

基本范例 (4)

范围 (7)

应用 (5)

属性和关系 (9)

巧妙范例 (1)

文本

CMS

APA

BibTeX

BibLaTeX

ArcSinDistribution

更多信息

背景

范例

基本范例 (4)

范围 (7)

应用 (5)

属性和关系 (9)

巧妙范例 (1)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX