CircularUnitaryMatrixDistribution

行列次元が{n,n}の円ユニタリ行列分布を表す．

詳細

CircularUnitaryMatrixDistributionは，円ユニタリアンサンブル(CUE)としても知られている．
CircularUnitaryMatrixDistributionは，ユニタリ群上のHarr測度としても知られている，次元 n のユニタリ正方行列上の一様分布を表す．
次元母数 n は任意の正の整数でよい．
CircularUnitaryMatrixDistributionは，MatrixPropertyDistributionやRandomVariate等の関数とともに使うことができる．

予備知識

CircularUnitaryMatrixDistribution[n]は，円ユニタリアンサンブル(CUE)とも呼ばれるもので，ユニタリ複素行列，具体的にはを満足する複素正方行列上の統計分布を表す．ただし，はの共役転置を表し，は恒等行列を表す．母数 n は分布の次元母数と呼ばれるもので，任意の正の整数でよい．
円ユニタリ行列分布は，円シンプレクティック分布および円直交行列分布（それぞれCircularSymplecticMatrixDistributionとCircularOrthogonalMatrixDistribution）と並んで，もともと1962年にFreeman Dysonによって量子力学の研究のために開発された3つのいわゆる円行列アンサンプルの一つである．円ユニタリ行列分布は，確率論的にはユニタリ正方行列上の一様分布を表すが，数学的にはユニタリ群上のいわゆるハール(Haar)測度である．円ユニタリ行列分布のような行列アンサンブルは，ランダム行列理論をはじめとする物理学および数学のさまざま分野の研究において非常に重要である．
RandomVariateを使って，円ユニタリ行列分布から，1つあるいは複数の機械精度あるいは任意精度（後者はWorkingPrecisionオプションを介す）の擬似乱数変量を得ることができる．そのような変量の集合の平均，中央値，分散，モーメント，中心モーメントは，それぞれMean，Median，Variance，Moment，CentralMomentを使って計算することができる．Distributed[A,CircularUnitaryMatrixDistribution[n]]（より簡単な表記では ACircularUnitaryMatrixDistribution[n]）を使ってランダム行列 A が円ユニタリ行列分布に従って分布していると宣言することができる．そのような宣言はMatrixPropertyDistribution等の関数で使うことができる．
円ユニタリ行列分布に従って分布する変量のトレース，固有値，ノルムは，それぞれTr，Eigenvalues，Normを使って計算することができる．そのような変量は，MatrixFunctionやMatrixPowerで調べることもできる．加えて，実部(Re)，虚部(Im)，複素引数(Arg)等の関連する実際の量はMatrixPlotを使ってプロットできる．
CircularUnitaryMatrixDistributionは他の数多くの分布と関連がある．上述の通り，この分布はCircularQuaternionMatrixDistribution，CircularRealMatrixDistribution，CircularSymplecticMatrixDistribution，CircularOrthogonalMatrixDistribution等の他の円行列分布と定性的に類似している．円行列アンサンブルは，もともとはいわゆるガウスアンサンブルの一般化として導かれたものなので，CircularUnitaryMatrixDistributionはGaussianOrthogonalMatrixDistribution，GaussianSymplecticMatrixDistribution，GaussianUnitaryMatrixDistributionと関係がある．CircularUnitaryMatrixDistributionはMatrixNormalDistribution，MatrixTDistribution，WishartMatrixDistribution，InverseWishartMatrixDistribution，TracyWidomDistribution，WignerSemicircleDistributionとも関係がある．

例題

すべて開くすべて閉じる

例 (2)

ランダムCUE行列を生成する：

Wolfram Language code: RandomVariate[CircularUnitaryMatrixDistribution[3]]

行列がユニタリ行列であることを確かめる：

Wolfram Language code: UnitaryMatrixQ[%]

MatrixPropertyDistributionを使ってランダム行列の固有値を表し，そこからサンプルを取る：

Wolfram Language code: RandomVariate[MatrixPropertyDistribution[Eigenvalues[x], xCircularUnitaryMatrixDistribution[4]]]

固有値は単位円上にある：

Wolfram Language code:

ComplexListPlot[RandomVariate[MatrixPropertyDistribution[Eigenvalues[x], xCircularUnitaryMatrixDistribution[10 ^ 2]]]]

スコープ (3)

ランダムユニタリ行列を生成する：

Wolfram Language code: RandomVariate[CircularUnitaryMatrixDistribution[2]]

ランダムユニタリ行列の集合を生成する：

Wolfram Language code: RandomVariate[CircularUnitaryMatrixDistribution[2], 2]

統計特性を数値計算する：

Wolfram Language code:

gap𝒟 = MatrixPropertyDistribution[Max[Differences[Sort[Arg[Eigenvalues[𝓂]]]]], 𝓂CircularUnitaryMatrixDistribution[50]];

期待値：

Wolfram Language code: NExpectation[Sinc[δ], δgap𝒟]

分布からのシミュレーション：

Wolfram Language code: Histogram[RandomVariate[gap𝒟, 10 ^ 3]]

アプリケーション (4)

ランダム行列の固有値の複素引数の分布を定義する：

Wolfram Language code: evs𝒟 = MatrixPropertyDistribution[Arg[Eigenvalues[x]], xCircularUnitaryMatrixDistribution[2]];

ランダム置換に続く固有値の位相をサンプルする：

Wolfram Language code: φs = RandomSample /@ RandomVariate[evs𝒟, 10 ^ 5];

結合位相分布を閉形式のPDFとともに可視化する：

Wolfram Language code:

