WOLFRAM

Wolfram 语言与系统参考资料中心

CircularUnitaryMatrixDistribution[n]

表示一个圆酉矩阵分布，矩阵的维度为 {n,n}.

更多信息
Details and Options Details and Options
背景
范例  
基本范例  
范围  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

CircularUnitaryMatrixDistribution

CircularUnitaryMatrixDistribution[n]

表示一个圆酉矩阵分布，矩阵的维度为 {n,n}.

更多信息

背景

范例

打开所有单元 关闭所有单元

基本范例  (2)

生成一个伪随机 CUE 矩阵：

Wolfram Language code: RandomVariate[CircularUnitaryMatrixDistribution[3]]

验证矩阵是酉矩阵：

Wolfram Language code: UnitaryMatrixQ[%]

用 MatrixPropertyDistribution 表示一个随机矩阵的特征值并从中抽样：

Wolfram Language code: RandomVariate[MatrixPropertyDistribution[Eigenvalues[x], xCircularUnitaryMatrixDistribution[4]]]

特征值位于单位圆上：

Wolfram Language code: ComplexListPlot[RandomVariate[MatrixPropertyDistribution[Eigenvalues[x], xCircularUnitaryMatrixDistribution[10 ^ 2]]]]

范围  (3)

生成一个随机酉矩阵：

Wolfram Language code: RandomVariate[CircularUnitaryMatrixDistribution[2]]

生成一组随机酉矩阵：

Wolfram Language code: RandomVariate[CircularUnitaryMatrixDistribution[2], 2]

用数值法计算统计特性：

Wolfram Language code: gap𝒟 = MatrixPropertyDistribution[Max[Differences[Sort[Arg[Eigenvalues[𝓂]]]]], 𝓂CircularUnitaryMatrixDistribution[50]];

期望：

Wolfram Language code: NExpectation[Sinc[δ], δgap𝒟]

对分布进行仿真：

Wolfram Language code: Histogram[RandomVariate[gap𝒟, 10 ^ 3]]

应用  (4)

定义随机矩阵特征值的复参数的分布：

Wolfram Language code: evs𝒟 = MatrixPropertyDistribution[Arg[Eigenvalues[x]], xCircularUnitaryMatrixDistribution[2]];

对随机排列的特征值的相位进行抽样：

Wolfram Language code: φs = RandomSample /@ RandomVariate[evs𝒟, 10 ^ 5];

可视化联合相位分布和 PDF 解析式：

Wolfram Language code: Show[ Histogram3D[φs, {-Pi, Pi, 0.25}, PDF], Plot3D[(1/8Pi^2)Abs[Exp[I ϕ1] - Exp[I ϕ2]] ^ 2, {ϕ1, -Pi, Pi}, {ϕ2, -Pi, Pi}, PlotStyle -> None, MeshStyle -> Thick]]

对于最长递增序列的最大长度为 、有 个元素的 ，可以通过对 TemplateBox[{{Tr, [, {U, _, n}, ]}}, Abs]^(2 k) 取平均来计算排列的数目，其中， 从 CircularUnitaryMatrixDistribution[n] 中得来：

Wolfram Language code: {k, n} = {6, 2};
Wolfram Language code: NExpectation[ℐ, ℐMatrixPropertyDistribution[Abs[Tr[𝒰]]^2k, 𝒰CircularUnitaryMatrixDistribution[n]]]

与直接计算的结果进行比较：

Wolfram Language code: Count[Permutations[Range[k]], perm_ /; Length[LongestOrderedSequence[perm]] ≤ n]

CircularUnitaryMatrixDistribution 的特征值的联合分布也是逆温度 时 Dyson 库仑气体在圆上的 Boltzmann 分布. 系统中每个粒子的平均哈密顿量为（不包含动能项）：

Wolfram Language code: hamiltonian[Z_] := Module[{n = Length[Z]}, Log[n] / 2 - Sum[Total[Log[Abs[Differences[Z, 1, k]]]], {k, n - 1}] / n ]

定义随机 CUE 矩阵上哈密顿量值的分布：

Wolfram Language code: h𝒟 = MatrixPropertyDistribution[hamiltonian[Eigenvalues[x]], xCircularUnitaryMatrixDistribution[n]];

计算大小不同的系统的哈密顿量的抽样平均：

Wolfram Language code: means = Table[{n, Mean[RandomVariate[h𝒟, 1000]]}, {n, 10, 60, 10}]

绘制抽样平均并将其与热力学极值进行比较：

Wolfram Language code: Show[ListPlot[means, PlotStyle -> {Red, PointSize[Medium]}, Filling -> Axis, PlotRange -> {0, 0.22}, AxesLabel -> {"N", "〈H〉"}], Plot[(1 - EulerGamma/2), {x, 0, 60}]]

利用 GaussianUnitaryMatrixDistribution 中的矩阵作为无穷小生成元，构建 CUE 上的布朗运动，

Wolfram Language code: mats = RandomVariate[GaussianUnitaryMatrixDistribution[0.1, 2], 100000]; mats = MatrixExp[I #]& /@ mats;

从 CircularUnitaryMatrixDistribution 中抽样取得初始矩阵，生成布朗路径：

Wolfram Language code: initial = RandomVariate[CircularUnitaryMatrixDistribution[2]]; res = FoldList[#2.#1&, initial, mats];

计算特征值的相位，将其与从 CircularUnitaryMatrixDistribution 中来的矩阵的特征值的 PDF 进行比较：

Wolfram Language code: phases = RandomSample /@ Arg[Eigenvalues /@ res];
Wolfram Language code: Show[ Histogram3D[phases, {-Pi, Pi, 0.25}, PDF], Plot3D[(1/8Pi^2)Abs[Exp[I ϕ1] - Exp[I ϕ2]] ^ 2, {ϕ1, -Pi, Pi}, {ϕ2, -Pi, Pi}, PlotStyle -> None, MeshStyle -> Thick]]

属性和关系  (2)

特征值的相角的分布：

Wolfram Language code: dim = 300; args = RandomVariate[MatrixPropertyDistribution[Arg[Eigenvalues[x]], xCircularUnitaryMatrixDistribution[dim]], 100];
Wolfram Language code: Histogram[Join@@args, {-Pi, Pi, 2Pi / 40}, PDF]

计算特征值之间的间距：

Wolfram Language code: diffs = Join@@Map[Composition[Differences, Sort], (args/2Pi)dim];

比较样本水平间距的直方图与解析形式，解析形式亦称为 Dyson 指标为2的 Wigner 估测：

Wolfram Language code: WignerSurmisePDF[x_, β : 2] := 2(4 x / Pi) ^ 2 Exp[(-4 / Pi) x ^ 2]
Wolfram Language code: Show[Histogram[diffs, {0.1}, PDF], Plot[WignerSurmisePDF[x, 2], {x, 0, 2.5}]]

对于维度大小为 的 CircularUnitaryMatrixDistribution 的特征向量，其元素的缩放模数服从 分布：

Wolfram Language code: 𝒟 = MatrixPropertyDistribution[Flatten[Abs[Eigenvectors[𝓂]] ^ 2], 𝓂CircularUnitaryMatrixDistribution[50]];
Wolfram Language code: data = 2Normalize[Join@@RandomVariate[𝒟, 100], Mean];

将直方图与 ChiSquareDistribution 的 PDF 进行比较：

Wolfram Language code: Show[Histogram[data, "Scott", PDF], Plot[PDF[ChiSquareDistribution[2], x], {x, 0, 9}]]
Wolfram Research (2015)，CircularUnitaryMatrixDistribution，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CircularUnitaryMatrixDistribution.html.

文本

Wolfram Research (2015)，CircularUnitaryMatrixDistribution，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CircularUnitaryMatrixDistribution.html.

CMS

Wolfram 语言. 2015. "CircularUnitaryMatrixDistribution." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/CircularUnitaryMatrixDistribution.html.

APA

Wolfram 语言. (2015). CircularUnitaryMatrixDistribution. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CircularUnitaryMatrixDistribution.html 年

BibTeX

@misc{reference.wolfram_2026_circularunitarymatrixdistribution, author="Wolfram Research", title="{CircularUnitaryMatrixDistribution}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/CircularUnitaryMatrixDistribution.html}", note=[Accessed: 12-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_circularunitarymatrixdistribution, organization={Wolfram Research}, title={CircularUnitaryMatrixDistribution}, year={2015}, url={https://reference.wolfram.com/language/ref/CircularUnitaryMatrixDistribution.html}, note=[Accessed: 12-September-2026]}