Wolfram 语言与系统参考资料中心

BirnbaumSaundersDistribution

表示形状参数为 α、尺度参数为 λ 的 Birnbaum–Saunders 分布.

背景

BirnbaumSaundersDistribution[α,λ] 表示了一个定义在区间上，有两个正值参数 α 和 λ 的连续统计分布，称为 Birnbaum–Saunders 分布. 这里，α 被称为“形状参数”，γ 是所谓的“比例参数”，而这些参数一起决定了其概率密度函数（PDF）的许多性质，包括它在平面上的高度和水平位置. Birnbaum–Saunders 分布的 PDF 是单峰的且有一个“薄尾部”，意思是说当的值较大时 PDF 是指数衰减的.（这一行为可通过研究分布的 SurvivalFunction 做精确的定量分析.）
Birnbaum–Saunders 分布可以追溯到 1960 年代末数学家 Z. W. Birnbaum 和 S. C. Saunders 的工作，最初是作为材料在反复的应力应变下的寿命模型提出的. Birnbaum–Saunders 分布，也被称为疲劳寿命分布，仍然积极的被用于对制造业中的生命周期建模. 最近，该分布的修正版本已经被用于对饮用水中的矿物质浓度分布进行精确的建模. 此外，该分布还被用于近似逆高斯分布（InverseGaussianDistribution）的分位点函数，在工程科学的各个领域进行分析，以及对某些快速下滑情况下的生物过程建模.
RandomVariate 可被用于给出 Birnbaum–Saunders 分布的一个或多个机器精度或任意精度（后者可用 WorkingPrecision 选项指定）的伪随机变量. Distributed[x,BirnbaumSaundersDistribution[α,λ]]，更简洁的写法是 xBirnbaumSaundersDistribution[α,λ]，可被用于声明随机变量 x 是 Birnbaum–Saunders 分布的. 这样一个声明之后可用在如 Probability、NProbability、Expectation 以及 NExpectation 这样的函数中.
概率密度函数和累积分布函数可用 PDF[BirnbaumSaundersDistribution[α,λ],x] 和 CDF[BirnbaumSaundersDistribution[α,λ],x] 求得. 平均数、中位数、方差、原点矩及中心矩可分别用 Mean、Median、Variance、Moment 和 CentralMoment 计算.
DistributionFitTest 可被用于测试给定的数据集是否与 Birnbaum–Saunders 分布一致，EstimatedDistribution 可被用于根据给定数据估算 Birnbaum–Saunders 参数化分布，而 FindDistributionParameters 可拟合数据和 Birnbaum–Saunders 分布. ProbabilityPlot 可被用于生成给定数据的 CDF 相对于符号 Birnbaum–Saunders 分布的 CDF 的图线，而 QuantilePlot 可被用于生成给定数据的分位数相对于符号 Birnbaum–Saunders 分布的分位数的图线.
TransformedDistribution 可被用于表示转换的 Birnbaum–Saunders 分布，CensoredDistribution 可被用于表示删截后位于上限值和下限值之间的值分布，而 TruncatedDistribution 可被用于表示截断后位于上限值和下限值之间的值分布. CopulaDistribution 可被用于建立包含了 Birnbaum–Saunders 分布的高维分布，而 ProductDistribution 可被用于计算包括 Birnbaum–Saunders 分布在内的，若干个独立分量分布的联合分布.
Birnbaum–Saunders 分布与许多其它分布密切相关. 例如，对给定的随机变量，XBirnbaumSaundersDistribution[α,γ] 当且仅当 YNormalDistribution[]，其中 . 从视觉上看，BirnbaumSaundersDistribution 的 PDF 往往呈“钟形”，从而引入了和许多其它分布的定性关系，包括 CauchyDistribution、StudentTDistribution 以及 LogisticDistribution. BirnbaumSaundersDistribution 还和 LogNormalDistribution、BetaDistribution 和 JohnsonDistribution 有关.

范例

打开所有单元关闭所有单元

基本范例 (4)

概率密度函数：

Wolfram Language code:

Plot[Table[PDF[BirnbaumSaundersDistribution[α, 3], x], {α, {1 / 4, 1 / 2, 1}}]//Evaluate, {x, 0, 1}, Filling -> Axis, PlotRange -> {0, 5}]

Wolfram Language code:

Plot[Table[PDF[BirnbaumSaundersDistribution[.5, λ], x], {λ, {2, 3, 5}}]//Evaluate, {x, 0, 1}, Filling -> Axis, PlotRange -> {0, 5}]

Wolfram Language code: PDF[BirnbaumSaundersDistribution[α, λ], x]

累积分布函数：

Wolfram Language code: Plot[Table[CDF[BirnbaumSaundersDistribution[α, 3], x], {α, {1 / 4, 1 / 2, 1}}]//Evaluate, {x, 0, 1}, Filling -> Axis]

Wolfram Language code: Plot[Table[CDF[BirnbaumSaundersDistribution[.5, λ], x], {λ, {2, 3, 5}}]//Evaluate, {x, 0, 1}, Filling -> Axis]

Wolfram Language code: CDF[BirnbaumSaundersDistribution[α, λ], x]

均值和方差：

Wolfram Language code: Mean[BirnbaumSaundersDistribution[α, λ]]

Wolfram Language code: Variance[BirnbaumSaundersDistribution[α, λ]]

中位数：

Wolfram Language code: Median[BirnbaumSaundersDistribution[α, λ]]

范围 (8)

生成一组服从 Birnbaum–Saunders分布的伪随机数样本：

Wolfram Language code: data = RandomVariate[BirnbaumSaundersDistribution[1 / 3, 3], 10 ^ 4];

将直方图与概率密度函数比较：

Wolfram Language code:

Show[
	Histogram[data, 15, "PDF"], 
	Plot[PDF[BirnbaumSaundersDistribution[1 / 3, 3], x], {x, 0, 1}, PlotStyle -> Thick]]

分布参数估计：

Wolfram Language code: sample = RandomVariate[BirnbaumSaundersDistribution[.2, 4], 10 ^ 3];

根据样本数据估计分布参数：

Wolfram Language code: edist = EstimatedDistribution[sample, BirnbaumSaundersDistribution[α, λ]]

比较样本密度直方图和所估计分布的概率密度函数：

Wolfram Language code: Show[Histogram[sample, Automatic, "PDF"], Plot[PDF[edist, x], {x, 0, 0.5}, PlotStyle -> Thick]]

偏度仅取决于形状参数 α：

Wolfram Language code: Plot[Skewness[BirnbaumSaundersDistribution[α, λ]], {α, 0, 5}, Filling -> Axis]

Wolfram Language code: Skewness[BirnbaumSaundersDistribution[α, λ]]

极限值：

Wolfram Language code: Limit[Skewness[BirnbaumSaundersDistribution[α, λ]], α -> ∞]

Wolfram Language code: N[%]

峰度仅取决于形状参数 α：

Wolfram Language code: Plot[Kurtosis[BirnbaumSaundersDistribution[α, λ]], {α, 0, 5}, Filling -> Axis]

Wolfram Language code: Kurtosis[BirnbaumSaundersDistribution[α, λ]]

极限值：

Wolfram Language code: Limit[Kurtosis[BirnbaumSaundersDistribution[α, λ]], α -> ∞]

Wolfram Language code: N[%]

以参数的函数形式表示不同矩的解析式：

Wolfram Language code: FormulaGrid[list_, type_] := Grid[...]

Moment:

Wolfram Language code: FormulaGrid[Table[Moment[BirnbaumSaundersDistribution[α, λ], k]//Together, {k, 5}], M]

具有符号式阶数的解析式：

Wolfram Language code: Moment[BirnbaumSaundersDistribution[α, λ], r]

CentralMoment:

Wolfram Language code: FormulaGrid[Table[CentralMoment[BirnbaumSaundersDistribution[α, λ], k]//Together, {k, 5}], CM]

FactorialMoment:

Wolfram Language code: FormulaGrid[Table[FactorialMoment[BirnbaumSaundersDistribution[α, λ], k]//Together, {k, 5}], FM]

Cumulant:

Wolfram Language code: FormulaGrid[Table[Cumulant[BirnbaumSaundersDistribution[α, λ], k], {k, 5}]//Together, C]

具有符号式阶数的解析式：

Wolfram Language code: Cumulant[BirnbaumSaundersDistribution[α, λ], r]

风险函数：

Wolfram Language code:

Plot[Table[HazardFunction[BirnbaumSaundersDistribution[α, 1], x], {α, {0.2, 0.3, .5}}]//Evaluate, {x, 0, 1.5}, Filling -> Axis]

Wolfram Language code:

Plot[Table[HazardFunction[BirnbaumSaundersDistribution[.4, λ], x], {λ, {1, 2, 3}}]//Evaluate, {x, 0, 2}, Filling -> Axis]

Wolfram Language code: HazardFunction[BirnbaumSaundersDistribution[α, λ], x]

分位数函数：

Wolfram Language code:

Plot[Table[Quantile[BirnbaumSaundersDistribution[α, 2], q], {α, {.5, 1, 2}}]//Evaluate, {q, 0, 1}, Filling -> Axis, Exclusions -> None]

Wolfram Language code:

Plot[Table[Quantile[BirnbaumSaundersDistribution[2, λ], q], {λ, {.5, 1, 2}}]//Evaluate, {q, 0, 1}, Filling -> Axis, Exclusions -> None]

Wolfram Language code: Quantile[BirnbaumSaundersDistribution[α, λ], q]

Quantity 在参数中的一致性使用生成 QuantityDistribution：

Wolfram Language code: time𝒟 = BirnbaumSaundersDistribution[1.6, Quantity[1, 1/"Minutes"]]

求四分位数：

Wolfram Language code: Quartiles[time𝒟]

应用 (3)

一个元件的寿命（以小时计）服从及的 Birnbaum-Saunders 分布. 求该元件寿命超过300小时的概率：

Wolfram Language code: 𝒟 = BirnbaumSaundersDistribution[100, Quantity[10, 1/"Hours"]];

Wolfram Language code: Probability[x ≥ Quantity[300, "Hours"], x𝒟]

Wolfram Language code: UnitConvert[N[%], "Percent"]

求该元件在正常工作300小时后，能够继续工作到500小时以后的概率：

Wolfram Language code: Probability[x ≥ Quantity[500, "Hours"]x ≥ Quantity[300, "Hours"], x𝒟]

Wolfram Language code: UnitConvert[N[%], "Percent"]

求元件失效的平均时间：

Wolfram Language code: Mean[𝒟]

Wolfram Language code: N[%]

对这样的30个独立元件的失效时间进行模拟：

Wolfram Language code:

ListPlot[{RandomVariate[𝒟, 30], {{0, Mean[𝒟]}, {30, Mean[𝒟]}}}, Joined -> {False, True}, Filling -> Axis, AxesLabel -> Automatic]

元件 A 失效的时间（以小时计）服从及的 Birnbaum-Saunders 分布，而元件 B 的失效率每小时为1. 求这两个元件均失效需要的平均时间：

Wolfram Language code: 𝒟1 = BirnbaumSaundersDistribution[2, Quantity[3, 1/"Hours"]];

Wolfram Language code: Mean[𝒟1]

Wolfram Language code: 𝒟2 = ExponentialDistribution[Quantity[1, 1/"Hours"]];

Wolfram Language code: Mean[𝒟2]

求元件 A 先于 B 失效的概率：

Wolfram Language code: NProbability[tA < tB, {tA𝒟1, tB𝒟2}]

尽管两个元件的平均寿命相同，服从 Birnbaum-Saunder 分布的元件往往会先失效：

Wolfram Language code:

Plot[{PDF[𝒟1, Quantity[x, "Hours"]], PDF[𝒟2, Quantity[x, "Hours"]]}, {x, 0, 3}, PlotRange -> {0, 3}, Filling -> Axis, AxesLabel -> {"h"}, PlotLegends -> {"Birnbaum-Saunders", "Exponential"}]

一设备的寿命服从 Birnbaum-Saunders 分布. 求该设备的可靠度：

Wolfram Language code: r = SurvivalFunction[BirnbaumSaundersDistribution[α, λ], t]

风险函数具有水平渐近线：

Wolfram Language code: Limit[Refine[HazardFunction[BirnbaumSaundersDistribution[α, 1], t], t > 0], t -> ∞, Assumptions -> α > 0]

Wolfram Language code: Limit[Refine[HazardFunction[BirnbaumSaundersDistribution[1, λ], t], t > 0], t -> ∞, Assumptions -> λ > 0]

求两个这种设备串联的可靠度：

Wolfram Language code: rs = r r//PiecewiseExpand

求两个这种设备并联的可靠度：

Wolfram Language code: rp = 1 - (1 - r)(1 - r)//PiecewiseExpand

比较及时两个系统的可靠度：

Wolfram Language code: Block[{α = 0.8, λ = 1.2}, Plot[{rs, rp}, {t, 0, 5}, PlotLegends -> {"in series", "in parallel"}]]

属性和关系 (3)

当使用一个正因子为比例进行缩放时，新生成的分布仍然是 Birnbaum–Saunders 分布：

Wolfram Language code: TransformedDistribution[k * u, uBirnbaumSaundersDistribution[α, λ]]

如果服从 Birnbaum–Saunders 分布，那么也服从 Birnbaum–Saunders 分布：

Wolfram Language code: TransformedDistribution[1 / u, uBirnbaumSaundersDistribution[α, λ]]

Birnbaum–Saunders 分布与 NormalDistribution 相关：

Wolfram Language code: CDF[BirnbaumSaundersDistribution[α, λ], x]

Wolfram Language code: CDF[NormalDistribution[], (1 / α)(Sqrt[x λ] - 1 / Sqrt[x λ])]//FunctionExpand

Wolfram Language code: % - %%//FullSimplify[#, x > 0 && λ > 0]&

巧妙范例 (1)

取不同 α 值时的概率密度函数与累积分布函数等高图：

Wolfram Language code:

dist = BirnbaumSaundersDistribution[α, 3];cdf = Function[{x, α}, Evaluate[CDF[dist, x]]];
ql = {0.025, 0.10, 0.25, 0.5, 0.75, 0.90, 0.975};
cl = Table[ColorData["Rainbow"][q], {q, Join[{0.0}, ql]}];

Wolfram Language code:

Legended[Plot3D[PDF[dist, x], {x, 0, 1}, {α, 1 / 4, 1}, PlotTheme -> "Marketing", MeshFunctions -> {cdf}, Mesh -> {ql}, MeshStyle -> GrayLevel[0.8], PlotRange -> All, MeshShading -> cl, AxesLabel -> Automatic, BaseStyle -> Opacity[0.9], ImageSize -> 400], BarLegend["Rainbow", ql, LegendLabel -> "prob"]]

Top

更多学习资源

技术支持

Wolfram 解决方案

Wolfram 的教育解决方案

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

BirnbaumSaundersDistribution

更多信息

背景

范例

基本范例 (4)

范围 (8)

应用 (3)

属性和关系 (3)

巧妙范例 (1)

文本

CMS

APA

BibTeX

BibLaTeX

BirnbaumSaundersDistribution

更多信息

背景

范例

基本范例 (4)

范围 (8)

应用 (3)

属性和关系 (3)

巧妙范例 (1)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX