WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DiagonalMatrix[list]

対角成分が list で与えられ，他の成分が0である行列を返す．

DiagonalMatrix[list,k]

k 次の対角上の list の要素の行列を返す．

DiagonalMatrix[list,k,n]

0で充填して n×n 行列を作る．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
TargetStructure  
アプリケーション  
特性と関係  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

DiagonalMatrix

DiagonalMatrix[list]

対角成分が list で与えられ，他の成分が0である行列を返す．

DiagonalMatrix[list,k]

k 次の対角上の list の要素の行列を返す．

DiagonalMatrix[list,k,n]

0で充填して n×n 行列を作る．

詳細とオプション

  • 対角行列を使って左から乗算することで行列の行をスケーリングしたり，右から乗算することで列をスケーリングしたりすることができる．
  • DiagonalMatrix[{d1,…,dn}]で与えられる対角行列 の成分は D〚i,j〛=d_iTemplateBox[{{i, ,, j}}, KroneckerDeltaSeq]で与えられる．つまり，i 番目の主対角成分は でその他の成分は0である．
  • DiagonalMatrix[list]は対称行列である．したがってその転置に等しい．
  • k が正の場合，DiagonalMatrix[{d1,…,ds},k]は大きさが(TemplateBox[{k}, Abs]+s)x(TemplateBox[{k}, Abs]+s)の行列の成分を主対角の k 位置分上に，DiagonalMatrix[{d1,…,ds},-k]は，成分を主対角の k 位置分下に置く．k の値が異なると行列の大きさも異なる，
  • DiagonalMatrix[list]はDiagonalMatrix[list,0]に等しい．
  • DiagonalMatrix[list,k,n]は，たとえそのために list 中の要素を取り除くことが必要だとしても，常に n×n 行列を作る． »
  • 対角行列の行列式は，のときは主対角成分の積で，それ以外のときは0である．
  • DiagonalMatrix[list,k,{m,n}]は m×n 行列を作る．
  • DiagonalMatrix[SparseArray[…],…]はSparseArrayオブジェクトを返す．
  • DiagonalMatrix[…,TargetStructure->struct]は対角行列を struct で指定された形式で返す．次は，その可能な設定である．
  • Automatic返す際の表現を自動選択する
    "Dense"行列を密な行列として表す
    "Sparse"行列を疎な行列として表す
    "Structured"行列を構造化配列として表す
    "Symmetric"行列を対称行列として表す
  • DiagonalMatrix[…,TargetStructureAutomatic]の設定では，行列の成分数が設定された閾値未満の場合は密な行列が返され，それ以外の場合は構造化配列が返される．
  • 対角行列は，構造化配列として返される場合は，効率的な格納とDet，Inverse，LinearSolve等のより効率的な操作を可能にする．
  • 次は，DiagonalMatrixで加速される操作である．
  • Det時間
    Dot時間
    Inverse時間
    LinearSolve時間
  • 構造化されたDiagonalMatrix sa は，次の特性"prop"に sa["prop"]でアクセスできる．
  • "Diagonal"k 番目の対角上の成分のリスト
    "Offset"オフセット k
    "Properties"サポートされる特性のリスト
    "Structure"構造化配列の型
    "StructuredData"構造化配列で保存されている内部データ
    "StructuredAlgorithms"構造化配列に対して特別なメソッドを持つ関数のリスト
    "Summary"Datasetして表される要約情報
  • Normal[DiagonalMatrix[…]]は対角行列を通常の行列として与える．

例題

すべて開く すべて閉じる

例  (1)

対角行列を構築する：

Wolfram Language code: DiagonalMatrix[{a, b, c}]//MatrixForm

上対角行列：

Wolfram Language code: DiagonalMatrix[{a, b}, 1]//MatrixForm

下対角行列：

Wolfram Language code: DiagonalMatrix[{a, b}, -1]//MatrixForm

スコープ  (6)

DiagonalMatrix中の要素はベクトルの要素とマッチするように選ばれる：

Wolfram Language code: v = 1 / Range[3];

厳密値の項目：

Wolfram Language code: DiagonalMatrix[v]//MatrixForm

機械数の項目：

Wolfram Language code: DiagonalMatrix[N[v]]//MatrixForm

任意精度数の項目：

Wolfram Language code: DiagonalMatrix[N[v, 20]]//MatrixForm

0で充填して大きい正方行列にする：

Wolfram Language code: DiagonalMatrix[{1, 2, 3}, 0, 5] // MatrixForm

指定した大きさの正方行列を作る：

Wolfram Language code: DiagonalMatrix[{1, 2, 3, 4, 5}, 0, 3] // MatrixForm

矩形対角行列：

Wolfram Language code: DiagonalMatrix[{1, 2, 3}, 0, {3, 5}] // MatrixForm
Wolfram Language code: DiagonalMatrix[{1, 2, 3}, 0, {5, 3}] // MatrixForm

オプション設定TargetStructure"Sparse"を使って疎な対角行列を構築する：

