Det

Det[m]

正方行列 m の行列式を返す．

詳細とオプション

Det[m,Modulus->n]は，n を法として行列式を計算する．

例題

すべて開くすべて閉じる

例 (2)

記号行列の行列式を求める：

Wolfram Language code:

Det[(⁠|       |       |
| :---- | :---- |
| a1, 1 | a1, 2 |
| a2, 1 | a2, 2 |⁠)]

厳密行列の行列式：

Wolfram Language code: Det[{{1, 2, 3}, {4, 5, 6}, {7, 8, 9}}]

スコープ (13)

基本的な用法 (8)

MachinePrecision行列の行列式を求める：

Wolfram Language code: Det[{{1.7, 7.1, -2.7}, {2.2, 8.7, 3.2}, {3.2, -9.2, 1.2}}]

複素行列の行列式：

Wolfram Language code: Det[{{1. + I, 2, 3 - 2 I}, {0, 4 π, 5I}, {3, 0, 6}}]

厳密行列の行列式：

Wolfram Language code: Det[{{1, 2, 4}, {5, 4, 5}, {9, 2, 7}}]

任意精度行列の行列式：

Wolfram Language code: Det[RandomReal[2, {3, 3}, WorkingPrecision -> 20]]

記号行列の行列式：

Wolfram Language code: Det[{{a, b, c}, {d, e, f}, {g, h, i}}]

大きい数値行列の行列式は効率的に計算される：

Wolfram Language code: mat = BlockRandom[RandomReal[3, {1500, 1500}], RandomSeeding -> 1234];

Wolfram Language code: Det[mat]//Timing

結果は機械精度ではないかもしれないので注意のこと：

Wolfram Language code: Divide[Abs[Last[%]], $MaxMachineNumber]

有限体の元を含む行列の行列式：

Wolfram Language code:

ℱ = FiniteField[17, 3];
Det[{{ℱ[12], ℱ[23], ℱ[34]}, {ℱ[45], ℱ[56], ℱ[67]}, {ℱ[78], ℱ[89], ℱ[90]}}]

CenteredInterval行列の行列式：

Wolfram Language code: (m = Map[CenteredInterval, RandomReal[{-10, 10}, {3, 3}, WorkingPrecision -> 10], {2}])//MatrixForm

Wolfram Language code: mdet = Det[m]

m のランダムな代表 mrep を求める：

Wolfram Language code:

ranrep[e_CenteredInterval] := e["Center"] + RandomInteger[{-1000, 1000}] / 1000 e["Radius"]
(mrep = Map[ranrep, m, {2}])//MatrixForm

mdet が mrep の行列式を含むことを確認する：

Wolfram Language code: IntervalMemberQ[mdet, Det[mrep]]

特殊行列 (5)

疎な行列の行列式：

Wolfram Language code: SparseArray[{{1, 3} -> 2, {2, 2} -> 3, {3, 1} -> 1, {4, 2} -> 5}, {4, 4}]

Wolfram Language code: Det[%]

Wolfram Language code: SparseArray[{{x_, y_} /; Abs[x - y] < 3 -> 1}, {10, 10}]

Wolfram Language code: Det[%]

構造化行列の行列式：

Wolfram Language code: SymmetrizedArray[{{1, 1} -> 2, {1, 2} -> 1}, {2, 2}, Symmetric[All]]

Wolfram Language code: Det[%]

Wolfram Language code: QuantityArray[{{1, 2}, {3, 4}}, {"Meters", "Seconds"}]

Wolfram Language code: Det[%]

IdentityMatrixは常に単位行列式を持つ：

Wolfram Language code: Det[IdentityMatrix[22]]

HilbertMatrixの行列式：

Wolfram Language code: HilbertMatrix[9]//Det

次数の一変量多項式の行列の行列式を計算する：

Wolfram Language code:

rpoly[n_] := RandomInteger[{-2 ^ 10, 2 ^ 10}, {n + 1}].x ^ Range[0, n]
SeedRandom[1234];
m = Table[rpoly[100], {10}, {10}];

Wolfram Language code: Det[m]//Short//AbsoluteTiming

オプション (1)

Modulus (1)

47を法とする演算で行列式を計算する：

Wolfram Language code: m = RandomInteger[46, {100, 100}];

Wolfram Language code: Det[m, Modulus -> 47]//AbsoluteTiming

これは，Mod[Det[m],47]を計算するよりも速い：

Wolfram Language code: Mod[Det[m], 47]//AbsoluteTiming

アプリケーション (19)

面積と体積 (6)

Detを使ってとにまたがる平行四辺形の面積を求める：

Wolfram Language code:

v = {1, 4};
w = {-5, 2};

頂点の一つが原点である平行四辺形を可視化する：

Wolfram Language code:

p = Parallelogram[{0, 0}, {v, w}];
Graphics[p, Axes -> True]

面積は行列式の絶対値で与えられる：

Wolfram Language code: Abs[Det[{v, w}]]

Areaが与える結果と比較する：

Wolfram Language code: Area[p]

Detを使って，，にまたがる平行六面体の体積を求める：

Wolfram Language code: {Subscript[v, 1], Subscript[v, 2], Subscript[v, 3]} = {{1, 4, 3}, {-2, -5, 2}, {-1, 2, -2}};

頂点の一つが原点である平行六面体を可視化する：

Wolfram Language code:

p = Parallelepiped[{0, 0, 0}, {Subscript[v, 1], Subscript[v, 2], Subscript[v, 3]}];
Graphics3D[p, Axes -> True]

体積は行列式の絶対値で与えられる：

Wolfram Language code: Abs[Det[{Subscript[v, 1], Subscript[v, 2], Subscript[v, 3]}]]

Volumeを使った直接計算と比較する：

Wolfram Language code: Volume[p]

Detを使って以下のベクトルにまたがる超平行六面体の超体積を求める：

Wolfram Language code: {v1, v2, v3, v4} = {{6, -6, -1, 6}, {10, -1, 0, -7}, {3, -2, -9, -3}, {4, 5, 6, -3}}

超体積は行列式の絶対値で与えられる：

Wolfram Language code: Abs[Det[{v1, v2, v3, v4}]]

RegionMeasureが与える結果と比較する：

Wolfram Language code: RegionMeasure[Parallelepiped[{0, 0, 0, 0}, {v1, v2, v3, v4}]]

行列式自体は負なので，は右手系ではない：

Wolfram Language code: Det[{v1, v2, v3, v4}]

単に任意の2つのベクトル（例えば真ん中の2つ）の順序を変えるだけで右手系の集合が与えられる：

Wolfram Language code: Det[{v1, v3, v2, v4}]

行列に関連付けられた線形変換の下で単位円板の画像の面積を求める：

Wolfram Language code:

m = {{7, -3}, {5, 7}, {-10, 4}};
m//MatrixForm

画像の面積はで与えられる：

Wolfram Language code: πSqrt[Det[Transpose[m].m]]

直接計算と比較する：

Wolfram Language code:

f𝔻 = ParametricRegion[ {m.{x, y}, {x, y}∈Disk[]}, {x, y}];
Area[f𝔻]

画像を可視化する：

Wolfram Language code: Region[f𝔻, PlotTheme -> "Scientific"]

デカルト座標と球座標間の変数変換公式中の体積係数を求める．極座標からデカルト座標への写像は以下で与えられる：

Wolfram Language code: polar[r_, θ_] := {r Cos[θ], r Sin[θ]}

Gradを使って写像のヤコビアンを計算する：

Wolfram Language code: jac = Grad[polar[r, θ], {r, θ}]

変数変換定理によって，体積はヤコビアンの行列式である：

Wolfram Language code: Simplify[Abs[Det[jac]], r > 0]

CoordinateChartDataが与える結果と比較する：

Wolfram Language code: CoordinateChartData["Polar", "VolumeFactor", {r, θ}]

例えば球座標のように任意の座標系で同じ操作を行うことができる：

Wolfram Language code:

spherical[r_, θ_, φ_] := {r Sin[θ]Cos[φ], r Sin[θ]Sin[φ], r Cos[θ]}
Simplify[Abs[Det[Grad[spherical[r, θ, φ], {r, θ, φ}]]], r > 0 && 0 <= θ <= π]

Wolfram Language code: CoordinateChartData["Spherical", "VolumeFactor", {r, θ, φ}]

変数変換定理を使ってを計算する．ただし，は以下の領域である：

Wolfram Language code:

