Wolfram 语言与系统参考资料中心

LineIntegrate

LineIntegrate[f,{x,y,…}∈curve]

计算函数 f[x,y,…] 在 curve 上的标量线积分.

LineIntegrate[{p,q,…},{x,y,…}∈curve]

计算矢量函数 {p[x,y,…],q[x,y,…],…} 的矢量线积分.

范例

打开所有单元关闭所有单元

基本范例 (7)

标量场在圆上的线积分：

Wolfram Language code: LineIntegrate[2x, {x, y}∈Circle[{0, 0}, 1, {0, Pi / 2}]]

矢量场在线段上的线积分：

Wolfram Language code: LineIntegrate[{x * y, x - y}, {x, y}∈Line[{{0, 0}, {1, 1}}]]

矢量场在空间曲线上的线积分：

Wolfram Language code: LineIntegrate[{x ^ 2 y z, 3x y, y ^ 2}, {x, y, z}∈ParametricRegion[{Cos[t], Sin[t], t}, {{t, 0, Pi / 2}}]]

二维标量场的线积分：

Wolfram Language code: f = y ^ 2;

要积分的曲线：

Wolfram Language code: reg = ParametricRegion[{{t ^ (5 / 2), t}, 0 <= t <= 2}, {t}];

和曲线的等值线图：

Wolfram Language code: Show[ContourPlot[f, {x, 0, 8}, {y, 0, 2}], ...]

线积分：

Wolfram Language code: LineIntegrate[f, {x, y}∈reg]

二维矢量场的线积分：

Wolfram Language code: f = {x + 2y, x ^ 2};

Wolfram Language code: reg = Line[{{0, 0}, {2, 3 / 2}, {3, 0}}];

矢量场和积分路径：

Wolfram Language code: VectorPlot[f, {x, 0, 3}, {y, 0, 2}, ...]

线积分：

Wolfram Language code: LineIntegrate[f, {x, y}∈reg]

三维矢量场的线积分：

Wolfram Language code: f = {z ^ 3, x ^ 3, y ^ 3};

Wolfram Language code: reg = Line[{{1, 1 / 2, 0}, {3, 2, 2}}];

Wolfram Language code: Show[VectorPlot3D[f, {x, 0, 4}, {y, 0, 2}, {z, 0, 2}, Rule[...]], ...]

Wolfram Language code: LineIntegrate[f, {x, y, z}∈reg]

使用 VectorSymbol:

Wolfram Language code: LineIntegrate[VectorSymbol["x"].VectorSymbol["x"], VectorSymbol["x"]∈Line[{{0, 0}, {0, 1}}]]

使用隐式向量符号：

Wolfram Language code: LineIntegrate[x, x∈Line[{{0, 0}, {0, 1}}]]

范围 (32)

基本用法 (4)

标量场的线积分：

Wolfram Language code: f = Exp[x];

Wolfram Language code: LineIntegrate[f, {x, y}∈Line[{{0, 0}, {2, 3}}]]

三维矢量场的线积分：

Wolfram Language code: f = {x, x - y, z x ^ 2};

Wolfram Language code: LineIntegrate[f, {x, y, z}∈ParametricRegion[{Sin[t], t, 2t}, {{t, 0, Pi}}]]

LineIntegrate 适用于许多特殊曲线：

Wolfram Language code: f = {x ^ 2 y, x};

Wolfram Language code: reg = Annulus[{0, 0}, {1, 2}, {0, Pi / 4}];

Wolfram Language code: LineIntegrate[f, {x, y}∈reg]

参数曲线上的线积分：

Wolfram Language code: f = {Log[x], y};

Wolfram Language code: reg = ParametricRegion[{2t + 1, t ^ 2}, {{t, 0, 1}}];

Wolfram Language code: LineIntegrate[f, {x, y}∈reg]

标量函数 (11)

标量场在曲线上的线积分：

Wolfram Language code: f = 2x - 2 y;

Wolfram Language code: reg = ParametricRegion[{t, t ^ (3 / 2)}, {{t, 0, 8}}];

和曲线的等值线图：

Wolfram Language code: Show[ContourPlot[f, {x, 0, 8}, {y, 0, 25}], ...]

线积分：

Wolfram Language code: LineIntegrate[f, {x, y}∈reg]

标量场在圆弧上的线积分：

Wolfram Language code: f = 1 / (x + y + 1);

Wolfram Language code: reg = Circle[{0, 0}, 1, {0, Pi / 2}];

