Wolfram 语言与系统参考资料中心

Eigenvectors

Eigenvectors[m]

给出矩阵 m 的特征向量列表.

Eigenvectors[{m,a}]

给出矩阵 m 的关于 a 的特征向量.

Eigenvectors[m,k]

给出矩阵 m 的前 k 个特征向量.

Eigenvectors[{m,a},k]

给出前 k 个特征向量.

范例

打开所有单元关闭所有单元

基本范例 (5)

精确二维矩阵的特征向量：

Wolfram Language code: Eigenvectors[{{-3, 2}, {-15, 8}}]

将特征向量赋给各变量：

Wolfram Language code:

m = {{1, 2}, {3, 4}};
{v1, v2} = Eigenvectors[m]

将每个特征向量乘以 m 的结果是该特征向量的标量倍数：

Wolfram Language code: {(m.v1/v1), (m.v2/v2)}//Simplify

这些因子是矩阵 m 的特征值：

Wolfram Language code: (%/Eigenvalues[m])

三维矩阵的特征向量：

Wolfram Language code: Eigenvectors[{{1, 2, 3}, {4, 5, 6}, {7, 8, 9}}]

以机器精度计算的特征向量：

Wolfram Language code: Eigenvectors[{{1.1, 2.2, 3.25}, {0.76, 4.6, 5}, {0.1, 0.1, 6.1}}]

符号特征向量：

Wolfram Language code: Eigenvectors[{{a, b}, {c, d}}]

范围 (20)

基本用法 (6)

求机器精度矩阵的特征向量：

Wolfram Language code: Eigenvectors[Table[N[1 / (i + j + 1)], {i, 3}, {j, 3}]]//MatrixForm

近似的 18 位精度的特征向量：

Wolfram Language code: Eigenvectors[Table[N[1 / (i + j + 1), 18], {i, 3}, {j, 3}]]

复矩阵的特征向量：

Wolfram Language code: Eigenvectors[{{1.1 - .2I, 2.2, 3.25}, {0.76, 4.6, 5 - 2I}, {0.1, 0.1 + I, 6.1}}]

精确实矩阵的特征向量：

Wolfram Language code: Eigenvectors[{{(1/3), (1/2), (3/5)}, {(1/2), (4/5), 1}, {(3/5), 1, (9/7)}}]

精确复矩阵的特征向量：

Wolfram Language code: Eigenvectors[{{π, (1/3)}, {I, 5}}]

符号特征向量：

Wolfram Language code:

Eigenvectors[(|   |   |   |
| - | - | - |
| a | 2 | 0 |
| 2 | 3 | 1 |
| 0 | 1 | 7 |)]

高效计算大型数值矩阵的特征向量：

Wolfram Language code: m = RandomReal[{0, 5}, {100, 100}];

Wolfram Language code: Eigenvectors[m] ;//Timing

特征向量的子集 (5)

计算与三个最大的特征值对应的特征向量：

Wolfram Language code: vecs = Eigenvectors[Table[If[Abs[i - j] < 3, 1.0, 0], {i, 100}, {j, 100}] , 3];

可视化这三个向量：

Wolfram Language code: ListPlot[vecs]

与三个最小的特征值对应的特征向量：

Wolfram Language code: Eigenvectors[Table[N[1 / (i + j + 1), 12], {i, 6}, {j, 6}], -3]

求与四个最大的特征值对应的特征向量，如果没有那么多，则有多少给出多少：

Wolfram Language code:

Eigenvectors[(⁠|       |       |       |
| ----- | ----- | ----- |
| (1/3) | (1/4) | (1/5) |
| (1/4) | (1/5) | (1/6) |
| (1/5) | (1/6) | (1/7) |⁠), UpTo[4]]

提取特征值的子集时考虑重复的特征值：

Wolfram Language code: mat = {{(7/2), 0, (1/2), 0}, {0, 3, 0, 1}, {(1/2), 0, (7/2), 0}, {0, 1, 0, 3}};

Wolfram Language code: {v1, v2, v3} = Eigenvectors[mat, 3]

前两个向量都对应于特征值 4：

Wolfram Language code: Solve[mat . v1 == λ v1, λ]

Wolfram Language code: Solve[mat . v2 == λ v2, λ]

第三个对应于特征值 3：

Wolfram Language code: Solve[mat . v3 == λ v3, λ]

当特征值多于独立的特征向量时，将使用零向量：

Wolfram Language code: Eigenvectors[{{2, 1, 0}, {0, 2, 0}, {0, 0, 1}}]

广义的特征向量 (4)

计算机器精度的广义特征特征向量：

Wolfram Language code: a = {{1., 2.}, {3., 4.}};

Wolfram Language code: b = {{1., 4.}, {9., 16.}};

Wolfram Language code: Eigenvectors[{a, b}]

广义的精确特征向量：

Wolfram Language code: a = {{1, 1, 1}, {1, 0, 1}, {0, 0, 1}};

Wolfram Language code: b = {{0, 1, 1}, {0, 1, 1}, {1, 0, 0}};

Wolfram Language code: Eigenvectors[{a, b}]

以有限的精度计算结果：

Wolfram Language code: Eigenvectors[N[{a, b}, 20]]//Chop

计算符号广义特征向量：

Wolfram Language code: a = {{x, 1 + x}, {1 - x, x}};

Wolfram Language code: b = {{1, 1}, {1, 1}};

Wolfram Language code: Eigenvectors[{a, b}]

求与两个最小的广义特征值对应的广义特征向量：

Wolfram Language code:

a = {{1, 2, 3}, {4, 5, 6}, {7, 8, 9}};
b = {{11, 12, 13}, {1, 15, 16}, {17, 18, 19}};
Eigenvectors[{a, b}, -2]

特殊矩阵 (5)

稀疏矩阵的特征向量：

Wolfram Language code: SparseArray[{{1, 3} -> 1, {2, 2} -> 2, {3, 1} -> 3, {4, 2} -> 5}, {4, 4}]

Wolfram Language code: Eigenvectors[%]

Wolfram Language code: SparseArray[Band[{1, 1}, {-1, -1}] -> {{{1, 2}, {2, 1}}}, {4, 4}]

Wolfram Language code: Eigenvectors[%]

结构化矩阵的特征向量：

Wolfram Language code: SymmetrizedArray[{{1, 1} -> 2.2, {1, 2} -> 1.1, {3, 2} -> 5.7}, {3, 3}, Symmetric[All]]

Wolfram Language code: Eigenvectors[%]

Wolfram Language code: QuantityArray[{{1, 2}, {3, 4}}, "Meters"]

QuantityArray 对象的单位在特征值中，而特征向量是无量纲的：

Wolfram Language code: Eigenvectors[%]

IdentityMatrix[n] 的特征向量形成了向量空间的标准基：

Wolfram Language code: Eigenvectors[IdentityMatrix[4]]

HilbertMatrix 的特征向量：

Wolfram Language code: Eigenvectors[HilbertMatrix[3]]

若矩阵先被数值化，其特征向量（而非特征值）将发生显著变化：

Wolfram Language code: Eigenvectors[N[HilbertMatrix[3]]]

这是因为对于数值输入，特征向量已被归一化：

Wolfram Language code: Norm /@ %

CenteredInterval 矩阵的特征向量：

Wolfram Language code: SeedRandom[777];(m = Map[CenteredInterval, RandomReal[{-10, 10}, {3, 3}, WorkingPrecision -> 10], {2}])//MatrixForm

Wolfram Language code: vecs = Eigenvectors[m]

找出 m 的随机代表 mrep 的特征向量：

Wolfram Language code:

ranrep[e_CenteredInterval] := e["Center"] + RandomInteger[{-1000, 1000}] / 1000 e["Radius"]
(mrep = Map[ranrep, m, {2}])//MatrixForm

Wolfram Language code: rvecs = Eigenvectors[mrep]

验证重新排序和缩放后，vecs 包含 rvecs：