𝔻 = ImplicitRegion[x > 0 && y > 0 && 1 <= x^2 - y^2 ≤ 9 && 2 <= x y <= 4, {x, y}];
RegionPlot[𝔻]

まず，双曲線座標を以下のように定義する：

Wolfram Language code: hyper[x_, y_] := {x^2 - y^2, x y}

領域は明らかにかつに対応する．変数変換公式によってである．傾きは以下で与えられる：

Wolfram Language code: Grad[hyper[x, y], {x, y}]

傾きの行列式は積分がである関数の2倍である：

Wolfram Language code: Det[%]

したがって，は自明な積分によって与えられる：

Wolfram Language code: Subsuperscript[∫, 2, 4]Subsuperscript[∫, 1, 9](1/2)ⅆuⅆv

領域上での直接の積分と比較する：

Wolfram Language code: Subscript[∫, {x, y}∈𝔻](x^2 + y^2)

向きと回転 (5)

$TemplateBox[{}, Reals]^3$ についての次の基底が右手系かどうかを判断する：

Wolfram Language code: {b1, b2, b3} = {{1, 0, 1}, {0, 1, 1}, {1, 0, 0}};

この基底によって形成される行列の行列式は負であるので，これは右手系ではない：

Wolfram Language code: Det[{b1, b2, b3}]

に対応する線形変換が，向きを保つものかあるいは向きを逆にするものかを判断する：

Wolfram Language code: m = {{-8, 10, -7, -10}, {2, 6, -7, -9}, {6, 2, 4, -10}, {-7, -4, -3, -10}};

なので，向きを保つ写像である：

Wolfram Language code: Det[m]

次の行列が回転行列ではないことを示す：

Wolfram Language code:

m = {{0.969655, -0.170187, -0.0303448, -0.170187, -0.0303448}, {0.170187, 0.254483, 0.170187, -0.0455171, 0.170187}, {-0.0303448, -0.170187, 0.969655, -0.170187, -0.0303448}, {0.170187, -0.0455171, 0.170187, 0.954483, 0.170187}, {-0.0303448, -0.170187, -0.0303448, -0.170187, 0.969655}};

回転行列はどれも単位行列式を持つ．なので，これは回転行列ではありえない：

Wolfram Language code: Det[m]

行列が直交行列であることを示し，これが回転行列であるか，あるいは鏡映を含むかどうかを判断する：

Wolfram Language code:

m = {{-0.969655, -0.170187, -0.0303448, -0.170187, -0.0303448}, {-0.170187, 0.954483, 0.170187, -0.0455171, 0.170187}, {0.0303448, -0.170187, 0.969655, -0.170187, -0.0303448}, {-0.170187, -0.0455171, 0.170187, 0.954483, 0.170187}, {0.0303448, -0.170187, -0.0303448, -0.170187, 0.969655}};

入力の精度までであるが，これはが直交行列であることを示している：

Wolfram Language code: Chop[Transpose[m].m, 10 ^ -6]//MatrixForm

直交行列はどれもであるが，回転はである．なのでには鏡映が含まれる：

Wolfram Language code: Det[m]

複素ベクトル空間への回転行列の一般化は，ユニタリで単位行列式を持つ特殊ユニタリ行列である．次の行列が特殊ユニタリ行列であることを示す：

Wolfram Language code:

u = (1/Sqrt[Cosh[2 Im[α]]])(⁠|               |               |
| ------------- | ------------- |
| Cosh[Im[α]]   | I Sinh[Im[α]] |
| I Sinh[Im[α]] | Cosh[Im[α]]   |);

なので行列はユニタリ行列である：

Wolfram Language code: ConjugateTranspose[u].u//Simplify

これは単位行列式を持つので，実際に特殊ユニタリ群の元である：

Wolfram Language code: Det[u]//Simplify

線形代数と抽象代数 (8)

系，が一意解を持つパラメータの値を定義し，その解を説明する．まず，係数行列と定数ベクトルを形成する：

Wolfram Language code:

a = (|    |    |
| -- | -- |
| 2s | 1  |
| 3s | 6s |);b = (⁠|   |
| - |
| 1 |
| 2 |⁠);

Wolfram Language code: b

解はのとき一意になる：

Wolfram Language code: Det[a] != 0

実数上で解くととで区切られた3つの開区間が与えられる：

Wolfram Language code: Reduce[%, s, Reals]

この行列はのこれらの値について可逆なので，解は単にである：

Wolfram Language code: Inverse[a].b//Simplify

もとの方程式系で解を確認する：

Wolfram Language code: Simplify[2 s x + y == 1 && 3 s x + 6 s y == 2 /. Thread[{x, y} -> %]]

クラメール(Cramer)の規則を使って方程式系, , を解く．まず，係数行列と定数ベクトルを形成する：

Wolfram Language code:

a = {{6, 9, 0}, {-7, 0, 3}, {0, 5, 9}};
b = {11, -12, -9};
{a//MatrixForm, b//MatrixForm}

3つの行列を形成する．ただし，は対応するの列を置換する：

Wolfram Language code:

{dx, dy, dz} = Table[ReplacePart[a, {j_, i} :> b[[j]]], {i, 3}];
{dx//MatrixForm, dy//MatrixForm, dz//MatrixForm}

解の項は $TemplateBox[{{d, _, j}}, Det]/TemplateBox[{a}, Det]$ で与えられる：

Wolfram Language code: ({Det[dx], Det[dy], Det[dz]}/Det[a])

結果を確認する：

Wolfram Language code: a.% == b

線形系 m.x=b を解くためのクラメールの公式を実装する関数を書く：

Wolfram Language code:

crule[m_, b_] := Module[{d = Det[m], a}, 
	Table[a = m;a[[All, k]] = b;Det[a] / d, {k, Length[m]}]]

この関数を使って m と b の特定の値について系を解く：

Wolfram Language code:

m = {{1, 2, 3}, {1, 4, 9}, {1, 8, 27}};
b = {4, 16, 46};

Wolfram Language code: x = crule[m, {4, 16, 46}]

結果を確認する：

Wolfram Language code: m.x == b

数値系では， LinearSolveの方がずっと速くかつ正確である：

Wolfram Language code:

n = 500;
m = RandomReal[1, {n, n}];
x = ConstantArray[1, n];
b = m.x;

Wolfram Language code: AbsoluteTiming[Norm[crule[m, b] - x]]

Wolfram Language code: AbsoluteTiming[Norm[LinearSolve[m, b] - x]]

行列が自明ではないカーネル（零空間）を持つかどうか判断する：

Wolfram Language code: a = {{-10, -7, -7, 8, -1}, {5, 0, 2, 0, -8}, {7, -4, -2, -10, 1}, {-5, 7, 10, 0, 3}, {-8, -5, -4, 1, -2}};

行列式が非零なので，カーネルは自明である：

Wolfram Language code: Det[a]

NullSpaceを使って結果を確認する：

Wolfram Language code: NullSpace[a]

行列に対応する写像が単射かどうかを判断する：

Wolfram Language code: a = {{3, 1, 1}, {2, -5, 3}, {1, -11, 5}};

なので，写像は単射ではない：

Wolfram Language code: Det[a]

FunctionInjectiveを使って結果を確認する：

Wolfram Language code: f[x_, y_, z_] := a.{x, y, z}

Wolfram Language code: FunctionInjective[f[x, y, z], {x, y, z}]

が線形関数 $f:TemplateBox[{}, Reals]^3->TemplateBox[{}, Reals]^3$ を定義するので，単射ではないという事実は全射でもないことを暗示している：

Wolfram Language code: FunctionSurjective[f[x, y, z], {x, y, z}]

行列が自己同型写像（全単射線形写像）を定義するかどうかを判断する：

Wolfram Language code: a = RandomInteger[{-10, 10}, {3, 3}]

なので，この写像は自己同型写像である：

Wolfram Language code: Det[a]

FunctionBijectiveを使って結果を確かめる：

Wolfram Language code: f[x_, y_, z_] := a.{x, y, z}

Wolfram Language code: FunctionBijective[f[x, y, z], {x, y, z}]

行 i と列 j を除去することで入手した余因子を計算する：

Wolfram Language code: cofactor[m_, {i_Integer, j_Integer}] := (-1) ^ (i + j)Det[Drop[m, {i}, {j}]]

Wolfram Language code: cofactor[{{1, 2, 3, 4}, {5, 6, 7, 8}, {8, 7, 6, 4}, {5, 3, 2, 1}}, {3, 2}]

結果を確かめる：

Wolfram Language code: (-1) ^ (3 + 2)Det[{{1, 3, 4}, {5, 7, 8}, {5, 2, 1}}]

行列式のモジュール計算：

Wolfram Language code: a = {{12, 13}, {14, 15}};

モジュール行列式：

Wolfram Language code: d1 = Det[a, Modulus -> 5]

Wolfram Language code: d2 = Det[a, Modulus -> 7]

結果を回復する：

Wolfram Language code: ChineseRemainder[{d1, d2}, {5, 7}]

対称になるように剰余をシフトする：

Wolfram Language code: Mod[33, 5 7, (-5 7 + 1) / 2]

非モジュラ行列式が回復されたことを確かめる：

Wolfram Language code: Det[a]

特性と関係 (15)

行列式は固有値の積である：

Wolfram Language code: m = RandomReal[1, {100, 100}];

Wolfram Language code: Det[m]

Wolfram Language code: Apply[Times, Eigenvalues[m]]

Detは $TemplateBox[{a}, Det]=sum_sigma^(S_n)sgn[sigma]product_i^na〚i,sigma〚i〛〛$ を満足する．ただし，はすべて -順列ではSignatureである：

Wolfram Language code: a = {{-4, 8, -5, 6, -3}, {10, 2, -5, -4, 8}, {8, 8, -1, 8, 0}, {-7, -6, -4, -5, 2}, {8, -7, -6, -7, 10}};

Wolfram Language code: s5 = Permutations[Range[5]];

Wolfram Language code: Det[a] == Underoverscript[∑, σ, s5]Signature[σ]Underoverscript[∏, i, 5]a[[i, σ[[i]]]]

行列式Det[m]は，m の行または列をLevi–Civitaテンソルへ縮約したものである：

Wolfram Language code:

m = Array[μ, {3, 3}];
Det[m] === TensorContract[m[[1]]m[[2]]m[[3]]LeviCivitaTensor[3, List], {{1, 4}, {2, 5}, {3, 6}}]

効率のためにInactive[TensorProduct]を用いて高次元に一般化する：

Wolfram Language code:

det[m_] := With[{n = Length[m]}, 
	Activate[TensorContract[Inactive[TensorProduct]@@Append[m, LeviCivitaTensor[n]], Table[{k, k + n}, {k, n}]]]];

Wolfram Language code:

m = Array[μ, {6, 6}];
Det[m] == det[m]//Simplify

Detは任意の行に沿って余因子展開を介して繰り返し計算できる：

Wolfram Language code:

m = RandomReal[1, {5, 5}];
Block[{n = Length[m], i = RandomInteger[{1, Length[m]}]}, 
	Sum[(-1)^i + km[[i, k]]Det[Drop[m, {i}, {k}]], {k, n}] == Det[m]]

あるいは任意の列に沿って：

Wolfram Language code:

Block[{n = Length[m], j = RandomInteger[{1, Length[m]}]}, 
	Sum[(-1)^j + km[[k, j]]Det[Drop[m, {k}, {j}]], {k, n}] == Det[m]]

行列式は，その行によって生成された平行六面体の符号付き体積である：

Wolfram Language code: m = {{1, 2, 3}, {-1, 1, 0}, {3, 2, 1}};

Wolfram Language code: Det[m]

以下は，符号まで体積と同じである：

Wolfram Language code: Volume[Parallelepiped[{0, 0, 0}, m]]

正方行列は，その行列式が非零のときかつそのときに限って逆行列を持つ：

Wolfram Language code: m = {{1, 2, 1}, {1, 0, 2}, {-1, 2, -3}};

Wolfram Language code: Det[m]

Wolfram Language code: Inverse[m]

三角行列の行列式は，その対角要素の積である：

Wolfram Language code: MatrixForm[m = SparseArray[{i_, j_} /; i ≥ j :> RandomReal[], {5, 5}]]

Wolfram Language code: Det[m]

Wolfram Language code: Apply[Times, Diagonal[m]]

行列の積の行列式は，行列式の積である：

Wolfram Language code: {a, b} = RandomReal[1, {2, 100, 100}];

Wolfram Language code: Det[a.b]

Wolfram Language code: Det[a]Det[b]

逆行列の行列式は，行列式の逆数である：

Wolfram Language code:

m = (⁠|       |       |       |
| :---- | :---- | :---- |
| a1, 1 | a1, 2 | a1, 3 |
| a2, 1 | a2, 2 | a2, 3 |
| a3, 1 | a3, 2 | a3, 3 |⁠);

Wolfram Language code: Det[Inverse[m]]//Simplify

Wolfram Language code: 1 / Det[m]

Wolfram Language code: %% == %//Simplify

行列とその転置行列は同じ行列式を持つ：

Wolfram Language code:

m = RandomReal[1, {5, 5}];
Det[m] == Det[Transpose[m]]

指数行列の行列式はトレースの指数関数である：

Wolfram Language code: m = RandomReal[1, {10, 10}, WorkingPrecision -> $MachinePrecision];

Wolfram Language code: Det[MatrixExp[m]] == Exp[Tr[m]]

CharacteristicPolynomial[m]はに等しい：

Wolfram Language code: m = RandomInteger[9, {3, 3}];

Wolfram Language code: Det[m - λ IdentityMatrix[3]]

Wolfram Language code: CharacteristicPolynomial[m, λ]

Det[m]はLUDecomposition[m]から計算できる：

Wolfram Language code:

m = RandomInteger[9, {5, 5}];
{l, u, p, c} = LUDecomposition[m];
Det[m] == Signature[p["PermutationList"]]Times@@Diagonal[u]

とがどちらも正方行列であるような2つの矩形行列とについて考える：

Wolfram Language code: a = RandomReal[1, {5, 3}];b = RandomReal[1, {3, 5}];

シルヴェスター(Sylvester)の行列式定理にはとある．ただし，は合致する恒等行列である：

Wolfram Language code: Det[IdentityMatrix[5] + a.b] == Det[IdentityMatrix[3] + b.a]

行列が2つのベクトルとのTensorProductなら，である：

Wolfram Language code: {u, v} = RandomReal[1, {2, 5}];

Wolfram Language code: Det[IdentityMatrix[5] + uv] == 1 + u.v

上記はKroneckerProductを使っても同様に表現できる：

Wolfram Language code: Det[IdentityMatrix[5] + KroneckerProduct[u, v]] == 1 + u.v

これは，対応する行行列と列行列についてのシルベスターの行列定理に従っている：

Wolfram Language code: c = List /@ u;r = {v};

Wolfram Language code: {Det[IdentityMatrix[5] + c.r] == Det[IdentityMatrix[1] + r.c], r.c == {{u.v}}}

おもしろい例題 (1)

三重対角行列の行列式：

Wolfram Language code: tridiagonal[n_] := SparseArray[{Band[{2, 1}] -> a, Band[{1, 1}] -> b, Band[{1, 2}] -> c}, {n, n}]

Wolfram Language code: tridiagonal[5]//MatrixForm

Wolfram Language code: Table[Det[tridiagonal[n]], {n, 2, 12}]//TableForm

これらの行列式の閉じた形の式は $(a c)^(n/2) TemplateBox[{n, {b, /, {(, {2, , {sqrt(, {a, , c}, )}}, )}}}, ChebyshevU]$ で与えられる：

Wolfram Language code: % == Table[(a c) ^ (n / 2) ChebyshevU[n, b / (2 Sqrt[a c])]//Simplify, {n, 2, 12}]

Top

その他のラーニングリソース

テクニカルサポート

Wolframソリューション

教育のためのWolframソリューション

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

Det

詳細とオプション

例題

例 (2)

スコープ (13)

基本的な用法 (8)

特殊行列 (5)

オプション (1)

Modulus (1)

アプリケーション (19)

面積と体積 (6)

向きと回転 (5)

線形代数と抽象代数 (8)

特性と関係 (15)

おもしろい例題 (1)

テキスト

CMS

APA

BibTeX

BibLaTeX

Det

詳細とオプション

例題

例 (2)

スコープ (13)

基本的な用法 (8)

特殊行列 (5)

オプション (1)

Modulus (1)

アプリケーション (19)

面積と体積 (6)

向きと回転 (5)

線形代数と抽象代数 (8)

特性と関係 (15)

おもしろい例題 (1)

関連項目

テクニカルノート

関連するガイド

関連リンク

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX