Wolfram 语言与系统参考资料中心

CentralMoment

CentralMoment[data,r]

给出 data 的 r 阶中心矩 .

CentralMoment[data,{r₁,…,r_m}]

给出 data 的 {r₁,…,r_m} 阶多变量中心矩 .

CentralMoment[dist,…]

给出分布 dist 的中心矩.

CentralMoment[r]

代表正式 r 阶中心矩.

范例

打开所有单元关闭所有单元

基本范例 (3)

根据数据计算中心矩：

Wolfram Language code: data = RandomVariate[LogNormalDistribution[1, 1], 10 ^ 5];

Wolfram Language code: CentralMoment[data, 3]

使用符号数据：

Wolfram Language code: CentralMoment[{Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}, 2]

日期列表的中心矩：

Wolfram Language code: CentralMoment[{Yesterday, Today, Tomorrow}, 4]

计算一个单变量分布的二阶中心矩：

Wolfram Language code: CentralMoment[GammaDistribution[α, β], 2]

一个多变量分布的中心矩：

Wolfram Language code: CentralMoment[DirichletDistribution[{Subscript[α, 1], Subscript[α, 2], Subscript[α, 3]}], {1, 1}]

范围 (26)

基础用法 (6)

精确输入产生精确输出：

Wolfram Language code: CentralMoment[{1, 2, 3, 4}, 4]

Wolfram Language code: CentralMoment[{π, E, 2}, 2]//Together

近似输入产生近似输出：

Wolfram Language code: CentralMoment[{1., 2., 3., 4.}, 2]

Wolfram Language code: CentralMoment[N[{1, 2, 3, 4}, 30], 2]

求 WeightedData 的中心矩：

Wolfram Language code: CentralMoment[WeightedData[{1, 2, 3}, {Subscript[w, 1], Subscript[w, 2], Subscript[w, 3]}], 2]

Wolfram Language code:

data = {8, 3, 5, 4, 9, 0, 4, 2, 2, 3};
weights = {0.15, 0.09, 0.12, 0.10, 0.16, 0., 0.11, 0.08, 0.08, 0.09};

Wolfram Language code: CentralMoment[WeightedData[data, weights], 2]

求 EventData 的中心矩：

Wolfram Language code:

e = {1.0, 2.1, 3.2, 4.5, 5.7};
ci = {0, 0, 0, 1, 0};

Wolfram Language code: CentralMoment[EventData[e, ci], 2]

求 TimeSeries 的中心矩：

Wolfram Language code:

CentralMoment[TemporalData[TimeSeries, {{{2.3, 1.2, 6.7, 5.8, 7.1, 4.6}}, {{0, 5, 1}}, 1, {"Discrete", 1}, 
  {"Discrete", 1}, 1, {}}, False, 10.], 2]

矩仅与数值有关：

Wolfram Language code:

CentralMoment[TemporalData[TimeSeries, {{{2.3, 1.2, 6.7, 5.8, 7.1, 4.6}}, {{0, 5, 1}}, 1, {"Discrete", 1}, 
  {"Discrete", 1}, 1, {}}, False, 10.]["Values"], 2]

求带单位数据的中心矩：

Wolfram Language code: data = Quantity[RandomReal[1, 6], "Meters"]

Wolfram Language code: CentralMoment[data, 2]

数组数据 (5)

矩阵的 CentralMoment 按列给出矩：

Wolfram Language code:

CentralMoment[(⁠|       |       |
| ----- | ----- |
| a1, 1 | a1, 2 |
| a2, 1 | a2, 2 |⁠), 4]//Simplify

张量的 CentralMoment 在第一层按列给出矩：

Wolfram Language code: CentralMoment[Array[Subscript[a, ##]&, {2, 2, 2}], 2]//Simplify//MatrixForm

数组的多变量 CentralMoment：

Wolfram Language code: CentralMoment[Array[Subscript[a, ##]&, {2, 2, 2}], {2, 2}]//Simplify

适用于大型数组：

Wolfram Language code: CentralMoment[RandomReal[1, 10 ^ 7], 2]

Wolfram Language code: CentralMoment[RandomReal[1, {10 ^ 6, 5}], 2]

当输入是 Association 时，CentralMoment 会对其值进行处理：

Wolfram Language code:

mat = RandomReal[1, {3, 2}];
assoc = AssociationThread[Range[3], mat]

Wolfram Language code: CentralMoment[assoc, 3]

SparseArray 数据可以像密集数组一样使用：

Wolfram Language code: CentralMoment[SparseArray[{{1} -> 1, {100} -> 1}], 4]

Wolfram Language code: CentralMoment[SparseArray[{{1, 1} -> 1, {2, 2} -> 2, {3, 3} -> 3, {1, 3} -> 4}], 2]

求 QuantityArray 的中心矩：

Wolfram Language code: data = QuantityArray[RandomReal[1, 6], "Pounds"]

Wolfram Language code: CentralMoment[data, 5]

图像和音频数据 (2)

RGB 图像的通道中心矩：

Wolfram Language code: CentralMoment[[image], 5]

Wolfram Language code: RGBColor[%]

灰度图像的中心矩强度值：

Wolfram Language code: CentralMoment[[image], 4]

对于音频对象，CentralMoment 按通道工作：

Wolfram Language code: a = ExampleData[{"Audio", "Bee"}]

Wolfram Language code: AudioMeasurements[a, "Channels"]

Wolfram Language code: CentralMoment[a, 3]

日期和时间 (4)

计算日期的中心矩：

Wolfram Language code: dates = WolframLanguageData[All, "DateIntroduced"];

Wolfram Language code: DateHistogram[dates]

Wolfram Language code: CentralMoment[dates, 4]

Wolfram Language code: UnitConvert[%, "Decades" ^ 4]

计算日期的加权中心矩：

Wolfram Language code: dates = RandomDate[4]

Wolfram Language code: weights = {1, 1, 1, 3};

Wolfram Language code: CentralMoment[WeightedData[dates, weights], 3]

Wolfram Language code: UnitConvert[%, "Years" ^ 3]

计算不同日历中日期的中心矩：

Wolfram Language code:

dates = {DateObject[{2024, 2, 29}, CalendarType -> "Julian"], DateObject[{1524, 1, 1}, CalendarType -> "Islamic"], DateObject[{6024, 1, 15}, CalendarType -> "Jewish"]}

Wolfram Language code: CentralMoment[dates, 2]

Wolfram Language code: UnitConvert[%, "Years" ^ 2]

与方差比较：

Wolfram Language code: Variance[dates]

Wolfram Language code: UnitConvert[%, "Years" ^ 2]

计算时间的中心矩：

Wolfram Language code: RandomTime[3]

Wolfram Language code: CentralMoment[%, 4]

不同时区规格的时间列表：

Wolfram Language code: {TimeObject[{12}, TimeZone -> 0], TimeObject[{12}, TimeZone -> 2], TimeObject[{12}, TimeZone -> "Asia/Tokyo"]}

Wolfram Language code: CentralMoment[%, 3]

分布与过程矩 (5)

Scalar 单变量分布的中心矩：

Wolfram Language code: CentralMoment[BinomialDistribution[n, p], 2]//Together

Wolfram Language code: CentralMoment[NormalDistribution[μ, σ], 2]

多元分布的标量中心矩：

Wolfram Language code: CentralMoment[BinormalDistribution[{Subscript[μ, 1], Subscript[μ, 2]}, {Subscript[σ, 1], Subscript[σ, 2]}, ρ], 2]

Wolfram Language code: CentralMoment[DirichletDistribution[{a, b, c}], 3]

多元分布的联合中心矩：

Wolfram Language code: CentralMoment[MultinomialDistribution[n, {Subscript[p, 1], Subscript[p, 2], Subscript[p, 3]}], {1, 1, 1}]

Wolfram Language code:

CentralMoment[BinormalDistribution[{Subscript[μ, 1], Subscript[μ, 2]}, {Subscript[σ, 1], Subscript[σ, 2]}, ρ], {2, 2}]

计算符号式阶 r 的中心矩：

Wolfram Language code: CentralMoment[BetaDistribution[a, b], r]

中心矩仅对具体阶数计算：

Wolfram Language code: CentralMoment[ExtremeValueDistribution[a, b], r]

Wolfram Language code: % /. r -> 3

中心矩仅能数值式计算：

Wolfram Language code: CentralMoment[VonMisesDistribution[Pi / 2, 2], 4]

Wolfram Language code: N[%]

导出分布的中心矩：

Wolfram Language code: CentralMoment[TransformedDistribution[x^2, xNormalDistribution[μ, σ]], 2]

Wolfram Language code: CentralMoment[ProbabilityDistribution[(Sqrt[2] / π)(1 / (1 + (x - 2)^4)), {x, -∞, ∞}], 2]

数据分布：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 10 ^ 3];

Wolfram Language code: CentralMoment[HistogramDistribution[data], 4]

随机过程的中心矩函数：

Wolfram Language code: CentralMoment[BrownianBridgeProcess[μ, σ][t], 4]

Wolfram Language code: Plot[Evaluate[% /. {μ -> 3, σ -> 1}], {t, 0, 1}, PlotRange -> All]

求 TemporalData 在某时刻 t=0.5 的中心矩：

Wolfram Language code: td = RandomFunction[WienerProcess[1, 1], {0, 10, 0.05}, 100]

Wolfram Language code: CentralMoment[td[0.5], 2]

结合所有模拟结果，找出相应的中心矩函数：

Wolfram Language code:

Show[ListLinePlot[td, PlotStyle -> Directive[Opacity[0.2], Thin]], Plot[CentralMoment[td[t], 2], {t, 0, 10}, PlotStyle -> Thick]]

正式矩 (4)

正式矩的 TraditionalForm 格式：

Wolfram Language code: CentralMoment[r]//TraditionalForm

Wolfram Language code: CentralMoment[{p, q, r}]//TraditionalForm

将正式矩的组合转换为含 CentralMoment 的表达式：

Wolfram Language code: MomentConvert[Moment[2], CentralMoment]//TraditionalForm

Wolfram Language code: MomentConvert[Moment[2]Cumulant[2], CentralMoment]//TraditionalForm

计算包含正式矩的一个分布的表达式：

Wolfram Language code: MomentEvaluate[CentralMoment[2] + CentralMoment[4], PoissonDistribution[λ]]

对数据计算：

Wolfram Language code: data = RandomVariate[PoissonDistribution[1], 10^4];

Wolfram Language code: MomentEvaluate[CentralMoment[2] + Moment[4], data]

求包含 CentralMoment 的一个表达式的样本估计量：

Wolfram Language code: (estimator = MomentConvert[CentralMoment[2], "UnbiasedSampleEstimator"])//TraditionalForm

计算数据所产生的估计量：

Wolfram Language code: data = RandomVariate[PoissonDistribution[1], 10^4];

Wolfram Language code: MomentEvaluate[estimator, data]

应用 (11)

一阶中心矩为 0：

Wolfram Language code: data = RandomReal[{-7, 3}, 100];

Wolfram Language code: CentralMoment[data, 1]

二阶中心矩是分散的度量：

Wolfram Language code: 𝒟 = NormalDistribution[0, σ];

Wolfram Language code: CentralMoment[𝒟, 2]

Wolfram Language code:

Table[Plot[PDF[𝒟, x], {x, -4, 4}, PlotRange -> {0, 0.4}, Filling -> Axis, Ticks -> {Automatic, None}], {σ, {1, 1.5, 2}}]

三阶中心矩是偏度的度量：

Wolfram Language code: dists = {NormalDistribution[0, 2.5], ChiSquareDistribution[5], GumbelDistribution[3, 2]};

Wolfram Language code: Table[CentralMoment[dists[[i]], 3], {i, 3}]//N

Wolfram Language code: Table[Plot[PDF[dists[[i]], x], {x, -7, 15}, PlotRange -> {0, 0.2}, Filling -> Axis, Ticks -> {Automatic, None}], {i, 3}]

使用矩方法，估计一个分布的参数：

Wolfram Language code: data = RandomVariate[GammaDistribution[3, 6], 10 ^ 4];

Wolfram Language code: meq = Table[CentralMoment[data, k] == CentralMoment[GammaDistribution[α, β], k], {k, 2, 3}]

Wolfram Language code: NSolve[meq, {α, β}]

比较数据和所估计的参数分布：

Wolfram Language code:

Show[Histogram[data, Automatic, "ProbabilityDensity"], Plot[Evaluate[PDF[GammaDistribution[α, β], x] /. %], {x, 0, 100}, PlotStyle -> Thick]]

使用矩方法，求 GammaDistribution 的正态近似：

Wolfram Language code: gdist = GammaDistribution[α, β];

Wolfram Language code:

meq = {Moment[gdist, 1] == Moment[NormalDistribution[μ, σ], 1], CentralMoment[gdist, 2] == CentralMoment[NormalDistribution[μ, σ], 2]}

证明和如何由和决定：

Wolfram Language code: Solve[(And@@meq)∧σ > 0, {μ, σ}, Reals]

Wolfram Language code: {ndist} = Refine[NormalDistribution[μ, σ] /. %, β > 0∧α > 0]

比较原分布和近似分布：

Wolfram Language code: Plot[{PDF[gdist, x], PDF[ndist, x]} /. {α -> 13, β -> 3}, {x, 0, 80}, Evaluated -> True]

创建二阶中心矩的样本估计量：

Wolfram Language code: estim = MomentConvert[CentralMoment[2], "SampleEstimator"]

假定样本量为，求其样本分布的期望：

Wolfram Language code: MomentConvert[estim, {CentralMoment, n}]

求估计量的样本分布方差：

Wolfram Language code: MomentConvert[(estim - %) ^ 2, {CentralMoment, n}]

求均匀分布样本的估计量的方差：

Wolfram Language code: MomentEvaluate[%, UniformDistribution[{0, 1}]]

根据大数定理，随样本量增大，样本矩趋近于总体矩. 使用 Histogram 说明在不同样本量时，一个均匀随机变量的二阶样本中心矩的概率分布：

Wolfram Language code:

Histogram[Table[CentralMoment[RandomReal[1, {n, 2 * 10 ^ 3}], 2], {n, {10, 10^2, 10^3}}], 30, "ProbabilityDensity", ChartLegends -> {10, 10^2, 10^3}]

对于近正态数据的三阶与四阶中心矩的埃奇沃斯展式：

Wolfram Language code:

pdf = (Exp[-(x^2/2)]/Sqrt[2 π]) (1 + ((-6 Sqrt[2] x + 2 Sqrt[2] x^3) CentralMoment[3]/12 Sqrt[2]) + (1/576) (-120 + 360 x^2 - 120 x^4 + 8 x^6) CentralMoment[3]^2 + (1/96) (12 - 24 x^2 + 4 x^4) (-3 + CentralMoment[4]));

Wolfram Language code: data = Standardize[Total[RandomReal[1, {3, 10 ^ 5}]]];

Wolfram Language code: dist = ProbabilityDistribution[MomentEvaluate[pdf, data], {x, -∞, ∞}]

Wolfram Language code: {NExpectation[x ^ 3, xdist], NExpectation[x ^ 4, xdist]}

Wolfram Language code: {CentralMoment[data, 3], CentralMoment[data, 4]}

Wolfram Language code:

Show[Histogram[data, Automatic, "ProbabilityDensity"], Plot[{PDF[dist, z], PDF[NormalDistribution[], z]}, {z, -3, 3}, PlotStyle -> {Directive[Thick], Directive[Dashed, Black]}]]

计算样本 Jarque–Bera 统计量的函数 [链接]:

Wolfram Language code:

JarqueBera[list_] := With[{cm2 = CentralMoment[list, 2]}, (Length[list]/6)((CentralMoment[list, 3]^2/cm2^3) + (1/4)((CentralMoment[list, 4]/cm2^2) - 3)^2)]

关于正态随机变量的累积统计量：

Wolfram Language code: data = Table[JarqueBera[RandomVariate[NormalDistribution[], 2 * 10^3]], {2 * 10^3}];

比较统计量直方图与渐进分布：

Wolfram Language code:

Show[
	Histogram[data, 30, "ProbabilityDensity"], 
	Plot[PDF[ChiSquareDistribution[2], x], {x, 0, 20}, PlotRange -> All]]

计算一些数据的移动中心矩：

Wolfram Language code:

data = TemporalData[TimeSeries, {{{0., 0.007220215826254015, -0.028898335552430553, -0.24236658577144637, 
    -0.05412788592296647, -0.03667481168713718, -0.17138823136819967, -0.3007558946785308, 
    -0.43687938826754796, -0.3573927720423709, -0.345586 ... 33201685, -1.2078738741401542, -1.1504147295751919, 
    -1.1306360665338737}}, {{0, 1., 0.01}}, 1, {"Continuous", 1}, {"Continuous", 1}, 1, 
  {ValueDimensions -> 1, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 
 10.1];

使用长度为 .1 的窗：

Wolfram Language code: md = MovingMap[CentralMoment[#, 2]&, data, {.1}];

Wolfram Language code: ListLinePlot[md, PlotRange -> All]

计算随机过程的一组路径切片的中心矩：

Wolfram Language code: data = RandomFunction[WienerProcess[], {0, 1, .01}, 10 ^ 3];

选择几个切片次数：

Wolfram Language code: times = Range[0, 1, .1];

Wolfram Language code: cm = Map[{#, CentralMoment[data[#], 2]}&, times];

绘制在这些路径上的中心矩：

Wolfram Language code: Show[ListPlot[data], ListLinePlot[cm, PlotStyle -> Black]]

属性和关系 (11)

中心矩对于平移是不变的：

Wolfram Language code: CentralMoment[ExponentialDistribution[λ], 5]

Wolfram Language code: CentralMoment[TransformedDistribution[x + a, xExponentialDistribution[λ]], 5]

二阶中心距是一个缩放后的 Variance：

Wolfram Language code: data = RandomReal[10, 20];

Wolfram Language code: Variance[data] (Length[data] - 1) / Length[data]

Wolfram Language code: CentralMoment[data, 2]

2×2 矩阵的奇矩消失了：

Wolfram Language code:

CentralMoment[(⁠|       |       |
| ----- | ----- |
| a1, 1 | a1, 2 |
| a2, 1 | a2, 2 |⁠), 5]//Simplify

对于多元阶，总阶必须是奇数：

Wolfram Language code:

CentralMoment[(⁠|       |       |
| ----- | ----- |
| a1, 1 | a1, 2 |
| a2, 1 | a2, 2 |⁠), {2, 3}]//Simplify

深度为的数组的多元中心矩深度为：

Wolfram Language code:

arr = Array[Subscript[a, Row@{##}]&, {n = 4, m = 3, 2, 3}];
rs = {2, 2, 2};
Length[rs] == m

Wolfram Language code:

CentralMoment[arr, rs] == 
	ArrayReduce[Mean, 
	ArrayReduce[Times@@Power[#, rs]&, 
	(*Centralize*)
	arr - TensorProduct[ConstantArray[1, n], Mean[arr]], 
	2], 
	1]//Simplify

二阶中心距的 Sqrt 是来自 Mean 的偏差的 RootMeanSquare：

Wolfram Language code: Sqrt[CentralMoment[{a, b, c, d}, 2]]

Wolfram Language code: RootMeanSquare[{a, b, c, d} - Mean[{a, b, c, d}]]

Skewness 是三阶中心距和二阶中心距的乘方的比：

Wolfram Language code: data = RandomReal[10, 10];

Wolfram Language code: Skewness[data]

Wolfram Language code: CentralMoment[data, 3] / CentralMoment[data, 2] ^ (3 / 2)

Kurtosis 是四阶中心距和二阶中心距的乘方的比：

Wolfram Language code: data = RandomReal[10, 10];

Wolfram Language code: Kurtosis[data]

Wolfram Language code: CentralMoment[data, 4] / CentralMoment[data, 2] ^ 2

CentralMoment 等价于一个随机变量在均值附近的幂的 Expectation：

Wolfram Language code: list = Range[100];

Wolfram Language code: Expectation[(x - Mean[list]) ^ 5, xlist] == CentralMoment[list, 5]

Wolfram Language code: dist = PoissonDistribution[μ];

Wolfram Language code: Expectation[(x - Mean[dist]) ^ 5, xdist] == CentralMoment[dist, 5]

阶数为的 CentralMoment 等价于，当两者都存在的情况下：

Wolfram Language code: cmgf = CentralMomentGeneratingFunction[LaplaceDistribution[0, 1], t]

Wolfram Language code: SeriesCoefficient[cmgf, {t, 0, r}]r!

直接使用 CentralMoment：

Wolfram Language code: CentralMoment[LaplaceDistribution[0, 1], r]

利用 GeneratingFunction 求中心矩母函数：

Wolfram Language code: GeneratingFunction[CentralMoment[ExponentialDistribution[λ], r] / r!, r, t, Assumptions -> λ > 0]

与 CentralMomentGeneratingFunction 的直接计算比较：

Wolfram Language code: CentralMomentGeneratingFunction[ExponentialDistribution[λ], t]

Wolfram Language code: FullSimplify[% - %%]

CentralMoment 可以使用 Moment、Cumulant 或者 FactorialMoment 表示：

Wolfram Language code: MomentConvert[CentralMoment[4], Cumulant]

Wolfram Language code: MomentConvert[CentralMoment[4], Moment]

Wolfram Language code: MomentConvert[CentralMoment[2], FactorialMoment]

可能存在的问题 (2)

对于重尾分布，高阶中心矩是不确定的：

Wolfram Language code: Table[CentralMoment[StudentTDistribution[3], r], {r, 2, 5}]

在该分布的5个独立样本上计算中心矩：

Wolfram Language code: data = RandomVariate[StudentTDistribution[3], {10 ^ 5, 5}];

高阶样本中心矩显示了轻微的波动：

Wolfram Language code: ListLogPlot[Abs@Table[CentralMoment[data, r], {r, 2, 5}], Joined -> True]

中心矩的样本估计量是有偏的：

Wolfram Language code: MomentConvert[CentralMoment[2], "SampleEstimator"]//TraditionalForm

假设样本大小为，求样本总体期望：

Wolfram Language code: MomentConvert[%, {CentralMoment, n}]

估计量是渐进无偏的：

Wolfram Language code: Limit[%, n -> ∞]

构建无偏估计量：

Wolfram Language code: MomentConvert[CentralMoment[2], "UnbiasedEstimator", "PowerSymmetricPolynomial"]//TraditionalForm

对于任何大小的样本，估计量的期望值是中心矩：

Wolfram Language code: MomentConvert[%, {CentralMoment, n}]

巧妙范例 (1)

对 20、100和 300 个样本 CentralMoment 的分布估计：

Wolfram Language code: CentralMoment[ExponentialDistribution[0.9], 2]

Wolfram Language code:

SmoothHistogram[Table[CentralMoment[RandomVariate[ExponentialDistribution[0.9], {s, 1000}], 2], {s, {20, 100, 300}}], Filling -> Axis, PlotLegends -> {20, 100, 300}, PlotRange -> {{0, 4}, Automatic}]

Top

			r 次幂之和 »
			r 次中心幂之纵向和 »
	$x in TemplateBox[{Arrays, paclet:ref/Arrays}, RefLink, BaseStyle -> {3ColumnTableMod}][{n_(1),...,n_(k)}]$		r 次中心幂之纵向和 »

	Association	值（忽略键值） »
	WeightedData	加权平均值，基于底层 EmpiricalDistribution »
	EventData	基于底层 SurvivalDistribution »
	TimeSeries, TemporalData, …	值的向量或数组（时间戳忽略不计） »
	Image,Image3D	RGB 通道值或灰度强度值 »
	Audio	所有通道的振幅值 »
	DateObject, TimeObject	日期列表或时间列表 »

更多学习资源

技术支持

Wolfram 解决方案

Wolfram 的教育解决方案

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

CentralMoment

更多信息

范例

基本范例 (3)

范围 (26)

基础用法 (6)

数组数据 (5)

图像和音频数据 (2)

日期和时间 (4)

分布与过程矩 (5)

正式矩 (4)

应用 (11)

属性和关系 (11)

可能存在的问题 (2)

巧妙范例 (1)

文本

CMS

APA

BibTeX

BibLaTeX

			第 j 列的 r_j 次中心幂之和
	$x in TemplateBox[{Arrays, paclet:ref/Arrays}, RefLink, BaseStyle -> {3ColumnTableMod}][{n_(1),...,n_(k)}]$		第 j 列的 r_j 次中心幂之和 »

CentralMoment

更多信息

范例

基本范例 (3)

范围 (26)

基础用法 (6)

数组数据 (5)

图像和音频数据 (2)

日期和时间 (4)

分布与过程矩 (5)

正式矩 (4)

应用 (11)

属性和关系 (11)

可能存在的问题 (2)

巧妙范例 (1)

参见

技术笔记

相关指南

相关的工作流程

历史

文本

CMS

APA

BibTeX

BibLaTeX