InfiniteLine

InfiniteLine[{p₁,p₂}]

点 p₁および p₂を通る無限の直線を表す．

InfiniteLine[p,v]

点 p を通り v 方向に進む無限の直線を表す．

詳細

InfiniteLineは線としても知られている．
InfiniteLineは，幾何学領域として，またグラフィックスプリミティブとして使うことができる．

InfiniteLineは，線形曲線あるいはを表す．
Hyperplane[n,p]は2Dで法線 n を使った別の表現である．
InfiniteLineはGraphicsおよびGraphics3Dで使うことができる．
InfiniteLineは，描画される際はPlotRangeで切り取られる．
グラフィックスでは，点 p，p_iおよびベクトル v はDynamic式でもよい．
グラフィックスの描画は，Thickness，Dashing，色等の指示子の影響を受ける．
InfiniteLineはGeometricSceneの記号的な点と一緒に使うことができる．

例題

すべて開くすべて閉じる

例 (3)

2DにおけるInfiniteLine：

Wolfram Language code: Graphics[InfiniteLine[{0, 0}, {1, 1}], Frame -> True]

3Dにおけるもの：

Wolfram Language code: Graphics3D[InfiniteLine[{0, 0, 0}, {1, 2, 3}]]

異なるスタイルが適用された無限直線：

Wolfram Language code: ℛ = InfiniteLine[{0, 0}, {1, 1}];

Wolfram Language code:

{Graphics[{Red, ℛ}, Frame -> True], Graphics[{Thick, Red, ℛ}, Frame -> True], Graphics[{Thick, Red, Dashed, ℛ}, Frame -> True]}

無限直線における点の帰属判定：

Wolfram Language code: ℛ = InfiniteLine[{0, 0}, {1, 1}];

Wolfram Language code: {RegionMember[ℛ, {2, 2}], RegionMember[ℛ, {2, 3}]}

スコープ (19)

グラフィックス (8)

指定 (3)

を含み，の方向に進むInfiniteLineを定義する：

Wolfram Language code:

ill = Graphics[{PointSize[Medium], Point[{{1, 1}}], Arrowheads[Medium], Thick, Arrow[{{1, 1}, {3, 2}}]}, PlotRange -> {{0, 4}, {0, 3}}, Frame -> True];

Wolfram Language code: Show[ill, Graphics[InfiniteLine[{1, 1}, {2, 1}]]]

およびを通る同じ線を定義する：

Wolfram Language code: ill = Graphics[{PointSize[Medium], Point[{{1, 1}, {3, 2}}]}, PlotRange -> {{0, 4}, {0, 3}}, Frame -> True];

Wolfram Language code: Show[ill, Graphics[InfiniteLine[{{1, 1}, {3, 2}}]]]

を含み，の方向に進む3Dの無限直線を定義する：

Wolfram Language code:

ill = Graphics3D[{PointSize[Medium], Point[{{1, 1, 1}}], Arrowheads[Medium], Thick, Arrow[{{1, 1, 1}, {2, 3, 4}}]}, PlotRange -> {{0, 5}, {0, 5}, {0, 5}}, Axes -> True];

Wolfram Language code: Show[ill, Graphics3D[InfiniteLine[{1, 1, 1}, {1, 2, 3}]]]

点およびを使って同じ無限直線を定義する：

Wolfram Language code:

ill = Graphics3D[{PointSize[Medium], Point[{{1, 1, 1}, {2, 3, 4}}]}, PlotRange -> {{0, 5}, {0, 5}, {0, 5}}, Axes -> True];

Wolfram Language code: Show[ill, Graphics3D[InfiniteLine[{{1, 1, 1}, {2, 3, 4}}]]]

方向が異なる無限直線：

Wolfram Language code: Table[Graphics[InfiniteLine[{0, 0}, {Cos[θ], Sin[θ]}], ImageSize -> Tiny, PlotLabel -> θ], {θ, 0, π, π / 4}]

スタイリング (4)

スケールされたサイズによる太さ：

Wolfram Language code: Table[Graphics[{Thickness[i], InfiniteLine[{{0, 0}, {2, 1}}]}], {i, {.005, .05, .1}}]

印刷用ポイント数による太さ：

Wolfram Language code: Table[Graphics[{AbsoluteThickness[i], InfiniteLine[{{0, 0}, {2, 1}}]}], {i, {1, 5, 10}}]

破線あるいは点線スタイルを使って無限直線を描画することができる：

Wolfram Language code: Table[Graphics[{Dashing[i], InfiniteLine[{{0, 0}, {2, 1}}]}], {i, {Tiny, Small, Medium, Large}}]

Wolfram Language code: Table[Graphics[{d, InfiniteLine[{{0, 0}, {2, 1}}]}], {d, {Dotted, Dashed, DotDashed}}]

無限直線の色の指定に色指示子を用いることができる：

Wolfram Language code: Table[Graphics[{c, InfiniteLine[{{0, 0}, {2, 1}}]}], {c, {Red, Green, Blue, Yellow}}]

さまざまな指示子を組み合せて無限直線にスタイルを与える：

Wolfram Language code: Graphics[{Thick, Blue, Dashed, InfiniteLine[{{0, 0}, {2, 1}}]}]

座標 (1)

点およびベクトルはDynamicでよい：

Wolfram Language code: DynamicModule[{θ = 0}, {Slider[Dynamic[θ], {0, Pi}], Graphics[InfiniteLine[{0, 0}, Dynamic[{Cos[θ], Sin[θ]}]]]}]

領域 (11)

埋込み次元は頂点の次元である：

Wolfram Language code: RegionEmbeddingDimension[InfiniteLine[{{x0, y0}, {x1, y1}}]]

Wolfram Language code: RegionEmbeddingDimension[InfiniteLine[{x, y, z}, {a, b, c}]]

幾何次元は領域の次元である：

Wolfram Language code: RegionDimension[InfiniteLine[{{x0, y0}, {x1, y1}}]]

Wolfram Language code: RegionDimension[InfiniteLine[{x, y, z}, {a, b, c}]]

点の帰属判定：

Wolfram Language code: RegionMember[InfiniteLine[{{0, 0, 0}, {1, 1, 1}}], {2, 2, 2}]

Wolfram Language code: RegionMember[InfiniteLine[{1, 1}, {2, 2}], {0, -1}]

帰属条件を得る：

Wolfram Language code: RegionMember[InfiniteLine[{{x0, y0}, {x1, y1}}], {x, y}]

無限直線は有界ではない：

Wolfram Language code: ℛ = InfiniteLine[{{0, 0}, {1, 1}}];

Wolfram Language code: BoundedRegionQ[ℛ]

領域範囲を求める：

Wolfram Language code: RegionBounds[ℛ]

InfiniteLineの測度は無限である：

Wolfram Language code: ℛ = InfiniteLine[{{0, 0}, {1, 1}}];

Wolfram Language code: RegionMeasure[ℛ]

Wolfram Language code: RegionCentroid[ℛ]

点からの距離：

Wolfram Language code: ℛ = InfiniteLine[{{2, 2}, {3, 3}}];

Wolfram Language code: RegionDistance[ℛ, {0, 1}]

領域までのプロット距離：

Wolfram Language code:

{Plot3D[Evaluate@RegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> {#3&}, Mesh -> 5], ContourPlot[Evaluate[RegionDistance[ℛ, {x, y}]], {x, -3, 3}, {y, -3, 3}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

点からの符号付き距離：

Wolfram Language code: ℛ = InfiniteLine[{{2, 2}, {3, 3}}];

Wolfram Language code: SignedRegionDistance[ℛ, {0, -1}]

最近点までの距離：

Wolfram Language code: Plot3D[SignedRegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> {#3&}, Mesh -> 5]

領域内の最近点：

Wolfram Language code: ℛ = InfiniteLine[{{2, 2}, {3, 3}}];

Wolfram Language code: RegionNearest[ℛ, {5, 6}]

最近点を可視化する：

Wolfram Language code:

pts = Table[{1, 2} + 5{Cos[k 2 π / 16], Sin[k 2π / 16]}, {k, 0., 15}];
nst = RegionNearest[ℛ, #]& /@ pts;

Wolfram Language code:

Legended[Graphics[{{Gray, ℛ}, {Thin, Gray, Line[Transpose[{pts, nst}]]}, {Red, Point[pts]}, {Blue, Point[nst]}}], PointLegend[{Red, Blue}, {"start", "nearest"}]]

無限直線上で積分する：

Wolfram Language code: ℛ = InfiniteLine[{{0, 0}, {1, 1}}];

Wolfram Language code: Integrate[Exp[-x y], {x, y}∈ℛ]

無限直線上で最適化する：

Wolfram Language code: ℛ = InfiniteLine[{0, 0}, {1, 1}];

Wolfram Language code: Minimize[{(x y - 1)^2 + 3, {x, y}∈ℛ}, {x, y}]

無限直線上で方程式を解く：

Wolfram Language code: ℛ = InfiniteLine[{0, 0, 0}, {1, 2, 3}];

Wolfram Language code: Solve[x^2 + y^2 + z^2 == 1 && {x, y, z}∈ℛ, {x, y, z}]

Wolfram Language code: Graphics3D[{{Opacity[0.5], Sphere[]}, ℛ, {Red, PointSize[Large], Point[{x, y, z} /. %]}}]

アプリケーション (17)

に並ぶ平行線を作成する：

Wolfram Language code: lines = Table[InfiniteLine[{0, y}, {1, 1}], {y, 5}];

Wolfram Language code: Graphics[lines, PlotRange -> {{-6, 6}, {0, 6}}]

漸近線を示す：

Wolfram Language code: asym = InfiniteLine[{0, 0}, {1, 1}];

Wolfram Language code: Plot[(x ^ 2 + x + 1/x + 1), {x, -1, 7}, Epilog -> {Red, Dashed, asym}, PlotRange -> 7]

Wolfram Language code: ParametricPlot[{t + Cos[14 t] / t, t + Sin[14 t] / t}, {t, 0.01, 10}, Epilog -> {Red, Dashed, asym}]

線の切片型をInfiniteLineに変換する：

Wolfram Language code:

a = 2;
b = 3;

Wolfram Language code: ir = ImplicitRegion[(x/a) + (y/b) == 1, {x, y}];

Wolfram Language code: il = InfiniteLine[{{a, 0}, {0, b}}];

線を可視化する：

Wolfram Language code: Table[RegionPlot[r, PlotRange -> {{0, 3}, {0, 3}}], {r, {ir, il}}]

線の点傾き型をInfiniteLineに変換する：

Wolfram Language code:

m = 2 / 3;
{x0, y0} = {1, 2};

Wolfram Language code: ir = ImplicitRegion[y - y0 == m(x - x0), {x, y}];

Wolfram Language code: il = InfiniteLine[{x0, y0}, {1, m}];

線を可視化する：

Wolfram Language code: Table[RegionPlot[r, PlotRange -> {{0, 3}, {0, 3}}], {r, {ir, il}}]

線の傾き切片型をInfiniteLineに変換する：

Wolfram Language code:

m = 2 / 3;
b = 1;

Wolfram Language code: ir = ImplicitRegion[y == m x + b, {x, y}];

Wolfram Language code: il = InfiniteLine[{0, b}, {1, m}];

線を可視化する：

Wolfram Language code: Table[RegionPlot[r, PlotRange -> {{0, 3}, {0, 3}}], {r, {ir, il}}]

線の2点型をInfiniteLineに変換する：

Wolfram Language code:

{x0, y0} = {0, 2};
{x1, y1} = {3, 1};

Wolfram Language code: ir = ImplicitRegion[y - y0 == (y1 - y0/x1 - x0)(x - x0), {x, y}];

Wolfram Language code: il = InfiniteLine[{{x0, y0}, {x1, y1}}];

線を可視化する：

Wolfram Language code: Table[RegionPlot[r, PlotRange -> {{0, 3}, {0, 3}}], {r, {ir, il}}]

線のパラメトリック型をInfiniteLineに変換する：

Wolfram Language code:

a = 2;
b = 3;
{x0, y0} = {1, 2};

Wolfram Language code: pr = ParametricRegion[{x0 + a t, y0 + b t}, {t}];

Wolfram Language code: il = InfiniteLine[{{x0, y0}, {x0 + a, y0 + b}}];

線を可視化する：

Wolfram Language code: Table[RegionPlot[r, PlotRange -> {{0, 3}, {0, 3}}], {r, {pr, il}}]

パラメトリック曲線 f[u]に対する接線はInfiniteLine[f[u],f'[u]]で与えられる．パラメトリック曲線に対する接線を求める：

Wolfram Language code: f1[u_] := {Cos[u], Sin[u]};

Wolfram Language code:

c1 = ParametricPlot[f1[u], {u, 0, 2π}];
t1 = With[{u = π / 4}, Graphics[InfiniteLine[f1[u], f1'[u]]]];

Wolfram Language code: Show[c1, t1, PlotRange -> {{-2, 2}, {-2, 2}}]

パラメトリック曲線についての接線を求める：

Wolfram Language code: f2[u_] := {Cos[u], Sin[u], u / 10};

Wolfram Language code:

c2 = ParametricPlot3D[f2[t], {t, 0, 20}];
t2 = With[{u = 4}, Graphics3D[InfiniteLine[f2[u], f2'[u]]]];

Wolfram Language code: Show[c2, t2, PlotRange -> {{-2, 2}, {-2, 2}, All}]

InfiniteLine[{0,0},{1,1}]とInfiniteLine[{{0,1},{1,0}}]の交点を求める：

Wolfram Language code:

line1 = InfiniteLine[{0, 0}, {1, 1}];
line2 = InfiniteLine[{{0, 1}, {1, 0}}];

Wolfram Language code: sol = Solve[{x, y}∈line1∧{x, y}∈line2, {x, y}]

これをプロットする：

Wolfram Language code: Graphics[{{Lighter[Blue, 0.5], line1, line2}, {Red, Point[{x, y} /. sol]}}, Axes -> True, ImageSize -> Small]

InfiniteLine[{0,0},{1,1}]とCircle[{0,0},1]の交点を求める：

Wolfram Language code:

line = InfiniteLine[{0, 0}, {1, 1}];
circle = Circle[{0, 0}, 1];

Wolfram Language code: sol = Solve[{x, y}∈line∧{x, y}∈circle, {x, y}]

これをプロットする：

Wolfram Language code: Graphics[{{Lighter[Blue, 0.5], line, circle}, {Red, Point[{x, y} /. sol]}}, ImageSize -> Small]

5本のランダムな線のすべてのペアについての交点を求める：

Wolfram Language code: lines = InfiniteLine /@ RandomReal[1, {5, 2, 2}];

BooleanCountingFunctionを使い，厳密に2つの条件が真であることを表す：

Wolfram Language code: sol = NSolve[{x, y}∈BooleanRegion[BooleanCountingFunction[{2}, 5], lines], {x, y}]

これをプロットする：

Wolfram Language code: Graphics[{{Lighter[Blue, 0.5], lines}, {Red, PointSize[Medium], Point[{x, y} /. sol]}}]

InfiniteLine[{{-1,1,1},{1,1,1}}]とInfinitePlane[{{2,0,0},{0,2,0},{0,0,2}}]の交点を求める：

Wolfram Language code:

line = InfiniteLine[{{-1, 1, 1}, {1, 1, 1}}];
plane = InfinitePlane[{{2, 0, 0}, {0, 2, 0}, {0, 0, 2}}];

Wolfram Language code: sol = Solve[{{x, y, z}∈line, {x, y, z}∈plane}, {x, y, z}]

これをプロットする：

Wolfram Language code:

Graphics3D[{{Opacity[0.5], line, plane}, {Red, PointSize[Large], Point[{x, y, z} /. sol]}}, Axes -> True, PlotRange -> {{-2, 2}, {-2, 2}, {-2, 2}}]

InfiniteLine[{{-1,1,1},{1,1,1}}]とSphere[{0,0,0},3]の交点を求める：

Wolfram Language code:

line = InfiniteLine[{{-1, 1, 1}, {1, 1, 1}}];
sphere = Sphere[{0, 0, 0}, 3];

Wolfram Language code: sol = Solve[{{x, y, z}∈line, {x, y, z}∈sphere}, {x, y, z}]

これをプロットする：

Wolfram Language code: Graphics3D[{{Opacity[0.5], line, sphere}, {Red, PointSize[Large], Point[{x, y, z} /. sol]}}, PlotRangePadding -> 0.5]

InfiniteLine[{{-1,1/3,1/2},{1,1/3,1/2}}]とTetrahedron[{{0,0,0},{1,0,0},{0,1,0},{0,0,1}}]の境界との交点を求める：

Wolfram Language code:

line = InfiniteLine[{{-1, 1 / 3, 1 / 2}, {1, 1 / 3, 1 / 2}}];
tet = RegionBoundary@Tetrahedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];

Wolfram Language code: sol = Solve[{x, y, z}∈RegionIntersection[line, tet], {x, y, z}]

これをプロットする：

Wolfram Language code:

Graphics3D[{{Opacity[0.5], line, Tetrahedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}]}, {Red, PointSize[Medium], Point[{x, y, z} /. sol]}}, PlotRangePadding -> 0.2]

Histogram上のMeanを示す：

Wolfram Language code: data = RandomVariate[NormalDistribution[1, 9], 200];

Wolfram Language code: h = Histogram[data];

Wolfram Language code: m = Graphics[{Dashed, Red, InfiniteLine[{Mean[data], 0}, {0, 1}]}];

Wolfram Language code: Show[h, m]

RotationTransformの回転軸を可視化する：

Wolfram Language code:

v = {4, 2, -5};
p = {2, 2, 3 / 2};

Wolfram Language code: axis = InfiniteLine[p, v];

Wolfram Language code: rt[θ_] := RotationTransform[θ, v, p];

Wolfram Language code: g = Graphics3D[Table[{GeometricTransformation[Sphere[], rt[θ]]}, {θ, 0, 2Pi, 2Pi / 8}], Boxed -> False];

Wolfram Language code: Show[g, Graphics3D[{Thick, Blue, Dashed, axis}]]

三角形の高さを求める：

Wolfram Language code: {a, b, c} = {{0, 0}, {3, 0}, {-1, 2}};

Wolfram Language code: base = InfiniteLine[{a, b}];

Wolfram Language code: foot = RegionNearest[base, c];

Wolfram Language code: altitude = Line[{c, foot}];

高さを赤で可視化する：

Wolfram Language code:

Graphics[{{LightBlue, Triangle[{a, b, c}]}, {Thick, Darker@LightBlue, base}, {PointSize@Medium, Red, Point[{c, foot}]}, {Dashed, Red, altitude}}]

特性と関係 (5)

InfiniteLine[{p₁,p₂}]はInfiniteLine[p₁,p₂-p₁]に等しい：

Wolfram Language code:

Subscript[ℛ, 1] = InfiniteLine[{{1, 0}, {2, 2}}];
Subscript[ℛ, 2] = InfiniteLine[{1, 0}, {1, 2}];

Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

InfiniteLine[p,v]は2DのHyperplane[Cross[v],p]に等しい：

Wolfram Language code: Subscript[ℛ, 1] = InfiniteLine[{1, 2}, {1, 1}];

Wolfram Language code: Subscript[ℛ, 2] = Hyperplane[Cross[{1, 1}], {1, 2}];

Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

ParametricRegionは任意のInfiniteLineを表すことができる：

Wolfram Language code:

Subscript[ℛ, 1] = ParametricRegion[{1, 2} + t{3, 4}, {t}];
Subscript[ℛ, 2] = InfiniteLine[{1, 2}, {3, 4}];

Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

ImplicitRegionは任意のInfiniteLineを表すことができる：

Wolfram Language code:

Subscript[ℛ, 1] = ImplicitRegion[y - x == 1, {x, y}];
Subscript[ℛ, 2] = InfiniteLine[{{1, 2}, {3, 4}}];

Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

InfiniteLineはConicHullRegionの特殊ケースである：

Wolfram Language code: pts = {{1, 2}, {3, 4}};

Wolfram Language code: RegionEqual[ConicHullRegion[pts], InfiniteLine[pts]]

おもしろい例題 (2)

線のランダムな集合：

Wolfram Language code: Graphics[Table[{Hue[RandomReal[]], InfiniteLine[RandomReal[1, {2, 2}]]}, {50}]]

Wolfram Language code: Graphics3D[Table[{Hue[RandomReal[]], InfiniteLine[RandomReal[1, {2, 3}]]}, {100}], BoxRatios -> 1]

線の構造化された集合：

Wolfram Language code: Graphics[Table[InfiniteLine[{0, 0}, {Cos[θ], Sin[θ]}], {θ, 0., π, π / 50}]]

Wolfram Language code: Graphics[Table[InfiniteLine[{Cos[θ], Sin[θ]}, {-Sin[θ], Cos[θ]}], {θ, 0, 2π, π / 20}], PlotRange -> 2]

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

InfiniteLine

詳細

例題

例 (3)

スコープ (19)

グラフィックス (8)

指定 (3)

スタイリング (4)

座標 (1)

領域 (11)

アプリケーション (17)

特性と関係 (5)

おもしろい例題 (2)

テキスト

CMS

APA

BibTeX

BibLaTeX

InfiniteLine

詳細

例題

例 (3)

スコープ (19)

グラフィックス (8)

指定 (3)

スタイリング (4)

座標 (1)

領域 (11)

アプリケーション (17)

特性と関係 (5)

おもしろい例題 (2)

関連項目

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX