WOLFRAM

Wolfram 语言与系统参考资料中心

ExponentialPowerDistribution[κ,μ,σ]

表示形状参数为 κ、定位参数为 μ 以及尺度参数为 σ 的指数幂分布.

ExponentialPowerDistribution[κ]

表示一个本地参数为0且尺度参数为1的指数幂分布.

更多信息
Details and Options Details and Options
背景
范例  
基本范例  
范围  
应用  
属性和关系  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

ExponentialPowerDistribution

ExponentialPowerDistribution[κ,μ,σ]

表示形状参数为 κ、定位参数为 μ 以及尺度参数为 σ 的指数幂分布.

ExponentialPowerDistribution[κ]

表示一个本地参数为0且尺度参数为1的指数幂分布.

更多信息

背景

范例

打开所有单元 关闭所有单元

基本范例  (4)

概率密度函数：

Wolfram Language code: Plot[Table[PDF[ExponentialPowerDistribution[κ, 1, 3], x], {κ, {1 / 2, 1.5, 6}}]//Evaluate, {x, -5, 8}, Filling -> Axis, Exclusions -> None]
Wolfram Language code: Plot[Table[PDF[ExponentialPowerDistribution[3, μ, .8], x], {μ, {-1 / 2, 1, 2}}]//Evaluate, {x, -3, 5}, Filling -> Axis, Exclusions -> None]
Wolfram Language code: Plot[Table[PDF[ExponentialPowerDistribution[3, 1, σ], x], {σ, {0.7, 1.1, 2}}]//Evaluate, {x, -3, 5}, Filling -> Axis, Exclusions -> None]
Wolfram Language code: PDF[ExponentialPowerDistribution[κ, μ, σ], x]

累积分布函数：

Wolfram Language code: Plot[Table[CDF[ExponentialPowerDistribution[κ, 1, 3], x], {κ, {1 / 2, 1.5, 6}}]//Evaluate, {x, -5, 8}, Filling -> Axis, Exclusions -> None]
Wolfram Language code: Plot[Table[CDF[ExponentialPowerDistribution[3, μ, .8], x], {μ, {-1 / 2, 1, 2}}]//Evaluate, {x, -3, 5}, Filling -> Axis, Exclusions -> None]
Wolfram Language code: Plot[Table[CDF[ExponentialPowerDistribution[3, 1, σ], x], {σ, {0.7, 1.1, 2}}]//Evaluate, {x, -3, 5}, Filling -> Axis, Exclusions -> None]
Wolfram Language code: CDF[ExponentialPowerDistribution[κ, μ, σ], x]

均值和方差：

Wolfram Language code: Mean[ExponentialPowerDistribution[κ, μ, σ]]
Wolfram Language code: Variance[ExponentialPowerDistribution[κ, μ, σ]]

中位数：

Wolfram Language code: Median[ExponentialPowerDistribution[κ, μ, σ]]

范围  (8)

生成指数幂分布的伪随机数样本：

Wolfram Language code: data = RandomVariate[ExponentialPowerDistribution[3, 1, 2], 10 ^ 4];

比较其直方图与概率密度函数：

Wolfram Language code: Show[ Histogram[data, 20, "PDF"], Plot[PDF[ExponentialPowerDistribution[3, 1, 2], x], {x, Min[data], Max[data]}, PlotStyle -> Thick]]

分布参数估计：

Wolfram Language code: sample = RandomVariate[ExponentialPowerDistribution[2, 1, 3], 10 ^ 3];

从样本数据估计分布参数：

Wolfram Language code: edist = EstimatedDistribution[sample, ExponentialPowerDistribution[k, μ, σ]]

比较样本密度直方图和估计分布的概率密度函数：

Wolfram Language code: Show[Histogram[sample, Automatic, "PDF"], Plot[PDF[edist, x], {x, Min[sample], Max[sample]}, PlotStyle -> Thick]]

指数幂分布是对称的：

Wolfram Language code: Skewness[ExponentialPowerDistribution[κ, μ, σ]]

峰度仅与形状参数 κ 有关：

Wolfram Language code: Plot[Kurtosis[ExponentialPowerDistribution[κ, μ, σ]], {κ, 0, 10}, Filling -> Axis]
Wolfram Language code: Kurtosis[ExponentialPowerDistribution[κ, μ, σ]]

峰度的极限值：

Wolfram Language code: Limit[Kurtosis[ExponentialPowerDistribution[κ, μ, σ]], κ -> ∞]

以参数的函数形式表示不同矩量的解析式：

Wolfram Language code: FormulaGrid[list_, type_] := Grid[...]

Moment:

Wolfram Language code: FormulaGrid[Table[Moment[ExponentialPowerDistribution[κ, μ, σ], k], {k, 5}], M]

CentralMoment:

Wolfram Language code: FormulaGrid[Table[CentralMoment[ExponentialPowerDistribution[κ, μ, σ], k], {k, 5}], CM]

FactorialMoment:

Wolfram Language code: FormulaGrid[Table[FactorialMoment[ExponentialPowerDistribution[κ, μ, σ], k]//Simplify, {k, 5}], FM]

Cumulant:

Wolfram Language code: FormulaGrid[Table[Cumulant[ExponentialPowerDistribution[κ, μ, σ], k], {k, 5}], C]

随着参数 κ 的不同，风险函数具有不同的形状：

Wolfram Language code: Plot[Table[HazardFunction[ExponentialPowerDistribution[κ, 3, 2], x], {κ, {1 / 2, 2, 6}}]//Evaluate, {x, -5, 5}, Filling -> Axis, Exclusions -> None]

分位数函数：

Wolfram Language code: Plot[Table[Quantile[ExponentialPowerDistribution[κ, 3, .2], q], {κ, {0.5, 1, 3}}]//Evaluate, {q, 0, 1}, Exclusions -> None, Filling -> Axis]
Wolfram Language code: Quantile[ExponentialPowerDistribution[κ, μ, σ], q]

持续在参数中使用 Quantity 会生成 QuantityDistribution：

Wolfram Language code: len𝒟 = ExponentialPowerDistribution[Quantity[3, "Percent"], Quantity[5.2, "Yards"], Quantity[10, "Yards"]]

求出 QuartileDeviation：

Wolfram Language code: QuartileDeviation[len𝒟]

应用  (1)

ExponentialPowerDistribution 可作为服从 DirichletDistribution 分布的一个随机向量的长度所服从的分布的平滑近似：

Wolfram Language code: len𝒟 = TransformedDistribution[Sqrt[u ^ 2 + v ^ 2], {u, v}DirichletDistribution[{3, 2, 1}]];

概率密度函数：

Wolfram Language code: pdf = PDF[len𝒟, x]

创建一个样本：

Wolfram Language code: lens = RandomVariate[len𝒟, 10 ^ 4];

对数据进行指数幂分布拟合：

Wolfram Language code: edist = EstimatedDistribution[lens, ExponentialPowerDistribution[κ, μ, σ], ParameterEstimator -> {"MaximumLikelihood", MaxIterations -> 500}]

比较样本直方图和这两个分布的概率密度函数：

Wolfram Language code: Show[Histogram[lens, 20, "PDF"], Plot[{PDF[edist, x], pdf}, {x, 0, 1}, PlotRange -> All, PlotStyle -> Thick, PlotLegends -> {"exponential power", "length of Dirichlet vector"}]]

比较均值：

Wolfram Language code: {Mean[len𝒟], Mean[edist]}
Wolfram Language code: N[%]

属性和关系  (5)

当平移并且使用一个正因子为比例进行缩放时，新生成的分布仍然是指数幂分布：

Wolfram Language code: TransformedDistribution[a * u + loc, uExponentialPowerDistribution[κ]]

均值和尺度参数为任意值的情况下：

Wolfram Language code: TransformedDistribution[a * u + loc, uExponentialPowerDistribution[κ, μ, σ]]

ExponentialPowerDistribution 可能比 NormalDistribution 更狭窄或者更宽，取决于形状参数 κ 的值：

Wolfram Language code: {mean, sd} = {Mean[ExponentialPowerDistribution[κ, μ, σ]], StandardDeviation[ExponentialPowerDistribution[κ, μ, σ]]}
Wolfram Language code: Block[{μ = 0, σ = 4}, Table[Plot[{PDF[NormalDistribution[mean, sd], x], PDF[ExponentialPowerDistribution[κ, μ, σ], x]}, {x, -10, 10}, PlotRange -> All, PlotLabel -> Row[{"κ =", Text[κ]}]], {κ, {1.3, 1.7, 2.5, 4}}]]

与其它分布的关系：

LaplaceDistribution 是一种特殊的指数幂分布：

Wolfram Language code: CDF[ExponentialPowerDistribution[1, μ, β], x]
Wolfram Language code: CDF[LaplaceDistribution[μ, β], x]
Wolfram Language code: % - %%//FullSimplify

NormalDistribution 是 ExponentialPowerDistribution 的一个特例：

Wolfram Language code: PDF[ExponentialPowerDistribution[2, μ, σ], x]
Wolfram Language code: PDF[NormalDistribution[μ, σ], x]
Wolfram Language code: % - %%//FullSimplify

巧妙范例  (1)

有不同累积分布函数等高线 κ 值的概率分布函数：

Wolfram Language code: dist = ExponentialPowerDistribution[κ];cdf = Function[{x, κ}, Evaluate[CDF[dist, x]]]; ql = {0.025, 0.10, 0.25, 0.5, 0.75, 0.90, 0.975}; cl = Table[ColorData["Rainbow"][q], {q, Join[{0.0}, ql]}];
Wolfram Language code: Legended[Plot3D[PDF[dist, x], {x, -3, 3}, {κ, 0.2, 4}, PlotTheme -> "Marketing", MeshFunctions -> {cdf}, Mesh -> {ql}, MeshStyle -> GrayLevel[0.8], MeshShading -> cl, AxesLabel -> Automatic, BaseStyle -> Opacity[0.9], ImageSize -> 400, PlotRange -> All], BarLegend["Rainbow", ql, LegendLabel -> "prob"]]
Wolfram Research (2010)，ExponentialPowerDistribution，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ExponentialPowerDistribution.html （更新于 2016 年）.

文本

Wolfram Research (2010)，ExponentialPowerDistribution，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ExponentialPowerDistribution.html （更新于 2016 年）.

CMS

Wolfram 语言. 2010. "ExponentialPowerDistribution." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2016. https://reference.wolfram.com/language/ref/ExponentialPowerDistribution.html.

APA

Wolfram 语言. (2010). ExponentialPowerDistribution. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ExponentialPowerDistribution.html 年

BibTeX

@misc{reference.wolfram_2026_exponentialpowerdistribution, author="Wolfram Research", title="{ExponentialPowerDistribution}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/ExponentialPowerDistribution.html}", note=[Accessed: 10-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_exponentialpowerdistribution, organization={Wolfram Research}, title={ExponentialPowerDistribution}, year={2016}, url={https://reference.wolfram.com/language/ref/ExponentialPowerDistribution.html}, note=[Accessed: 10-September-2026]}