Wolfram 语言与系统参考资料中心

DagumDistribution

DagumDistribution[p,a,b]

表示形状参数为 p 和 a、尺度参数为 b 的 Dagum 分布.

背景

DagumDistribution[p,a,b] 表示一个定义在区间上的，有三个正值参数 p、a 和 b 的连续统计分布：Dagum 分布. 参数 p 和 a 被称为“形状参数”，并且根据它们的值，Dagum 分布的概率密度函数 (PDF) 可能是在其定义域下界附近有潜在奇点的单调递减形状或者是单峰形状. 参数 b 是“尺度参数”，它决定了 PDF 的整体高度（当 b 向零减小时高度增加）. 和参数值无关的是，Dagum 分布的 PDF 的尾部比较“胖”，意思是说当值较大时 PDF 的衰减是代数的而不是指数的.（这一行为可通过研究分布的 SurvivalFunction 做精确的定量分析.）Dagum 分布有时又被称为 Burr III 分布.
Dagum 分布可以追溯到阿根廷统计及经济学家 Camilo Dagum 在 1970 年代的工作. 在注意到收入的累积分布函数 (CDF) 的收入弹性是递减且有界的函数后，Dagum 着手构建了一个统计分布来对财富分布建模，这个分布结合了帕累托分布正的部分以及对数正态分布（分别是 ParetoDistribution 和 LogNormalDistribution）. 勿庸置疑，Dagum 分布的主要应用是在经济学和精算学中，但最近，该分布被用来对各个领域的许多现象建模，包括环境科学领域的对流层臭氧浓度，以及统计中的寿命数据/生存分析.
RandomVariate 可被用于给出 Dagum 分布的一个或多个机器精度或任意精度（后者可用 WorkingPrecision 选项指定）的伪随机变量. Distributed[x,DagumDistribution[p,a,b]]，更简洁的写法是 xDagumDistribution[p,a,b]，可被用于声明随机变量 x 是 Dagum 分布的. 这样一个声明之后可用在如 Probability、NProbability、Expectation 以及 NExpectation 这样的函数中.
概率密度函数和累积分布函数可用 PDF[DagumDistribution[p,a,b],x] 和 CDF[DagumDistribution[p,a,b],x] 求得. 平均数、中位数、方差、原点矩及中心矩可分别用 Mean、Median、Variance、Moment 和 CentralMoment 计算，虽然因为 Dagum 分布的胖尾部，这些量中有一些可能不存在.
DistributionFitTest 可被用于测试给定的数据集是否与 Dagum 分布一致，EstimatedDistribution 可被用于根据给定数据估算 Dagum 参数化分布，而 FindDistributionParameters 可拟合数据和 Dagum 分布. ProbabilityPlot 可被用于生成给定数据的 CDF 相对于符号 Dagum 分布的 CDF 的图线，而 QuantilePlot 可被用于生成给定数据的分位数相对于符号 Dagum 分布的分位数的图线.
TransformedDistribution 可被用于表示转换的 Dagum 分布，CensoredDistribution 可被用于表示删截后位于上限值和下限值之间的值分布，而 TruncatedDistribution 可被用于表示截断后位于上限值和下限值之间的值分布. CopulaDistribution 可被用于建立包含了 Dagum 分布的高维分布，而 ProductDistribution 可被用于计算包括 Dagum 分布在内的，若干个独立分量的联合分布.
Dagum 分布与许多其它分布有关. 例如，DagumDistribution 是 BetaPrimeDistribution 的特例，因为 BetaPrimeDistribution[p,1,a,b] 的 PDF 恰好等于 DagumDistribution[p,a,b] 的 PDF. DagumDistribution 也推广了更具体的 LogLogisticDistribution，即 DagumDistribution[1,γ,σ] 和 LogLogisticDistribution[λ,σ] 有相同的 PDF 且是结合了 LogNormalDistribution 和 ParetoDistribution 两者的定性特征构造的. DagumDistribution 是 Burr/Singh–Maddala 分布 (SinghMaddalaDistribution) 的逆分布而且还和 BeniniDistribution、GammaDistribution 及 WeibullDistribution 有关.

范例

打开所有单元关闭所有单元

基本范例 (4)

概率密度函数：

Wolfram Language code: Plot[Table[PDF[DagumDistribution[p, 2, 3], x], {p, {1 / 4, 1 / 2, 1}}]//Evaluate, {x, 0, 6}, Filling -> Axis]

Wolfram Language code: Plot[Table[PDF[DagumDistribution[2, a, 3], x], {a, {1 / 2, 1, 2}}]//Evaluate, {x, 0, 6}, Filling -> Axis]

Wolfram Language code: PDF[DagumDistribution[p, a, b], x]

累积分布函数：

Wolfram Language code: Plot[Table[CDF[DagumDistribution[p, 2, 3], x], {p, {1 / 4, 1 / 2, 1}}]//Evaluate, {x, 0, 6}, Filling -> Axis]

Wolfram Language code: Plot[Table[CDF[DagumDistribution[2, a, 3], x], {a, {1 / 2, 1, 2}}]//Evaluate, {x, 0, 6}, Filling -> Axis]

Wolfram Language code: CDF[DagumDistribution[p, a, b], x]

均值和方差：

Wolfram Language code: Mean[DagumDistribution[p, a, b]]

Wolfram Language code: Variance[DagumDistribution[p, a, b]]

中位数：

Wolfram Language code: Median[DagumDistribution[p, a, b]]

范围 (8)

生成一组服从 Dagum 分布的伪随机数样本：

Wolfram Language code: data = RandomVariate[DagumDistribution[2, 1, 1.2], 10 ^ 4];

比较其直方图与概率密度函数：

Wolfram Language code:

Show[
	Histogram[data, {0, 20, 1}, "PDF"], 
	Plot[PDF[TruncatedDistribution[{0, 20}, DagumDistribution[2, 1, 1.2]], x], {x, 0, 20}, PlotStyle -> Thick]]

分布参数估计：

Wolfram Language code: sample = RandomVariate[DagumDistribution[3, 1.5, 2], 10 ^ 3];

从样本数据估计分布参数：

Wolfram Language code: edist = EstimatedDistribution[sample, DagumDistribution[p, a, b]]

比较样本密度直方图和估计分布的概率密度函数：

Wolfram Language code:

Show[Histogram[sample, {0, 20, 1}, "PDF"], Plot[PDF[TruncatedDistribution[{0, 20}, edist], x], {x, 0, 20}, PlotStyle -> Thick]]

偏度取决于形状参数 a 和 p，且当时有定义：

Wolfram Language code:

Plot[Table[Skewness[DagumDistribution[p, a, b]], {a, r = {3.1, 3.3, 3.5, 4, 6}}]//Evaluate, {p, 0.1, 1}, PlotLegends -> (Row[{"a = ", #}]& /@ r)]

Wolfram Language code:

Plot3D[Skewness[DagumDistribution[p, a, b]], {a, 3, 8}, {p, 1, 3}, MeshFunctions -> {#3&}, MeshShading -> ColorData[35, "ColorList"], AxesLabel -> Automatic]

Wolfram Language code: Skewness[DagumDistribution[p, a, b]]//FullSimplify

当时峰度有定义：

Wolfram Language code:

Plot[Table[Kurtosis[DagumDistribution[p, a, b]], {a, r = {4.1, 4.3, 4.5, 5, 6}}]//Evaluate, {p, 0.1, 1}, PlotLegends -> (Row[{"a = ", #}]& /@ r)]

Wolfram Language code:

Plot3D[Kurtosis[DagumDistribution[p, a, b]], {a, 4, 8}, {p, 1, 3}, MeshFunctions -> {#3&}, MeshShading -> ColorData[35, "ColorList"], AxesLabel -> Automatic]

以参数的函数形式表示不同矩的解析式：

Wolfram Language code: FormulaGrid[list_, type_] := Grid[...]

Moment：

Wolfram Language code: FormulaGrid[Table[Moment[DagumDistribution[p, a, b], k], {k, 3}], M]

具有符号式阶数的解析式：

Wolfram Language code: Moment[DagumDistribution[p, a, b], r]

CentralMoment：

Wolfram Language code: FormulaGrid[Table[CentralMoment[DagumDistribution[p, a, b], k]//FullSimplify, {k, 3}], CM]

FactorialMoment：

Wolfram Language code: FormulaGrid[Table[FactorialMoment[DagumDistribution[p, a, b], k]//FullSimplify, {k, 3}], FM]

Cumulant：

Wolfram Language code: FormulaGrid[Table[Cumulant[DagumDistribution[p, a, b], k]//FullSimplify, {k, 3}], C]

风险函数在时为单峰形，其它情况下递减：

Wolfram Language code: Plot[Table[HazardFunction[DagumDistribution[0.5, a, 2], x], {a, {1, 2, 4}}]//Evaluate, {x, 0, 8}, Filling -> Axis]

Wolfram Language code: Plot[Table[HazardFunction[DagumDistribution[p, 3, 2], x], {p, {0.5, 1, 4}}]//Evaluate, {x, 0, 8}, Filling -> Axis]

Wolfram Language code: HazardFunction[DagumDistribution[p, a, b], x]

分位数函数：

Wolfram Language code: Plot[Table[Quantile[DagumDistribution[3.5, a, 2], q], {a, {0.5, 0.75, 1.5}}]//Evaluate, {q, 0, 1}, Filling -> Axis]

Wolfram Language code: Plot[Table[Quantile[DagumDistribution[3.5, 2, b], q], {b, {0.5, 1, 1.5}}]//Evaluate, {q, 0, 1}, Filling -> Axis]

Wolfram Language code: Plot[Table[Quantile[DagumDistribution[p, 2, 3.5], q], {p, {0.5, 1.5, 3}}]//Evaluate, {q, 0, 1}, Filling -> Axis]

Wolfram Language code: Quantile[DagumDistribution[p, a, b], q]

在参数中一致地使用 Quantity 会产生 QuantityDistribution：

Wolfram Language code: salary𝒟 = DagumDistribution[5.76, 2.66, Quantity[23590, "USDollars"]]

求四分位数间距：

Wolfram Language code: InterquartileRange[salary𝒟]

应用 (4)

DagumDistribution 可用于对收入建模：

Wolfram Language code: ExampleData[{"Statistics", "UniversitySalaries"}, "ColumnDescriptions"]

Wolfram Language code:

universityA = Cases[ExampleData[{"Statistics", "UniversitySalaries"}], {dept_, perc_, salary_, campus : "A"} :> {perc, salary}];

把兼职调整为全职，并且选择非零值：

Wolfram Language code: salaries = QuantityArray[Cases[universityA, {p_ ? Positive, s_ ? Positive} :> s / p], "USDollars"];

对数据进行 Dagum 分布拟合：

Wolfram Language code: edist = EstimatedDistribution[salaries, DagumDistribution[p, a, b]]

比较数据直方图和估计分布的概率密度函数：

Wolfram Language code:

Show[Histogram[salaries, {0, 200000, 10000}, "PDF", AxesLabel -> Automatic], Plot[PDF[edist, Quantity[x, "USDollars"]], {x, 0, 200000}, PlotStyle -> Thick]]

求一个大型州立大学的平均收入：

Wolfram Language code: Mean[edist]

求工资至多 $25,000 的概率：

Wolfram Language code: NProbability[x ≤ Quantity[25000, "USDollars"], xedist]

求工资至少 $150,000 的概率：

Wolfram Language code: NProbability[x ≥ Quantity[150000, "USDollars"], xedist]

求工资的中位数：

Wolfram Language code: Median[edist]

模拟一所这样的大学内100个随机选择的员工的工资：

Wolfram Language code:

ListPlot[{RandomVariate[edist, 100], {{0, Median[edist]}, {100, Median[edist]}}}, Filling -> {1 -> Axis}, Joined -> {False, True}, AxesOrigin -> {0, 20000}, AxesLabel -> Automatic]

DagumDistribution 可用于对州人均收入建模：

Wolfram Language code: data = ExampleData[{"Statistics", "USStateIncome"}]

添加货币单位：

Wolfram Language code:

incomes = MapAt[Quantity[#, "USDollars"]&, data, {All, 2}];
incomeValues = Part[incomes, All, 2];

对数据进行 Dagum 分布拟合：

Wolfram Language code: edist = EstimatedDistribution[incomeValues, DagumDistribution[p, a, b], {{p, 2}, {a, 10}, {b, Median[incomeValues]}}]

比较数据直方图和估计分布的概率密度函数：

Wolfram Language code:

Show[Histogram[incomeValues, 15, "PDF", AxesLabel -> Automatic], Plot[PDF[edist, Quantity[x, "USDollars"]], {x, 20000, 50000}, PlotStyle -> Thick]]

求人均收入的均值：

Wolfram Language code: meanIncome = Mean[edist]

求收入与均值最接近的州：

Wolfram Language code: Cases[incomes, {s_, inc_} /; Abs[inc - meanIncome] < Quantity[200, "USDollars"]]

求人均收入的中位数：

Wolfram Language code: medianIncome = Median[edist]

求收入与中位数最接近的州：

Wolfram Language code: Cases[incomes, {s_, inc_} /; Abs[inc - medianIncome] < Quantity[300, "USDollars"]]

求对数似然值：

Wolfram Language code: LogLikelihood[edist, incomeValues]

DagumDistribution 可用于对尺寸大小建模；考虑紫岩蟹的厚度（以毫米为单位）：

Wolfram Language code: ExampleData[{"Statistics", "CrabMeasures"}, "ColumnDescriptions"]

Wolfram Language code: crabDepth = Quantity[ExampleData[{"Statistics", "CrabMeasures"}][[All, 8]], "Millimeters"];

对数据进行 Dagum 分布拟合：

Wolfram Language code: edist = EstimatedDistribution[crabDepth, DagumDistribution[p, a, b]]

比较数据直方图和估计分布的概率密度函数：

Wolfram Language code:

Show[Histogram[crabDepth, 20, "PDF", AxesLabel -> Automatic], Plot[PDF[edist, Quantity[x, "Millimeters"]], {x, 0, 30}, PlotStyle -> Thick]]

求紫岩蟹的平均厚度：

Wolfram Language code: Mean[edist]

求一只紫岩蟹比15毫米更厚的概率：

Wolfram Language code: Probability[x > Quantity[15, "Millimeters"], xedist]

模拟30只紫岩蟹的厚度：

Wolfram Language code:

ListPlot[{RandomVariate[edist, 30], {{0, Mean[edist]}, {30, Mean[edist]}}}, Joined -> {False, True}, Filling -> Axis, AxesLabel -> Automatic]

DagumDistribution 可用于对等待时间建模：

Wolfram Language code: ExampleData[{"Statistics", "EarthquakeWaitingTimes"}, "LongDescription"]

Wolfram Language code: earthquakesTimes = Quantity[ExampleData[{"Statistics", "EarthquakeWaitingTimes"}], "Days"];

对数据进行 Dagum 分布拟合：

Wolfram Language code: edist = EstimatedDistribution[earthquakesTimes, DagumDistribution[p, a, b]]

比较数据直方图和估计分布的概率密度函数：

Wolfram Language code:

Show[Histogram[earthquakesTimes, 20, "PDF", AxesLabel -> Automatic], Plot[PDF[edist, Quantity[x, "Days"]], {x, 0, 2000}, PlotStyle -> Thick]]

求大规模地震之间的平均天数：

Wolfram Language code: Mean[edist]

求两次大规模地震之间至少有200天的概率：

Wolfram Language code: Probability[x ≥ Quantity[200, "Days"], xedist]

属性和关系 (7)

当使用正因子进行成比例缩放时，新生成的分布仍然是 Dagum 分布：

Wolfram Language code: TransformedDistribution[k * u, uDagumDistribution[p, a, b]]

当使用 Max 时，所得分布仍然是 Dagum 分布：

Wolfram Language code: OrderDistribution[{DagumDistribution[p, a, b], n}, n]

Wolfram Language code:

TransformedDistribution[Max[x, y], {xDagumDistribution[Subscript[p, 1], a, b], yDagumDistribution[Subscript[p, 2], a, b]}]

Dagum 分布在时，呈单峰形，其余情况下无峰：

Wolfram Language code:

Plot[Table[PDF[DagumDistribution[p, .75, 2], x], {p, 0.5, 4}]//Evaluate, {x, 0, 10}, PlotLegends -> (Row[{"p = ", #}]& /@ Range[.5, 4])]

与其他分布的关系：

DagumDistribution 是 BetaPrimeDistribution 的一个特例：

Wolfram Language code: PDF[BetaPrimeDistribution[p, 1, a, b], x]//FunctionExpand

Wolfram Language code: PDF[DagumDistribution[p, a, b], x]

Wolfram Language code: % - %%//FullSimplify[#, a > 0 && b > 0]&

DagumDistribution 是 SinghMaddalaDistribution 的逆：

Wolfram Language code: TransformedDistribution[1 / x, xSinghMaddalaDistribution[p, a, 1 / b]]

LogLogisticDistribution 是 DagumDistribution 的一个特例：

Wolfram Language code: PDF[DagumDistribution[1, γ, σ], x]

Wolfram Language code: PDF[LogLogisticDistribution[γ, σ], x]

Wolfram Language code: % - %%

巧妙范例 (1)

绘制不同 p 值的概率密度函数，同时显示 CDF 等高线：

Wolfram Language code:

dist = DagumDistribution[p, 2, 3];cdf = Function[{x, p}, Evaluate[CDF[dist, x]]];
ql = {0.025, 0.10, 0.25, 0.5, 0.75, 0.90, 0.975};
cl = Table[ColorData["Rainbow"][q], {q, Join[{0.0}, ql]}];

Wolfram Language code:

Legended[Plot3D[PDF[dist, x], {x, 0, 30}, {p, 1, 7}, PlotTheme -> "Marketing", MeshFunctions -> {cdf}, Mesh -> {ql}, MeshStyle -> GrayLevel[0.8], PlotPoints -> 100, PlotRange -> All, MeshShading -> cl, AxesLabel -> Automatic, BaseStyle -> Opacity[0.9], ImageSize -> 400], BarLegend["Rainbow", ql, LegendLabel -> "prob"]]

Top

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

DagumDistribution

更多信息

背景

范例

基本范例 (4)

范围 (8)

应用 (4)

属性和关系 (7)

巧妙范例 (1)

文本

CMS

APA

BibTeX

BibLaTeX

DagumDistribution

更多信息

背景

范例

基本范例 (4)

范围 (8)

应用 (4)

属性和关系 (7)

巧妙范例 (1)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX