WOLFRAM

Wolfram 语言与系统参考资料中心

ProductDistribution[dist1,dist2,…]

表示独立分量分布为 dist1, dist2, … 的联合分布.

更多信息
Details and Options Details and Options
背景
范例  
基本范例  
范围  
基本用途  
参数分布  
非参数分布  
导出分布  
应用  
属性和关系  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

ProductDistribution

ProductDistribution[dist1,dist2,…]

表示独立分量分布为 dist1, dist2, … 的联合分布.

更多信息

  • ProductDistribution[dist1,dist2,…] 的概率密度由 给出，其中 f1 是 dist1 的概率密度函数，f2 是 dist2 的概率密度函数等等.
  • 符号 {disti,n} 表示 disti 重复 n 次.
  • 分布 disti 可以是单变量、多变量、连续或离散分布的任意组合.
  • ProductDistribution 可与 Mean、CDF 和 RandomVariate 等函数联合使用.

背景

范例

打开所有单元 关闭所有单元

基本范例  (3)

定义独立正态随机变量的二维分布：

Wolfram Language code: 𝒟 = ProductDistribution[NormalDistribution[0, 2], NormalDistribution[1 / 3, 1]];
Wolfram Language code: Plot3D[PDF[𝒟, {x, y}], {x, -3, 3}, {y, -2, 2}]

定义独立同分布分量的二维分布：

Wolfram Language code: 𝒟 = ProductDistribution[{PoissonDistribution[6], 2}];
Wolfram Language code: DiscretePlot3D[PDF[𝒟, {x, y}], {x, 0, 12}, {y, 0, 12}, ExtentSize -> Full]

定义连续和离散分量的多元分布：

Wolfram Language code: 𝒟 = ProductDistribution[BinomialDistribution[10, 1 / 4], ExponentialDistribution[3]];
Wolfram Language code: RandomVariate[𝒟]

范围  (26)

基本用途  (7)

定义两个独立连续分布的乘积：

Wolfram Language code: 𝒟1 = NormalDistribution[1, 2]; 𝒟2 = CauchyDistribution[0, 1]; 𝒟 = ProductDistribution[𝒟1, 𝒟2];

概率密度函数是分量概率密度函数的乘积：

Wolfram Language code: PDF[𝒟, {x, y}] == PDF[𝒟1, x]PDF[𝒟2, y]
Wolfram Language code: Plot3D[PDF[𝒟, {x, y}], {x, -3, 5}, {y, -3, 3}, PlotRange -> All]

离散分布的乘积：

Wolfram Language code: 𝒟1 = BinomialDistribution[7, 2 / 3]; 𝒟2 = PoissonDistribution[6]; 𝒟 = ProductDistribution[𝒟1, 𝒟2];
Wolfram Language code: 𝒟 = ProductDistribution[𝒟1, 𝒟2];

概率密度函数是分量概率密度函数的乘积：

Wolfram Language code: PDF[𝒟, {x, y}] == PDF[𝒟1, x]PDF[𝒟2, y]//Simplify
Wolfram Language code: DiscretePlot3D[PDF[𝒟, {x, y}], {x, 0, 9}, {y, 0, 12}, ExtentSize -> 0.5]

定义一个乘积分布，其中有三个成分是重复的：

Wolfram Language code: 𝒟 = ProductDistribution[{ExponentialDistribution[4], 3}, NormalDistribution[]];

四维乘积分布的概率密度函数：

Wolfram Language code: PDF[𝒟, {w, x, y, z}]

同时具有连续和离散成分的乘积分布：

Wolfram Language code: 𝒟 = ProductDistribution[GeometricDistribution[1 / 3], BetaDistribution[3, 2]];

从该分布抽取随机样本：

Wolfram Language code: data = RandomVariate[𝒟, 10 ^ 5];

使用随机样本，从这些成分估计分布参数：

Wolfram Language code: 𝒟1 = ProductDistribution[GeometricDistribution[a], BetaDistribution[3, b]];
Wolfram Language code: FindDistributionParameters[data, 𝒟1]

定义一个具有很少重复分量的普通乘积分布：

Wolfram Language code: 𝒟 = ProductDistribution[{NormalDistribution[], 2}, UniformDistribution[], {PoissonDistribution[5], 3}];
Wolfram Language code: Variance[𝒟]//N

比较随机样本：

Wolfram Language code: sample = RandomVariate[𝒟, 10 ^ 5];
Wolfram Language code: Variance[sample]//N

多元连续分布的乘积：

Wolfram Language code: 𝒟 = ProductDistribution[DirichletDistribution[{2, 4, 7}], DirichletDistribution[{1, 3, 5}]];

概率密度函数：

Wolfram Language code: PDF[𝒟, {w, x, y, z}]

验证 PDF 的积分是 ：

Wolfram Language code: Integrate[PDF[𝒟, {w, x, y, z}], {w, -∞, ∞}, {x, -∞, ∞}, {y, -∞, ∞}, {z, -∞, ∞}]

多元离散分布的乘积：

Wolfram Language code: 𝒟 = ProductDistribution[MultinomialDistribution[30, {1 / 2, 1 / 3, 1 / 6}], MultinomialDistribution[10, {1 / 7, 2 / 7, 4 / 7}]];

计算该分布的方差：

Wolfram Language code: Variance[𝒟]//N

与通过使用随机样本得到的值相比较：

Wolfram Language code: data = RandomVariate[𝒟, 10 ^ 4];
Wolfram Language code: Variance[data]//N

参数分布  (6)

创建具有独立分量的二元正态分布：

Wolfram Language code: 𝒟 = ProductDistribution[NormalDistribution[-1, 2], NormalDistribution[1 / 3, 1]];

概率密度函数：

Wolfram Language code: Plot3D[PDF[𝒟, {x, y}], {x, -5, 3}, {y, -3, 3}]
Wolfram Language code: PDF[𝒟, {x, y}]

比较 BinormalDistribution：

Wolfram Language code: PDF[BinormalDistribution[{-1, 1 / 3}, {2, 1}, 0], {x, y}]
Wolfram Language code: % - %%//Simplify

定义一个二维拉普拉斯分布：

Wolfram Language code: 𝒟 = ProductDistribution[{LaplaceDistribution[0, 1], 2}];

概率密度函数：

Wolfram Language code: Plot3D[PDF[𝒟, {x, y}], {x, -1.5, 1.5}, {y, -1.5, 1.5}]
Wolfram Language code: PDF[𝒟, {x, y}]

均值和方差：

Wolfram Language code: {Mean[𝒟], Variance[𝒟]}

定义独立 PoissonDistribution 的乘积分布：

Wolfram Language code: 𝒟 = ProductDistribution[PoissonDistribution[3], PoissonDistribution[9]];

概率密度函数：

Wolfram Language code: DiscretePlot3D[PDF[𝒟, {x, y}], {x, 0, 9}, {y, 3, 12}, ExtentSize -> Full]
Wolfram Language code: PDF[𝒟, {x, y}]

协方差：

Wolfram Language code: Covariance[𝒟]//MatrixForm

MultivariatePoissonDistribution 没有独立分量：

Wolfram Language code: Covariance[MultivariatePoissonDistribution[μ, {Subscript[μ, 1], Subscript[μ, 2]}]]//MatrixForm

假设：

Wolfram Language code: DistributionParameterAssumptions[MultivariatePoissonDistribution[μ, {Subscript[μ, 1], Subscript[μ, 2]}]]

创建 StudentTDistribution 的两个独立例子的乘积分布：

Wolfram Language code: 𝒟 = ProductDistribution[{StudentTDistribution[0, 1, 9], 2}];

生成随机样本：

Wolfram Language code: sample = RandomVariate[𝒟, 10 ^ 3];

拟合 MultivariateTDistribution：

Wolfram Language code: edist = EstimatedDistribution[sample, MultivariateTDistribution[{{1, 0}, {0, 1}}, ν]]

拟合优度试验：

Wolfram Language code: DistributionFitTest[sample, edist]

计算具有符号参数的属性：

Wolfram Language code: 𝒟 = ProductDistribution[PoissonDistribution[m], GeometricDistribution[p]];

分布函数：

Wolfram Language code: PDF[𝒟, {x, y}]
Wolfram Language code: CDF[𝒟, {x, y}]

特殊矩：

Wolfram Language code: {Mean[𝒟], Variance[𝒟]}
Wolfram Language code: {Skewness[𝒟], Kurtosis[𝒟]}

有些矩可以表示为具有符号式阶数的解析式：

Wolfram Language code: Moment[𝒟, {Subscript[r, 1], Subscript[r, 2]}]//PiecewiseExpand
Wolfram Language code: FactorialMoment[𝒟, {Subscript[r, 1], Subscript[r, 2]}]//PiecewiseExpand

可以通过数值求解获得其它矩：

Wolfram Language code: CentralMoment[𝒟, {2, 3}]//Simplify
Wolfram Language code: Cumulant[𝒟, {2, 4}]

母函数：

Wolfram Language code: CharacteristicFunction[𝒟, {s, t}]
Wolfram Language code: MomentGeneratingFunction[𝒟, {s, t}]
Wolfram Language code: FactorialMomentGeneratingFunction[𝒟, {s, t}]

求 MultinormalDistribution 的边缘：

Wolfram Language code: Σ = (⁠| | | | | --------- | --------- | --------- | | σ1^2 | ρ12 σ1 σ2 | ρ13 σ1 σ3 | | ρ12 σ1 σ2 | σ2^2 | ρ23 σ2 σ3 | | ρ13 σ1 σ3 | ρ23 σ2 σ3 | σ3^2 |⁠);
Wolfram Language code: 𝒟 = MultinormalDistribution[{μ1, μ2, μ3}, Σ]; ℳ1 = MarginalDistribution[𝒟, 1]; ℳ2 = MarginalDistribution[𝒟, 2]; ℳ3 = MarginalDistribution[𝒟, 3];

求边缘分布的乘积分布：

Wolfram Language code: 𝒫 = ProductDistribution[ℳ1, ℳ2, ℳ3];

的概率密度函数：

Wolfram Language code: PDF[𝒫, {x, y, z}]

是具有对角协方差矩阵的 MultinormalDistribution：

Wolfram Language code: PDF[𝒟, {x, y, z}] /. {ρ12 -> 0, ρ13 -> 0, ρ23 -> 0}
Wolfram Language code: FullSimplify[% - %%, σ1 > 0 && σ2 > 0 && σ3 > 0]

非参数分布  (3)

定义 SmoothKernelDistribution 的乘积：

Wolfram Language code: skd1 = SmoothKernelDistribution[RandomVariate[LaplaceDistribution[0, 1], 10 ^ 3]]; skd2 = SmoothKernelDistribution[RandomVariate[NormalDistribution[], 10 ^ 3]]; 𝒟 = ProductDistribution[skd1, skd2];

比较原分布的乘积：

Wolfram Language code: 𝒫 = ProductDistribution[LaplaceDistribution[0, 1], NormalDistribution[]];
Wolfram Language code: Plot3D[First[#], {x, -3, 3}, {y, -3, 3}, PlotRange -> All, Exclusions -> None, Mesh -> 5, ColorFunction -> "SandyTerrain", PlotLabel -> Last[#]]& /@ {{PDF[𝒟, {x, y}], "𝒟"}, {PDF[𝒫, {x, y}], "𝒫"}}

从 中创建一个样本并为此定义一个 SmoothKernelDistribution：

Wolfram Language code: skd3 = SmoothKernelDistribution[RandomVariate[𝒫, 10 ^ 3]];

比较所有三个分布：

Wolfram Language code: Plot3D[First[#], {x, -3, 3}, {y, -3, 3}, PlotRange -> All, Exclusions -> None, Mesh -> 5, ColorFunction -> "SandyTerrain", PlotLabel -> Last[#]]& /@ {{PDF[𝒟, {x, y}], "𝒟"}, {PDF[𝒫, {x, y}], "𝒫"}, {PDF[skd3, {x, y}], "skd3"}}

定义一个 EmpiricalDistribution 的一个乘积：

Wolfram Language code: ed1 = EmpiricalDistribution[RandomVariate[PoissonDistribution[9], 20]]; ed2 = EmpiricalDistribution[RandomVariate[BenfordDistribution[10], 10]]; 𝒟 = ProductDistribution[ed1, ed2];

绘制概率密度函数和累积分布函数：

Wolfram Language code: {DiscretePlot3D[PDF[𝒟, {x, y}], {x, 5, 15}, {y, 0, 10}, ExtentSize -> 1 / 2, PlotLabel -> "PDF"], DiscretePlot3D[CDF[𝒟, {x, y}], {x, 5, 15}, {y, 0, 10}, ExtentSize -> Right, PlotLabel -> "CDF"]}

定义 HistogramDistribution 的一个乘积分布：

Wolfram Language code: hd = HistogramDistribution[RandomVariate[NormalDistribution[], 10 ^ 2]]; 𝒟 = ProductDistribution[hd, NormalDistribution[]];

概率密度函数：

Wolfram Language code: Plot3D[PDF[𝒟, {x, y}]//Evaluate, {x, -3, 3}, {y, -3, 3}, PlotRange -> All, Mesh -> None, ExclusionsStyle -> {None, Black}]
Wolfram Language code: PDF[𝒟, {x, y}]

导出分布  (10)

定义具有 CensoredDistribution 的乘积：

Wolfram Language code: 𝒞 = CensoredDistribution[{5, 9}, PoissonDistribution[7]]; 𝒟 = ProductDistribution[𝒞, PoissonDistribution[9]];
Wolfram Language code: DiscretePlot3D[PDF[𝒟, {x, y}]//Evaluate, {x, 0, 15}, {y, 0, 15}, ExtentSize -> Full]

MarginalDistribution 选择 ProductDistribution 分量：

Wolfram Language code: ℳ1 = MarginalDistribution[BinormalDistribution[ρ], 1]; ℳ2 = MarginalDistribution[BinormalDistribution[ρ], 2];

从边缘分布中合成乘积分布：

Wolfram Language code: 𝒫 = ProductDistribution[ℳ1, ℳ2];

概率密度函数：

Wolfram Language code: PDF[𝒫, {x, y}]

与无相关的二元分布一样：

Wolfram Language code: PDF[BinormalDistribution[0], {x, y}]

乘积分布的分量假设为是独立的，因此原分布不能恢复，当 非零时：

Wolfram Language code: PDF[BinormalDistribution[0.4], {x, y}]

从 MixtureDistribution 中创建乘积分布：

Wolfram Language code: ℳ1 = MixtureDistribution[{1, 1}, {NormalDistribution[1, 1 / 2], NormalDistribution[-2, 1]}]; ℳ2 = MixtureDistribution[{1, 2}, {LaplaceDistribution[0, 1], LaplaceDistribution[2, 1]}]; 𝒟 = ProductDistribution[ℳ1, ℳ2];

概率密度函数：

Wolfram Language code: Plot3D[PDF[𝒟, {x, y}]//Evaluate, {x, -3, 3}, {y, -2, 4}, PlotPoints -> 35, PlotRange -> All, Exclusions -> None]
Wolfram Language code: PDF[𝒟, {x, y}]

均值和方差：

Wolfram Language code: Mean[𝒟]
Wolfram Language code: Variance[𝒟]

求最小最大 OrderDistribution 的乘积分布：

Wolfram Language code: 𝒫 = ProductDistribution[OrderDistribution[{ErlangDistribution[2, 3.5], n}, n], OrderDistribution[{ErlangDistribution[2, 3.5], n}, 1]];

概率密度函数：

Wolfram Language code: PDF[𝒫, {x, y}]

绘制固定的 的密度函数：

Wolfram Language code: Block[{n = 4}, Plot3D[PDF[𝒫, {x, y}], {x, 0, 2}, {y, 0, 0.7}]]

定义 ParameterMixtureDistribution 的乘积分布：

Wolfram Language code: ℳ = ParameterMixtureDistribution[UniformDistribution[{a, b}], {aUniformDistribution[], bUniformDistribution[{2, 3}]}]; 𝒟 = ProductDistribution[ℳ, ℳ];
Wolfram Language code: Plot3D[PDF[𝒟, {x, y}]//Evaluate, {x, -0.5, 3.5}, {y, -0.5, 3.5}, Exclusions -> None]

乘积分布被用于 TransformedDistribution 的输入：

Wolfram Language code: TransformedDistribution[u + v, {u, v}ProductDistribution[{NormalDistribution[μ, σ], 2}]]

求 TransformedDistribution 的乘积分布：

Wolfram Language code: 𝒟1 = TransformedDistribution[2 u, uPoissonDistribution[7]]; 𝒟2 = TransformedDistribution[u, uPoissonDistribution[7]]; 𝒟 = ProductDistribution[𝒟1, 𝒟2];

概率密度函数：

Wolfram Language code: DiscretePlot3D[PDF[𝒟, {x, y}], {x, 4, 20, 2}, {y, 0, 14}, ExtentSize -> Full, Ticks -> {Range[4, 20, 2], Range[0, 14, 2]}]
Wolfram Language code: PDF[𝒟, {x, y}]

求 TruncatedDistribution 的乘积分布：

Wolfram Language code: 𝒟1 = TruncatedDistribution[{-2, 2}, NormalDistribution[]]; 𝒟2 = TruncatedDistribution[{-1, 1}, NormalDistribution[]]; 𝒟 = ProductDistribution[𝒟1, 𝒟2];

依赖于截断间隙的方差：

Wolfram Language code: Variance[𝒟]//FullSimplify
Wolfram Language code: N[%]

比较 PDF 和分布没有截断的乘积：

Wolfram Language code: 𝒫 = ProductDistribution[NormalDistribution[], NormalDistribution[]];
Wolfram Language code: {Plot3D[PDF[𝒟, {x, y}]//Evaluate, {x, -2.5, 2.5}, {y, -2.5, 2.5}, PlotRange -> All, Mesh -> None, ExclusionsStyle -> Lighter[Purple], PlotRange -> {0, 0.25}], Plot3D[PDF[𝒫, {x, y}]//Evaluate, {x, -2.5, 2.5}, {y, -2.5, 2.5}, Mesh -> None, PlotRange -> {0, 0.25}]}

求 TruncatedDistribution 的乘积分布：

Wolfram Language code: 𝒟1 = TruncatedDistribution[{-∞, 10}, PoissonDistribution[9]]; 𝒟2 = TruncatedDistribution[{5, ∞}, PoissonDistribution[9]]; 𝒟 = ProductDistribution[𝒟1, 𝒟2];

比较 PDF 和两个泊松分布的乘积分布：

Wolfram Language code: 𝒫 = ProductDistribution[{PoissonDistribution[9], 2}];
Wolfram Language code: {DiscretePlot3D[PDF[𝒟, {x, y}], {x, 0, 15}, {y, 0, 15}, ExtentSize -> 1, PlotRange -> {0, 0.03}], DiscretePlot3D[PDF[𝒫, {x, y}], {x, 0, 15}, {y, 0, 15}, ExtentSize -> 1, PlotRange -> {0, 0.03}]}

删截影响偏度的方向和值：

Wolfram Language code: Skewness[𝒟]//N
Wolfram Language code: Skewness[𝒫]//N

两个 QuantityDistribution 的积的结果是 QuantityDistribution：

Wolfram Language code: 𝒟1 = NormalDistribution[Quantity[10, "Grams"], Quantity[1, "Grams"]]; 𝒟2 = BinormalDistribution[{Quantity[1, "Pounds"], Quantity[1.3, "Pounds"]}, {Quantity[0.1, "Pounds"], Quantity[0.1, "Pounds"]}, .4]; 𝒟 = ProductDistribution[𝒟1, 𝒟2]

求矩：

Wolfram Language code: Moment[𝒟, {1, 2, 1}]
Wolfram Language code: CentralMoment[𝒟, {2, 2, 2}]

将分布中的单位转换成千克：

Wolfram Language code: UnitConvert[𝒟, "Kilograms"]

应用  (8)

从二元分布中产生一个不相关样本：

Wolfram Language code: sample = RandomVariate[BinormalDistribution[{2, -3}, {1, 1 / 2}, 0], 10 ^ 3];

样本轻度相关，虽然源分布不是：

Wolfram Language code: Correlation[sample]//MatrixForm

从数据中估计分布：

Wolfram Language code: PDF[edist = EstimatedDistribution[sample, BinormalDistribution[{μ1, μ2}, {σ1, σ2}, ρ]], {x, y}]

估计分布有类似于样本的相关：

Wolfram Language code: Correlation[edist]//MatrixForm

通过估计边缘分布形成独立估计：

Wolfram Language code: edist1 = EstimatedDistribution[sample[[All, 1]], NormalDistribution[μ, σ]]
Wolfram Language code: edist2 = EstimatedDistribution[sample[[All, 2]], NormalDistribution[μ, σ]]

创建乘积分布：

Wolfram Language code: pdist = ProductDistribution[edist1, edist2];
Wolfram Language code: PDF[pdist, {x, y}]

由此得出的分布不相关：

Wolfram Language code: Correlation[pdist]//MatrixForm

两个人想要在下午5点到5点半之间于某地见面. 两人的到达时刻在该时间段上相互独立，并各自停留5分钟. 求两人能见面的概率：

Wolfram Language code: Probability[Abs[x - y] ≤ Quantity[5, "Minutes"], {x, y}ProductDistribution[{UniformDistribution[{Quantity[0, "Minutes"], Quantity[30, "Minutes"]}], 2}]]

显示重合事件发生的区域：

Wolfram Language code: RegionPlot[Abs[x - y] ≤ 5, {x, 0, 30}, {y, 0, 30}]

独立抛掷两个六面骰子. 求两者点数之和的密度：

Wolfram Language code: Probability[x + y == n, {x, y}ProductDistribution[{DiscreteUniformDistribution[{1, 6}], 2}]]
Wolfram Language code: DiscretePlot[%, {n, 1, 12}, ExtentSize -> 1 / 3]

求独立抛掷三个骰子时，点数之和的密度：

Wolfram Language code: Probability[x + y + z == n, {x, y, z}ProductDistribution[{DiscreteUniformDistribution[{1, 6}], 3}]]
Wolfram Language code: DiscretePlot[%, {n, 1, 18}, ExtentSize -> 1 / 3]

求值位于半径为7的圆外，边为14的正方形圆内的概率：

Wolfram Language code: 𝒟 = ProductDistribution[{UniformDistribution[{-7, 7}], 2}];
Wolfram Language code: Graphics[{{Blend[{Green, Blue}], Rectangle[{-7, -7}, {7, 7}]}, {Blend[{Orange, Yellow}], Disk[{0, 0}, 7]}}, AspectRatio -> 1.1]
Wolfram Language code: Probability[x ^ 2 + y ^ 2 > 49, {x, y}𝒟]

从标准正态分布中生成样本量为100的随机样本：

Wolfram Language code: 𝒟 = ProductDistribution[{NormalDistribution[], 100}];
Wolfram Language code: data = RandomVariate[𝒟, 10 ^ 5];

均值的抽样分布由 NormalDistribution[0,1/10] 给出：

Wolfram Language code: av = Mean[Transpose[data]];
Wolfram Language code: Histogram[av, 50, "PDF", AxesOrigin -> {0, 0}, Ticks -> {Automatic, None}]
Wolfram Language code: Mean[av]
Wolfram Language code: StandardDeviation[av]

一种彩票销售10张票，每张票1美元. 每次只有一张彩票中奖. 一位赌徒只有5美元可以用于购买彩票. 求如果该赌徒购买5张属于5种不同类型的彩票时，他的中奖率：

Wolfram Language code: 𝒟 = ProductDistribution[{BinomialDistribution[1, 1 / 10], 5}];
Wolfram Language code: Probability[1 ≤ x + y + u + v + w, {x, y, u, v, w}𝒟]
Wolfram Language code: N[%]

如果该赌徒购买5张相同种类的彩票，他的中奖率会增加：

Wolfram Language code: PDF[HypergeometricDistribution[5, 1, 10], 1]
Wolfram Language code: N[%]

在影院买票和买爆米花的等待时间是独立的，它们均是指数分布. 买票的平均等待时间是10分钟，买爆米花是5分钟. 求影迷就坐前等待小于25分钟的概率：

Wolfram Language code: 𝒟 = ProductDistribution[ExponentialDistribution[1 / Quantity[10, "Minutes"]], ExponentialDistribution[1 / Quantity[5, "Minutes"]]]
Wolfram Language code: Probability[x + y ≤ Quantity[25, "Minutes"], {x, y}𝒟]//Expand
Wolfram Language code: N[%]

直接获得概率的数值值：

Wolfram Language code: NProbability[x + y < Quantity[25, "Minutes"], {x, y}𝒟]

一个工厂生产的圆柱状滚子轴承. 轴承的直径是正态分布，均值为5厘米和标准偏差为0.01厘米. 轴承的长度是正态分布，均值为7厘米和标准偏差为0.01厘米. 假设直径和长度是独立分布的，求轴承的直径或长度不同于均值相差大于0.02厘米的概率.

直径和长度的联合分布为：

Wolfram Language code: 𝒟 = ProductDistribution[NormalDistribution[Quantity[5, "Centimeters"], Quantity[0.01, "Centimeters"]], NormalDistribution[Quantity[7, "Centimeters"], Quantity[0.01, "Centimeters"]]];
Wolfram Language code: Plot3D[PDF[𝒟, {Quantity[x, "Centimeters"], Quantity[y, "Centimeters"]}]//Evaluate, {x, 4.95, 5.05}, {y, 6.95, 7.05}, PlotRange -> All, ColorFunction -> Hue]
Wolfram Language code: 1 - Probability[Abs[x - Quantity[5, "Centimeters"]] < Quantity[0.02, "Centimeters"] && Abs[y - Quantity[7, "Centimeters"]] < Quantity[0.02, "Centimeters"], {x, y}𝒟]

属性和关系  (7)

边缘分布只与分量分布有关：

Wolfram Language code: 𝒟 = ProductDistribution[PoissonDistribution[m], GeometricDistribution[p], BinomialDistribution[n, q]];

一维边缘分布：

Wolfram Language code: MarginalDistribution[𝒟, 2]

二维边缘分布：

Wolfram Language code: MarginalDistribution[𝒟, {1, 3}]

一个乘积 Copula 表示一个乘积分布：

Wolfram Language code: 𝒟1 = NormalDistribution[0, 1]; 𝒟2 = NormalDistribution[2, 3];
Wolfram Language code: copula = CopulaDistribution["Product", {𝒟1, 𝒟2}]; product = ProductDistribution[𝒟1, 𝒟2];
Wolfram Language code: PDF[copula, {x, y}]
Wolfram Language code: PDF[product, {x, y}]
Wolfram Language code: % - %%

PDF 是各分量分布的概率密度分布的乘积：

Wolfram Language code: 𝒟1 = NormalDistribution[2, 5]; 𝒟2 = NormalDistribution[3, 7]; 𝒟 = ProductDistribution[𝒟1, 𝒟2];
Wolfram Language code: PDF[𝒟, {x, y}]
Wolfram Language code: PDF[𝒟1, x]PDF[𝒟2, y]
Wolfram Language code: % - %%

CDF 是各分量的累积分布函数的乘积：

Wolfram Language code: 𝒟1 = NormalDistribution[2, 5]; 𝒟2 = NormalDistribution[3, 7]; 𝒟 = ProductDistribution[𝒟1, 𝒟2];
Wolfram Language code: CDF[𝒟, {x, y}]
Wolfram Language code: CDF[𝒟1, x] CDF[𝒟2, y]
Wolfram Language code: % - %%

母函数是各分量分布的母函数的乘积：

Wolfram Language code: 𝒟1 = NormalDistribution[2, 5]; 𝒟2 = NormalDistribution[3, 7]; 𝒟 = ProductDistribution[𝒟1, 𝒟2];
Wolfram Language code: MomentGeneratingFunction[𝒟, {t, u}]
Wolfram Language code: MomentGeneratingFunction[𝒟1, t] MomentGeneratingFunction[𝒟2, u]
Wolfram Language code: % - %%

均值向量的各个元素是各分量分布的均值：

Wolfram Language code: 𝒟1 = NormalDistribution[2, 5]; 𝒟2 = NormalDistribution[3, 7]; 𝒟 = ProductDistribution[𝒟1, 𝒟2];
Wolfram Language code: Mean[𝒟]
Wolfram Language code: {Mean[𝒟1], Mean[𝒟2]}

方差与此类似：

Wolfram Language code: Variance[𝒟]
Wolfram Language code: {Variance[𝒟1], Variance[𝒟2]}

当协方差矩阵为对角矩阵时，MultinormalDistribution 是乘积分布：

Wolfram Language code: 𝒟1 = MultinormalDistribution[{Subscript[μ, 1], Subscript[μ, 2]}, DiagonalMatrix[{Subscript[σ, 1]^2, Subscript[σ, 2]^2}]]; 𝒟2 = ProductDistribution[NormalDistribution[Subscript[μ, 1], Subscript[σ, 1]], NormalDistribution[Subscript[μ, 2], Subscript[σ, 2]]];
Wolfram Language code: PDF[𝒟1, {x, y}]
Wolfram Language code: PDF[𝒟2, {x, y}]
Wolfram Language code: Simplify[%% - %, Subscript[σ, 1] > 0 && Subscript[σ, 2] > 0]

巧妙范例  (1)

一个三维乘积分布的等概率密度水平：

Wolfram Language code: 𝒟 = ProductDistribution[NormalDistribution[], ExponentialDistribution[0.5], LaplaceDistribution[0, 1]];
Wolfram Language code: ContourPlot3D[Evaluate[PDF[𝒟, {x, y, z}]], {x, -3, 3}, {y, 0, 5}, {z, -2.5, 2.5}, Mesh -> 10, MeshFunctions -> {#2&}, MeshShading -> {Automatic, None}, Contours -> {{0.01, Red}, {0.02, Green}, {0.04, Blue}}, AxesLabel -> Table[Style[ToString[MarginalDistribution[𝒟, i]], 10, Bold, FontFamily -> "Vendana"], {i, 3}]]
Wolfram Research (2010)，ProductDistribution，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ProductDistribution.html （更新于 2016 年）.

文本

Wolfram Research (2010)，ProductDistribution，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ProductDistribution.html （更新于 2016 年）.

CMS

Wolfram 语言. 2010. "ProductDistribution." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2016. https://reference.wolfram.com/language/ref/ProductDistribution.html.

APA

Wolfram 语言. (2010). ProductDistribution. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ProductDistribution.html 年

BibTeX

@misc{reference.wolfram_2026_productdistribution, author="Wolfram Research", title="{ProductDistribution}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/ProductDistribution.html}", note=[Accessed: 31-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_productdistribution, organization={Wolfram Research}, title={ProductDistribution}, year={2016}, url={https://reference.wolfram.com/language/ref/ProductDistribution.html}, note=[Accessed: 31-October-2026]}