Wolfram Language code: MapThread[IntervalMemberQ, {vecs, rvecs[[{3, 1, 2}]] * (Last[#]["Center"]& /@ vecs)}, 2]

选项 (10)

Cubics (1)

3×3 Vandermonde 矩阵：

Wolfram Language code: m = Table[{1, -1, 2} ^ j, {j, 3}]

一般来说，对于精确 3×3 矩阵，结果以 Root 对象给出：

Wolfram Language code: er = Eigenvectors[m]

若要获得以根式表示的结果，使用 Cubics 选项：

Wolfram Language code: ec = Eigenvectors[m, Cubics -> True]

Method (8)

"Arnoldi" (5)

Arnoldi 方法可用于机器和任意精度矩阵. Arnoldi 方法的实现基于 "ARPACK" 程序库. 它对于大型稀疏矩阵很有用.

可为 "Arnoldi" 方法指定下列子选项：

	"BasisSize"	Arnoldi 基向量的大小
	"Criteria"	要使用的标准
	"MaxIterations"	最大迭代次数
	"Shift"	Arnoldi 位移
	"StartingVector"	初始迭代向量
	"Tolerance"	用于终止迭代的容差

"Criteria" 的可能设置包括：

	"Magnitude"	基于 Abs
	"RealPart"	基于 Re
	"ImaginaryPart"	基于 Im
	"BothEnds"	实对称矩阵谱两端的几个特征值

用不同的 "Criteria" 设置计算最大特征向量. 矩阵 m 具有特征值：

Wolfram Language code:

d = DiagonalMatrix[{1, 0.8 + 0.8I, I}];
t = {{1, 2, 0}, {0, 3, 2}, {1, 0, 4}};
m = t.d.Inverse[t];

默认情况下，"Criteria"->"Magnitude" 选择对应于最大幅度特征值的特征向量：

Wolfram Language code: Eigenvectors[m, 1, Method -> "Arnoldi"]

求对应于最大实部特征值的特征向量：

Wolfram Language code: Eigenvectors[m, 1, Method -> {"Arnoldi", "Criteria" -> "RealPart"}]

求对应于最大虚部特征值的特征向量：

Wolfram Language code: Eigenvectors[m, 1, Method -> {"Arnoldi", "Criteria" -> "ImaginaryPart"}]

求来自矩阵谱的两个特征向量：

Wolfram Language code:

d = DiagonalMatrix[{1, 0.8, -1, 2}];
t = Orthogonalize[{{1, 2, 0, 1}, {0, 3, 2, -2}, {1, 0, 4, -1}, {0, 1, 0, 1}}];
m = t.d.Transpose[t];

Wolfram Language code: Eigenvectors[m, 2, Method -> {"Arnoldi", "Criteria" -> "BothEnds"}]

使用 "StartingVector" 避免随机性：

Wolfram Language code:

d = DiagonalMatrix[{1, -1, 0.}];
t = {{1, 2, 0}, {0, 3, 2}, {1, 0, 4}};
m = t.d.Inverse[t];

不同的初始值可能收敛到不同的特征向量：

Wolfram Language code: Eigenvectors[m, 1, Method -> {"Arnoldi", "StartingVector" -> {1, 0, 0}}]

Wolfram Language code: Eigenvectors[m, 1, Method -> {"Arnoldi", "StartingVector" -> {0, 0, 1}}]

使用 "Shift"->μ 通过将矩阵变换为平移特征值. 这保持了特征向量，但是将特征值改变了 -μ. 方法对变化了的特征值进行补偿. "Shift" 通常用于求没有选择最大或者最小幅度的标准的特征对：

Wolfram Language code:

d = DiagonalMatrix[{1, 2, 3}];
t = {{1, 2, 0}, {0, 3, 2}, {1, 0, 4}};
m = N@t.d.Inverse[t];

Wolfram Language code: μ = 2.1;

手动平移矩阵，以获取特征向量：

Wolfram Language code: vl1 = Eigenvectors[m - μ IdentityMatrix[3], -1, Method -> "Arnoldi"]

自动平移，以获取特征向量：

Wolfram Language code: vl2 = Eigenvectors[m, -1, Method -> {"Arnoldi", "Shift" -> μ}]

"Banded" (1)

带状方法可用于实对称或复厄米特机器精度矩阵. 该方法对于求出所有特征向量最有用.

计算带状矩阵的两个最大的特征向量：

Wolfram Language code: s = SparseArray[{{i_, i_} -> -2., {i_, j_} /; Abs[i - j] == 1 -> 1.}, {2000, 2000}];

Wolfram Language code: MatrixPlot[s]

Wolfram Language code: Eigenvectors[s, 2, Method -> "Banded"]; //AbsoluteTiming

"FEAST" (2)

FEAST 方法可用于实对称或者复 Hermitian 机器精度矩阵. 方法对于在给定区间内求特征向量很有用.

可为 "FEAST" 方法指定下列子选项：

	"ContourPoints"	选择围道点的数量
	"Interval"	特征值搜索区间
	"MaxIterations"	最大细化循环次数
	"NumberOfRestarts"	最大重启次数
	"SubspaceSize"	子空间的初始大小
	"Tolerance"	终止细化的容差
	"UseBandedSolver"	是否使用带状求解器

计算对应于来自区间的特征值的特征向量：

Wolfram Language code: s = SparseArray[{{i_, i_} -> -2., {i_, j_} /; Abs[i - j] == 1 -> 1.}, {1000, 1000}];

使用 "Interval" 指定区间：

Wolfram Language code: v1 = Eigenvectors[s, 2, Method -> {"FEAST", "Interval" -> {-1.0, -0.9}}];

Wolfram Language code: ListPlot[v1]

Quartics (1)

4×4 矩阵：

Wolfram Language code: m = Table[{1, 2, -1, -2} ^ j, {j, 4}]

一般来说，对于4×4矩阵，结果以 Root 对象的形式给出：

Wolfram Language code: Eigenvectors[m]

您可以使用 Cubics 和 Quartics 选项获取以根式表示的结果：

Wolfram Language code: Eigenvectors[m, Cubics -> True, Quartics -> True]

应用 (16)

特征向量的几何学 (3)

当被矩阵作用时，特征值为正的特征向量指向相同的方向：

Wolfram Language code:

m = {{1, 2}, {2, 1}};
{λ1, λ2} = Eigenvalues[m]

Wolfram Language code: {v1, v2} = Eigenvectors[m]

Wolfram Language code: Graphics[{{Thick, Arrow[{{0, 0}, v1}]}, {Red, Arrow[{{0, 0}, m.v1}]}}, Axes -> True]

当被矩阵作用时，特征值为负的特征向量指向相反的方向：

Wolfram Language code: Graphics[{{Thick, Arrow[{{0, 0}, v2}]}, {Red, Arrow[{{0, 0}, m.v2}]}}, Axes -> True]

思考以下矩阵及其关联的二次形式：

Wolfram Language code: a = {{-2, 2}, {2, 1}};

Wolfram Language code: q = {x, y}.a.{x, y}//Expand

特征向量是由定义的双曲线的轴：

Wolfram Language code: v = Eigenvectors[a]

特征值的符号对应于双曲线方程右侧的符号：

Wolfram Language code: λ = Eigenvalues[a]

Wolfram Language code:

ContourPlot[Table[q == n, {n, {-9, -4, -1, 1, 4, 9}}]//Evaluate, {x, -3, 3}, {y, -3, 3}, Epilog -> (Arrow[{{0, 0}, #}]& /@ v), PlotLegends -> "Expressions"]

此为三维正定二次式：

Wolfram Language code: q = 20 x ^ 2 - 16 x y + 23 y ^ 2 - 12 x z - 2 y z + 17 z ^ 2;

绘制曲面：

Wolfram Language code: cp = ContourPlot3D[q, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, Contours -> {10}, Mesh -> False, ContourStyle -> Opacity[.5]]

用 CoefficientArrays 得到二次形式的对称矩阵：

Wolfram Language code: m = Normal[CoefficientArrays[q, {x, y, z}, Symmetric -> True][[3]]]

数值计算其特征值和特征向量：

Wolfram Language code: {vals, vecs} = {Eigenvalues[N[m]], Eigenvectors[N[m]]}

显示椭球体的主轴：

Wolfram Language code: Show[cp, Graphics3D[{Thickness[0.015], Green, Table[Line[{{0, 0, 0}, vecs[[i]] * Sqrt[10 / vals[[i]]]}], {i, 1, 3}]}]]

对角化 (5)

将以下矩阵对角化为 . 首先，计算的特征值：

Wolfram Language code: m = {{9, -7, 3}, {12, -10, 3}, {16, -16, 1}};

Wolfram Language code: Eigenvalues[m]

根据特征值构建对角矩阵：

Wolfram Language code: d = DiagonalMatrix[%]

接下来，计算的特征向量并将其放在矩阵的列中：

Wolfram Language code: p = Transpose[Eigenvectors[m]]

确认恒等式：

Wolfram Language code: m == p.d.Inverse[p]

现在可以将矩阵的任何函数以的形式计算. 例如，MatrixPower：

Wolfram Language code: MatrixPower[m, k] == p . MatrixPower[d, k].Inverse[p]

同样，只需要对的对角线元素求幂可使 MatrixExp 变为平凡：

Wolfram Language code: MatrixExp[m] == p . MatrixExp[d].Inverse[p]

Wolfram Language code: MatrixExp[d]

令为其标准矩阵由矩阵给出的线性变换. 求 $TemplateBox[{}, Reals]^4$ 的基，其性质为在该基中的表示为对角矩阵：

Wolfram Language code:

a = (|    |    |   |   |
| -- | -- | - | - |
| -6 | 4  | 0 | 9 |
| -3 | 0  | 1 | 6 |
| -1 | -2 | 1 | 0 |
| -4 | 4  | 0 | 7 |);

设由的特征向量组成，且设为矩阵，其列是的元素：

Wolfram Language code: b = Transpose[Eigenvectors[a]]

从坐标转换为标准坐标. 其逆矩阵变换为反方向：

Wolfram Language code: bInv = Inverse[b]

因此由给出，为对角线矩阵：

Wolfram Language code: bInv . a .b//MatrixForm

请注意这只是对角矩阵，其项为特征值：

Wolfram Language code: % == DiagonalMatrix[Eigenvalues[a]]

实值对称矩阵可正交对角化为，其中为实对角矩阵且为正交矩阵. 验证以下矩阵是否对称，并进行对角化：

Wolfram Language code: (s = {{1, 4, -2}, {4, 5, -3}, {-2, -3, 2}})//MatrixForm

Wolfram Language code: Transpose[s] == s

计算的特征向量：

Wolfram Language code: v = Eigenvectors[s]

对于正交矩阵，需要在将特征向量放入列之前对其正规化：

Wolfram Language code: o = Transpose[FullSimplify[Normalize /@ v]]

计算特征值，结果如预期所想为实数：

Wolfram Language code: λ = Eigenvalues[s]

矩阵在对角线上有特征值：

Wolfram Language code: d = DiagonalMatrix[λ]

验证：

Wolfram Language code: s == o.d.Transpose[o]//FullSimplify

如果，则矩阵称为正规矩阵. 正规矩阵是可以通过酉变换进行对角化的最通用的矩阵类型. 所有实对称矩阵都是正规矩阵，因为等式的两边都仅为：

Wolfram Language code:

TensorExpand[ConjugateTranspose[s].s == s.ConjugateTranspose[s] == s.s, Assumptions -> s∈Matrices[{n, n}, Reals, Symmetric[{1, 2}]]]

证明下面的矩阵是正规矩阵，并对其对角化：

Wolfram Language code: (n = {{3, -1}, {1, 3}})//MatrixForm

Wolfram Language code: n.ConjugateTranspose[n] == ConjugateTranspose[n].n

使用 NormalMatrixQ 进行验证：

Wolfram Language code: NormalMatrixQ[n]

计算特征向量：

Wolfram Language code: v = Eigenvectors[n]

对特征向量进行正规化并将其放置于列中可得到酉矩阵：

Wolfram Language code:

u = Transpose[Normalize /@ v];
UnitaryMatrixQ[u]

非对称实正规矩阵的特征值是复值：

Wolfram Language code: λ = Eigenvalues[n]

根据特征值构造对角矩阵：

Wolfram Language code: (d = DiagonalMatrix[λ])//MatrixForm

验证对角化：

Wolfram Language code: n == u.d.ConjugateTranspose[u]

不可对角化矩阵的特征向量：

Wolfram Language code:

m = {{1, 1, 0}, {0, 1, 0}, {0, 0, 2}};
vecs = Eigenvectors[m]

所有特征向量的空间维度小于矩阵的长度 3：

Wolfram Language code: Count[vecs, v_ /; Norm[v] > 0]

计算一个由 1 和 0 组成的随机 4×4 矩阵不可对角化的概率：

Wolfram Language code:

Block[{nd = 0, trials = 10 ^ 4}, Do[m = N[RandomInteger[1, {4, 4}]];If[Count[Eigenvectors[m], v_ /; Norm[v] > 0] < Length[m], nd++], {trials}];N[nd / trials]]

微分方程和动力系统 (4)

求解常微分方程 (ODE) 方程组 , , . 首先，构造右侧的系数矩阵：

Wolfram Language code: a = {{0, 1, 0}, {0, 0, 1}, {-2, 1, 2}};

求特征值和特征向量：

Wolfram Language code: {λ, v} = {Eigenvalues[a], Eigenvectors[a]}

构造一个对角矩阵，其项是的指数：

Wolfram Language code: d = DiagonalMatrix[Exp[t λ]]

构造其列是对应特征向量的矩阵：

Wolfram Language code: p = Transpose[v]

三个任意起始值的通解为：

Wolfram Language code: p.d.Inverse[p] . {C[1], C[2], C[3]}

使用 DSolveValue 验证解：

Wolfram Language code: Simplify[% == DSolveValue[{x'[t] == y[t], y'[t] == z[t], z'[t] == -2x[t] + y[t] + 2z[t]}, {x[t], y[t], z[t]}, t]]

假设一个粒子在平面力场中运动，其位置向量满足且，其中和为如下. 当时求解初始问题：

Wolfram Language code:

a = (|    |    |
| -- | -- |
| 4  | -5 |
| -2 | 1  |);

Wolfram Language code:

Subscript[x, 0] = (⁠|     |
| --- |
| 1.9 |
| 3.6 |⁠);

首先，计算的特征值和对应的特征向量：

Wolfram Language code: λ = Eigenvalues[a]

Wolfram Language code: v = Eigenvectors[a]

方程组的通解为 . 使用 LinearSolve 确定系数：

Wolfram Language code: c = LinearSolve[Transpose[v], Subscript[x, 0]]

为特征向量构建线性组合：

Wolfram Language code: x[t_] = (c Exp[λ t]).v

使用 DSolveValue 验证该解：

Wolfram Language code:

x[t] == DSolveValue[{{u1'[t], u2'[t]} == a.{u1[t], u2[t]}, {u1[0], u2[0]} == Subscript[x, 0]}, {u1[t], u2[t]}, t] //Simplify//Chop

当是以下随机矩阵时，计算动力系统的通解：

Wolfram Language code:

a = (|     |     |     |
| --- | --- | --- |
| .90 | .01 | .09 |
| .01 | .90 | .01 |
| .09 | .09 | .90 |);

求特征值和特征向量，使用 Chop 丢弃小数值误差：

Wolfram Language code:

{{Subscript[λ, 1], Subscript[λ, 2], Subscript[λ, 3]}, {Subscript[v, 1], Subscript[v, 2], Subscript[v, 3]}} = Chop[{Eigenvalues[a], Eigenvectors[a]}]

通解是形式为的项的任意线性组合：

Wolfram Language code: x[k_] = Sum[C[i] Subsuperscript[λ, i, k]Subscript[v, i], {i, 3}]

验证在数值舍入完成之前满足动力学方程：

Wolfram Language code: x[k] == a.x[k - 1]//Simplify//Chop

Lorenz 方程：

Wolfram Language code:

leqn = {Derivative[1][x][t] == -3(x[t] - y[t]), Derivative[1][y][t] == -x[t] z[t] + 26 x[t] - y[t], Derivative[1][z][t] == x[t] y[t] - z[t]};

求方程右边的雅可比行列式：

Wolfram Language code: lj = D[leqn[[All, 2]], {{x[t], y[t], z[t]}}]

求出平衡点：

Wolfram Language code: eqp = Solve[leqn /. {x'[t] -> 0, y'[t] -> 0, z'[t] -> 0}, {x[t], y[t], z[t]}]

在第一个八分圆处求雅可比行列式的特征值和特征向量：

Wolfram Language code: vals = Eigenvalues[N[lj /. eqp[[3]]]]

Wolfram Language code: vecs = Eigenvectors[N[lj /. eqp[[3]]]]

沿 dir 方向上、 pt 中的向后小干扰积分函数：

Wolfram Language code:

st[pt_, dir_] := First[{x[t], y[t], z[t]} /. NDSolve[{leqn, Thread[{x[0], y[0], z[0]} == pt + 10^-6dir]}, {x, y, z}, {t, 0, -4}]];

显示右侧平衡点的稳定曲线：

Wolfram Language code:

pt = {x[t], y[t], z[t]} /. eqp[[3]];dir = vecs[[3]];sr = ParametricPlot3D[Evaluate[{st[pt, dir], st[pt, -dir]}], {t, 0, -4}, PlotStyle -> Table[{Thickness[0.015], Red}, {2}]]

求出左侧平衡点的稳定曲线：

Wolfram Language code:

pt = {x[t], y[t], z[t]} /. eqp[[2]];{vals, vecs} = Eigensystem[N[lj /. eqp[[2]]]];
dir = vecs[[3]];sl = ParametricPlot3D[Evaluate[{st[pt, dir], st[pt, -dir]}], {t, 0, -4}, PlotStyle -> Table[{Thickness[0.015], Green}, {2}]];

显示带有 Lorenz 方程解的稳定曲线：

Wolfram Language code:

Show[{ParametricPlot3D[Evaluate[{x[t], y[t], z[t]} /. NDSolve[{leqn, x[0] == 5, y[0] == 0, z[0] == 25}, {x, y, z}, {t, 0, 100}]], {t, 0, 100}], sr, sl}, PlotRange -> {{-25, 25}, {-25, 25}, {0, 50}}]

物理 (4)

在量子力学中，状态由复单位向量表示，物理量由厄米特线性算子表示. 特征值表示可能的观测值，关于特征向量的分量的模的平方表示这些观测值的概率. 对于给定的自旋算子和状态，找出可能的观测值及其概率：

Wolfram Language code:

σ = (ℏ/2)(|   |    |
| - | -- |
| 0 | -I |
| I | 0  |);ψ = (1/Sqrt[5])(⁠|     |
| --- |
| 1   |
| 2 I |⁠);

找到特征向量并正规化以计算正确投影：

Wolfram Language code: {e1, e2} = Normalize /@ Eigenvectors[σ]

计算特征值，可能的观测值为 :

Wolfram Language code: Eigenvalues[σ]

的相对概率为，的为：

Wolfram Language code: {Abs[e1.ψ]^2, Abs[e2.ψ]^2}//Simplify

在量子力学中，能量算子称为哈密顿量，根据薛定谔方程具有能量的状态. 给定方向上恒定磁场中自旋 1 粒子的哈密顿量，求处于初始状态表示表示的粒子在时间的状态：

Wolfram Language code:

ℋ = (Subscript[ω, 0]ℏ/Sqrt[2]) (|   |    |    |
| - | -- | -- |
| 0 | -I | 0  |
| I | 0  | -I |
| 0 | I  | 0  |);Subscript[ψ, 0] = {1, 0, 0};

求特征向量并将其归一化：

Wolfram Language code: {Subscript[e, 1], Subscript[e, 2], Subscript[e, 3]} = Normalize /@ Eigenvectors[ℋ]

计算特征值，能级为和：

Wolfram Language code: {Subscript[ℰ, 1], Subscript[ℰ, 2], Subscript[ℰ, 3]} = Eigenvalues[ℋ]

时间的状态是根据薛定谔方程演化的每个特征态的总和：

Wolfram Language code:

ψ[t_] = Underoverscript[∑, i = 1, 3]Exp[-(I Subscript[ℰ, i]t/ℏ)]Subscript[e, i].Subscript[ψ, 0] Subscript[e, i] //FullSimplify

惯性矩是一个实对称矩阵，描述了刚体对不同方向旋转的阻力. 该矩阵的特征值称为主惯性矩，相应的特征向量（必须正交）称为主轴. 求下列四面体的主惯性矩和主轴：

Wolfram Language code: tet = Tetrahedron[{{-1.25, -1, -0.75}, {3.75, -1, -0.75}, {-1.25, 3., -0.75}, {-1.25, -1, 2.25}}]

首先计算惯性矩：

Wolfram Language code: (ℐ = MomentOfInertia[tet])//MatrixForm

主轴为的特征向量：

Wolfram Language code: a = Eigenvectors[ℐ]

主矩是的特征值：

Wolfram Language code: Eigenvalues[ℐ]

验证轴为正交：

Wolfram Language code: a.a//Chop

四面体的质心在原点：

Wolfram Language code: RegionCentroid[tet]

可视化四面体及其主轴：

Wolfram Language code: Graphics3D[{{Opacity[.5], tet}, Arrow[{{0, 0, 0}, 3#}]& /@ a}]

广义特征系统可用于找到解耦项的耦合振荡的正规模. 思考图中所示的系统：

根据胡克定律，该系统服从 , . 代入通解得到矩阵方程，其中刚度矩阵和质量矩阵为如下：

Wolfram Language code:

k = {{k1 + k2, -k2}, {-k2, k2}};
m = {{m1, 0}, {0, m2}};

如果 , , 且，求特征频率和正规模：

Wolfram Language code:

k = k /. {k1 -> 9.5, k2 -> 4.5};
m = m /. {m1 -> 2, m2 -> 3};

可从关于的的广义特征向量推导出模的形状：

Wolfram Language code: v = Eigenvectors[{k, m}]

计算广义特征值：

Wolfram Language code: λ = Eigenvalues[{k, m}]

特征频率是特征值的平方根：

Wolfram Language code: {ω1, ω2} = Sqrt[λ]

将正规模解构造为广义特征向量乘以相应指数：

Wolfram Language code: sol1[t_] = First[v]Exp[I ω1 t];

Wolfram Language code: sol2[t_] = Last[v]Exp[I ω2 t];

验证两者是否满足系统的微分方程：

Wolfram Language code: -k.sol1[t] == m.sol1''[t] && -k.sol2[t] == m.sol2''[t]//FullSimplify

属性和关系 (15)

数值矩阵返回的特征向量是单位向量：

Wolfram Language code: Norm /@ Eigenvectors[{{1., 2.}, {2., 1.}}]

精确矩阵和符号矩阵返回的特征向量通常不是单位向量：

Wolfram Language code: Norm /@ Eigenvectors[{{1, 2}, {2, 1}}]

Eigenvectors[m] 是 Eigensystem 返回的对的第二个元素：

Wolfram Language code:

m = RandomReal[1, {3, 3}];
Eigenvectors[m] == Last[Eigensystem[m]]

如果同时需要特征向量和特征值，仅调用 Eigensystem 通常会更有效：

Wolfram Language code: m = RandomReal[1, {1000, 1000}];

Wolfram Language code: AbsoluteTiming[Eigensystem[m];]

Wolfram Language code: AbsoluteTiming[{Eigenvalues[m], Eigenvectors[m]};]

特征向量求解，其中是特征多项式的根，是单位矩阵：

Wolfram Language code:

m = {{a, b}, {c, d}};
v = Eigenvectors[m]

使用 CharacteristicPolynomial 求根：

Wolfram Language code: λ = SolveValues[CharacteristicPolynomial[m, x] == 0, x]

为了验证等式，带入使用 NullSpace 找到的齐次方程的解：

Wolfram Language code: Join@@ NullSpace[m - # IdentityMatrix[2]]& /@ λ

广义特征向量或者求解，其中是广义特征多项式的根，或者对于某些标量服从：

Wolfram Language code:

m = {{1, 2}, {3, 2}};
a = {{1, 1}, {1, 1}};

Wolfram Language code: {v1, v2} = Eigenvectors[{m, a}]

使用 CharacteristicPolynomial，只有一个根：

Wolfram Language code: {λ} = SolveValues[CharacteristicPolynomial[{m, a}, x] == 0, x]

满足条件：

Wolfram Language code: (m - λ a).v2 == {0, 0}

在时，满足：

Wolfram Language code: m.v1 == -v1 && a.v1 == {0, 0}

当且仅当 DiagonalizableMatrixQ[m] 为 True 时矩阵 m 有一组完整的特征向量：

Wolfram Language code:

diag = {{17, -1 + Sqrt[3], -1 - Sqrt[3]}, {-1 + Sqrt[3], 14 + 2 Sqrt[3], 2}, {-1 - Sqrt[3], 2, 14 - 2 Sqrt[3]}};
{DiagonalizableMatrixQ[diag], Eigenvectors[diag]}

以下矩阵缺少由表示的特征向量：

Wolfram Language code:

nondiag = {{15, 3 + 3 Sqrt[3], 0}, {0, 15 + 3 Sqrt[3], 3}, {3 - 3 Sqrt[3], 0, 15 - 3 Sqrt[3]}};
{DiagonalizableMatrixQ[nondiag], Eigenvectors[nondiag]}

对于可逆矩阵、和具有相同的特征向量：

Wolfram Language code:

m = {{0, 3, 7}, {0, -3, 1}, {-4, 2, -8}};
Eigenvectors[m]

因为特征值是按绝对值排序的，所以会给出相同的向量，但顺序相反：

Wolfram Language code: Eigenvectors[Inverse[m]]

对于解析函数，的特征向量也是的特征向量：

Wolfram Language code:

m = {{1, 1, 0}, {-1, 1, 0}, {0, 0, 5}};
v = Eigenvectors[m]

例如，具有相同的特征向量：

Wolfram Language code: v == Eigenvectors[m.m]

也是：

Wolfram Language code: v == Eigenvectors[MatrixExp[m]]//FullSimplify

实对称矩阵的特征向量为正交：

Wolfram Language code: (s = {{1, 4, -2}, {4, 0, -3}, {-2, -3, 2}})//MatrixForm

矩阵对称：

Wolfram Language code: SymmetricMatrixQ[s]

验证特征向量彼此正交：

Wolfram Language code: v = Eigenvectors[s]

Wolfram Language code: v.Transpose[v]//Simplify

实反对称矩阵的特征向量是正交的：

Wolfram Language code: (a = {{0, 4, -2}, {-4, 0, -3}, {2, 3, 0}})//MatrixForm

这个矩阵是反对称的：

Wolfram Language code: AntisymmetricMatrixQ[a]

验证特征向量彼此正交：

Wolfram Language code: v = Eigenvectors[a]

Wolfram Language code: v.ConjugateTranspose[v]//Simplify

酉矩阵的特征向量为正交：

Wolfram Language code: u = {{1 / Sqrt[2], I / Sqrt[2]}, {I / Sqrt[2], 1 / Sqrt[2]}};

Wolfram Language code: UnitaryMatrixQ[u]

验证特征向量彼此正交：

Wolfram Language code: v = Eigenvectors[u]

Wolfram Language code: v.ConjugateTranspose[v]//Simplify

任何正规矩阵的特征向量都为正交：

Wolfram Language code: n = {{1, 2, -1}, {-1, 1, 2}, {2, -1, 1}};

Wolfram Language code: NormalMatrixQ[n]

确认特征向量为正交：

Wolfram Language code: v = Eigenvectors[n]

Wolfram Language code: v.ConjugateTranspose[v]//Simplify

SingularValueDecomposition[m] 根据和的特征向量构建：

Wolfram Language code: m = {{-5.2, 0, -5, -6.1}, {1.7, 5.4, -4.3, 7.3}, {-10.1, 8.2, 1.3, -2.5}};

Wolfram Language code: {u, Σ, v} = SingularValueDecomposition[m];

的列为的特征向量：

Wolfram Language code: {u//MatrixForm, Eigenvectors[m . ConjugateTranspose[m]]//MatrixForm}

的列为的特征向量：

Wolfram Language code: {v//MatrixForm, Transpose[Eigenvectors[ConjugateTranspose[m].m]]//MatrixForm}

思考具有一组完整特征向量的矩阵：

Wolfram Language code:

m = {{-(1/Sqrt[2]), -(1/Sqrt[2])}, {(1/Sqrt[2]), -(1/Sqrt[2])}};
v = Eigenvectors[m]

JordanDecomposition[m] 返回由特征值和特征向量构建的矩阵：

Wolfram Language code: {s, j} = JordanDecomposition[m]

矩阵将特征向量作为其列，其顺序可能与 Eigenvectors 不同：

Wolfram Language code: s == Transpose[Reverse@v]

对于数值正规矩阵，SchurDecomposition[n,RealBlockDiagonalFormFalse]：

Wolfram Language code:

n = {{1., 3., -1.}, {-1., 1., 3.}, {3., -1., 1.}};
NormalMatrixQ[n]

Wolfram Language code: {q, t} = SchurDecomposition[n, RealBlockDiagonalForm -> False]//Chop

矩阵 q 由特征向量构建，其顺序可能与 Eigenvectors 不同：

Wolfram Language code: v = Eigenvectors[n]//Chop

要验证 q 是否将特征向量作为列，请将每个向量的第一项设置为 1. 以消除 q 和 v 之间的相位差：

Wolfram Language code: Transpose[(#1/First[q])& /@ q] - (v / First /@ v)//Chop

如果矩阵共用一个维度为的零空间，则 Eigenvectors[m₁,m₂] 返回个零向量：

Wolfram Language code:

a = {{1, 1, 1}, {1, 1, 1}, {1, 1, 1}};b = {{1, 2, 3}, {4, 5, 6}, {7, 8, 9}};
NullSpace[a]

关于自身的广义特征值用两个零向量填充：

Wolfram Language code: Eigenvectors[{a, a}]

矩阵有一维零空间：

Wolfram Language code: NullSpace[b]

位于的零空间中：

Wolfram Language code: MatrixRank[Join[NullSpace[a], NullSpace[b]]]

因此，关于的广义特征向量用一个零向量填充：

Wolfram Language code: Eigenvectors[{a, b}]

可能存在的问题 (5)

Eigenvectors 和 Eigenvalues 不能保证绝对按相应顺序给出结果：

Wolfram Language code:

mat = N@AdjacencyMatrix@GraphData["DodecahedralGraph"];
vec7 = Eigenvectors[mat][[7]];
{val6, val7} = Eigenvalues[mat][[{6, 7}]];

第六个和第七个特征值基本上相等但正负相反：

Wolfram Language code: val6 + val7//Chop

在此特定情况下，第七个特征向量不对应于第七个特征值：

Wolfram Language code: Norm[mat.vec7 - val7 vec7]

它对应的是第六个特征值：

Wolfram Language code: Norm[mat.vec7 - val6 vec7]//Chop

用 Eigensystem[mat] 确保相应的结果始终匹配：

Wolfram Language code:

{val, vec} = Eigensystem[mat][[All, 7]];
Norm[mat.vec - val vec]//Chop

通常符号矩阵会很快演变成复杂情况：

Wolfram Language code: Array[Subscript[a, ##]&, {2, 2}]

Wolfram Language code: Eigenvectors[%]

表达式大小的增速甚至高于指数增长：

Wolfram Language code: Table[ByteCount[Eigenvectors[Array[Subscript[a, ##]&, {n, n}]]], {n, 4}]

不是所有矩阵都有完整的一组特征向量：

Wolfram Language code: Eigenvectors[{{7, -1}, {9, 1}}]

使用 JordanDecomposition 进行精确计算：

Wolfram Language code: JordanDecomposition[{{7, -1}, {9, 1}}]

使用 SchurDecomposition 进行数值计算：

Wolfram Language code: SchurDecomposition[N@{{7, -1}, {9, 1}}]

构造 10,000×10,000 的稀疏矩阵：

Wolfram Language code:

n = 10 ^ 4;
s = SparseArray[{Band[{1, 1}] -> 1., Band[{1, -1}, {-1, 1}, {1, -1}] -> 1.}, {n, n}];

Wolfram Language code: ArrayPlot[s, MaxPlotPoints -> 1000, ColorFunction -> (If[# == 0, White, Black]&)]

特征向量矩阵是密集矩阵，大到无法列举：

Wolfram Language code: MemoryConstrained[Eigenvectors[s], 10 ^ 8]

计算最大特征值的特征向量更简单一些：

Wolfram Language code: Timing[Eigenvectors[s, 2];]

当特征向量很相近时，对稀疏矩阵的迭代可能无法收敛：

Wolfram Language code: s = SparseArray[{{x_, y_} /; Abs[x - y] ≤ 1 -> 3. Abs[x - y] - 2.}, {1000, 1000}];

迭代 1000 次后没有收敛：

Wolfram Language code: ListPlot[Eigenvectors[s, 3]]

你可以给该算法一个接近的预期特征值，以加快收敛：

Wolfram Language code: ListPlot[Eigenvectors[s, 3, Method -> {"Arnoldi", "Shift" -> -4}]]

巧妙范例 (1)

带状矩阵的前四个特征向量：

Wolfram Language code:

n = 200;
s = N[SparseArray[{i_, j_} /; Abs[i - j] == 1 -> i - j, {n, n}]];
vecs = Eigenvectors[s, 4, Method -> {"Arnoldi", MaxIterations -> 2000}];

前四个特征向量的图：

Wolfram Language code:

Show[MapThread[Function[{c, v}, Graphics3D[{c, MapIndexed[Point[Join[#2, {Re[#1], Im[#1]}]]&, v]}]], {{Red, Yellow, Blue, Green}, vecs}], Axes -> True, BoxRatios -> {1, 1, 1}]

Top

Cubics	False	是否使用根式求解三次曲线
Method	Automatic	使用的方法
Quartics	False	是否使用根式求解四次曲线
ZeroTest	Automatic	测试来判断什么时候表达式等于零

	"Arnoldi"	Arnoldi 迭代方法，以求解一些特征值
	"Banded"	厄米特矩阵的带状矩阵直接求解器 (direct banded matrix solver)
	"Direct"	求解所有特征值的直接方法
	"FEAST"	FEAST 迭代方法，以求解某区间内的特征值（只应用于 Hermitian 矩阵）

Eigenvectors

更多信息和选项

范例

基本范例 (5)

范围 (20)

基本用法 (6)

特征向量的子集 (5)

广义的特征向量 (4)

特殊矩阵 (5)

选项 (10)

Cubics (1)

Method (8)

"Arnoldi" (5)

"Banded" (1)

"FEAST" (2)

Quartics (1)

应用 (16)

特征向量的几何学 (3)

对角化 (5)

微分方程和动力系统 (4)

物理 (4)

属性和关系 (15)

可能存在的问题 (5)

巧妙范例 (1)

参见

技术笔记

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX