WOLFRAM

Wolfram 语言与系统参考资料中心

EntityClass[type,name]

表示由 name 识别的指定类型的实体类别.

EntityClass[type,{property1vspec1,property2vspec2,…}]

表示包含指定类型实体的隐式定义的实体类，其属性 propertyi 符合值选择器 vspeci.

EntityClass[cspec,psel]

表示一个实体类别，其成员由 cspec 指定，由属性选择器 psel 选择.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
可能存在的问题  
参见
技术笔记
相关指南
历史
按以下格式引用：

EntityClass   

实体类型列表»

EntityClass[type,name]

表示由 name 识别的指定类型的实体类别.

EntityClass[type,{property1vspec1,property2vspec2,…}]

表示包含指定类型实体的隐式定义的实体类，其属性 propertyi 符合值选择器 vspeci.

EntityClass[cspec,psel]

表示一个实体类别，其成员由 cspec 指定，由属性选择器 psel 选择.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (7)

使用 WolframAlpha 界面探索特定实体：

Wolfram Language code: ["united nations"]

表示所有欧洲国家：

Wolfram Language code: EntityClass["Country", "Europe"]

获取所有国家列表：

Wolfram Language code: EntityList[%]

获取所有酒精化学物质列表：

Wolfram Language code: EntityList[EntityClass["Chemical", "Alcohols"]]//Shallow

获取所有 G7 国家人口列表：

Wolfram Language code: EntityValue[EntityClass["Country", "GroupOf7"], "Population"]

可以使用 EntityClassList 找到可用实体类型列表：

Wolfram Language code: EntityClassList["MinorPlanet"]
Wolfram Language code: EntityValue[EntityClass["MinorPlanet", "InnerMainBeltAsteroid"], "EntityCount"]

创建一个隐式定义实体类，由密度落在指定范围内的所有元素组成：

Wolfram Language code: EntityClass["Element", {"Density" -> Quantity[Interval[{5, 8}], "Grams" / "Centimeters" ^ 3]}]

Explicitly list the elements:

Wolfram Language code: EntityList[%]

使用隐式定义的实体类，选择世界上边界线最长的10个国家，并且将它们与相应边界长度一起返回：

Wolfram Language code: EntityValue[EntityClass["Country", {EntityProperty["Country", "BoundaryLength"] -> TakeLargest[10]}], EntityProperty["Country", "BoundaryLength"], "EntityAssociation"]

范围  (7)

隐式定义实体类可以使用任意数量的属性值进行指定：

Wolfram Language code: EntityClass["Aircraft", {"CruiseSpeed" -> Quantity[Interval[{550, 600}], "Miles" / "Hours"], "Height" -> Quantity[Interval[{75, 200}], "Feet"], "Wingspan" -> Quantity[Interval[{75, 80}], "Meters"] }]

返回满足上述标准的飞行器列表：

Wolfram Language code: EntityList[%]

列出同时满足最大和最小次序条件与显式属性值的组合的实体：

Wolfram Language code: EntityClass["Polyhedron", {"FaceCount" -> TakeLargest[95], "EdgeCount" -> TakeSmallest[95], "VertexCount" -> 14}]["Entities"]

按人口列出 8 国集团中最大的三个国家：

Wolfram Language code: EntityList[EntityClass[EntityClass["Country", "G8"], "Population" -> TakeLargest[3]]]

获取一个 EntityClass 的相关信息：

Wolfram Language code: Information[EntityClass["Element", "NobleGas"]]

计算所有按照最大公狗身高指定的狗的品种的最小体重的均值和标准差：

Wolfram Language code: EntityValue[EntityClass["DogBreed", {EntityProperty["DogBreed", "HeightMaleMinimum"] -> Quantity[Interval[{15, 18}], "Inches"]}], EntityProperty["DogBreed", "WeightMaleMaximum"], {Mean, StandardDeviation}]

构建一个由安吉丽娜茱莉亚主演的电影所组成的隐式定义实体：

Wolfram Language code: ajmovies = EntityClass["Movie", {EntityProperty["Movie", "Cast"] -> Entity["Person", "AngelinaJolie::8cggf"]}];

获取这些电影的名称、发布日期和海报：

Wolfram Language code: (ajmoviedata = Values[DeleteMissing[EntityValue[ajmovies, {EntityProperty["Movie", "Name"], EntityProperty["Movie", "ReleaseDate"], EntityProperty["Movie", "Image"]}, "EntityAssociation"], 1, 2]])//Short

制作一个时间轴，显示这些电影上映的时间：

Wolfram Language code: TimelinePlot[Labeled[#2, Tooltip[#3, Column[{#1, #2}]]]&@@@ajmoviedata, PlotLayout -> "ReverseVertical"]

确定哪些测量设备是温度计的范例：

Wolfram Language code: EntityClass["MeasurementDevice", {"InstanceOf" -> ContainsAll[{Entity["MeasurementDevice", "Thermometer"]}]}]//EntityList

列出 1930 年发现的所有物理效应：

Wolfram Language code: EntityClass["PhysicalEffect", {"DiscoveryDate" -> DateObject[{1930}]}]//EntityList

应用  (7)

使用一个由五个最长的消化器官组成的隐式定义的实体类，并返回上述消化器官及其图像：

Wolfram Language code: organ = EntityClass["AnatomicalStructure", {EntityProperty["AnatomicalStructure", "EntityClasses"] -> EntityClass["AnatomicalStructure", "DigestiveOrgans"], EntityProperty["AnatomicalStructure", "Length", {"StatisticalGroup" -> Entity["StatisticalGroup", "AverageOfAll"]}] -> TakeLargest[5]}];
Wolfram Language code: EntityValue[organ, {"Length", "Image"}, "Dataset"]

使用一个隐式定义的实体类，按产绒量查找排序前 10 的羊品种，返回上述品种及其图像：

Wolfram Language code: sheep = EntityClass["SheepBreed", {EntityProperty["SheepBreed", "FleeceWeight"] -> TakeLargest[10]}];
Wolfram Language code: EntityValue[sheep, {"FleeceWeight", "Image"}, "Dataset"]

查找体重在 50 至 100 公斤之间的黄色神奇宝贝：

Wolfram Language code: pok = EntityClass["Pokemon", {EntityProperty["Pokemon", "EntityClasses"] -> EntityClass["Pokemon", "Yellow"], EntityProperty["Pokemon", "Weight"] -> Between[{Quantity[50, "Kilograms"], Quantity[100, "Kilograms"]}]}];

将上述神奇宝贝的图像按体重加权制成拼贴画：

Wolfram Language code: ImageCollage[Rule@@@EntityValue[pok, {"Weight", "Image"}], Background -> White]

视星等在 和 1 之间的恒星：

Wolfram Language code: EntityList[EntityClass["Star", {"ApparentMagnitude" -> Between[{-1, 1}]}]]

最近的 15 颗恒星：

Wolfram Language code: EntityList[EntityClass["Star", {"DistanceFromEarth" -> TakeSmallest[15]}]]

15 颗最亮的恒星：

Wolfram Language code: brightest = EntityClass["Star", {"ApparentMagnitude" -> TakeSmallest[15]}];
Wolfram Language code: EntityList[brightest]
Wolfram Language code: ResourceFunction["HertzsprungRussellDiagram"][brightest]

找到同时属于 15 颗最近和最亮的恒星：

Wolfram Language code: EntityList[EntityClass["Star", {"DistanceFromEarth" -> TakeSmallest[15], "ApparentMagnitude" -> TakeSmallest[15]}]]

太阳系中最大的三颗行星：

Wolfram Language code: EntityList[EntityClass["Planet", {"Radius" -> TakeLargest[3]}]]

除太阳外，离地球最近的恒星：

Wolfram Language code: EntityList[EntityClass["Star", {EntityProperty["Star", "DistanceFromEarth", {}] -> TakeSmallest[1], "EntityClasses" -> EntityClass["Star", "NightSkyStar"]}]]

按距离排序 2013 年 1 月 3 日离地球最近的三颗行星：

Wolfram Language code: date = DateObject[{2013, 1, 13}];
Wolfram Language code: datedproperty = Dated["DistanceFromEarth", date];
Wolfram Language code: ec = EntityClass["Planet", {datedproperty -> TakeSmallest[3]}];
Wolfram Language code: EntityValue[SortedEntityClass[ec, datedproperty], datedproperty, "Dataset"]

查找与古德曼尼（Gudermannian）函数有关的数学函数：

Wolfram Language code: EntityClass["MathematicalFunction", {"RelatedFunctions" -> ContainsAny[{Entity["MathematicalFunction", "Gudermannian"]}]}]//EntityList

寻找有 10 个以上命名恒等式的数学函数：

Wolfram Language code: EntityClass["MathematicalFunction", {"NamedIdentities" -> (Length[#] > 10&)}]//EntityList

获取一个自由度为 2 的随机物理系统：

Wolfram Language code: RandomEntity[EntityClass["PhysicalSystem", {EntityProperty["PhysicalSystem", "DegreesOfFreedom"] -> 2}]]

属性和关系  (1)

获取人口最多的三个洲：

Wolfram Language code: EntityClass[ ExtendedEntityClass[ AggregatedEntityClass["Country", "Population" -> Total, "Continent"], "Population" -> EntityFunction[e, e["Population"] /. _Missing :> Quantity[0, "People"]] ], "Population" -> TakeLargest[3] ][{"Continent", "Population"}]

可能存在的问题  (1)

隐式实体类可能不包含实体：

Wolfram Language code: EntityClass["Building", {"FloorCount" -> Interval[{800, 900}]}]
Wolfram Language code: EntityList[%]

验证世界上建筑的楼层数甚至比上述指定区间的下端点都小（得多）：

Wolfram Language code: EntityValue[EntityClass["Building", {"FloorCount" -> TakeLargest[5]}], "FloorCount", "EntityAssociation"]
Wolfram Research (2014)，EntityClass，Wolfram 语言函数，https://reference.wolfram.com/language/ref/EntityClass.html （更新于 2019 年）.

文本

Wolfram Research (2014)，EntityClass，Wolfram 语言函数，https://reference.wolfram.com/language/ref/EntityClass.html （更新于 2019 年）.

CMS

Wolfram 语言. 2014. "EntityClass." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2019. https://reference.wolfram.com/language/ref/EntityClass.html.

APA

Wolfram 语言. (2014). EntityClass. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/EntityClass.html 年

BibTeX

@misc{reference.wolfram_2026_entityclass, author="Wolfram Research", title="{EntityClass}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/EntityClass.html}", note=[Accessed: 07-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_entityclass, organization={Wolfram Research}, title={EntityClass}, year={2019}, url={https://reference.wolfram.com/language/ref/EntityClass.html}, note=[Accessed: 07-September-2026]}