Wolfram Language code: ContourPlot[f, {x, 0, 1}, {y, 0, 1}, Epilog -> reg, ImageSize -> Small]

Wolfram Language code: LineIntegrate[f, {x, y}∈reg]

标量场在参数曲线上的线积分：

Wolfram Language code: f = 1 / (x + 1) - y / 5;

Wolfram Language code: reg = ParametricRegion[{3 / 2t ^ 2, 4t}, {{t, -1, 1}}];

函数和曲线的等值线图：

Wolfram Language code: Show[ContourPlot[f, {x, -1 / 2, 2}, {y, -4, 4}], ...]

Wolfram Language code: LineIntegrate[f, {x, y}∈reg]

标量场在圆上的线积分：

Wolfram Language code: f = x ^ 3 + y + 1;

Wolfram Language code: reg = Circle[{1, 2}, 3];

Wolfram Language code: ContourPlot[f, {x, -2, 4}, {y, -1, 5}, Epilog -> reg, ImageSize -> Small]

Wolfram Language code: LineIntegrate[f, {x, y}∈reg]

标量场在空间曲线上的线积分：

Wolfram Language code: f = x + y - z;

Wolfram Language code: reg = ParametricRegion[{t ^ 3 / 3, Sqrt[2]t ^ 2 / 2, t}, {{t, 0, 1}}];

线积分：

Wolfram Language code: LineIntegrate[f, {x, y, z}∈reg]

标量场在环形边界上的线积分：

Wolfram Language code: f = 1 / (x + y + 5);

Wolfram Language code: reg = Annulus[{0, 0}, {1, 2}, {0, 3 / 4Pi}];

函数和曲线的等值线图：

Wolfram Language code: ContourPlot[f, {x, -2, 4}, {y, -1, 5}, ...]

Wolfram Language code: LineIntegrate[f, {x, y}∈reg]

标量场在闭合多边形上的线积分：

Wolfram Language code: f = Exp[Abs[x - y]];

Wolfram Language code: reg = Line[{{0, 0}, {1, 2}, {0, 1}, {0, 0}}];

函数和曲线的等值线图：

Wolfram Language code: ContourPlot[f, {x, 0, 1}, {y, 0, 2}, Epilog -> reg, AspectRatio -> Automatic]

Wolfram Language code: LineIntegrate[f, {x, y}∈reg]

标量场在椭圆路径上的线积分：

Wolfram Language code: f = 2 x y;

Wolfram Language code: reg = Circle[{0, 0}, {1, 1 / Sqrt[2]}];

函数和曲线的等高线图：

Wolfram Language code: ContourPlot[f, {x, -1, 1}, {y, -1, 1}, Epilog -> reg, ImageSize -> Small]

线积分：

Wolfram Language code: LineIntegrate[f, {x, y}∈reg]

标量场在参数曲线上的线积分：

Wolfram Language code: f = x / 2 + y ^ 2;

Wolfram Language code: reg = ParametricRegion[{6Cos[t] - Cos[6t], 6Sin[t] - Sin[6t]}, {{t, 0, 2Pi}}];

Wolfram Language code: Show[ContourPlot[f, {x, -10, 10}, {y, -10, 10}], RegionPlot[reg, BoundaryStyle -> Blue], ImageSize -> Small]

线积分：

Wolfram Language code: LineIntegrate[f, {x, y}∈reg]

标量场在圆上的线积分：

Wolfram Language code: f = ArcTan[(y / x) ^ 2];

Wolfram Language code: reg = Circle[{0, 0}, 4];

和曲线的等值线图：

Wolfram Language code: ContourPlot[f, {x, -4, 4}, {y, -4, 4}, Epilog -> reg, ImageSize -> Small]

线积分：

Wolfram Language code: LineIntegrate[f, {x, y}∈reg]

标量场在圆盘扇区边界上的线积分：

Wolfram Language code: f = x - y;

Wolfram Language code: reg = Disk[{0, 0}, 3, {0, 3Pi / 4}];

和曲线的等值线图：

Wolfram Language code: ContourPlot[f, {x, -3, 3}, {y, -1, 5}, ...]

线积分：

Wolfram Language code: LineIntegrate[f, {x, y}∈reg]

矢量函数 (12)

三维矢量场在参数化曲线上的线积分：

Wolfram Language code: f = {2x, x, 1};

Wolfram Language code: reg = ParametricRegion[{Sin[t], Cos[t], t}, {{t, 0, 2Pi}}];

矢量场和曲线的可视化：

Wolfram Language code: Show[VectorPlot3D[f, {x, -1, 1}, {y, -1, 1}, {z, 0, 7}, ...], ...]

线积分：

Wolfram Language code: LineIntegrate[f, {x, y, z}∈reg]

矢量场在二维曲线上的线积分：

Wolfram Language code: f = {Sin[x], y};

Wolfram Language code: reg = ParametricRegion[{t ^ 2, t ^ 3}, {{t, 0, 1}}];

Wolfram Language code: Show[VectorPlot[f, {x, 0, 1}, {y, 0, 1}, Rule[...]], ...]

线积分：

Wolfram Language code: LineIntegrate[f, {x, y}∈reg]

矢量场在圆弧上的线积分：

Wolfram Language code: f = {x * (x ^ 2 + y ^ 2), y * (x ^ 2 + y ^ 2)};

Wolfram Language code: reg = Circle[{0, 0}, 1, {0, Pi / 2}];

Wolfram Language code: VectorPlot[f, {x, 0, 1}, {y, 0, 1}, ...]

Wolfram Language code: LineIntegrate[f, {x, y}∈reg]

矢量场在线段上的线积分：

Wolfram Language code: f = {Sqrt[x ^ 2 + y ^ 2], Sqrt[x + y]};

Wolfram Language code: reg = Line[{{0, 0}, {2, 2}, {4, 0}}];

Wolfram Language code: VectorPlot[f, {x, -1, 5}, {y, -1, 3}, ...]

Wolfram Language code: LineIntegrate[f, {x, y}∈reg]

矢量场在三维参数化曲线上的线积分：

Wolfram Language code: f = {x, x ^ 2 y ^ 2, 0};

Wolfram Language code: reg = ParametricRegion[{Cos[t] ^ 2, Cos[t]Sin[t], Sqrt[Cos[t](1 - Cos[t])]}, {{t, 0, 2Pi}}];

Wolfram Language code: Show[VectorPlot3D[f, {x, -1, 1}, {y, -1, 1}, {z, 0, 1}, Rule[...]], ...]

Wolfram Language code: LineIntegrate[f, {x, y, z}∈reg]

矢量场在曲线上的线积分：

Wolfram Language code: f = {x + y, y + z, z + x};

Wolfram Language code:

reg = ParametricRegion[{Sin[t] ^ 2 / Sqrt[2] + Cos[t] ^ 2, (1 - 1 / Sqrt[2])Cos[t]Sin[t], Sin[t] / Sqrt[2]}, {{t, 0, 2Pi}}];

Wolfram Language code: Show[VectorPlot3D[f, {x, 0, 1}, {y, -1, 1}, {z, -1, 1}, ...], ...]

Wolfram Language code: LineIntegrate[f, {x, y, z}∈reg]

矢量场在椭圆弧上的线积分：

Wolfram Language code: f = {x, x y};

Wolfram Language code: reg = Circle[{0, 0}, {2, 1}, {0, Pi}];

Wolfram Language code: VectorPlot[f, {x, -2, 2}, {y, -1 / 2, 3 / 2}, ...]

Wolfram Language code: LineIntegrate[f, {x, y}∈reg]

矢量场在参数曲线上的线积分：

Wolfram Language code: f = {x ^ 2, x ^ 2, y ^ 2};

Wolfram Language code: reg = ParametricRegion[{(2 + Cos[3t])Cos[t], (2 + Cos[3t])Sin[t], Sin[3t]}, {{t, 0, 2Pi}}];

Wolfram Language code: Show[VectorPlot3D[f, {x, -3, 3}, {y, -3, 3}, {z, -1, 1}, ...], ...]

Wolfram Language code: LineIntegrate[f, {x, y, z}∈reg]

矢量场在三维参数曲线上的线积分：

Wolfram Language code: f = {(y - 1) ^ 2z, x ^ 2y, 2x y};

Wolfram Language code: reg = ParametricRegion[{Cos[t], Sin[t] / 2, Sin[t] / 2}, {{t, 0, Pi}}];

Wolfram Language code: Show[VectorPlot3D[f, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, Rule[...]], ...]

Wolfram Language code: LineIntegrate[f, {x, y, z}∈reg]

矢量场在参数化曲线上的线积分：

Wolfram Language code: f = {x ^ 2, 1 / 3, z ^ 2};

Wolfram Language code: reg = ParametricRegion[{2 / (1 + t ^ 2), 3t, 2t / (1 + t ^ 2)}, {{t, -10, 10}}];

Wolfram Language code: Show[VectorPlot3D[f, {x, 0, 2}, {y, -30, 30}, {z, -1, 1}, ...], ...]

Wolfram Language code: LineIntegrate[f, {x, y, z}∈reg]

矢量场在椭圆路径上的线积分：

Wolfram Language code: f = {y ^ 2, Sin[y]};

Wolfram Language code: reg = Circle[{0, 1}, {Sqrt[2], 1}];

Wolfram Language code: VectorPlot[f, {x, -2, 2}, {y, 0, 2}, ...]

Wolfram Language code: LineIntegrate[f, {x, y}∈reg]

高维矢量场的线积分：

Wolfram Language code: f = {x y, x ^ 2t z, y t, z t};

Wolfram Language code: LineIntegrate[f, {x, y, z, t}∈Line[{{0, 0, 0, 0}, {1, 2, 3, 4}}]]

特殊曲线 (4)

圆弧上的线积分：

Wolfram Language code: f = Sqrt[x] * y ^ 4;

Wolfram Language code: reg = Circle[{0, 0}, 4, {-Pi / 2, Pi / 2}];

Wolfram Language code: ContourPlot[f, {x, 0, 4}, {y, -4, 4}, ...]

Wolfram Language code: LineIntegrate[f, {x, y}∈reg]

矢量场在半径为 1 的圆扇形边界上的线积分：

Wolfram Language code: f = {0, x ^ 2};

Wolfram Language code: reg = Disk[{0, 0}, 1, {0, Pi / 2}];

Wolfram Language code: VectorPlot[f, {x, 0, 1}, {y, 0, 1}, ...]

Wolfram Language code: LineIntegrate[f, {x, y}∈reg]

多边形上的线积分：

Wolfram Language code: f = {1 / (x + y), -1 / (x + y)};

Wolfram Language code: reg = Line[{{1, 0}, {0, 1}, {-1, 0}, {0, -1}, {1, 0}}];

Wolfram Language code: VectorPlot[f, {x, -1, 1}, {y, -1, 1}, ...]

Wolfram Language code: LineIntegrate[f, {x, y}∈reg]

环形边界上的线积分：

Wolfram Language code: f = {-y, x};

Wolfram Language code: reg = Annulus[{0, 0}, {1, 2}, {0, Pi / 4}];

Wolfram Language code: VectorPlot[f, {x, 0, 2}, {y, 0, 2}, ...]

Wolfram Language code: LineIntegrate[f, {x, y}∈reg]

参数曲线 (1)

矢量场在三维螺旋上的线积分：

Wolfram Language code: f = {y - z, z - x, x - y};

Wolfram Language code: reg = ParametricRegion[{ Cos[t], Sin[t], t}, {{t, 0, 2Pi}}];

Wolfram Language code: Show[VectorPlot3D[f, {x, -1, 1}, {y, -1, 1}, {z, 0, 2Pi}, ...], ...]

Wolfram Language code: LineIntegrate[f, {x, y, z}∈reg]

选项 (5)

Assumptions (1)

选项 Assumptions 可用于参数：

Wolfram Language code: LineIntegrate[Exp[-a x], {x, y}∈ParametricRegion[{2t, 3t}, {{t, 0, Infinity}}]]

Wolfram Language code: LineIntegrate[Exp[-a x], {x, y}∈ParametricRegion[{2t, 3t}, {{t, 0, Infinity}}], Assumptions -> Re[a] > 0]

Direction (1)

闭合圆形路径的默认 Direction 是逆时针方向：

Wolfram Language code: f = {-x ^ 2y, y ^ 2};

Wolfram Language code: reg = Circle[];

Wolfram Language code: VectorPlot[f, {x, -1, 1}, {y, -1, 1}, ...]

Wolfram Language code: LineIntegrate[f, {x, y}∈reg]

等价于：

Wolfram Language code: LineIntegrate[f, {x, y}∈reg, Direction -> "Anticlockwise"]

可以使用选项 Direction 选择顺时针方向：

Wolfram Language code: LineIntegrate[f, {x, y}∈reg, Direction -> "Clockwise"]

GenerateConditions (1)

LineIntegrate 可以使用符号参数：

Wolfram Language code: LineIntegrate[Exp[-a x], {x, y}∈ParametricRegion[{2t, 3t}, {{t, 0, Infinity}}]]

抑制参数上的条件：

Wolfram Language code: LineIntegrate[Exp[-a x], {x, y}∈ParametricRegion[{2t, 3t}, {{t, 0, Infinity}}], GenerateConditions -> False]

WorkingPrecision (2)

如果指定了 WorkingPrecision，则给出数值结果：

Wolfram Language code: LineIntegrate[1, {x, y}∈Circle[]]

Wolfram Language code: LineIntegrate[1, {x, y}∈Circle[], WorkingPrecision -> 16]

如果被积函数具有有限精度，则结果具有有限精度：

Wolfram Language code: LineIntegrate[{-y, 0.567x}, {x, y}∈Line[{{0, 0}, {2, 4}}]]

应用 (27)

大学微积分 (10)

函数在线段上的线积分：

Wolfram Language code: f = x y ^ 2 z ^ 3;

Wolfram Language code: reg = Line[{{-1, 3, 1}, {1, 7, 3}}];

Wolfram Language code: LineIntegrate[f, {x, y, z}∈reg]

矢量场在曲线上的线积分：

Wolfram Language code: f = {x Sin[y], y Cos[z], z Sin[x]};

Wolfram Language code: reg = ParametricRegion[{Cos[t], Sin[t] ^ 2, -Cos[t]}, {{t, 0, Pi}}];

Wolfram Language code: LineIntegrate[f, {x, y, z}∈reg]

半径为 1 且线密度为的细圆线的质量：

Wolfram Language code: ρ = x ^ 2y ^ 2;

Wolfram Language code: reg = Circle[{0, 0}, 1];

Wolfram Language code: LineIntegrate[ρ, {x, y}∈reg]

力场对沿线段移动的粒子所做的功：

Wolfram Language code: f = {x - y ^ 3, y - z ^ 3, z - x ^ 3};

Wolfram Language code: reg = Line[{{0, 0, 0}, {1, 2, 3}}];

Wolfram Language code: LineIntegrate[f, {x, y, z}∈reg]

矢量场沿路径的线积分：

Wolfram Language code: f = {Cos[x], Sin[y]};

Wolfram Language code: reg = Line[{{0, 0}, {3, 0}, {3, 3}, {0, 3}, {0, 0}}];

Wolfram Language code: LineIntegrate[f, {x, y}∈reg]

矢量场沿曲线的线积分：

Wolfram Language code: f = {x ^ 2, y ^ 2};

Wolfram Language code: reg = ParametricRegion[{t, t ^ 2}, {{t, 0, 1}}];

Wolfram Language code: LineIntegrate[f, {x, y}∈reg]

当粒子沿曲线移动时，力所做的功：

Wolfram Language code: f = {x ^ 2, y};

Wolfram Language code: reg = ParametricRegion[{t - Sin[t], 1 - Cos[t]}, {{t, 0, 2Pi}}];

Wolfram Language code: LineIntegrate[f, {x, y}∈reg]

矢量场沿以原点为中心的单位圆的线积分：

Wolfram Language code: f = {x + y, x ^ 2};

Wolfram Language code: LineIntegrate[f, {x, y}∈Circle[]]

矢量场沿以原点为中心、半径为的圆的线积分：

Wolfram Language code: f = {x ^ 2 / (x ^ 2 + y ^ 2), (y ^ 2 - x ^ 2) / (x ^ 2 + y ^ 2)};

Wolfram Language code: LineIntegrate[f, {x, y}∈Circle[{0, 0}, R]]

矢量场在路径上线积分的数量值：

Wolfram Language code: f = {Exp[Sin[x ^ 2]], Exp[Sqrt[x ^ 2 + y ^ 2]]};

Wolfram Language code: reg = ParametricRegion[{Sin[t ^ 2], Cos[t] ^ 3}, {{t, 0, 2Pi}}];

Wolfram Language code: LineIntegrate[f, {x, y}∈reg, WorkingPrecision -> 16]

长度 (3)

圆的周长：

Wolfram Language code: LineIntegrate[1, {x, y}∈Circle[]]

使用线积分计算心形周长：

Wolfram Language code: reg = ParametricRegion[{(2Cos[t] - Cos[2t]), (2Sin[t] - Sin[2t])}, {{t, 0, 2Pi}}];

Wolfram Language code: RegionPlot[reg, ImageSize -> Small]

Wolfram Language code: LineIntegrate[1, {x, y}∈reg]

长度也可以用 RegionMeasure 计算：

Wolfram Language code: RegionMeasure[reg]

星形线的周长：

Wolfram Language code: reg = ParametricRegion[{Cos[t] ^ 3, Sin[t] ^ 3}, {{t, 0, 2Pi}}];

Wolfram Language code: RegionPlot[reg, ImageSize -> Small]

Wolfram Language code: LineIntegrate[1, {x, y}∈reg]

面积 (5)

使用线积分计算半轴为和的椭圆的面积：

Wolfram Language code: LineIntegrate[{-y / 2, x / 2}, {x, y}∈Circle[{0, 0}, {a, b}]]

使用线积分计算的双纽线右手环的面积：

Wolfram Language code: f = {-y / 2, x / 2};

Wolfram Language code: reg = ParametricRegion[{Sqrt[Cos[2ϕ]]Cos[ϕ], Sqrt[Cos[2ϕ]]Sin[ϕ]}, {{ϕ, -Pi / 4, Pi / 4}}];

Wolfram Language code: Show[VectorPlot[f, {x, 0, 1}, {y, -1 / 2, 1 / 2}, ...], ...]

Wolfram Language code: LineIntegrate[f, {x, y}∈reg]

参数为和的外摆线的面积：

Wolfram Language code: reg = ParametricRegion[{(R + r)Cos[t] - r Cos[(R + r) / r * t], (R + r)Sin[t] - r Sin[(R + r) / r * t]}, {{t, 0, 2Pi}}];

Wolfram Language code: LineIntegrate[{-y / 2, x / 2}, {x, y}∈reg, Assumptions -> R == k * r && k∈Integers]

使用线积分计算心形面积：

Wolfram Language code: reg = ParametricRegion[{(2Cos[t] - Cos[2t]), (2Sin[t] - Sin[2t])}, {{t, 0, 2Pi}}];

Wolfram Language code: RegionPlot[reg, ImageSize -> Small]

Wolfram Language code: LineIntegrate[{-y / 2, x / 2}, {x, y}∈reg]

使用线积分计算星形线周长：

Wolfram Language code: reg = ParametricRegion[{Cos[t] ^ 3, Sin[t] ^ 3}, {{t, 0, 2Pi}}];

Wolfram Language code: RegionPlot[reg, ImageSize -> Small]

Wolfram Language code: LineIntegrate[{-y / 2, x / 2}, {x, y}∈reg]

力所做的功 (4)

物体沿直线运动时，重力所做的功：

Wolfram Language code: f = {0, 0, -m g};

Wolfram Language code: LineIntegrate[f, {x, y, z}∈Line[{{x1, y1, z1}, {x2, y2, z2}}]]

在电荷密度为的带电无限导线的电场中，当电荷从 {1,1,0} 移动到 {2,2,0}时，电力所做的功：

Wolfram Language code: f = {(λ * q * x/2Pi Subscript[ϵ, 0](x ^ 2 + y ^ 2)), (λ * q * y/2Pi Subscript[ϵ, 0](x ^ 2 + y ^ 2)), 0};

Wolfram Language code: LineIntegrate[f, {x, y, z}∈Line[{{1, 1, 0}, {2, 2, 0}}]]

指向原点的弹力沿四分之一椭圆所做的功：

Wolfram Language code: f = {-k x, -k y};

Wolfram Language code: reg = Circle[{0, 0}, {a, b}, {0, Pi / 2}];

Wolfram Language code: LineIntegrate[f, {x, y}∈reg]

电荷在电荷的电场中沿轴从移动到无穷大时，电力所做的功：

Wolfram Language code:

f = {(Q * q * x/4π Subscript[ϵ, 0](x ^ 2 + y ^ 2 + z ^ 2) ^ (3 / 2)), (Q * q * y/4π Subscript[ϵ, 0](x ^ 2 + y ^ 2 + z ^ 2) ^ (3 / 2)), (Q * q * z/4π Subscript[ϵ, 0](x ^ 2 + y ^ 2 + z ^ 2) ^ (3 / 2))};

Wolfram Language code: reg = ParametricRegion[{Subscript[x, 0] + t, 0, 0}, {{t, 0, Infinity}}];

Wolfram Language code: LineIntegrate[f, {x, y, z}∈reg, Assumptions -> Subscript[x, 0] > 0]

质心 (2)

半径为且线密度为的闭合半圆导线的质量：

Wolfram Language code: reg = Disk[{0, 0}, {1, 1}, {0, Pi}];

Wolfram Language code: m = LineIntegrate[λ, {x, y}∈reg]

质心的坐标：

Wolfram Language code: (1 / m) * LineIntegrate[λ * x, {x, y}∈reg]

质心的坐标：

Wolfram Language code: (1 / m) * LineIntegrate[λ * y, {x, y}∈reg]

线密度恒定为的螺旋线的惯性矩：

Wolfram Language code: reg = ParametricRegion[{Cos[t], Sin[t], t / 10}, {{t, 0, 6Pi}}];

Wolfram Language code: ParametricPlot3D[{Cos[t], Sin[t], t / 10}, {t, 0, 6Pi}, ImageSize -> Small]

关于轴：

Wolfram Language code: LineIntegrate[(y ^ 2 + z ^ 2) * ρ, {x, y, z}∈reg]

关于轴：

Wolfram Language code: LineIntegrate[(x ^ 2 + z ^ 2) * ρ, {x, y, z}∈reg]

关于轴：

Wolfram Language code: LineIntegrate[(x ^ 2 + y ^ 2) * ρ, {x, y, z}∈reg]

经典定理 (3)

如果矢量场的线积分只取决于端点的值，而不取决于路径，那么这个矢量场为保守的（conservative）：

Wolfram Language code: f = {3 x^2 y, x^3};

场是标量函数的梯度：

Wolfram Language code: g = x ^ 3 y;

Wolfram Language code: f == Grad[g, {x, y}]

所有标量场的梯度都是保守的. 例如，在曲线上的线积分为：

Wolfram Language code: reg = ParametricRegion[{t ^ 2, Exp[t]}, {{t, 0, 1}}];

Wolfram Language code: LineIntegrate[f, {x, y}∈reg]

这与曲线端点的值之差相同：

Wolfram Language code: (g /. {x -> t ^ 2, y -> Exp[t]} /. t -> 1) - (g /. {x -> t ^ 2, y -> Exp[t]} /. t -> 0)

封闭曲线上矢量场的线积分为：

Wolfram Language code: f = {x ^ 4, x * y ^ 2 + 1};

Wolfram Language code: LineIntegrate[f, {x, y}∈Line[{{0, 0}, {1, 0}, {0, 1}, {0, 0}}]]

这与在曲线所包围区域内的曲面积分有关，其中的定义为：

Wolfram Language code: g = D[f[[2]], x] - D[f[[1]], y];

Wolfram Language code: Integrate[g, {x, y}∈Triangle[{{0, 0}, {1, 0}, {0, 1}}]]

向量场在三维空间中沿闭合直线的线积分为：

Wolfram Language code: f = {-y + x y ^ 2, x, z};

Wolfram Language code: reg = ParametricRegion[{Cos[t], Sin[t], 0}, {{t, 0, 2Pi}}];

Wolfram Language code: LineIntegrate[f, {x, y, z}∈reg]

这等于以曲线为边界的任何曲面上的 Curl 的曲面积分：

Wolfram Language code: reg2 = ParametricRegion[{Cos[t]Cos[p], Cos[t]Sin[p], Sin[t]}, {{p, 0, 2Pi}, {t, 0, Pi / 2}}];

Wolfram Language code: SurfaceIntegrate[Curl[f, {x, y, z}], {x, y, z}∈reg2]

相同边界的不同曲面的曲面积分是相同的：

Wolfram Language code: SurfaceIntegrate[Curl[f, {x, y, z}], {x, y, z}∈ParametricRegion[{r Cos[t], r Sin[t], 0}, {{r, 0, 1}, {t, 0, 2Pi}}]]

属性和关系 (5)

如果符号计算失败，应用 N[LineIntegrate[...]] 获得数值解：

Wolfram Language code: f = Sin[x + y + z];

Wolfram Language code: reg = ParametricRegion[{t ^ 2, t ^ 3, t ^ 4}, {{t, 0, 1}}];

Wolfram Language code: LineIntegrate[f, {x, y, z}∈reg]

Wolfram Language code: N[LineIntegrate[f, {x, y, z}∈reg]]

求单位线密度的三角形导线的质心：

Wolfram Language code: reg = Line[{{0, 0}, {1, 0}, {1, 1}, {0, 0}}];

Wolfram Language code: RegionPlot[reg, ImageSize -> Small]

求总质量：

Wolfram Language code: m = LineIntegrate[1, {x, y}∈reg]

求质心的分量：

Wolfram Language code: 1 / m * LineIntegrate[x, {x, y}∈reg]

也可以使用 RegionCentroid 获得质心：

Wolfram Language code: RegionCentroid[reg]

求在 - 平面上以原点为中心的单位线密度圆线绕轴的惯性矩：

Wolfram Language code: reg = ParametricRegion[{Cos[t], Sin[t], 0}, {{t, 0, 2Pi}}];

Wolfram Language code: LineIntegrate[(x ^ 2 + y ^ 2), {x, y, z}∈reg]

答案也可以用 MomentOfInertia 计算得到：

Wolfram Language code: MomentOfInertia[reg, {0, 0, 0}, {0, 0, 1}]

求外摆线的长度：

Wolfram Language code: reg = ParametricRegion[{6 Cos[t] - Cos[6 t], 6 Sin[t] - Sin[6 t]}, {{t, 0, 2Pi}}];

Wolfram Language code: RegionPlot[reg, ImageSize -> Small]

Wolfram Language code: LineIntegrate[1, {x, y}∈reg]

使用 ArcLength 可以获得相同的答案：

Wolfram Language code: ArcLength[{6 Cos[t] - Cos[6 t], 6 Sin[t] - Sin[6 t]}, {t, 0, 2Pi}]

求椭圆的面积：

Wolfram Language code: reg = Circle[{0, 0}, {1 / Sqrt[2], 1 / Sqrt[3]}];

Wolfram Language code: LineIntegrate[{-y / 2, x / 2}, {x, y}∈reg]

结果可以使用 RegionMeasure 获得：

Wolfram Language code: RegionMeasure[Disk[{0, 0}, {1 / Sqrt[2], 1 / Sqrt[3]}]]

巧妙范例 (2)

悬链线长度：

Wolfram Language code: reg = ParametricRegion[{t, Cosh[t]}, {{t, -1, 1}}];

Wolfram Language code: ParametricPlot[{t, Cosh[t]}, {t, -1, 1}, ImageSize -> Small]

Wolfram Language code: LineIntegrate[1, {x, y}∈reg]

矢量场在 Clelia 曲线上的积分：

Wolfram Language code: f = {x ^ 2 + y, y ^ 2 + z, z ^ 2 + x};

Wolfram Language code: reg = ParametricRegion[{Cos[t]Cos[3t], Cos[t]Sin[3t], Sin[t]}, {{t, 0, 2Pi}}];

Wolfram Language code: Show[VectorPlot3D[f, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, Rule[...]], ...]

Wolfram Language code: LineIntegrate[f, {x, y, z}∈reg]

Top

		Line[{p₁,p₂,…}]	方向按照点从 p₁ 到 p₂ 等给出的顺序.
		HalfLine[{p₁,p₂}] HalfLine[p,v]	方向是从 p₁ 到 p₂，或在 v 方向
		InfiniteLine[{p₁,p₂}] InfiniteLine[p,v]	方向是从 p₁ 到 p₂，或在 v 方向
		Circle[p,r]	方向是逆时针

		Line[{p₁,p₂,…}]	方向按照点从 p₁ 到 p₂ 等给出的顺序
		HalfLine[{p₁,p₂}] HalfLine[p,v]	方向是从 p₁ 到 p₂，或在 v 方向
		InfiniteLine[{p₁,p₂}] InfiniteLine[p,v]	方向是从 p₁ 到 p₂，或在 v 方向

		Line[{p₁,p₂,…}]	方向按照给定的点的顺序
		HalfLine[{p₁,p₂}] HalfLine[p,v]	方向是从 p₁ 到 p₂ 方向由 v 给出
		InfiniteLine[{p₁,p₂}] InfiniteLine[p,v]	方向是从 p₁ 到 p₂ 方向由 v 给出

Assumptions	$Assumptions	关于参数的假设
Direction	Automatic	曲线的方向
GenerateConditions	Automatic	是否生成涉及参数条件的答案
WorkingPrecision	Automatic	内部计算中使用的精度

LineIntegrate

更多信息和选项

范例

基本范例 (7)

范围 (32)

基本用法 (4)

标量函数 (11)

矢量函数 (12)

特殊曲线 (4)

参数曲线 (1)

选项 (5)

Assumptions (1)

Direction (1)

GenerateConditions (1)

WorkingPrecision (2)

应用 (27)

大学微积分 (10)

长度 (3)

面积 (5)

力所做的功 (4)

质心 (2)

经典定理 (3)

属性和关系 (5)

巧妙范例 (2)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX