Det

给出方阵 m 的行列式.

范例

打开所有单元关闭所有单元

基本范例 (2)

求符号矩阵的行列式：

Wolfram Language code:

Det[(⁠|       |       |
| :---- | :---- |
| a1, 1 | a1, 2 |
| a2, 1 | a2, 2 |⁠)]

精确矩阵的行列式：

Wolfram Language code: Det[{{1, 2, 3}, {4, 5, 6}, {7, 8, 9}}]

范围 (13)

基本用法 (8)

求 MachinePrecision 矩阵的行列式：

Wolfram Language code: Det[{{1.7, 7.1, -2.7}, {2.2, 8.7, 3.2}, {3.2, -9.2, 1.2}}]

复矩阵的行列式：

Wolfram Language code: Det[{{1. + I, 2, 3 - 2 I}, {0, 4 π, 5I}, {3, 0, 6}}]

精确矩阵的行列式：

Wolfram Language code: Det[{{1, 2, 4}, {5, 4, 5}, {9, 2, 7}}]

任意精度矩阵的行列式：

Wolfram Language code: Det[RandomReal[2, {3, 3}, WorkingPrecision -> 20]]

符号矩阵的行列式：

Wolfram Language code: Det[{{a, b, c}, {d, e, f}, {g, h, i}}]

高效计算大型数值矩阵的行列式：

Wolfram Language code: mat = BlockRandom[RandomReal[3, {1500, 1500}], RandomSeeding -> 1234];

Wolfram Language code: Det[mat]//Timing

结果不一定是机器精度的数字：

Wolfram Language code: Divide[Abs[Last[%]], $MaxMachineNumber]

有限域元素构成的矩阵的行列式：

Wolfram Language code:

ℱ = FiniteField[17, 3];
Det[{{ℱ[12], ℱ[23], ℱ[34]}, {ℱ[45], ℱ[56], ℱ[67]}, {ℱ[78], ℱ[89], ℱ[90]}}]

CenteredInterval 矩阵的行列式：

Wolfram Language code: (m = Map[CenteredInterval, RandomReal[{-10, 10}, {3, 3}, WorkingPrecision -> 10], {2}])//MatrixForm

Wolfram Language code: mdet = Det[m]

找到 m 的随机表示 mrep：

Wolfram Language code:

ranrep[e_CenteredInterval] := e["Center"] + RandomInteger[{-1000, 1000}] / 1000 e["Radius"]
(mrep = Map[ranrep, m, {2}])//MatrixForm

验证 mdet 包含 mrep 的行列式：

Wolfram Language code: IntervalMemberQ[mdet, Det[mrep]]

特殊矩阵 (5)

稀疏矩阵的行列式：

Wolfram Language code: SparseArray[{{1, 3} -> 2, {2, 2} -> 3, {3, 1} -> 1, {4, 2} -> 5}, {4, 4}]

Wolfram Language code: Det[%]

Wolfram Language code: SparseArray[{{x_, y_} /; Abs[x - y] < 3 -> 1}, {10, 10}]

Wolfram Language code: Det[%]

结构化矩阵的行列式：

Wolfram Language code: SymmetrizedArray[{{1, 1} -> 2, {1, 2} -> 1}, {2, 2}, Symmetric[All]]

Wolfram Language code: Det[%]

Wolfram Language code: QuantityArray[{{1, 2}, {3, 4}}, {"Meters", "Seconds"}]

Wolfram Language code: Det[%]

IdentityMatrix 的行列式为 1：

Wolfram Language code: Det[IdentityMatrix[22]]

HilbertMatrix 的行列式：

Wolfram Language code: HilbertMatrix[9]//Det

计算阶数为的单变量多项式的矩阵的行列式：

Wolfram Language code:

rpoly[n_] := RandomInteger[{-2 ^ 10, 2 ^ 10}, {n + 1}].x ^ Range[0, n]
SeedRandom[1234];
m = Table[rpoly[100], {10}, {10}];

Wolfram Language code: Det[m]//Short//AbsoluteTiming

选项 (1)

Modulus (1)

用模 47 的算术计算行列式：

Wolfram Language code: m = RandomInteger[46, {100, 100}];

Wolfram Language code: Det[m, Modulus -> 47]//AbsoluteTiming

这比 Mod[Det[m],47] 的计算速度快：

Wolfram Language code: Mod[Det[m], 47]//AbsoluteTiming

应用 (19)

面积和体积 (6)

用 Det 求和之间的平行四边形的面积：

Wolfram Language code:

v = {1, 4};
w = {-5, 2};

可视化一个顶点在原点时的平行四边形：

Wolfram Language code:

p = Parallelogram[{0, 0}, {v, w}];
Graphics[p, Axes -> True]

面积由行列式的绝对值给出：

Wolfram Language code: Abs[Det[{v, w}]]

与 Area 给出的结果相比较：

Wolfram Language code: Area[p]

用 Det 求、和之间的平行六面体的体积：

Wolfram Language code: {Subscript[v, 1], Subscript[v, 2], Subscript[v, 3]} = {{1, 4, 3}, {-2, -5, 2}, {-1, 2, -2}};

可视化一个顶点在原点时的平行六面体：

Wolfram Language code:

p = Parallelepiped[{0, 0, 0}, {Subscript[v, 1], Subscript[v, 2], Subscript[v, 3]}];
Graphics3D[p, Axes -> True]

体积由行列式的绝对值给出：

Wolfram Language code: Abs[Det[{Subscript[v, 1], Subscript[v, 2], Subscript[v, 3]}]]

与用 Volume 直接计算所得的结果相比较：

Wolfram Language code: Volume[p]

用 Det 求由以下向量形成的超平行六面体的超体积：

Wolfram Language code: {v1, v2, v3, v4} = {{6, -6, -1, 6}, {10, -1, 0, -7}, {3, -2, -9, -3}, {4, 5, 6, -3}}

超体积由行列式的绝对值给出：

Wolfram Language code: Abs[Det[{v1, v2, v3, v4}]]

与 RegionMeasure 给出的结果相比较：

Wolfram Language code: RegionMeasure[Parallelepiped[{0, 0, 0, 0}, {v1, v2, v3, v4}]]

行列式本身是负数，因此不是右手系的：

Wolfram Language code: Det[{v1, v2, v3, v4}]

只需交换任意两个向量（例如中间两个向量）的顺序，即可生成右手系的超平行六面体：

Wolfram Language code: Det[{v1, v3, v2, v4}]

求经过与矩阵相关联的线性变换后单位圆盘的图像的面积：

Wolfram Language code:

m = {{7, -3}, {5, 7}, {-10, 4}};
m//MatrixForm

图像的面积由给出：

Wolfram Language code: πSqrt[Det[Transpose[m].m]]

与直接计算的结果相比较：

Wolfram Language code:

f𝔻 = ParametricRegion[ {m.{x, y}, {x, y}∈Disk[]}, {x, y}];
Area[f𝔻]

可视化图像：

Wolfram Language code: Region[f𝔻, PlotTheme -> "Scientific"]

求直角坐标和极坐标之间变量变换公式中的体积因子 . 从极坐标到直角坐标的映射由下式给出：

Wolfram Language code: polar[r_, θ_] := {r Cos[θ], r Sin[θ]}

用 Grad 计算映射的雅可比矩阵：

Wolfram Language code: jac = Grad[polar[r, θ], {r, θ}]

根据变量变换定理，体积是雅可比矩阵的行列式：

Wolfram Language code: Simplify[Abs[Det[jac]], r > 0]

与 CoordinateChartData 给出的结果相比较：

Wolfram Language code: CoordinateChartData["Polar", "VolumeFactor", {r, θ}]

相同的过程适用于任何坐标系，例如，球坐标系：

Wolfram Language code:

spherical[r_, θ_, φ_] := {r Sin[θ]Cos[φ], r Sin[θ]Sin[φ], r Cos[θ]}
Simplify[Abs[Det[Grad[spherical[r, θ, φ], {r, θ, φ}]]], r > 0 && 0 <= θ <= π]

Wolfram Language code: CoordinateChartData["Spherical", "VolumeFactor", {r, θ, φ}]

用变量变换定理计算，其中是以下区域：

Wolfram Language code:

𝔻 = ImplicitRegion[x > 0 && y > 0 && 1 <= x^2 - y^2 ≤ 9 && 2 <= x y <= 4, {x, y}];
RegionPlot[𝔻]

首先，定义双曲坐标：

Wolfram Language code: hyper[x_, y_] := {x^2 - y^2, x y}

区域明确对应于和 . 通过变量变换公式 . 梯度由下式给出：

Wolfram Language code: Grad[hyper[x, y], {x, y}]

梯度的行列式是积分为的函数的两倍：

Wolfram Language code: Det[%]

因此，由平凡积分给出：

Wolfram Language code: Subsuperscript[∫, 2, 4]Subsuperscript[∫, 1, 9](1/2)ⅆuⅆv

与直接在区域上积分的结果相比：

Wolfram Language code: Subscript[∫, {x, y}∈𝔻](x^2 + y^2)

方向和旋转 (5)

确定 $TemplateBox[{}, Reals]^3$ 的以下基向量是否为右手系：

Wolfram Language code: {b1, b2, b3} = {{1, 0, 1}, {0, 1, 1}, {1, 0, 0}};

基向量形成的矩阵的行列式是负的，因此不是右手系的：

Wolfram Language code: Det[{b1, b2, b3}]

确定对应于的线性变换为保持定向的 (orientation-preserving) 还是反转定向的 (orientation-reversing)：

Wolfram Language code: m = {{-8, 10, -7, -10}, {2, 6, -7, -9}, {6, 2, 4, -10}, {-7, -4, -3, -10}};

当时，映射是保持定向的：

Wolfram Language code: Det[m]

证明下面的矩阵不是旋转矩阵：

Wolfram Language code:

m = {{0.969655, -0.170187, -0.0303448, -0.170187, -0.0303448}, {0.170187, 0.254483, 0.170187, -0.0455171, 0.170187}, {-0.0303448, -0.170187, 0.969655, -0.170187, -0.0303448}, {0.170187, -0.0455171, 0.170187, 0.954483, 0.170187}, {-0.0303448, -0.170187, -0.0303448, -0.170187, 0.969655}};

所有旋转矩阵的行列式都为 1；因为，因此不是旋转矩阵：

Wolfram Language code: Det[m]

证明矩阵为正交矩阵，确定它是旋转矩阵还是包含反射：

Wolfram Language code:

m = {{-0.969655, -0.170187, -0.0303448, -0.170187, -0.0303448}, {-0.170187, 0.954483, 0.170187, -0.0455171, 0.170187}, {0.0303448, -0.170187, 0.969655, -0.170187, -0.0303448}, {-0.170187, -0.0455171, 0.170187, 0.954483, 0.170187}, {0.0303448, -0.170187, -0.0303448, -0.170187, 0.969655}};

就输入的精度来说，，因此为正交矩阵：

Wolfram Language code: Chop[Transpose[m].m, 10 ^ -6]//MatrixForm

对于所有正交矩阵，，但对于旋转矩阵；因为，所以包含反射：

Wolfram Language code: Det[m]

将旋转矩阵推广到复向量空间，结果是一个特殊的酉矩阵，它是行列式为 1 的酉矩阵. 证明下列矩阵是一个特殊酉矩阵：

Wolfram Language code:

u = (1/Sqrt[Cosh[2 Im[α]]])(⁠|               |               |
| ------------- | ------------- |
| Cosh[Im[α]]   | I Sinh[Im[α]] |
| I Sinh[Im[α]] | Cosh[Im[α]]   |);

矩阵是酉矩阵，因为：

Wolfram Language code: ConjugateTranspose[u].u//Simplify

行列式为 1，所以它实际上是特殊酉群的一个元素：

Wolfram Language code: Det[u]//Simplify

线性代数与抽象代数 (8)

确定参数的值，使得方程组、有唯一解，并对解进行描述. 首先，形成系数矩阵和常向量：

Wolfram Language code:

a = (|    |    |
| -- | -- |
| 2s | 1  |
| 3s | 6s |);b = (⁠|   |
| - |
| 1 |
| 2 |⁠);

Wolfram Language code: b

当时有唯一解：

Wolfram Language code: Det[a] != 0

在实数上求解，给出三个开区间，由和分开：

Wolfram Language code: Reduce[%, s, Reals]

由于对的这些值矩阵是可逆的，解即为：

Wolfram Language code: Inverse[a].b//Simplify

在原始方程组中验证解：

Wolfram Language code: Simplify[2 s x + y == 1 && 3 s x + 6 s y == 2 /. Thread[{x, y} -> %]]

用克莱默法则解方程组、、. 首先，形成系数矩阵和常向量：

Wolfram Language code:

a = {{6, 9, 0}, {-7, 0, 3}, {0, 5, 9}};
b = {11, -12, -9};
{a//MatrixForm, b//MatrixForm}

形成三个矩阵，其中替换的相应列：

Wolfram Language code:

{dx, dy, dz} = Table[ReplacePart[a, {j_, i} :> b[[j]]], {i, 3}];
{dx//MatrixForm, dy//MatrixForm, dz//MatrixForm}

解的项由 $TemplateBox[{{d, _, j}}, Det]/TemplateBox[{a}, Det]$ 给出：

Wolfram Language code: ({Det[dx], Det[dy], Det[dz]}/Det[a])

验证结果：

Wolfram Language code: a.% == b

编写一个函数，实现克莱默法则，求解线性方程组 m.x=b：

Wolfram Language code:

crule[m_, b_] := Module[{d = Det[m], a}, 
	Table[a = m;a[[All, k]] = b;Det[a] / d, {k, Length[m]}]]

m 和 b 取特定值，用该函数解方程组：

Wolfram Language code:

m = {{1, 2, 3}, {1, 4, 9}, {1, 8, 27}};
b = {4, 16, 46};

Wolfram Language code: x = crule[m, {4, 16, 46}]

验证解：

Wolfram Language code: m.x == b

对于数值型方程组， LinearSolve 更快且更准确：

Wolfram Language code:

n = 500;
m = RandomReal[1, {n, n}];
x = ConstantArray[1, n];
b = m.x;

Wolfram Language code: AbsoluteTiming[Norm[crule[m, b] - x]]

Wolfram Language code: AbsoluteTiming[Norm[LinearSolve[m, b] - x]]

判断矩阵是否有非平凡内核（零空间）：

Wolfram Language code: a = {{-10, -7, -7, 8, -1}, {5, 0, 2, 0, -8}, {7, -4, -2, -10, 1}, {-5, 7, 10, 0, 3}, {-8, -5, -4, 1, -2}};

由于行列式非零，内核是非平凡的：

Wolfram Language code: Det[a]

用 NullSpace 确认结果：

Wolfram Language code: NullSpace[a]

判断矩阵对应的映射是否是单射：

Wolfram Language code: a = {{3, 1, 1}, {2, -5, 3}, {1, -11, 5}};

由于，映射不是单射：

Wolfram Language code: Det[a]

用 FunctionInjective 确认结果：

Wolfram Language code: f[x_, y_, z_] := a.{x, y, z}

Wolfram Language code: FunctionInjective[f[x, y, z], {x, y, z}]

由于定义了一个线性函数 $f:TemplateBox[{}, Reals]^3->TemplateBox[{}, Reals]^3$ ，不是单射意味着也不是满射：

Wolfram Language code: FunctionSurjective[f[x, y, z], {x, y, z}]

判断矩阵是否定义了一个自同构（双射线性映射）：

Wolfram Language code: a = RandomInteger[{-10, 10}, {3, 3}]

由于，映射是自同构：

Wolfram Language code: Det[a]

用 FunctionBijective 确认结果：

Wolfram Language code: f[x_, y_, z_] := a.{x, y, z}

Wolfram Language code: FunctionBijective[f[x, y, z], {x, y, z}]

计算删除第 i 行和第 j 列后获得的余因子矩阵：

Wolfram Language code: cofactor[m_, {i_Integer, j_Integer}] := (-1) ^ (i + j)Det[Drop[m, {i}, {j}]]

Wolfram Language code: cofactor[{{1, 2, 3, 4}, {5, 6, 7, 8}, {8, 7, 6, 4}, {5, 3, 2, 1}}, {3, 2}]

检查结果：

Wolfram Language code: (-1) ^ (3 + 2)Det[{{1, 3, 4}, {5, 7, 8}, {5, 2, 1}}]

行列式的模计算：

Wolfram Language code: a = {{12, 13}, {14, 15}};

行列式取模：

Wolfram Language code: d1 = Det[a, Modulus -> 5]

Wolfram Language code: d2 = Det[a, Modulus -> 7]

恢复结果：

Wolfram Language code: ChineseRemainder[{d1, d2}, {5, 7}]

移动残差，使其对称：

Wolfram Language code: Mod[33, 5 7, (-5 7 + 1) / 2]

确认恢复了不取模的行列式：

Wolfram Language code: Det[a]

属性和关系 (15)

行列式是特征值的积：

Wolfram Language code: m = RandomReal[1, {100, 100}];

Wolfram Language code: Det[m]

Wolfram Language code: Apply[Times, Eigenvalues[m]]

Det 满足 $TemplateBox[{a}, Det]=sum_sigma^(S_n)sgn[sigma]product_i^na〚i,sigma〚i〛〛$ ，其中是 -全排列，是 Signature：

Wolfram Language code: a = {{-4, 8, -5, 6, -3}, {10, 2, -5, -4, 8}, {8, 8, -1, 8, 0}, {-7, -6, -4, -5, 2}, {8, -7, -6, -7, 10}};

Wolfram Language code: s5 = Permutations[Range[5]];

Wolfram Language code: Det[a] == Underoverscript[∑, σ, s5]Signature[σ]Underoverscript[∏, i, 5]a[[i, σ[[i]]]]

行列式 Det[m] 是将矩阵 m 的行或列缩并为 Levi–Civita 张量的结果：

Wolfram Language code:

m = Array[μ, {3, 3}];
Det[m] === TensorContract[m[[1]]m[[2]]m[[3]]LeviCivitaTensor[3, List], {{1, 4}, {2, 5}, {3, 6}}]

推广到更高维度，用 Inactive[TensorProduct] 提高效率：

Wolfram Language code:

det[m_] := With[{n = Length[m]}, 
	Activate[TensorContract[Inactive[TensorProduct]@@Append[m, LeviCivitaTensor[n]], Table[{k, k + n}, {k, n}]]]];

Wolfram Language code:

m = Array[μ, {6, 6}];
Det[m] == det[m]//Simplify

Det 可以通过任意行的余子式展开递归计算：

Wolfram Language code:

m = RandomReal[1, {5, 5}];
Block[{n = Length[m], i = RandomInteger[{1, Length[m]}]}, 
	Sum[(-1)^i + km[[i, k]]Det[Drop[m, {i}, {k}]], {k, n}] == Det[m]]

或任意列：

Wolfram Language code:

Block[{n = Length[m], j = RandomInteger[{1, Length[m]}]}, 
	Sum[(-1)^j + km[[k, j]]Det[Drop[m, {k}, {j}]], {k, n}] == Det[m]]

行列式是由其行生成的平行六面体的有符号体积：

Wolfram Language code: m = {{1, 2, 3}, {-1, 1, 0}, {3, 2, 1}};

Wolfram Language code: Det[m]

等于平行六面体的体积，除了符号：

Wolfram Language code: Volume[Parallelepiped[{0, 0, 0}, m]]

当且仅当其行列式非零时，方阵才具有逆矩阵：

Wolfram Language code: m = {{1, 2, 1}, {1, 0, 2}, {-1, 2, -3}};

Wolfram Language code: Det[m]

Wolfram Language code: Inverse[m]

一个三角形矩阵的行列式是它的对角元素的乘积：

Wolfram Language code: MatrixForm[m = SparseArray[{i_, j_} /; i ≥ j :> RandomReal[], {5, 5}]]

Wolfram Language code: Det[m]

Wolfram Language code: Apply[Times, Diagonal[m]]

矩阵积的行列式是各自矩阵行列式的积：

Wolfram Language code: {a, b} = RandomReal[1, {2, 100, 100}];

Wolfram Language code: Det[a.b]

Wolfram Language code: Det[a]Det[b]

逆矩阵的行列式是原矩阵行列式的倒数：

Wolfram Language code:

m = (⁠|       |       |       |
| :---- | :---- | :---- |
| a1, 1 | a1, 2 | a1, 3 |
| a2, 1 | a2, 2 | a2, 3 |
| a3, 1 | a3, 2 | a3, 3 |⁠);

Wolfram Language code: Det[Inverse[m]]//Simplify

Wolfram Language code: 1 / Det[m]

Wolfram Language code: %% == %//Simplify

矩阵及其转置具有相等的行列式：

Wolfram Language code:

m = RandomReal[1, {5, 5}];
Det[m] == Det[Transpose[m]]

矩阵指数的行列式是迹的指数：

Wolfram Language code: m = RandomReal[1, {10, 10}, WorkingPrecision -> $MachinePrecision];

Wolfram Language code: Det[MatrixExp[m]] == Exp[Tr[m]]

CharacteristicPolynomial[m] 等价于：

Wolfram Language code: m = RandomInteger[9, {3, 3}];

Wolfram Language code: Det[m - λ IdentityMatrix[3]]

Wolfram Language code: CharacteristicPolynomial[m, λ]

可使用 LUDecomposition[m] 计算 Det[m]：

Wolfram Language code:

m = RandomInteger[9, {5, 5}];
{l, u, p, c} = LUDecomposition[m];
Det[m] == Signature[p["PermutationList"]]Times@@Diagonal[u]

考虑使得和为方阵的两个长方形矩阵和：

Wolfram Language code: a = RandomReal[1, {5, 3}];b = RandomReal[1, {3, 5}];

西尔维斯特行列式定理指出，其中是匹配的单位矩阵：

Wolfram Language code: Det[IdentityMatrix[5] + a.b] == Det[IdentityMatrix[3] + b.a]

如果矩阵是两个向量和的 TensorProduct，则有：

Wolfram Language code: {u, v} = RandomReal[1, {2, 5}];

Wolfram Language code: Det[IdentityMatrix[5] + uv] == 1 + u.v

也可用 KroneckerProduct 来等效表示：

Wolfram Language code: Det[IdentityMatrix[5] + KroneckerProduct[u, v]] == 1 + u.v

对于相应的行和列矩阵，根据 Sylvester 行列式定理有以下式子：

Wolfram Language code: c = List /@ u;r = {v};

Wolfram Language code: {Det[IdentityMatrix[5] + c.r] == Det[IdentityMatrix[1] + r.c], r.c == {{u.v}}}

巧妙范例 (1)

三角矩阵的行列式：

Wolfram Language code: tridiagonal[n_] := SparseArray[{Band[{2, 1}] -> a, Band[{1, 1}] -> b, Band[{1, 2}] -> c}, {n, n}]

Wolfram Language code: tridiagonal[5]//MatrixForm

Wolfram Language code: Table[Det[tridiagonal[n]], {n, 2, 12}]//TableForm

$(a c)^(n/2) TemplateBox[{n, {b, /, {(, {2, , {sqrt(, {a, , c}, )}}, )}}}, ChebyshevU]$ 给出了这些行列式的闭式公式：

Wolfram Language code: % == Table[(a c) ^ (n / 2) ChebyshevU[n, b / (2 Sqrt[a c])]//Simplify, {n, 2, 12}]

Top

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

Det

更多信息和选项

范例

基本范例 (2)

范围 (13)

基本用法 (8)

特殊矩阵 (5)

选项 (1)

Modulus (1)

应用 (19)

面积和体积 (6)

方向和旋转 (5)

线性代数与抽象代数 (8)

属性和关系 (15)

巧妙范例 (1)

文本

CMS

APA

BibTeX

BibLaTeX

Det

更多信息和选项

范例

基本范例 (2)

范围 (13)

基本用法 (8)

特殊矩阵 (5)

选项 (1)

Modulus (1)

应用 (19)

面积和体积 (6)

方向和旋转 (5)

线性代数与抽象代数 (8)

属性和关系 (15)

巧妙范例 (1)

参见

技术笔记

相关指南

相关链接

历史

文本

CMS

APA

BibTeX

BibLaTeX