Wolfram Language code: 𝒟 = DiagonalMatrix[RandomReal[1, 1000], TargetStructure -> "Sparse"]

疎な表現を使うと大きい行列の場合はメモリが大幅に節約できる：

Wolfram Language code: {ByteCount[𝒟], ByteCount[Normal[𝒟]]}

オプション設定TargetStructure"Structured"を使って構造化直交行列を構築する：

Wolfram Language code: 𝒟 = DiagonalMatrix[RandomReal[{1, 2}, 1000], TargetStructure -> "Structured"]

この表現と計算は構造化配列については効率的である：

Wolfram Language code: 𝒟//ByteCount
Wolfram Language code: Det[𝒟]//AbsoluteTiming
Wolfram Language code: Inverse[𝒟]//ByteCount//AbsoluteTiming

通常の表現は非常に大きくなり計算も遅くなる：

Wolfram Language code: (dnormal = Normal@𝒟)//ByteCount//AbsoluteTiming
Wolfram Language code: Det[dnormal]//AbsoluteTiming

逆行列には大きいストレージが必要である：

Wolfram Language code: Inverse[dnormal]//ByteCount//AbsoluteTiming

DiagonalMatrixオブジェクトは配列についての情報を与える特性を含む：

Wolfram Language code: dm = DiagonalMatrix[1 / Range[6], -2, TargetStructure -> "Structured"]
Wolfram Language code: dm["Properties"]

"Diagonal"は対角成分を与える：

Wolfram Language code: dm["Diagonal"]

"Offset"はオフセットを与える．これは，対角要素がそれぞれ主対角の上，その上，またはその下にある場合にそれぞれ0，正または負になる：

Wolfram Language code: dm["Offset"]

"Summary"特性は配列についての情報の簡単な要約を与える：

Wolfram Language code: dm["Summary"]

"StructuredAlgorithms"特性は構造化アルゴリズムを持つ関数のリストを与える：

Wolfram Language code: dm["StructuredAlgorithms"]

オプション  (3)

TargetStructure  (3)

対角行列を密な行列として返す：

Wolfram Language code: DiagonalMatrix[{1, 2, 3}, TargetStructure -> "Dense"]

対角行列を構造化配列として返す：

Wolfram Language code: DiagonalMatrix[{1, 2, 3}, TargetStructure -> "Structured"]

対角行列を疎な配列として返す：

Wolfram Language code: DiagonalMatrix[{1, 2, 3}, TargetStructure -> "Sparse"]

TargetStructureAutomaticの設定のとき，小さい次元では密な行列が返される：

Wolfram Language code: DiagonalMatrix[Range[5], TargetStructure -> Automatic]

次元が大きくなると構造化表現が返される：

Wolfram Language code: DiagonalMatrix[Range[10000], TargetStructure -> Automatic]

密な表現は大きいリストの場合は大量のメモリを使う：

Wolfram Language code: DiagonalMatrix[Range[10000], TargetStructure -> "Dense"] //ByteCount

疎な表現が使うメモリは，通常は少ない：

Wolfram Language code: DiagonalMatrix[Range[10000], TargetStructure -> "Sparse"] //ByteCount

構造化表現で使うメモリはさらに少なくなる：

Wolfram Language code: DiagonalMatrix[Range[10000], TargetStructure -> "Structured"] //ByteCount

アプリケーション  (5)

行列を対角部分とそれ以外の部分の和として表す：

Wolfram Language code: MatrixForm[m = Array[Subscript[a, ##]&, {3, 3}]]
Wolfram Language code: md = DiagonalMatrix[Diagonal[m]]; mo = m - md;
Wolfram Language code: Map[MatrixForm, {md, mo}]

行列とその固有値の対角行列の類似性を証明する：

Wolfram Language code: m = N[HilbertMatrix[3]]
Wolfram Language code: {vals, vecs} = Eigensystem[m]
Wolfram Language code: Transpose[vecs].DiagonalMatrix[vals].vecs

ジョルダン(Jordan)行列を定義する：

Wolfram Language code: jordanMatrix[λ_, n_] := DiagonalMatrix[Table[λ, {n}]] + DiagonalMatrix[Table[1, {n - 1}], 1]
Wolfram Language code: jordanMatrix[λ, 3]//MatrixForm

5×5の3重対角行列を作る：

Wolfram Language code: n = 5; MatrixForm[DiagonalMatrix[Array[Subscript[a, #]&, n - 1], -1] + DiagonalMatrix[Array[Subscript[b, #]&, n]] + DiagonalMatrix[Array[Subscript[c, #]&, n - 1], 1]]

この行列はBandを使って作ることもできる：

Wolfram Language code: MatrixForm[SparseArray[{Band[{2, 1}] -> Array[Subscript[a, #]&, n - 1], Band[{1, 1}] -> Array[Subscript[b, #]&, n], Band[{1, 2}] -> Array[Subscript[c, #]&, n - 1]}]]

対角矩形行列から対角成分を抽出する：

Wolfram Language code: m = (| | | | - | - | | a | 0 | | 0 | b | | 0 | 0 |);
Wolfram Language code: DiagonalMatrixQ[m]
Wolfram Language code: d = Diagonal[m]

対角成分からもとの行列を再構築する：

Wolfram Language code: DiagonalMatrix[d, 0, {3, 2}] == m

特性と関係  (9)

IdentityMatrixはDiagonalMatrixの特殊ケースである：

Wolfram Language code: IdentityMatrix[5] == DiagonalMatrix[ConstantArray[1, 5]]

IdentityMatrixを構造化DiagonalMatrixに変換する：

Wolfram Language code: DiagonalMatrix[IdentityMatrix[5]]

DiagonalMatrixはDiagonalMatrixQである行列を作る：

Wolfram Language code: (m = DiagonalMatrix[{a, b, c, d}])//MatrixForm
Wolfram Language code: DiagonalMatrixQ[m]

DiagonalMatrix[l]はUpperTriangularMatrixQおよびLowerTriangularMatrixQである：

Wolfram Language code: DiagonalMatrix[{a, b, c, d}]
Wolfram Language code: UpperTriangularMatrixQ[%]
Wolfram Language code: LowerTriangularMatrixQ[%%]

いくつかの単純な特性は対角行列にも当てはまる：

Wolfram Language code: v = Range[5];

Inverse，MatrixExp，MatrixPowerはDiagonalMatrixと交換できる：

Wolfram Language code: Inverse[DiagonalMatrix[v]] == DiagonalMatrix[1 / v]
Wolfram Language code: MatrixExp[DiagonalMatrix[v]] == DiagonalMatrix[Exp[v]]
Wolfram Language code: MatrixPower[DiagonalMatrix[v], n] == DiagonalMatrix[Power[v, n]]

DetとTrにも互換関係がある：

Wolfram Language code: Det[DiagonalMatrix[v]] == Times@@v
Wolfram Language code: Tr[DiagonalMatrix[v]] == Plus@@v

対角行列と一般行列の積の永久式は，一般行列に対角行列の対角成分を掛けたものの永久式に等しい：

Wolfram Language code: n = 5; diag = DiagonalMatrix[Array[, n]]; mat = Array[C, {n, n}];
Wolfram Language code: Permanent[diag.mat] == Apply[Times, Diagonal[diag]] * Permanent[mat]//Simplify

DiagonalMatrixの対角(Diagonal)はもとのベクトルを返す：

Wolfram Language code: v = RandomReal[1, 100];
Wolfram Language code: Diagonal[DiagonalMatrix[v]] === v

これは，たとえベクトルがSparseArrayオブジェクトであってもそうである：

Wolfram Language code: s = SparseArray[v];
Wolfram Language code: Diagonal[DiagonalMatrix[s]] === s

下対角あるいは上対角のみの行列は常にベキ零である：

Wolfram Language code: MatrixPower[DiagonalMatrix[Range[4], -1], 5]
Wolfram Language code: MatrixPower[DiagonalMatrix[Range[4], 1], 5]

DiagonalMatrix[list, k]で生成される行列のサイズはLength[list]+Abs[k]に等しい：

Wolfram Language code: list = RandomReal[1, RandomInteger[{1, 10}]]; k = RandomInteger[{-20, 20}];
Wolfram Language code: Thread[Dimensions[DiagonalMatrix[list, k]] == Length[list] + Abs[k]]

Bandを使ってDiagonalMatrix[list,k]と等価な対角が構築できる：

Wolfram Language code: list = Range[5]; k = RandomInteger[{-2, 2}];
Wolfram Language code: DiagonalMatrix[list, k] == SparseArray[Band[If[k > 0, {1, 1 + k}, {1 - k, 1}]] -> list, (Length[list] + Abs[k]){1, 1}]

TargetStructure"Sparse"と設定すると両者はSameQになる：

Wolfram Language code: DiagonalMatrix[list, k, TargetStructure -> "Sparse"] === SparseArray[Band[If[k > 0, {1, 1 + k}, {1 - k, 1}]] -> list, (Length[list] + Abs[k]){1, 1}]
Wolfram Research (1988), DiagonalMatrix, Wolfram言語関数， https://reference.wolfram.com/language/ref/DiagonalMatrix.html （2024年に更新）.

テキスト

Wolfram Research (1988), DiagonalMatrix, Wolfram言語関数， https://reference.wolfram.com/language/ref/DiagonalMatrix.html （2024年に更新）.

CMS

Wolfram Language. 1988. "DiagonalMatrix." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2024. https://reference.wolfram.com/language/ref/DiagonalMatrix.html.

APA

Wolfram Language. (1988). DiagonalMatrix. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DiagonalMatrix.html

BibTeX

@misc{reference.wolfram_2026_diagonalmatrix, author="Wolfram Research", title="{DiagonalMatrix}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/DiagonalMatrix.html}", note=[Accessed: 10-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_diagonalmatrix, organization={Wolfram Research}, title={DiagonalMatrix}, year={2024}, url={https://reference.wolfram.com/language/ref/DiagonalMatrix.html}, note=[Accessed: 10-September-2026]}