WOLFRAM

Wolfram 语言与系统参考资料中心

GeoDistance[{lat1,lon1},{lat2,lon2}]

给出地球上用经纬度表示的位置之间的地理距离.

GeoDistance[loc1,loc2]

给出由位置对象或者地理实体指定的位置之间的距离.

GeoDistance[{loc1,…,locn}]

给出从 loc1 到 locn、经过所有中间 loci 的总距离.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
地理数据  
历史数据  
选项  
DistanceFunction  
UnitSystem  
应用  
属性和关系  
可能存在的问题  
参见
相关指南
相关链接
历史
按以下格式引用：

GeoDistance

GeoDistance[{lat1,lon1},{lat2,lon2}]

给出地球上用经纬度表示的位置之间的地理距离.

GeoDistance[loc1,loc2]

给出由位置对象或者地理实体指定的位置之间的距离.

GeoDistance[{loc1,…,locn}]

给出从 loc1 到 locn、经过所有中间 loci 的总距离.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (6)

参考椭圆上两个位置之间的距离：

Wolfram Language code: GeoDistance[{37, -109}, {40.113, -88.261}]

两个城市之间的距离：

Wolfram Language code: GeoDistance[Entity["City", {"Chicago", "Illinois", "UnitedStates"}], Entity["City", {"Tokyo", "Tokyo", "Japan"}]]

两个完全指定的大地测量位置之间的距离：

Wolfram Language code: GeoDistance[GeoPosition[{37, -109, 150}, "ITRF00"], GeoPosition[{40.113, -88.261, 192.868}, "ITRF00"]]

两个历史实体最接近时的距离：

Wolfram Language code: GeoDistance[Entity["MilitaryConflict", "BattleOfZama"], Entity["HistoricalCountry", "RomanRepublic"]]

一个位置到一组不同位置之间的距离：

Wolfram Language code: GeoDistance[{37, -109}, {{40.113, -88.261}, Entity["City", {"Chicago", "Illinois", "UnitedStates"}], GeoPosition[{38.52, -85.23}]}]
Wolfram Language code: Normal[%]

几个位置间的总距离：

Wolfram Language code: GeoDistance[{Entity["City", {"LosAngeles", "California", "UnitedStates"}], Entity["City", {"Dallas", "Texas", "UnitedStates"}], Entity["City", {"Miami", "Florida", "UnitedStates"}]}]

范围  (11)

地理数据  (8)

地球上任意两点之间的距离，使用默认数据 "ITRF00" 的参数表示：

Wolfram Language code: GeoDistance[{46.42, -21.02}, {-30.23, 40.51}]

角度也可以指定为 DMS 字符串：

Wolfram Language code: GeoDistance["46°25'12''N 21°1'12''W", {"30°13'48.''S", "40°30'36.''E"}]

或作为 Quantity 对象：

Wolfram Language code: GeoDistance[{Quantity[46.42, "AngularDegrees"], Quantity[-21.02, "AngularDegrees"]}, {Quantity[-30.23, "AngularDegrees"], Quantity[40.51, "AngularDegrees"]}]

计算 Entity 对象之间的距离：

Wolfram Language code: GeoDistance[Entity["Country", "Spain"], Entity["Country", "Germany"]]

或者 Entity 对象与地理位置之间：

Wolfram Language code: GeoDistance[GeoPosition[{40, -4}], Entity["Country", "Germany"]]

测地位置之间的距离，以不同格式表示：

Wolfram Language code: p = GeoPosition[{46.42, -21.02}]
Wolfram Language code: q = GeoGridPosition[{0.7, 0.9}, "Mercator"]
Wolfram Language code: GeoDistance[p, q]
Wolfram Language code: GeoDistance[GeoPositionXYZ[p], GeoPositionENU[q, GeoPosition[{0, 0}]]]

计算一个常见位置到一组以任意格式给出的不同位置之间的距离：

Wolfram Language code: GeoDistance[Here, {{0, 0}, Entity["City", {"Paris", "IleDeFrance", "France"}], GeoPosition[{40, 20}], GeoGridPosition[{40, 20}, "Mercator"]}]

归一化所得 QuantityArray 对象：

Wolfram Language code: Normal[%]

计算两组位置之间的距离矩阵：

Wolfram Language code: SeedRandom[1234]; locs1 = RandomGeoPosition[100]; locs2 = RandomGeoPosition[200];
Wolfram Language code: AbsoluteTiming[dists12 = GeoDistance[locs1, locs2]]

单独计算所有单个距离比较慢：

Wolfram Language code: AbsoluteTiming[outer = Outer[GeoDistance, locs1["Data"], locs2["Data"], 1];]
Wolfram Language code: dists12 == outer

GeoDistance 计算中忽略高度和时间信息：

Wolfram Language code: GeoDistance[GeoPosition[{20, 30, 100}], GeoPosition[{-20, -30, 200, 3.6 10 ^ 9}]]
Wolfram Language code: % === GeoDistance[GeoPosition[{20, 30}], GeoPosition[{-20, -30}]]

不同数据中的点. 第二个点的数据改为第一个点的数据：

Wolfram Language code: GeoDistance[GeoPosition[{30., 40.}, "ITRF90"], GeoPosition[{-50., -60.}, "WGS72"]]
Wolfram Language code: GeoDistance[GeoPosition[{30., 40.}], GeoPosition[{-50., -60.}]]

差异很小：

Wolfram Language code: UnitConvert[% - %%, "Meters"]

几个位置间的总距离：

Wolfram Language code: GeoDistance[{Entity["City", {"LosAngeles", "California", "UnitedStates"}], GeoPosition[{40, -90}], Entity["City", {"Miami", "Florida", "UnitedStates"}]}]
Wolfram Language code: % == GeoDistance[Entity["City", {"LosAngeles", "California", "UnitedStates"}], GeoPosition[{40, -90}]] + GeoDistance[GeoPosition[{40, -90}], Entity["City", {"Miami", "Florida", "UnitedStates"}]]

历史数据  (3)

两个历史实体之间的距离是它们在同一时期领土之间的最小距离：

Wolfram Language code: GeoDistance[Entity["HistoricalCountry", "RomanRepublic"], Entity["HistoricalCountry", "HanDynasty"]]

使用 GeoVariant "UnionArea" 进行计算，忽略时间信息：

Wolfram Language code: GeoDistance[Entity["HistoricalCountry", "RomanRepublic"], GeoVariant[Entity["HistoricalCountry", "HanDynasty"], "UnionArea"]]

Dated 将历史实体限制在特定日期：

Wolfram Language code: GeoDistance[Entity["HistoricalCountry", "RomanRepublic"], Dated[Entity["HistoricalCountry", "HanDynasty"], -200]]

Dated 也可以给出一个日期间隔、一对日期或年份：

Wolfram Language code: GeoDistance[Entity["HistoricalCountry", "RomanRepublic"], Dated[Entity["HistoricalCountry", "HanDynasty"], {-200, -150}]]

历史实体与非历史实体之间的距离是通过所有领土计算得出的：

Wolfram Language code: GeoDistance[Entity["HistoricalCountry", "RomanEmpire"], Entity["City", {"London", "GreaterLondon", "UnitedKingdom"}]]

Dated 可用于将多边形限制在给定的日期或时间间隔内：

Wolfram Language code: GeoDistance[Dated[Entity["HistoricalCountry", "RomanEmpire"], 50], Entity["City", {"London", "GreaterLondon", "UnitedKingdom"}]]

选项  (2)

DistanceFunction  (1)

对于扩展实体，距离按照边界点之间的最小值计算：

Wolfram Language code: GeoDistance[Entity["AdministrativeDivision", {"Illinois", "UnitedStates"}], Entity["AdministrativeDivision", {"Florida", "UnitedStates"}], DistanceFunction -> "Boundary"]

中心之间的距离更大：

Wolfram Language code: GeoDistance[Entity["AdministrativeDivision", {"Illinois", "UnitedStates"}], Entity["AdministrativeDivision", {"Florida", "UnitedStates"}], DistanceFunction -> "Center"]

当一个实体在另一个中时，可以使用距离的带符号定义：

Wolfram Language code: GeoDistance[Entity["AdministrativeDivision", {"Illinois", "UnitedStates"}], Entity["City", {"Champaign", "Illinois", "UnitedStates"}]]
Wolfram Language code: GeoDistance[Entity["AdministrativeDivision", {"Illinois", "UnitedStates"}], Entity["City", {"Champaign", "Illinois", "UnitedStates"}], DistanceFunction -> "SignedBoundary"]

UnitSystem  (1)

结果的默认单位根据 $UnitSystem 的值决定：

Wolfram Language code: $UnitSystem
Wolfram Language code: GeoDistance[Entity["City", {"NewYork", "NewYork", "UnitedStates"}], Entity["City", {"London", "GreaterLondon", "UnitedKingdom"}]]

改为一个不同的系统：

Wolfram Language code: GeoDistance[Entity["City", {"NewYork", "NewYork", "UnitedStates"}], Entity["City", {"London", "GreaterLondon", "UnitedKingdom"}], UnitSystem -> "Metric"]

应用  (2)

计算你所处的位置到所有美国所有州首府城市的距离：

Wolfram Language code: USstateCapitals = EntityClass["AdministrativeDivision", "AllUSStatesPlusDC"]["CapitalCity"]
Wolfram Language code: dists = GeoDistance[Here, USstateCapitals]

求最小距离、最大距离和平均距离：

Wolfram Language code: MinMax[dists]
Wolfram Language code: Mean[dists]

绘制所有距离的直方图：

Wolfram Language code: Histogram[dists, 20, PlotRange -> All]

绘制一个墨卡托地图，其中包括从你所在位置到美国各州首府城市的所有测地线：

