WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DavisDistribution[b,n,μ]

尺度母数 b，形状母数 n，位置母数 μ のDavis分布を表す．

詳細
Details and Options Details and Options
予備知識
例題  
例  
スコープ  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

DavisDistribution

DavisDistribution[b,n,μ]

尺度母数 b，形状母数 n，位置母数 μ のDavis分布を表す．

詳細

  • Davis分布における値 の確率密度は のときに比例する．
  • DavisDistributionでは，b は任意の正の実数，μ は任意の非負の実数でよく，である．
  • DavisDistributionでは，μ と b は任意の単位次元の任意の数量でよく，n は無次元量でよい． »
  • DavisDistributionは，Mean，CDF，RandomVariate等の関数とともに使うことができる．

予備知識

  • DavisDistribution[b,n,μ]は，区間上で定義され，値 b，n，μ でパラメータ化された連続統計分布を表す．母数 b（「尺度母数」と呼ばれる正の実数）および n（「形状母数」と呼ばれる の正の実数）は，Davis分布の確率密度関数(PDF)の全体的な高さと傾斜を決定する．「位置母数」と呼ばれる非負の実数 μ はPDFの水平位置を決定する．Davis分布のPDFは単峰で，PDFが大きい値の について指数的ではなく代数的に減少するという意味で「太い」裾部を持つ．
  • Davis分布は，米国の数学者であり統計学者でもあるHarold Davisによって考案された．Davisは1940年代に収入の大きさと分布をモデル化する代替案としてこれを提案した．Davis分布はまた，統計物理学からのプランクの法則の一般化でもある．
  • RandomVariateを使って，Davis分布から，1つあるいは複数の機械精度あるいは任意精度（後者はWorkingPrecisionオプションを介す）の擬似乱数変量を得ることができる．Distributed[x,DavisDistribution[b,n,μ]]（より簡略すると xDavisDistribution[b,n,μ]）を使って，確率変数 x が，Davis分布に従って分布していると宣言することができる．このような宣言は，Probability，NProbability，Expectation，NExpectation等の関数で使うことができる．
  • 確率密度関数および累積分布関数は，PDF[DavisDistribution[b,n,μ],x]およびCDF[DavisDistribution[b,n,μ],x]を使って得られることがある．平均，中央値，分散，原点の周りのモーメント，中心モーメントは，それぞれMean，Median，Variance，Moment，CentralMomentを使って計算することができる．
  • DistributionFitTestを使って，与えられたデータ集合がDavis分布と一致するかどうかを検定することが，EstimatedDistributionを使って与えられたデータからパラメトリックDavis分布を推定することが，FindDistributionParametersを使ってデータをDavis分布にフィットすることができる．ProbabilityPlotを使って記号Davis分布のCDFに対する与えられたデータのCDFのプロットを生成することが，QuantilePlotを使って記号Davis分布の変位値に対する与えられたデータの変位値のプロットを生成することができる．
  • TransformedDistributionを使って変換されたDavis分布を表すことが，CensoredDistributionを使って上限値と下限値の間で切り取られた値の分布を表すことが，TruncatedDistributionを使って上限値と下限値の間で切断された値の分布を表すことができる．CopulaDistributionを使ってDavis分布を含む高次元分布を構築することが，ProductDistributionを使ってDavis分布含む独立成分分布の結合分布を計算することができる．
  • DavisDistributionは他の多くの分布と関連している．例えば，DavisDistributionの長期崩壊は，ParetoDistributionのそれに漸近的であり，裾部が太い点が等しい．品質面では，DavisDistributionは，BetaPrimeDistribution，DagumDistribution，LogLogisticDistribution，BeniniDistributionを含む，収入をモデル化する他の分布と関連している．DavisDistributionは，BenktanderGibratDistributionおよびBenktanderWeibullDistributionとも関連している．

例題

すべて開く すべて閉じる

例  (3)

確率密度関数：

Wolfram Language code: Plot[Table[PDF[DavisDistribution[b, 2, 1], x], {b, {2, 3, 4}}]//Evaluate, {x, 1.1, 6}, Filling -> Axis]
Wolfram Language code: Plot[Table[PDF[DavisDistribution[4, n, 1], x], {n, {2, 2.5, 3}}]//Evaluate, {x, 1.1, 6}, Filling -> Axis]
Wolfram Language code: PDF[DavisDistribution[b, n, μ], x]

累積分布関数：

Wolfram Language code: Plot[Table[CDF[DavisDistribution[b, 2, 1], x], {b, {2, 3, 4}}]//Evaluate, {x, 1.1, 6}, Filling -> Axis]
Wolfram Language code: Plot[Table[CDF[DavisDistribution[4, n, 1], x], {n, {2, 2.5, 3}}]//Evaluate, {x, 1.1, 6}, Filling -> Axis]

平均と分散：

Wolfram Language code: Mean[DavisDistribution[b, n, μ]]
Wolfram Language code: Variance[DavisDistribution[b, n, μ]]

スコープ  (8)

Davis分布から擬似乱数のサンプルを生成する：

Wolfram Language code: data = RandomVariate[dist = DavisDistribution[13.2, 12, 0], 10 ^ 5];

そのヒストグラムを確率密度関数と比較する：

Wolfram Language code: Show[ Histogram[data, {0, 3, .15}, "PDF"], Plot[PDF[TruncatedDistribution[{0, 3}, dist], x], {x, Min[data], Max[data]}, PlotStyle -> Thick, PlotRange -> All]]

分布母数推定：

Wolfram Language code: sample = RandomVariate[DavisDistribution[13, 10, 1], 10 ^ 3];

分布母数をサンプルデータから推定する：

Wolfram Language code: edist = EstimatedDistribution[sample, DavisDistribution[b, n, μ]]

サンプルの密度ヒストグラムを推定分布の確率密度分布と比較する：

Wolfram Language code: Show[Histogram[sample, 20, "PDF"], Plot[PDF[edist, x], {x, Min[sample], Max[sample]}, PlotStyle -> Thick]]

歪度は形状母数 n のみに依存する：

Wolfram Language code: Plot[Skewness[DavisDistribution[b, n, μ]], {n, 4, 10}]
Wolfram Language code: Skewness[DavisDistribution[b, n, μ]]

尖度は形状母数 n のみに依存する：

Wolfram Language code: Plot[Kurtosis[DavisDistribution[b, n, μ]], {n, 5, 10}]
Wolfram Language code: Kurtosis[DavisDistribution[b, n, μ]]

母数の関数としての閉じた形の種々のモーメント：

Wolfram Language code: FormulaGrid[list_, type_] := Grid[...]

Moment：

Wolfram Language code: FormulaGrid[Table[Moment[DavisDistribution[b, n, μ], r]//Together, {r, 3}], M]

CentralMoment：

Wolfram Language code: FormulaGrid[Table[CentralMoment[DavisDistribution[b, n, μ], r]//FullSimplify, {r, 3}], CM]

FactorialMoment：

Wolfram Language code: FormulaGrid[Table[FactorialMoment[DavisDistribution[b, n, μ], r]//FullSimplify, {r, 3}], FM]

Cumulant：

Wolfram Language code: FormulaGrid[Table[Cumulant[DavisDistribution[b, n, μ], r]//FullSimplify, {r, 3}], C]

ハザード関数：

Wolfram Language code: Plot[Table[HazardFunction[DavisDistribution[b, 2, 0], x], {b, {1, 2, 3}}]//Evaluate, {x, 0.1, 4}, Filling -> Axis]
Wolfram Language code: Plot[Table[HazardFunction[DavisDistribution[2, n, 0], x], {n, {2, 3, 4}}]//Evaluate, {x, 0.1, 4}, Filling -> Axis]

分位関数：

Wolfram Language code: Plot[Table[Quantile[DavisDistribution[b, 2, 0], q], {b, {1, 2, 3}}]//Evaluate, {q, 0, 1}, Filling -> Axis]
Wolfram Language code: Plot[Table[Quantile[DavisDistribution[2, n, 0], q], {n, {2, 3, 4}}]//Evaluate, {q, 0, 1}, Filling -> Axis]

母数でQuantityを一貫して使うとQuantityDistributionが与えられる：

Wolfram Language code: salary𝒟 = DavisDistribution[Quantity[196500, "USDollars"], 4.54, Quantity[3600., "USDollars"]]

給与の中央値を求める：

Wolfram Language code: Median[salary𝒟]

アプリケーション  (2)

DavisDistributionは収入のモデル化に使用できる：

Wolfram Language code: ExampleData[{"Statistics", "UniversitySalaries"}, "ColumnDescriptions"]
Wolfram Language code: universityA = Cases[ExampleData[{"Statistics", "UniversitySalaries"}], {dept_, perc_, salary_, campus : "A"} :> {perc, salary}];

パートタイムをフルタイムに調整して非零の値を選ぶ：

Wolfram Language code: salaries = Quantity[Cases[universityA, {p_ ? Positive, s_ ? Positive} :> s / p], "USDollars"];

Davis分布をデータにフィットする：

Wolfram Language code: edist = EstimatedDistribution[salaries, DavisDistribution[b, n, μ], {{b, QuartileDeviation[salaries]}, {n, 5}, {μ, Min[salaries] / 2}}]

データのヒストグラムを推定分布の確率密度関数と比較する：

Wolfram Language code: Show[Histogram[salaries, {10000, 200000, 10000}, "PDF", AxesLabel -> Automatic], Plot[PDF[edist, Quantity[x, "USDollars"]], {x, 10000, 200000}, PlotStyle -> Thick]]

大規模な州立大学の平均給与を求める：

Wolfram Language code: Mean[edist]

給与が最高で3万ドルになる確率を求める：

Wolfram Language code: NProbability[x ≤ Quantity[30000, "USDollars"], xedist]

給与が最低でも15万ドルになる確率を求める：

Wolfram Language code: NProbability[x ≥ Quantity[150000, "USDollars"], xedist]

給与の中央値を求める：

Wolfram Language code: Median[edist]

上記のような大学の無作為に選んだ100名の被雇用者の給与のシミュレーションを行う：

Wolfram Language code: ListPlot[{RandomVariate[edist, 100], {{0, Median[edist]}, {100, Median[edist]}}}, Filling -> {1 -> Axis}, Joined -> {False, True}, AxesOrigin -> {0, 20000}, AxesLabel -> Automatic]

DavisDistributionを使って各州の州民1人あたりの収入をモデル化することができる：

Wolfram Language code: data = ExampleData[{"Statistics", "USStateIncome"}]

通貨単位を加える：

Wolfram Language code: incomes = MapAt[Quantity[#, "USDollars"]&, data, {All, 2}]; incomeValues = Part[incomes, All, 2];

Davis分布をデータにフィットさせる：

Wolfram Language code: edist = EstimatedDistribution[incomeValues, DavisDistribution[b, n, μ], ParameterEstimator -> {"MaximumLikelihood", Method -> "FindMaximum"}]

データのヒストグラムを推定分布の確率密度関数と比較する：

Wolfram Language code: Show[Histogram[incomeValues, 15, "PDF", AxesLabel -> Automatic], Plot[PDF[edist, Quantity[x, "USDollars"]], {x, 20000, 48000}, PlotStyle -> Thick]]

州民1人あたりの収入の平均を求める：

Wolfram Language code: meanIncome = Mean[edist]

収入が平均に近い州を求める：

Wolfram Language code: Cases[incomes, {s_, inc_} /; Abs[inc - meanIncome] < Quantity[400, "USDollars"]]

1人あたりの収入の中央値を求める：

Wolfram Language code: medianIncome = Median[edist]

収入が中央値に近い州を求める：

Wolfram Language code: Cases[incomes, {s_, inc_} /; Abs[inc - medianIncome] < Quantity[400, "USDollars"]]

対数尤度値を求める：

Wolfram Language code: LogLikelihood[edist, incomeValues]

特性と関係  (1)

Davis分布は平行移動と正の因子によるスケーリングの下では閉じている：

Wolfram Language code: TransformedDistribution[k u + m, uDavisDistribution[b, n, μ]]

おもしろい例題  (1)

CDFの等高線を持つ b のさまざまな値についてのPDF：

Wolfram Language code: dist = DavisDistribution[b, 2, 1]; cdf = Function[{x, b}, Evaluate[CDF[dist, x]]]; ql = {0.025, 0.10, 0.25, 0.5, 0.75, 0.90, 0.975}; cl = Table[ColorData["Rainbow"][q], {q, Join[{0.0}, ql]}];
Wolfram Language code: Legended[Plot3D[PDF[dist, x], {x, 1.1, 60}, {b, 2, 4}, PlotTheme -> "Marketing", MeshFunctions -> {cdf}, Mesh -> {ql}, MeshStyle -> GrayLevel[0.8], MeshShading -> cl, AxesLabel -> Automatic, BaseStyle -> Opacity[0.9], ImageSize -> 400, PlotRange -> All, PlotPoints -> 100], BarLegend["Rainbow", ql, LegendLabel -> "prob"]]
Wolfram Research (2010), DavisDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/DavisDistribution.html （2016年に更新）.

テキスト

Wolfram Research (2010), DavisDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/DavisDistribution.html （2016年に更新）.

CMS

Wolfram Language. 2010. "DavisDistribution." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2016. https://reference.wolfram.com/language/ref/DavisDistribution.html.

APA

Wolfram Language. (2010). DavisDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DavisDistribution.html

BibTeX

@misc{reference.wolfram_2026_davisdistribution, author="Wolfram Research", title="{DavisDistribution}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/DavisDistribution.html}", note=[Accessed: 15-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_davisdistribution, organization={Wolfram Research}, title={DavisDistribution}, year={2016}, url={https://reference.wolfram.com/language/ref/DavisDistribution.html}, note=[Accessed: 15-September-2026]}