Show[
	Histogram3D[φs, {-Pi, Pi, 0.25}, PDF], 
	Plot3D[(1/8Pi^2)Abs[Exp[I ϕ1] - Exp[I ϕ2]] ^ 2, {ϕ1, -Pi, Pi}, {ϕ2, -Pi, Pi}, PlotStyle -> None, MeshStyle -> Thick]]

最長増加部分数列の長さが最大である個の要素の置換数は， $TemplateBox[{{Tr, [, {U, _, n}, ]}}, Abs]^(2 k)$ 上の平均で計算することができる．ただし，はCircularUnitaryMatrixDistribution[n]から取られるものとする：

Wolfram Language code: {k, n} = {6, 2};

Wolfram Language code: NExpectation[ℐ, ℐMatrixPropertyDistribution[Abs[Tr[𝒰]]^2k, 𝒰CircularUnitaryMatrixDistribution[n]]]

直接の数と比較する：

Wolfram Language code: Count[Permutations[Range[k]], perm_ /; Length[LongestOrderedSequence[perm]] ≤ n]

CircularUnitaryMatrixDistributionについての固有値の結合分布は，逆気温がの円上のDysonのCoulombガスのBoltzmann分布でもある．系の粒子あたりの平均ハミルトニアンは以下の通りである（運動項は除く）：

Wolfram Language code:

hamiltonian[Z_] := Module[{n = Length[Z]}, 
	Log[n] / 2 - Sum[Total[Log[Abs[Differences[Z, 1, k]]]], {k, n - 1}] / n
	]

ランダムなCUE行列上のハミルトニアンの値の分布を定義する：

Wolfram Language code: h𝒟 = MatrixPropertyDistribution[hamiltonian[Eigenvalues[x]], xCircularUnitaryMatrixDistribution[n]];

サイズが異なる系についてのハミルトニアンのサンプル平均を計算する：

Wolfram Language code: means = Table[{n, Mean[RandomVariate[h𝒟, 1000]]}, {n, 10, 60, 10}]

サンプル平均をプロットし，それを熱力学極限と比較する：

Wolfram Language code:

Show[ListPlot[means, PlotStyle -> {Red, PointSize[Medium]}, Filling -> Axis, PlotRange -> {0, 0.22}, AxesLabel -> {"N", "〈H〉"}], Plot[(1 - EulerGamma/2), {x, 0, 60}]]

GaussianUnitaryMatrixDistributionからの行列を無限小生成作用素として使ってCUE上のブラウン運動を構築する：

Wolfram Language code:

mats = RandomVariate[GaussianUnitaryMatrixDistribution[0.1, 2], 100000];
mats = MatrixExp[I #]& /@ mats;

CircularUnitaryMatrixDistributionからサンプルされた初期行列でブラン経路を生成する：

Wolfram Language code:

initial = RandomVariate[CircularUnitaryMatrixDistribution[2]];
res = FoldList[#2.#1&, initial, mats];

固有値の位相を計算し，それをCircularUnitaryMatrixDistributionからの行列の固有値の確率密度関数と比較する：

Wolfram Language code: phases = RandomSample /@ Arg[Eigenvalues /@ res];

Wolfram Language code:

Show[
	Histogram3D[phases, {-Pi, Pi, 0.25}, PDF], 
	Plot3D[(1/8Pi^2)Abs[Exp[I ϕ1] - Exp[I ϕ2]] ^ 2, {ϕ1, -Pi, Pi}, {ϕ2, -Pi, Pi}, PlotStyle -> None, MeshStyle -> Thick]]

特性と関係 (2)

固有値の位相角の分布：

Wolfram Language code:

dim = 300;
args = RandomVariate[MatrixPropertyDistribution[Arg[Eigenvalues[x]], xCircularUnitaryMatrixDistribution[dim]], 100];

Wolfram Language code: Histogram[Join@@args, {-Pi, Pi, 2Pi / 40}, PDF]

固有値間の間隔を計算する：

Wolfram Language code: diffs = Join@@Map[Composition[Differences, Sort], (args/2Pi)dim];

サンプルレベルの間隔のヒストグラムを，Dyson指数が2のWigner推測としても知られる閉形式と比較する：

Wolfram Language code: WignerSurmisePDF[x_, β : 2] := 2(4 x / Pi) ^ 2 Exp[(-4 / Pi) x ^ 2]

Wolfram Language code: Show[Histogram[diffs, {0.1}, PDF], Plot[WignerSurmisePDF[x, 2], {x, 0, 2.5}]]

次元が大のCircularUnitaryMatrixDistributionの固有ベクトルについては，要素のスケールされた法はカイ二乗分布に従う：

Wolfram Language code: 𝒟 = MatrixPropertyDistribution[Flatten[Abs[Eigenvectors[𝓂]] ^ 2], 𝓂CircularUnitaryMatrixDistribution[50]];

Wolfram Language code: data = 2Normalize[Join@@RandomVariate[𝒟, 100], Mean];

ヒストグラムをChiSquareDistributionのPDFと比較する：

Wolfram Language code: Show[Histogram[data, "Scott", PDF], Plot[PDF[ChiSquareDistribution[2], x], {x, 0, 9}]]

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

CircularUnitaryMatrixDistribution

詳細

予備知識

例題

例 (2)

スコープ (3)

アプリケーション (4)

特性と関係 (2)

テキスト

CMS

APA

BibTeX

BibLaTeX

CircularUnitaryMatrixDistribution

詳細

予備知識

例題

例 (2)

スコープ (3)

アプリケーション (4)

特性と関係 (2)

関連項目

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX