WOLFRAM

Wolfram 语言与系统参考资料中心

DavisDistribution[b,n,μ]

表示尺度参数为 b、形状参数为 n 以及定位参数为 μ 的戴维斯分布.

更多信息
Details and Options Details and Options
背景
范例  
基本范例  
范围  
应用  
属性和关系  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

DavisDistribution

DavisDistribution[b,n,μ]

表示尺度参数为 b、形状参数为 n 以及定位参数为 μ 的戴维斯分布.

更多信息

背景

范例

打开所有单元 关闭所有单元

基本范例  (3)

概率密度函数：

Wolfram Language code: Plot[Table[PDF[DavisDistribution[b, 2, 1], x], {b, {2, 3, 4}}]//Evaluate, {x, 1.1, 6}, Filling -> Axis]
Wolfram Language code: Plot[Table[PDF[DavisDistribution[4, n, 1], x], {n, {2, 2.5, 3}}]//Evaluate, {x, 1.1, 6}, Filling -> Axis]
Wolfram Language code: PDF[DavisDistribution[b, n, μ], x]

累积分布函数：

Wolfram Language code: Plot[Table[CDF[DavisDistribution[b, 2, 1], x], {b, {2, 3, 4}}]//Evaluate, {x, 1.1, 6}, Filling -> Axis]
Wolfram Language code: Plot[Table[CDF[DavisDistribution[4, n, 1], x], {n, {2, 2.5, 3}}]//Evaluate, {x, 1.1, 6}, Filling -> Axis]

均值和方差：

Wolfram Language code: Mean[DavisDistribution[b, n, μ]]
Wolfram Language code: Variance[DavisDistribution[b, n, μ]]

范围  (8)

生成一组服从戴维斯分布的伪随机数样本：

Wolfram Language code: data = RandomVariate[dist = DavisDistribution[13.2, 12, 0], 10 ^ 5];

比较其直方图与概率密度函数：

Wolfram Language code: Show[ Histogram[data, {0, 3, .15}, "PDF"], Plot[PDF[TruncatedDistribution[{0, 3}, dist], x], {x, Min[data], Max[data]}, PlotStyle -> Thick, PlotRange -> All]]

分布参数估计：

Wolfram Language code: sample = RandomVariate[DavisDistribution[13, 10, 1], 10 ^ 3];

从样本数据估计分布参数：

Wolfram Language code: edist = EstimatedDistribution[sample, DavisDistribution[b, n, μ]]

比较样本的密度直方图和估计分布的概率密度函数：

Wolfram Language code: Show[Histogram[sample, 20, "PDF"], Plot[PDF[edist, x], {x, Min[sample], Max[sample]}, PlotStyle -> Thick]]

偏度只取决于形状参数 n：

Wolfram Language code: Plot[Skewness[DavisDistribution[b, n, μ]], {n, 4, 10}]
Wolfram Language code: Skewness[DavisDistribution[b, n, μ]]

峰度只取决于形状参数 n：

Wolfram Language code: Plot[Kurtosis[DavisDistribution[b, n, μ]], {n, 5, 10}]
Wolfram Language code: Kurtosis[DavisDistribution[b, n, μ]]

以参数的函数形式表示不同矩量的解析式：

Wolfram Language code: FormulaGrid[list_, type_] := Grid[...]

Moment：

Wolfram Language code: FormulaGrid[Table[Moment[DavisDistribution[b, n, μ], r]//Together, {r, 3}], M]

CentralMoment：

Wolfram Language code: FormulaGrid[Table[CentralMoment[DavisDistribution[b, n, μ], r]//FullSimplify, {r, 3}], CM]

FactorialMoment：

Wolfram Language code: FormulaGrid[Table[FactorialMoment[DavisDistribution[b, n, μ], r]//FullSimplify, {r, 3}], FM]

Cumulant：

Wolfram Language code: FormulaGrid[Table[Cumulant[DavisDistribution[b, n, μ], r]//FullSimplify, {r, 3}], C]

风险函数：

Wolfram Language code: Plot[Table[HazardFunction[DavisDistribution[b, 2, 0], x], {b, {1, 2, 3}}]//Evaluate, {x, 0.1, 4}, Filling -> Axis]
Wolfram Language code: Plot[Table[HazardFunction[DavisDistribution[2, n, 0], x], {n, {2, 3, 4}}]//Evaluate, {x, 0.1, 4}, Filling -> Axis]

分位数函数：

Wolfram Language code: Plot[Table[Quantile[DavisDistribution[b, 2, 0], q], {b, {1, 2, 3}}]//Evaluate, {q, 0, 1}, Filling -> Axis]
Wolfram Language code: Plot[Table[Quantile[DavisDistribution[2, n, 0], q], {n, {2, 3, 4}}]//Evaluate, {q, 0, 1}, Filling -> Axis]

在参数中一致地使用 Quantity 可获得 QuantityDistribution：

Wolfram Language code: salary𝒟 = DavisDistribution[Quantity[196500, "USDollars"], 4.54, Quantity[3600., "USDollars"]]

找出中位数工资：

Wolfram Language code: Median[salary𝒟]

应用  (2)

DavisDistribution 可以用于对收入建模：

Wolfram Language code: ExampleData[{"Statistics", "UniversitySalaries"}, "ColumnDescriptions"]
Wolfram Language code: universityA = Cases[ExampleData[{"Statistics", "UniversitySalaries"}], {dept_, perc_, salary_, campus : "A"} :> {perc, salary}];

把兼职调整为全职，并且选择非零值：

Wolfram Language code: salaries = Quantity[Cases[universityA, {p_ ? Positive, s_ ? Positive} :> s / p], "USDollars"];

对数据进行戴维斯分布拟合：

Wolfram Language code: edist = EstimatedDistribution[salaries, DavisDistribution[b, n, μ], {{b, QuartileDeviation[salaries]}, {n, 5}, {μ, Min[salaries] / 2}}]

比较数据直方图和估计分布的概率密度函数：

Wolfram Language code: Show[Histogram[salaries, {10000, 200000, 10000}, "PDF", AxesLabel -> Automatic], Plot[PDF[edist, Quantity[x, "USDollars"]], {x, 10000, 200000}, PlotStyle -> Thick]]

求一所大型州立大学的平均收入：

Wolfram Language code: Mean[edist]

求一份工资至多为30,000美元的概率：

Wolfram Language code: NProbability[x ≤ Quantity[30000, "USDollars"], xedist]

求一份工资至少150,000美元的概率：

Wolfram Language code: NProbability[x ≥ Quantity[150000, "USDollars"], xedist]

求工资的中位数：

Wolfram Language code: Median[edist]

模拟这样一所大学内100个随机选择的员工的收入：

Wolfram Language code: ListPlot[{RandomVariate[edist, 100], {{0, Median[edist]}, {100, Median[edist]}}}, Filling -> {1 -> Axis}, Joined -> {False, True}, AxesOrigin -> {0, 20000}, AxesLabel -> Automatic]

DavisDistribution 可用于对州人均收入建模：

Wolfram Language code: data = ExampleData[{"Statistics", "USStateIncome"}]

添加货币单位：

Wolfram Language code: incomes = MapAt[Quantity[#, "USDollars"]&, data, {All, 2}]; incomeValues = Part[incomes, All, 2];

对数据进行戴维斯分布拟合：

Wolfram Language code: edist = EstimatedDistribution[incomeValues, DavisDistribution[b, n, μ], ParameterEstimator -> {"MaximumLikelihood", Method -> "FindMaximum"}]

比较数据直方图和估计分布的概率密度函数：

Wolfram Language code: Show[Histogram[incomeValues, 15, "PDF", AxesLabel -> Automatic], Plot[PDF[edist, Quantity[x, "USDollars"]], {x, 20000, 48000}, PlotStyle -> Thick]]

求平均人均收入：

Wolfram Language code: meanIncome = Mean[edist]

求收入与均值最接近的州：

Wolfram Language code: Cases[incomes, {s_, inc_} /; Abs[inc - meanIncome] < Quantity[400, "USDollars"]]

求人均收入的中位数：

Wolfram Language code: medianIncome = Median[edist]

求收入与中位数最接近的州：

Wolfram Language code: Cases[incomes, {s_, inc_} /; Abs[inc - medianIncome] < Quantity[400, "USDollars"]]

求对数似然值：

Wolfram Language code: LogLikelihood[edist, incomeValues]

属性和关系  (1)

当平移并且使用一个正因子为比例进行缩放时，新生成的分布仍然是戴维斯分布：

Wolfram Language code: TransformedDistribution[k u + m, uDavisDistribution[b, n, μ]]

巧妙范例  (1)

取不同 b 值时的概率密度函数与累积分布函数等高图：

Wolfram Language code: dist = DavisDistribution[b, 2, 1]; cdf = Function[{x, b}, Evaluate[CDF[dist, x]]]; ql = {0.025, 0.10, 0.25, 0.5, 0.75, 0.90, 0.975}; cl = Table[ColorData["Rainbow"][q], {q, Join[{0.0}, ql]}];
Wolfram Language code: Legended[Plot3D[PDF[dist, x], {x, 1.1, 60}, {b, 2, 4}, PlotTheme -> "Marketing", MeshFunctions -> {cdf}, Mesh -> {ql}, MeshStyle -> GrayLevel[0.8], MeshShading -> cl, AxesLabel -> Automatic, BaseStyle -> Opacity[0.9], ImageSize -> 400, PlotRange -> All, PlotPoints -> 100], BarLegend["Rainbow", ql, LegendLabel -> "prob"]]
Wolfram Research (2010)，DavisDistribution，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DavisDistribution.html （更新于 2016 年）.

文本

Wolfram Research (2010)，DavisDistribution，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DavisDistribution.html （更新于 2016 年）.

CMS

Wolfram 语言. 2010. "DavisDistribution." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2016. https://reference.wolfram.com/language/ref/DavisDistribution.html.

APA

Wolfram 语言. (2010). DavisDistribution. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/DavisDistribution.html 年

BibTeX

@misc{reference.wolfram_2026_davisdistribution, author="Wolfram Research", title="{DavisDistribution}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/DavisDistribution.html}", note=[Accessed: 11-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_davisdistribution, organization={Wolfram Research}, title={DavisDistribution}, year={2016}, url={https://reference.wolfram.com/language/ref/DavisDistribution.html}, note=[Accessed: 11-September-2026]}