WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ListAnimate[{expr1,expr2,…}]

フレームが連続する expriであるアニメーションを生成する．

ListAnimate[list,fps]

1秒間に fps 個のフレームを描画する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
ListAnimateのコンテンツ  
ListAnimateのコントロール  
オプション  
Alignment  
AnimationDirection  
AnimationRate  
Show More Show More
AnimationRepetitions  
AnimationRunning  
AppearanceElements  
ControlPlacement  
DefaultDuration  
Deployed  
FrameMargins  
ImageMargins  
ImageSize  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
関連するワークフロー
関連リンク
履歴
引用書式

ListAnimate

ListAnimate[{expr1,expr2,…}]

フレームが連続する expriであるアニメーションを生成する．

ListAnimate[list,fps]

1秒間に fps 個のフレームを描画する．

詳細とオプション

例題

すべて開く すべて閉じる

例  (1)

連続する画像をアニメーションにする：

Wolfram Language code: ListAnimate[Table[Plot[Sin[n x], {x, 0, 10}], {n, 5}]]

スコープ  (4)

ListAnimateのコンテンツ  (3)

Wolfram言語による式のリストをアニメーションにする：

Wolfram Language code: ListAnimate[{Style["", Large], "string", Framed[x + y], Graphics[Rectangle[], ImageSize -> 20]}]

一連の式をアニメーションにする：

Wolfram Language code: ListAnimate[Table[Factor[x ^ n - 1], {n, 15}]]

式が一定の幅で折り返すように強制する：

Wolfram Language code: ListAnimate[Table[Pane[Factor[x ^ n - 1], 200], {n, 50}]]

TimeSeriesをアニメーションにする：

Wolfram Language code: ts = CountryData["UnitedStates", {"Population", {1970, 2014}}]
Wolfram Language code: ListAnimate[ts]

ListAnimateのコントロール  (1)

デフォルトでアニメーションは合計5秒間続くようになっている：

Wolfram Language code: ListAnimate[Table[Graphics[Disk[{0, 0}, n], PlotRange -> 5], {n, 5}]]

第2引数を使って各フレームの表示割合を制御する：

Wolfram Language code: ListAnimate[Table[Graphics[Disk[{0, 0}, n], PlotRange -> 5], {n, 5}], 1]

オプション  (19)

Alignment  (1)

設定済みの値を使う：

Wolfram Language code: Table[ListAnimate[{1, 2, 3}, Alignment -> a, AnimationRunning -> False], {a, {Left, Center, Right}}]

AnimationDirection  (1)

アニメーションの方向を制御する：

Wolfram Language code: Table[ListAnimate[{1, 2, 3}, AnimationDirection -> a, AnimationRunning -> False], {a, {Forward, Backward, ForwardBackward}}]

AnimationRate  (1)

アニメーションの速度を制御する：

Wolfram Language code: Table[ListAnimate[Range[10], AnimationRate -> a, AnimationRunning -> False], {a, {0.5, 1}}]

AnimationRepetitions  (1)

アニメーションサイクルの数を制御する：

Wolfram Language code: Table[ListAnimate[{1, 2, 3}, AnimationRepetitions -> a, AnimationRunning -> False], {a, 1, 2}]

AnimationRunning  (2)

デフォルトで，ListAnimateは評価されたときに実行し始める：

Wolfram Language code: ListAnimate[{1, 2, 3}]

AnimationRunning->Falseと設定すると，ListAnimateは休止状態で始まる：

Wolfram Language code: ListAnimate[{1, 2, 3}, AnimationRunning -> False]

AppearanceElements  (2)

デフォルトで，ListAnimateはAnimatorしか含んでいない：

Wolfram Language code: ListAnimate[{1, 2, 3}, AnimationRunning -> False]

AppearanceElementsを使って追加的なコントロールを入れることができる：

Wolfram Language code: Table[ListAnimate[{1, 2, 3}, AppearanceElements -> a, AnimationRunning -> False], {a, {"HideControlsButton", "SnapshotButton", "ResetButton", "UpdateButton", All}}]

ControlPlacement  (1)

コントロールの位置を指定する：

Wolfram Language code: Table[ListAnimate[{1, 2, 3}, ControlPlacement -> p, AnimationRunning -> False], {p, {Left, Right, Bottom, Top}}]

DefaultDuration  (1)

1回のアニメーションサイクルの持続時間を制御する：

Wolfram Language code: Table[ListAnimate[{1, 2, 3}, DefaultDuration -> a, AnimationRunning -> False], {a, 1, 2}]

Deployed  (2)

デフォルトで，コンテンツは選択したり編集したりできる：

Wolfram Language code: ListAnimate[Table[Graphics[Disk[]], {3}], AnimationRunning -> False]

Deployedを使ってコンテンツのインタラクティブ性を制限できる：

Wolfram Language code: ListAnimate[Table[Graphics[Disk[]], {3}], Deployed -> True, AnimationRunning -> False]

FrameMargins  (2)

設定済みの値を使う：

Wolfram Language code: Table[ListAnimate[Framed /@ {1, 2, 3}, FrameMargins -> f, AnimationRunning -> False], {f, {Tiny, Small, Medium, Large}}]

あるいは，任意の値を使う：

Wolfram Language code: ListAnimate[Framed /@ {1, 2, 3}, FrameMargins -> 20, AnimationRunning -> False]

ImageMargins  (2)

設定値を使う：

Wolfram Language code: Table[Framed@ListAnimate[{1, 2, 3}, ImageMargins -> f, AnimationRunning -> False], {f, {Tiny, Small, Medium, Large}}]

あるいは，任意の値を使う：

Wolfram Language code: Framed@ListAnimate[{1, 2, 3}, ImageMargins -> 20, AnimationRunning -> False]

ImageSize  (3)

デフォルトで，ListAnimateはコンテンツに十分なスペースを取ってありサイズ調整の必要はない：

Wolfram Language code: ListAnimate[Table[Graphics[Circle[], ImageSize -> s], {s, 20, 50, 10}], AnimationRunning -> False]

ImageSizeを設定すると，現行の表示に十分なだけのスペースが取られる：

Wolfram Language code: ListAnimate[Table[Graphics[Circle[], ImageSize -> s], {s, 20, 50, 10}], ImageSize -> Automatic, AnimationRunning -> False]

完全にカスタマイズされた画像サイズ：

Wolfram Language code: ListAnimate[Table[Graphics[Circle[], ImageSize -> s], {s, 20, 50, 10}], ImageSize -> {300, 100}, AnimationRunning -> False]

アプリケーション  (4)

最適化問題で個々のステップを集める：

Wolfram Language code: {sol, {steps}} = Reap[FindMinimum[(x - 1) ^ 2 + 100(y - x ^ 2) ^ 2, {{x, -1}, {y, 1}}, StepMonitor :> Sow[{x, y}]]]

ソルバの進行状況をアニメーションにする：

Wolfram Language code: ListAnimate[Table[ListLinePlot[Take[steps, i], Mesh -> All, PlotRange -> {{-1, 1.1}, {-1, 1.1}}], {i, Length[steps]}]]

正弦Gordonの偏微分方程式を解く際の個々のステップを集める：

Wolfram Language code: {sol, {steps}} = Reap@NDSolve[{Subscript[∂, t, t]u[t, x] == Subscript[∂, x, x]u[t, x] + Sin[u[t, x]] , u[0, x] == E^-x^2, u^(1, 0)[0, x] == 0, u[t, -10] == u[t, 10]}, u, {t, 0, 8}, {x, -10, 10}, StepMonitor :> Sow[Plot[u[t, x], {x, -10, 10}, PlotRange -> {0, 8}]]];//Quiet

解の進行状況をアニメーションにする：

Wolfram Language code: ListAnimate[steps]

中間ステップすべてでSowを使うLU分解の実装：

Wolfram Language code: LU[A_] := Module[{m, n, L, U}, {m, n} = Dimensions[A]; L = IdentityMatrix[n]; Sow[L, "L" ]; U = A; Sow[U, "U"]; Do[ L[[k ;; n, k]] = U[[k ;; n, k]] / U[[k, k]]; Sow[L, "L"]; U[[(k + 1) ;; n, k ;; n]] = U[[(k + 1) ;; n, k ;; n]] - L[[(k + 1) ;; n, {k}]].U[[{k}, k ;; n]]; Sow[U, "U"]; , {k, 1, n - 1}]; {L, U} ];

中間結果を収穫(Reap)し，アニメーションを作る：

Wolfram Language code: LUAnimate[A_, f_] := Module[ {lu, l, u}, {lu, {{l}, {u}}} = Reap[ LU[ A ], {"L", "U"}]; ListAnimate[Table[Row[{f[l[[i]]], ".", f[u[[i]]], "==", f[A]}], {i, Length[l]}]] ]
Wolfram Language code: LUAnimate[RandomInteger[{1, 10}, {5, 5}], MatrixForm]

より大きい行列にMatrixPlotを使う：

Wolfram Language code: LUAnimate[RandomInteger[{1, 10}, {20, 20}], MatrixPlot[#, FrameTicks -> None, ImageSize -> 100]&]

1ヶ月で変化する月相を示す：

Wolfram Language code: dates = DateRange[DateObject[{2014, 1, 1, 12}], DateObject[{2014, 1, 31, 12}], 1];
Wolfram Language code: mp = MoonPhase[dates, "Icon"]; sf = MoonPhase[dates, "Fraction"];

TimeSeriesThreadを使って，アイコンと分数からなるベクトル値を持つTimeSeriesを作る．次に時系列を再スケールし，タイムスタンプを整数にする：

Wolfram Language code: moon = TimeSeriesRescale[TimeSeriesThread[#&, {mp, sf}], {1, 31, 1}];

TimeSeriesMapThreadを使って，勾配背景を持つラベル付きの画像の列を作る：

Wolfram Language code: ts = TimeSeriesMapThread[Framed[Labeled[ImageResize[First[#2], 45], Style[#1, Bold, FontFamily -> "Helvetica"]], Background -> Lighter[ColorData["StarryNightColors", Last[#2]], .3]]&, moon];

この列をアニメーションにする：

Wolfram Language code: ListAnimate[ts]

特性と関係  (3)

ListAnimateを使ってTableの出力をアニメーションにする：

Wolfram Language code: ListAnimate[Table[Plot[BesselJ[n, x], {x, 0, 10}], {n, 5}], AnimationRunning -> False]

パラメータに依存するアニメーションにAnimateを使う：

Wolfram Language code: Animate[Plot[BesselJ[n, x], {x, 0, 10}, PlotRange -> 0.7], {n, 1, 5, 1}, AnimationRunning -> False]

カスタマイズしたアニメーションフレームの組立てにAnimatorを使う：

Wolfram Language code: Column[{Animator[Dynamic[t], {0, 1}], Dynamic@Plot[Sinc[t x], {x, 0, 10}, PlotRange -> 1]}]

おもしろい例題  (1)

ランダムな大きさの一連の円板をアニメーションにする：

Wolfram Language code: ListAnimate[Table[Graphics[Disk[], ImageSize -> RandomReal[100]], {50}]]
Wolfram Research (2007), ListAnimate, Wolfram言語関数， https://reference.wolfram.com/language/ref/ListAnimate.html （2014年に更新）.

テキスト

Wolfram Research (2007), ListAnimate, Wolfram言語関数， https://reference.wolfram.com/language/ref/ListAnimate.html （2014年に更新）.

CMS

Wolfram Language. 2007. "ListAnimate." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2014. https://reference.wolfram.com/language/ref/ListAnimate.html.

APA

Wolfram Language. (2007). ListAnimate. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ListAnimate.html

BibTeX

@misc{reference.wolfram_2026_listanimate, author="Wolfram Research", title="{ListAnimate}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/ListAnimate.html}", note=[Accessed: 01-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_listanimate, organization={Wolfram Research}, title={ListAnimate}, year={2014}, url={https://reference.wolfram.com/language/ref/ListAnimate.html}, note=[Accessed: 01-November-2026]}