Wolfram Language code: GeoGraphics[GeoPath[{Here, #}]& /@ USstateCapitals, GeoProjection -> "Mercator"]

传统意义上，海里定义为与子午线一分钟弧线相对应的距离：

Wolfram Language code: nauticMile[lat_] := GeoDistance[{lat - 1 / 120, 0}, {lat + 1 / 120, 0}]

这取决于纬度：

Wolfram Language code: Plot[nauticMile[lat], {lat, 0, 90}, TargetUnits -> "Meters"]

标准 "NauticalMiles" 单位近似于纬度 45 度处的数值：

Wolfram Language code: UnitConvert["NauticalMiles", "Meters"]
Wolfram Language code: UnitConvert[nauticMile[45], "Meters"]

属性和关系  (10)

GeoDistance 是对称函数：

Wolfram Language code: p = GeoPosition[{30, 40}]; q = GeoPosition[{-40, 120}];
Wolfram Language code: GeoDistance[p, q]
Wolfram Language code: GeoDistance[q, p]

GeoDistance 是 GeoDestination 的部分反函数：

Wolfram Language code: GeoDestination[GeoPosition[{30, 40}], {10 ^ 6, 135}]
Wolfram Language code: GeoDistance[GeoPosition[{30, 40}], %, UnitSystem -> "Metric"]

对于类点地点 GeoDistance 返回由 GeoDisplacement 返回的部分结果：

Wolfram Language code: p = Entity["City", {"Oslo", "Oslo", "Norway"}]; q = Entity["City", {"BuenosAires", "BuenosAires", "Argentina"}];
Wolfram Language code: GeoDistance[p, q, UnitSystem -> "SIBase"]
Wolfram Language code: GeoDisplacement[p, q]

纬线的度数的长度强依赖于纬度：

Wolfram Language code: GeoDistance[{10, 0}, {10, 1}]
Wolfram Language code: GeoDistance[{80, 0}, {80, 1}]

但是经线的度数的长度是大致恒定的：

Wolfram Language code: GeoDistance[{10, 0}, {11, 0}]
Wolfram Language code: GeoDistance[{80, 0}, {81, 0}]

当接近极点时，对应于给定经线角度 α 的距离增加：

Wolfram Language code: α = 1;
Wolfram Language code: Plot[QuantityMagnitude@GeoDistance[{lat - α / 2, 0}, {lat + α / 2, 0}], {lat, -90 + α / 2, 90 - α / 2}]

计算有 GeoDistanceList 的点的列表中连续对之间的距离：

Wolfram Language code: points = {{-20, 10}, {40, 20}, {-23, 45}, {82, -132}};
Wolfram Language code: GeoDistanceList[points]//Normal

同样的结果可以通过 Partition 和 GeoDistance 获得，但这是一个较低效率的方式：

Wolfram Language code: GeoDistance@@@Partition[points, 2, 1]

包括最后一个和第一个点之间的距离：

Wolfram Language code: GeoDistance@@@Partition[points, 2, 1, 1]

GeoDistance 计算点间的距离：

Wolfram Language code: points = {{-20, 10}, {40, 20}, {-23, 45}, {82, -132}};
Wolfram Language code: GeoDistance[points]

GeoLength 计算地理路径的长度：

Wolfram Language code: GeoLength[GeoPath[points]]

从规则方向开始，在测地圆上构建各个点：

Wolfram Language code: points = First@GeoDestination[{70, 0}, {1000000, Range[0, 360, 30]}]

在一个椭球上，它们不是完全等距的：

Wolfram Language code: GeoDistance@@@Partition[points, 2, 1]
Wolfram Language code: Differences[%]

构建间隔规律的沿着测地线的多个点：

Wolfram Language code: points = First@GeoDestination[{70, 0}, {Range[0, 1000000, 100000], 90}]
Wolfram Language code: GeoDistance@@@Partition[points, 2, 1]

距离列表也可以通过 GeoDistanceList 获得：

Wolfram Language code: % == GeoDistanceList[points]

两个位置间的距离正好与它们对跖点间的距离一致：

Wolfram Language code: p = GeoPosition[{35.1, 75.7}]; q = GeoPosition[{60.4, 130.9}];
Wolfram Language code: GeoDistance[p, q]
Wolfram Language code: GeoDistance[GeoAntipode[p], GeoAntipode[q]]

可能存在的问题  (2)

默认延伸地理实体间的距离是根据边界计算的，因此相邻实体间的距离会是零：

Wolfram Language code: GeoDistance[Entity["Country", "Mexico"], Entity["Country", "UnitedStates"]]
Wolfram Language code: GeoDistance[Entity["Country", "UnitedStates"], Entity["Country", "Canada"]]

因此，总距离也是零：

Wolfram Language code: GeoDistance[{Entity["Country", "Mexico"], Entity["Country", "UnitedStates"], Entity["Country", "Canada"]}]

两个在时间上并不共存的历史实体的 GeoDistance 返回未进行计算的结果：

Wolfram Language code: GeoDistance[Entity["HistoricalCountry", "RomanRepublic"], Entity["HistoricalCountry", "Prussia"]]
Wolfram Research (2008)，GeoDistance，Wolfram 语言函数，https://reference.wolfram.com/language/ref/GeoDistance.html （更新于 2024 年）.

文本

Wolfram Research (2008)，GeoDistance，Wolfram 语言函数，https://reference.wolfram.com/language/ref/GeoDistance.html （更新于 2024 年）.

CMS

Wolfram 语言. 2008. "GeoDistance." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2024. https://reference.wolfram.com/language/ref/GeoDistance.html.

APA

Wolfram 语言. (2008). GeoDistance. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/GeoDistance.html 年

BibTeX

@misc{reference.wolfram_2026_geodistance, author="Wolfram Research", title="{GeoDistance}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/GeoDistance.html}", note=[Accessed: 02-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_geodistance, organization={Wolfram Research}, title={GeoDistance}, year={2024}, url={https://reference.wolfram.com/language/ref/GeoDistance.html}, note=[Accessed: 02-September-2026]}