WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BirnbaumSaundersDistribution[α,λ]

形状母数 α，尺度母数 λ のBirnbaum–Saunders分布を表す．

詳細
Details and Options Details and Options
予備知識
例題  
例  
スコープ  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

BirnbaumSaundersDistribution

BirnbaumSaundersDistribution[α,λ]

形状母数 α，尺度母数 λ のBirnbaum–Saunders分布を表す．

詳細

予備知識

  • BirnbaumSaundersDistribution[α,λ]は，区間上で定義され，2つの正の値 α および λ でパラメータ化された連続統計分布を表す．α は「形状母数」として知られ，γ は「尺度母数」として知られているものであり，両者が一緒になって，高さや平面上の水平位置等，確率密度関数(PDF)のさまざまな特性を決定する．Birnbaum–Saunders分布のPDFは，単峰性で，PDFが の大きい値について指数関数的に減少するという意味で「薄い裾部」を持つ．（この動作は，分布のSurvivalFunctionを分析することで数量的に厳密にすることができる．）
  • Birnbaum–Saunders分布は，もともとは，1960年代の後半に，数学者のZ.W. BirnbaumとS.C. Saundersによって，応力と歪みの周期性パターンに影響される物質の寿命モデルとして提案された．Birnbaum–Saunders分布は，疲労寿命分布としても知られており，現在も製造業における寿命サイクルのモデル化に盛んに使われている．より最近になって，この分布の修正バージョンが，飲料水におけるミネラル濃度の分布の正確なモデル化に使われるようになった．この他では，この分布は逆ガウス分布(InverseGaussianDistribution)の分位関数の近似，工業科学のさまざまな分野における分析，急速な低下の影響を受けるある種の生物学過程のモデル化等に使われている．
  • RandomVariateを使ってBirnbaum–Saunders分布から，1つあるいは複数の機械精度あるいは任意精度（後者はWorkingPrecisionオプションを介す）の擬似乱数変量を得ることができる．Distributed[x,BirnbaumSaundersDistribution[α,λ]]（より簡略すると xBirnbaumSaundersDistribution[α,λ]）を使って，確率変数 x がBirnbaum–Saunders分布に従って分布していると宣言することができる．このような宣言は，Probability，NProbability，Expectation，NExpectation等の関数で使うことができる．
  • 確率密度関数および累積分布関数は，PDF[BirnbaumSaundersDistribution[α,λ],x]およびCDF[BirnbaumSaundersDistribution[α,λ],x]を使って得られることがある．平均，中央値，分散，原点の周りのモーメント，中心モーメントは，それぞれMean，Median，Variance，Moment，CentralMomentを使って計算することができる．
  • DistributionFitTestを使って，与えられたデータ集合がBirnbaum–Saunders分布と一致するかどうかを検定することが，EstimatedDistributionを使って与えられたデータからBirnbaum–Saundersパラメトリック分布を推定することが，FindDistributionParametersを使ってデータをBirnbaum–Saunders分布にフィットすることができる．ProbabilityPlotを使って記号Birnbaum–Saunders分布のCDFに対する与えられたデータのCDFのプロットを生成することが，QuantilePlotを使って記号Birnbaum–Saunders分布の変位値に対する与えられたデータの変位値のプロットを生成することができる．
  • TransformedDistributionを使って変換されたBirnbaum–Saunders分布を表すことが，CensoredDistributionを使って上限値と下限値の間で切り取られた値の分布を表すことが，TruncatedDistributionを使って上限値と下限値の間で切断された値の分布を表すことができる．CopulaDistributionを使ってBirnbaum–Saunders分布を含む高次元分布を構築することが，ProductDistributionを使ってBirnbaum–Saunders分布を含む独立成分分布の結合分布を計算することができる．
  • Birnbaum–Saunders分布は他の多くの分布に関連している．例えば，確率変量 を与えられた場合，YNormalDistribution[]である場合かつその場合に限り XBirnbaumSaundersDistribution[α,γ]である．ただし，である．視覚的には，BirnbaumSaundersDistributionのPDFは「ベルの形」に見えることが多く，したがって，CauchyDistribution，StudentTDistribution，LogisticDistributionを含む他の多くの関数との定性的関係を導く．BirnbaumSaundersDistributionはLogNormalDistribution，BetaDistribution，JohnsonDistributionとも関係がある．

例題

すべて開く すべて閉じる

例  (4)

確率密度関数：

Wolfram Language code: Plot[Table[PDF[BirnbaumSaundersDistribution[α, 3], x], {α, {1 / 4, 1 / 2, 1}}]//Evaluate, {x, 0, 1}, Filling -> Axis, PlotRange -> {0, 5}]
Wolfram Language code: Plot[Table[PDF[BirnbaumSaundersDistribution[.5, λ], x], {λ, {2, 3, 5}}]//Evaluate, {x, 0, 1}, Filling -> Axis, PlotRange -> {0, 5}]
Wolfram Language code: PDF[BirnbaumSaundersDistribution[α, λ], x]

累積分布関数：

Wolfram Language code: Plot[Table[CDF[BirnbaumSaundersDistribution[α, 3], x], {α, {1 / 4, 1 / 2, 1}}]//Evaluate, {x, 0, 1}, Filling -> Axis]
Wolfram Language code: Plot[Table[CDF[BirnbaumSaundersDistribution[.5, λ], x], {λ, {2, 3, 5}}]//Evaluate, {x, 0, 1}, Filling -> Axis]
Wolfram Language code: CDF[BirnbaumSaundersDistribution[α, λ], x]

平均と分散：

Wolfram Language code: Mean[BirnbaumSaundersDistribution[α, λ]]
Wolfram Language code: Variance[BirnbaumSaundersDistribution[α, λ]]

中央値：

Wolfram Language code: Median[BirnbaumSaundersDistribution[α, λ]]

スコープ  (8)

Birnbaum–Saunders分布から擬似乱数のサンプルを生成する：

Wolfram Language code: data = RandomVariate[BirnbaumSaundersDistribution[1 / 3, 3], 10 ^ 4];

そのヒストグラムを累積分布関数と比較する：

Wolfram Language code: Show[ Histogram[data, 15, "PDF"], Plot[PDF[BirnbaumSaundersDistribution[1 / 3, 3], x], {x, 0, 1}, PlotStyle -> Thick]]

分布母数推定：

Wolfram Language code: sample = RandomVariate[BirnbaumSaundersDistribution[.2, 4], 10 ^ 3];

サンプルデータから分布母数を推定する：

Wolfram Language code: edist = EstimatedDistribution[sample, BirnbaumSaundersDistribution[α, λ]]

サンプルの密度ヒストグラムを推定分布の確率密度関数と比較する：

Wolfram Language code: Show[Histogram[sample, Automatic, "PDF"], Plot[PDF[edist, x], {x, 0, 0.5}, PlotStyle -> Thick]]

歪度は形状母数 α のみに依存する：

Wolfram Language code: Plot[Skewness[BirnbaumSaundersDistribution[α, λ]], {α, 0, 5}, Filling -> Axis]
Wolfram Language code: Skewness[BirnbaumSaundersDistribution[α, λ]]

極限値：

Wolfram Language code: Limit[Skewness[BirnbaumSaundersDistribution[α, λ]], α -> ∞]
Wolfram Language code: N[%]

尖度は形状母数 α のみに依存する：

Wolfram Language code: Plot[Kurtosis[BirnbaumSaundersDistribution[α, λ]], {α, 0, 5}, Filling -> Axis]
Wolfram Language code: Kurtosis[BirnbaumSaundersDistribution[α, λ]]

極限値：

Wolfram Language code: Limit[Kurtosis[BirnbaumSaundersDistribution[α, λ]], α -> ∞]
Wolfram Language code: N[%]

母数の関数としての閉じた形の種々のモーメント：

Wolfram Language code: FormulaGrid[list_, type_] := Grid[...]

Moment：

Wolfram Language code: FormulaGrid[Table[Moment[BirnbaumSaundersDistribution[α, λ], k]//Together, {k, 5}], M]

記号次数の閉じた形：

Wolfram Language code: Moment[BirnbaumSaundersDistribution[α, λ], r]

CentralMoment：

Wolfram Language code: FormulaGrid[Table[CentralMoment[BirnbaumSaundersDistribution[α, λ], k]//Together, {k, 5}], CM]

FactorialMoment：

Wolfram Language code: FormulaGrid[Table[FactorialMoment[BirnbaumSaundersDistribution[α, λ], k]//Together, {k, 5}], FM]

Cumulant：

Wolfram Language code: FormulaGrid[Table[Cumulant[BirnbaumSaundersDistribution[α, λ], k], {k, 5}]//Together, C]

記号次数の閉じた形：

Wolfram Language code: Cumulant[BirnbaumSaundersDistribution[α, λ], r]

ハザード関数：

Wolfram Language code: Plot[Table[HazardFunction[BirnbaumSaundersDistribution[α, 1], x], {α, {0.2, 0.3, .5}}]//Evaluate, {x, 0, 1.5}, Filling -> Axis]
Wolfram Language code: Plot[Table[HazardFunction[BirnbaumSaundersDistribution[.4, λ], x], {λ, {1, 2, 3}}]//Evaluate, {x, 0, 2}, Filling -> Axis]
Wolfram Language code: HazardFunction[BirnbaumSaundersDistribution[α, λ], x]

分位関数：

Wolfram Language code: Plot[Table[Quantile[BirnbaumSaundersDistribution[α, 2], q], {α, {.5, 1, 2}}]//Evaluate, {q, 0, 1}, Filling -> Axis, Exclusions -> None]
Wolfram Language code: Plot[Table[Quantile[BirnbaumSaundersDistribution[2, λ], q], {λ, {.5, 1, 2}}]//Evaluate, {q, 0, 1}, Filling -> Axis, Exclusions -> None]
Wolfram Language code: Quantile[BirnbaumSaundersDistribution[α, λ], q]

母数でQuantityを一貫して使うとQuantityDistributionが与えられる：

Wolfram Language code: time𝒟 = BirnbaumSaundersDistribution[1.6, Quantity[1, 1/"Minutes"]]

四分位数を求める：

Wolfram Language code: Quartiles[time𝒟]

アプリケーション  (3)

ある部品の寿命を時間単位で表すと，1時間あたり ，のBirnbaum–Saunders分布に従うとする．この部品が300時間以上使える確率を求める：

Wolfram Language code: 𝒟 = BirnbaumSaundersDistribution[100, Quantity[10, 1/"Hours"]];
Wolfram Language code: Probability[x ≥ Quantity[300, "Hours"], x𝒟]
Wolfram Language code: UnitConvert[N[%], "Percent"]

この部品が寿命の300時間を超え500時間以上経ってもまだ使える確率を求める：

Wolfram Language code: Probability[x ≥ Quantity[500, "Hours"]x ≥ Quantity[300, "Hours"], x𝒟]
Wolfram Language code: UnitConvert[N[%], "Percent"]

この部品が故障するまでの平均時間を求める：

Wolfram Language code: Mean[𝒟]
Wolfram Language code: N[%]

これと類似する独立した30個の部品の故障までの時間のシミュレーションを行う：

Wolfram Language code: ListPlot[{RandomVariate[𝒟, 30], {{0, Mean[𝒟]}, {30, Mean[𝒟]}}}, Joined -> {False, True}, Filling -> Axis, AxesLabel -> Automatic]

部品Aの故障までの時間は1時間あたり ，のBirnbaum–Saundersに従い，部品Bの故障率は1時間あたり1であるとして，この両方の部品の故障までの平均時間を求める：

Wolfram Language code: 𝒟1 = BirnbaumSaundersDistribution[2, Quantity[3, 1/"Hours"]];
Wolfram Language code: Mean[𝒟1]
Wolfram Language code: 𝒟2 = ExponentialDistribution[Quantity[1, 1/"Hours"]];
Wolfram Language code: Mean[𝒟2]

部品Aが部品Bよりも先に故障する確率を求める：

Wolfram Language code: NProbability[tA < tB, {tA𝒟1, tB𝒟2}]

両者の平均寿命は同じだが，Birnbaum–Saunders分布に従う方が早く故障する率が高い：

Wolfram Language code: Plot[{PDF[𝒟1, Quantity[x, "Hours"]], PDF[𝒟2, Quantity[x, "Hours"]]}, {x, 0, 3}, PlotRange -> {0, 3}, Filling -> Axis, AxesLabel -> {"h"}, PlotLegends -> {"Birnbaum-Saunders", "Exponential"}]

あるデバイスの寿命がBirnbaum–Saunders分布に従うとして，このデバイスの信頼性を求める：

Wolfram Language code: r = SurvivalFunction[BirnbaumSaundersDistribution[α, λ], t]

ハザード関数は水平漸近線 を持つ：

Wolfram Language code: Limit[Refine[HazardFunction[BirnbaumSaundersDistribution[α, 1], t], t > 0], t -> ∞, Assumptions -> α > 0]
Wolfram Language code: Limit[Refine[HazardFunction[BirnbaumSaundersDistribution[1, λ], t], t > 0], t -> ∞, Assumptions -> λ > 0]

直列に繋がれたこのようなデバイス2つの信頼性を求める：

Wolfram Language code: rs = r r//PiecewiseExpand

並列に繋がれたこのようなデバイス2つの信頼性を求める：

Wolfram Language code: rp = 1 - (1 - r)(1 - r)//PiecewiseExpand

両方の系の信頼性を と について比較する：

Wolfram Language code: Block[{α = 0.8, λ = 1.2}, Plot[{rs, rp}, {t, 0, 5}, PlotLegends -> {"in series", "in parallel"}]]

特性と関係  (3)

Birnbaum–Saunders分布は正の因子によるスケーリングの下では閉じている：

Wolfram Language code: TransformedDistribution[k * u, uBirnbaumSaundersDistribution[α, λ]]

がBirnbaum–Saunders分布に従うなら， もまたBirnbaum–Saunders分布に従う：

Wolfram Language code: TransformedDistribution[1 / u, uBirnbaumSaundersDistribution[α, λ]]

Birnbaum–Saunders分布はNormalDistributionに関連している：

Wolfram Language code: CDF[BirnbaumSaundersDistribution[α, λ], x]
Wolfram Language code: CDF[NormalDistribution[], (1 / α)(Sqrt[x λ] - 1 / Sqrt[x λ])]//FunctionExpand
Wolfram Language code: % - %%//FullSimplify[#, x > 0 && λ > 0]&

おもしろい例題  (1)

累積分布関数の等高線を持つ α のさまざまな値についての確率密度関数：

Wolfram Language code: dist = BirnbaumSaundersDistribution[α, 3];cdf = Function[{x, α}, Evaluate[CDF[dist, x]]]; ql = {0.025, 0.10, 0.25, 0.5, 0.75, 0.90, 0.975}; cl = Table[ColorData["Rainbow"][q], {q, Join[{0.0}, ql]}];
Wolfram Language code: Legended[Plot3D[PDF[dist, x], {x, 0, 1}, {α, 1 / 4, 1}, PlotTheme -> "Marketing", MeshFunctions -> {cdf}, Mesh -> {ql}, MeshStyle -> GrayLevel[0.8], PlotRange -> All, MeshShading -> cl, AxesLabel -> Automatic, BaseStyle -> Opacity[0.9], ImageSize -> 400], BarLegend["Rainbow", ql, LegendLabel -> "prob"]]
Wolfram Research (2010), BirnbaumSaundersDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/BirnbaumSaundersDistribution.html （2016年に更新）.

テキスト

Wolfram Research (2010), BirnbaumSaundersDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/BirnbaumSaundersDistribution.html （2016年に更新）.

CMS

Wolfram Language. 2010. "BirnbaumSaundersDistribution." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2016. https://reference.wolfram.com/language/ref/BirnbaumSaundersDistribution.html.

APA

Wolfram Language. (2010). BirnbaumSaundersDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BirnbaumSaundersDistribution.html

BibTeX

@misc{reference.wolfram_2026_birnbaumsaundersdistribution, author="Wolfram Research", title="{BirnbaumSaundersDistribution}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/BirnbaumSaundersDistribution.html}", note=[Accessed: 13-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_birnbaumsaundersdistribution, organization={Wolfram Research}, title={BirnbaumSaundersDistribution}, year={2016}, url={https://reference.wolfram.com/language/ref/BirnbaumSaundersDistribution.html}, note=[Accessed: 13-August-2026]}