WOLFRAM

Wolfram 语言与系统参考资料中心

CircularSymplecticMatrixDistribution[n]

表示复数域上的圆辛矩阵分布，其矩阵维数为 {2 n,2 n}.

更多信息
Details and Options Details and Options
背景
范例  
基本范例  
范围  
应用  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

CircularSymplecticMatrixDistribution

CircularSymplecticMatrixDistribution[n]

表示复数域上的圆辛矩阵分布，其矩阵维数为 {2 n,2 n}.

更多信息

背景

范例

打开所有单元 关闭所有单元

基本范例  (2)

根据酉辛群生成一个随机矩阵：

Wolfram Language code: 𝓂 = RandomVariate[CircularSymplecticMatrixDistribution[100]];

随机矩阵是酉矩阵：

Wolfram Language code: UnitaryMatrixQ[𝓂]

同时也验证了自对偶辛条件：

Wolfram Language code: 𝒥 = KroneckerProduct[{{0, -1}, {1, 0}}, IdentityMatrix[100, SparseArray]]; 𝒥.Transpose[𝓂] == 𝓂.𝒥

用 MatrixPropertyDistribution 表示一个随机矩阵的特征值，并从中抽样：

Wolfram Language code: RandomVariate[MatrixPropertyDistribution[Eigenvalues[x], xCircularSymplecticMatrixDistribution[4]]]

范围  (3)

生成单个伪随机矩阵：

Wolfram Language code: RandomVariate[CircularSymplecticMatrixDistribution[2]]

生成一组伪随机矩阵：

Wolfram Language code: RandomVariate[CircularSymplecticMatrixDistribution[2], 2]

数值法计算统计特性：

Wolfram Language code: 𝒟 = MatrixPropertyDistribution[Max[Differences[Sort[Arg[Eigenvalues[m]]]]], mCircularSymplecticMatrixDistribution[50]];
Wolfram Language code: NExpectation[100x / (2Pi), x𝒟]

应用  (1)

CircularSymplecticMatrixDistribution 的特征值的联合分布也是当逆温度 时，戴森的库仑气体在圆上的 Boltzmann 分布. 系统中每个粒子的平均哈密顿量（不包含动能项）为：

Wolfram Language code: hamiltonian[Z_] := Module[{n = Length[Z]}, Log[n] / 2 - Sum[Total[Log[Abs[Differences[Z, 1, k]]]], {k, n - 1}] / n ]

定义随机 CSE 矩阵上的哈密顿量值的分布：

Wolfram Language code: h𝒟 = MatrixPropertyDistribution[hamiltonian[Take[SortBy[Eigenvalues[x], Arg], {1, -1, 2}]], xCircularSymplecticMatrixDistribution[n]];

计算大小不同的系统的哈密顿量的抽样均值：

Wolfram Language code: means = Table[{n, Mean[RandomVariate[h𝒟, 1000]]}, {n, 10, 60, 10}]

绘制抽样均值，并与热力学极值进行比较：

Wolfram Language code: Show[ListPlot[means, PlotStyle -> {Red, PointSize[Medium]}, Filling -> Axis, PlotRange -> {0, 0.12}, AxesLabel -> {"N", "〈H〉"}], Plot[(1/2) ((3/2) - EulerGamma - Log[2]), {x, 0, 60}]]

属性和关系  (2)

特征值的相角的分布：

Wolfram Language code: dim = 150; args = RandomVariate[MatrixPropertyDistribution[Arg[Eigenvalues[x]], xCircularSymplecticMatrixDistribution[dim]], 100];
Wolfram Language code: Histogram[Join@@args, {-Pi, Pi, 2Pi / 40}, PDF]

计算特征值之间的间距，计算时要考虑到它们是成对出现的：

Wolfram Language code: diffs = Join@@Map[Composition[Differences[#, 1, 2]&, Sort], (args/2Pi)dim];

比较样本水平间距的直方图与解析形式，亦称为 Dyson 指标为4的 Wigner 估测：

Wolfram Language code: WignerSurmisePDF[x_, β : 4] := (64 / (9 Pi)) ^ 3 x ^ 4 Exp[(-64 / (9 Pi)) x ^ 2]
Wolfram Language code: Show[Histogram[diffs, {0.1}, PDF], Plot[WignerSurmisePDF[x, 4], {x, 0, 2.5}]]

对于维度大小为 的 CircularSymplecticMatrixDistribution 的特征向量，四元数元素的缩放模数服从 分布：

Wolfram Language code: With[{n = 50}, 𝒟 = MatrixPropertyDistribution[Flatten[Total[ArrayReshape[Abs[Eigenvectors[𝓂]] ^ 2, {2n, 2, n}], {2}]], 𝓂CircularSymplecticMatrixDistribution[n]]];
Wolfram Language code: data = 4Normalize[Join@@RandomVariate[𝒟, 25], Mean];

将直方图与 ChiSquareDistribution 的 PDF 进行比较：

Wolfram Language code: Show[Histogram[data, "Scott", PDF], Plot[PDF[ChiSquareDistribution[4], x], {x, 0, 14}]]

可能存在的问题  (1)

从 CircularSymplecticMatrixDistribution 得来的矩阵不必是辛矩阵：

Wolfram Language code: dim = 3; cseℳ = RandomVariate[CircularSymplecticMatrixDistribution[dim]];
Wolfram Language code: 𝒥 = KroneckerProduct[{{0, -1}, {1, 0}}, IdentityMatrix[dim, SparseArray]];
Wolfram Language code: Norm[Transpose[cseℳ].𝒥.cseℳ - 𝒥]

用 CircularQuaternionMatrixDistribution 随机生成一个酉辛阵：

Wolfram Language code: cqeℳ = RandomVariate[CircularQuaternionMatrixDistribution[dim]];
Wolfram Language code: Norm[Transpose[cqeℳ].𝒥.cqeℳ - 𝒥]
Wolfram Research (2015)，CircularSymplecticMatrixDistribution，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CircularSymplecticMatrixDistribution.html.

文本

Wolfram Research (2015)，CircularSymplecticMatrixDistribution，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CircularSymplecticMatrixDistribution.html.

CMS

Wolfram 语言. 2015. "CircularSymplecticMatrixDistribution." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/CircularSymplecticMatrixDistribution.html.

APA

Wolfram 语言. (2015). CircularSymplecticMatrixDistribution. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CircularSymplecticMatrixDistribution.html 年

BibTeX

@misc{reference.wolfram_2026_circularsymplecticmatrixdistribution, author="Wolfram Research", title="{CircularSymplecticMatrixDistribution}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/CircularSymplecticMatrixDistribution.html}", note=[Accessed: 14-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_circularsymplecticmatrixdistribution, organization={Wolfram Research}, title={CircularSymplecticMatrixDistribution}, year={2015}, url={https://reference.wolfram.com/language/ref/CircularSymplecticMatrixDistribution.html}, note=[Accessed: 14-August-2026]}