WOLFRAM

Wolfram 语言与系统参考资料中心

BetaNegativeBinomialDistribution[α,β,n]

表示一个 β 负二项混合分布，其中 β 分布的参数为 α 和 β，试验成功的次数为 n.

更多信息
Details and Options Details and Options
背景
范例  
基本范例  
范围  
应用  
属性和关系  
可能存在的问题  
参见
技术笔记
相关指南
历史
按以下格式引用：

BetaNegativeBinomialDistribution

BetaNegativeBinomialDistribution[α,β,n]

表示一个 β 负二项混合分布，其中 β 分布的参数为 α 和 β，试验成功的次数为 n.

更多信息

背景

范例

打开所有单元 关闭所有单元

基本范例  (3)

概率质量函数：

Wolfram Language code: DiscretePlot[Table[PDF[BetaNegativeBinomialDistribution[α, 3, 20], x], {α, {1, 2.5, 5}}]//Evaluate, {x, 0, 30}, PlotMarkers -> Automatic]
Wolfram Language code: DiscretePlot[Table[PDF[BetaNegativeBinomialDistribution[1.2, β, 20], x], {β, {0.5, 1.5, 3}}]//Evaluate, {x, 0, 30}, PlotRange -> {0, 0.08}, PlotMarkers -> Automatic]
Wolfram Language code: PDF[BetaNegativeBinomialDistribution[α, β, n], k]

累积分布函数：

Wolfram Language code: DiscretePlot[Table[CDF[BetaNegativeBinomialDistribution[α, 1, 20], x], {α, {1, 2.5, 5}}]//Evaluate, {x, 0, 30}, ExtentSize -> Right]
Wolfram Language code: DiscretePlot[Table[CDF[BetaNegativeBinomialDistribution[1, β, 20], x], {β, {1 / 2, 1, 2}}]//Evaluate, {x, 0, 30}, ExtentSize -> Right]
Wolfram Language code: CDF[BetaNegativeBinomialDistribution[α, β, n], k]

均值和方差：

Wolfram Language code: Mean[BetaNegativeBinomialDistribution[α, β, n]]
Wolfram Language code: Variance[BetaNegativeBinomialDistribution[α, β, n]]

范围  (7)

生成一组服从 β 负二项分布的伪随机数样本：

Wolfram Language code: data = RandomVariate[BetaNegativeBinomialDistribution[15, 25, 30], 10 ^ 3];

将直方图与概率密度函数进行比较：

Wolfram Language code: Show[ Histogram[data, {5}, "PDF"], DiscretePlot[PDF[BetaNegativeBinomialDistribution[15, 25, 30], x], {x, 0, 120, 2}, PlotStyle -> PointSize[Medium]]]

分布参数估计：

Wolfram Language code: sample = RandomVariate[BetaNegativeBinomialDistribution[31, 18, 50], 10 ^ 3];

从样本数据估计分布参数：

Wolfram Language code: edist = EstimatedDistribution[sample, BetaNegativeBinomialDistribution[α, β, 50]]

比较样本密度直方图和估计分布的概率密度函数：

Wolfram Language code: Show[Histogram[sample, {2}, "PDF"], DiscretePlot[PDF[edist, x], {x, 0, 62, 2}, PlotStyle -> PointSize[Medium]]]

偏度：

Wolfram Language code: Plot3D[Skewness[BetaNegativeBinomialDistribution[α, β, 100]], {α, 0, 20}, {β, 0, 20}, MeshFunctions -> {#3&}, MeshShading -> ColorData[35, "ColorList"], AxesLabel -> Automatic, ViewPoint -> {15, 8, 5}]
Wolfram Language code: Skewness[BetaNegativeBinomialDistribution[α, β, n]]

峰度：

Wolfram Language code: Plot3D[Kurtosis[BetaNegativeBinomialDistribution[α, β, 100]], {α, 0, 20}, {β, 0, 20}, MeshFunctions -> {#3&}, MeshShading -> ColorData[35, "ColorList"], AxesLabel -> Automatic, ViewPoint -> {15, 8, 5}]
Wolfram Language code: Kurtosis[BetaNegativeBinomialDistribution[α, β, n]]

以参数的函数形式表示不同矩的解析式：

Wolfram Language code: FormulaGrid[list_, type_] := Grid[...]

Moment：

Wolfram Language code: FormulaGrid[Table[Moment[BetaNegativeBinomialDistribution[α, β, n], k]//Simplify, {k, 3}], M]

CentralMoment：

Wolfram Language code: FormulaGrid[Table[CentralMoment[BetaNegativeBinomialDistribution[α, β, n], k]//Simplify, {k, 3}], CM]

FactorialMoment：

Wolfram Language code: FormulaGrid[Table[FactorialMoment[BetaNegativeBinomialDistribution[α, β, n], k]//Simplify, {k, 3}], FM]

具有符号式阶数的解析式：

Wolfram Language code: FactorialMoment[BetaNegativeBinomialDistribution[α, β, n], r]

Cumulant：

Wolfram Language code: FormulaGrid[Table[Cumulant[BetaNegativeBinomialDistribution[α, β, n], k]//Simplify, {k, 3}], C]

风险函数：

Wolfram Language code: DiscretePlot[Table[HazardFunction[BetaNegativeBinomialDistribution[α, 1, 20], x], {α, {0.3, 0.5, 1}}]//Evaluate, {x, 0, 20}, PlotMarkers -> Automatic]
Wolfram Language code: DiscretePlot[Table[HazardFunction[BetaNegativeBinomialDistribution[1, β, 20], x], {β, {1 / 3, 1 / 2, 1}}]//Evaluate, {x, 0, 20}, PlotMarkers -> Automatic]
Wolfram Language code: HazardFunction[BetaNegativeBinomialDistribution[α, β, n], x]

分位数函数：

Wolfram Language code: 𝒟 = BetaNegativeBinomialDistribution[3, 2, 10]; points = Table[CDF[𝒟, x], {x, 0, 10}]//N;
Wolfram Language code: DiscretePlot[Quantile[𝒟, p], {p, points}, ExtentSize -> Right, ExtentMarkers -> {"Empty", "Filled"}]

应用  (2)

BetaNegativeBinomialDistribution 的 CDF 是右连续函数的一个例子：

Wolfram Language code: DiscretePlot[CDF[BetaNegativeBinomialDistribution[3, 2, 10], x], {x, 0, 10}, ExtentSize -> Right, ExtentMarkers -> {"Filled", "Empty"}]

假设 服从 β 分布，求成功10次之前至少经历50次失败的概率：

Wolfram Language code: Probability[x ≥ 50, xBetaNegativeBinomialDistribution[4, 5, 10]]
Wolfram Language code: N[%]

通过计算 为固定值时的概率和求平均进行验证：

Wolfram Language code: Probability[x ≥ 50, xNegativeBinomialDistribution[10, p]]
Wolfram Language code: NExpectation[%, pBetaDistribution[4, 5]]

属性和关系  (5)

获得负整数、超出 n 的整数或者非整数数的概率为零：

Wolfram Language code: PDF[BetaNegativeBinomialDistribution[α, β, n], π]

与其它分布的关系：

WaringYuleDistribution 是 β 负二项分布的一个特殊情况：

Wolfram Language code: PDF[WaringYuleDistribution[α], x]
Wolfram Language code: PDF[BetaNegativeBinomialDistribution[α, 1, 1], x]
Wolfram Language code: % - %%//FullSimplify

WaringYuleDistribution 是 β 负二项分布的一个特殊情况：

Wolfram Language code: PDF[WaringYuleDistribution[α, β], x]
Wolfram Language code: PDF[BetaNegativeBinomialDistribution[α, β, 1], x]
Wolfram Language code: % - %%//FullSimplify

β 负二项分布是 NegativeBinomialDistribution 和 BetaDistribution 的混合：

Wolfram Language code: ParameterMixtureDistribution[NegativeBinomialDistribution[n, p], pBetaDistribution[α, β]]

可能存在的问题  (2)

当 α、β 或 n 非正时，BetaNegativeBinomialDistribution 没有定义：

Wolfram Language code: Mean[BetaNegativeBinomialDistribution[-4, 6.2, 40]]

将无效参数代入符号式输出时，所得到的结果没有意义：

Wolfram Language code: Mean[BetaNegativeBinomialDistribution[α, β, n]] /. {α -> 3 + I, β -> 7, n -> 23}
Wolfram Research (2007)，BetaNegativeBinomialDistribution，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BetaNegativeBinomialDistribution.html.

文本

Wolfram Research (2007)，BetaNegativeBinomialDistribution，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BetaNegativeBinomialDistribution.html.

CMS

Wolfram 语言. 2007. "BetaNegativeBinomialDistribution." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/BetaNegativeBinomialDistribution.html.

APA

Wolfram 语言. (2007). BetaNegativeBinomialDistribution. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BetaNegativeBinomialDistribution.html 年

BibTeX

@misc{reference.wolfram_2026_betanegativebinomialdistribution, author="Wolfram Research", title="{BetaNegativeBinomialDistribution}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/BetaNegativeBinomialDistribution.html}", note=[Accessed: 14-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_betanegativebinomialdistribution, organization={Wolfram Research}, title={BetaNegativeBinomialDistribution}, year={2007}, url={https://reference.wolfram.com/language/ref/BetaNegativeBinomialDistribution.html}, note=[Accessed: 14-August-2026]}