RegionMeasure
RegionMeasure
RegionMeasure[reg]
領域 reg の測度を与える．
RegionMeasure[reg,d]
領域 reg の d 次元測度を与える．
RegionMeasure[{x1,…,xn},{{t1,a1,b1},…,{tk,ak,bk}}]
直交座標 xiが tjの関数であるパラメトリック式の k 測度を与える．
RegionMeasure[{x1,…,xn},{{t1,a1,b1},…,{tk,ak,bk}},chart]
xiを指定された座標チャートにおける座標として解釈する．
詳細とオプション
- RegionMeasureは，数(0D)，長さ(1D)，面積(2D)，体積(3D)，ルベーグ(Lebesgue)測度としても知られている．
- 行が埋込み次元，列が幾何学次元に相当する例
- 領域 reg の次元が d≥0のときは，d 次元測度が使われる．
- 零次元測度は，領域内の点の数を数える．
- RegionMeasure[x,{{t1,a1,b1},…,{tk,ak,bk}}]では，x がスカラーならRegionMeasureは k+1次元の超曲面{t1,…,tk,x}の測度を返す．
- RegionMeasureの第3引数における座標チャートはCoordinateChartDataの第1引数におけるのと同じ方法で3つトリプル{coordsys,metric,dim}を使って指定することができる．dim を省略した短縮形も使うことができる．
- 次のオプションが使える．
-
AccuracyGoal Infinity 目標絶対確度の桁数 Assumptions $Assumptions パラメータに関する仮定 GenerateConditions Automatic パラメータについての条件を生成するかどうか PerformanceGoal $PerformanceGoal パフォーマンスのどの面について最適化するか PrecisionGoal Automatic 目標精度の桁数 WorkingPrecision Automatic 内部計算に使用する精度 - 積分の記号極限は実数で順序付けられていると仮定される．記号座標チャートのパラメータはCoordinateChartDataの"ParameterRangeAssumptions"特性で与えられる範囲内の収まるものと仮定される．
- RegionMeasureは，GeometricSceneの記号領域と一緒に使うことができる．
例題
すべて開く すべて閉じる例 (6)
RegionMeasureは，零次元領域の点の数に相当する：
ℛ = Point[{{0, 0}, {1, 0}, {1, 1}}];RegionDimension[ℛ]RegionMeasure[ℛ]RegionMeasureは，一次元領域の曲線の長さに相当する：
ℛ = Line[{{0, 0, 0}, {1, 1, 1}}];RegionDimension[ℛ]RegionMeasure[ℛ]ArcLength[ℛ]RegionMeasureは，二次元領域の表面積に相当する：
ℛ = Disk[];RegionDimension[ℛ]RegionMeasure[ℛ]Area[ℛ]RegionMeasureは，三次元領域の体積に相当する：
ℛ = Ball[];RegionDimension[ℛ]RegionMeasure[ℛ]Volume[ℛ]RegionMeasure[{r Cos[x], r Sin[2x]}, {{x, 0, 2π}, {r, 1 / 2, 1}}]ParametricPlot[{r Cos[x], r Sin[2x]}, {x, 0, 2π}, {r, 1 / 2, 1}]RegionMeasure[{r, t, z}, {{r, 0, R}, {t, 0, 2Pi}, {z, 0, Z}}, "Cylindrical"]スコープ (29)
特別な領域 (10)
Pointについての測度は数に相当する：
ℛ = Point[Tuples[Range[5], 2]];
Region[ℛ]RegionMeasure[ℛ]RegionMeasure[Point[Tuples[Range[5], 4]]]Lineについての測度は弧長に相当する：
ℛ = Line[{{0, 0}, {1, 1}}];
Region[ℛ]RegionMeasure[ℛ]RegionMeasure[Line[{{0}, {1}}]]RegionMeasure[Line[{{0, 0, 0}, {1, 1, 1}}]]Rectangleは2Dで使うことができ，この測度は面積に相当する：
RegionMeasure[Rectangle[{Subscript[l, x], Subscript[l, y]}, {Subscript[u, x], Subscript[u, y]}]]Region[Rectangle[{0, 0}, {2, 1}]]Cuboidは任意の次元で使うことができる：
RegionMeasure[Cuboid[{Subscript[l, x], Subscript[l, y], Subscript[l, z]}, {Subscript[u, x], Subscript[u, y], Subscript[u, z]}]]Region[Cuboid[{0, 0, 0}, {3, 2, 1}]]RegionMeasure[Cuboid[{Subscript[l, x], Subscript[l, y], Subscript[l, z], Subscript[l, w]}, {Subscript[u, x], Subscript[u, y], Subscript[u, z], Subscript[u, w]}]]Simplexは，二次元では，点，線，三角形に相当し得る：
ℛ = {Simplex[{{0, 0}}], Simplex[{{0, 0}, {1, 1}}], Simplex[{{0, 0}, {1, 0}, {0, 1}}]};Table[Region[s], {s, ℛ}]RegionMeasure /@ ℛRegionMeasure[Simplex[{{0}, {1}}]]RegionMeasure[Simplex[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}]]
Table[RegionMeasure[Simplex[n]], {n, 1, 7}]Polygonは面積を表す：
ℛ = Polygon[{{0, 0}, {2, -1}, {1, 0}, {2, 1}}];
Region[ℛ]RegionMeasure[ℛ]ℛ = Polygon[{{0, 0, 0}, {(5/3), (2/3), -(4/3)}, {(2/3), (2/3), -(1/3)}, {1, 2, 0}}];
Region[ℛ]RegionMeasure[ℛ]Diskは2Dで使うことができる：
RegionMeasure[Disk[{Subscript[c, x], Subscript[c, y]}, r]]Region[Disk[{0, 0}, 1]]Ballは任意の次元で使うことができる．測度は一般化された体積である：
RegionMeasure[Ball[{Subscript[c, x], Subscript[c, y], Subscript[c, z]}, r]]Region[Ball[{0, 0, 0}, 1]]
Table[RegionMeasure[Ball[n]], {n, 1, 7}]楕円としてのDiskは2Dで使うことができる：
RegionMeasure[Disk[{Subscript[c, x], Subscript[c, y]}, {Subscript[r, x], Subscript[r, y]}]]Region[Disk[{0, 0}, {3, 2}]]Ellipsoidは任意の次元で使うことができる：
RegionMeasure[Ellipsoid[{Subscript[c, x], Subscript[c, y], Subscript[c, z]}, {Subscript[r, x], Subscript[r, y], Subscript[r, z]}]]Region[Ellipsoid[{0, 0, 0}, {3, 2, 1}]]RegionMeasure[Ellipsoid[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3], Subscript[c, 4], Subscript[c, 5]}, {Subscript[r, 1], Subscript[r, 2], Subscript[r, 3], Subscript[r, 4], Subscript[r, 5]}]]Circleは2Dで使うことができる：
RegionMeasure[Circle[{Subscript[c, x], Subscript[c, y]}, r]]Region[Circle[{0, 0}, 1]]RegionMeasure[Circle[{Subscript[c, x], Subscript[c, y]}, {Subscript[r, x], Subscript[r, y]}]]Region[Circle[{0, 0}, {3, 2}]]Cylinderは3Dで使うことができる：
RegionMeasure[Cylinder[{{Subscript[x, 1], Subscript[y, 1], Subscript[z, 1]}, {Subscript[x, 2], Subscript[y, 2], Subscript[z, 2]}}, r]]Region[Cylinder[{{0, 0, 0}, {0, 0, 2}}, 1]]Coneは3Dで使うことができる：
RegionMeasure[Cone[{{Subscript[x, 1], Subscript[y, 1], Subscript[z, 1]}, {Subscript[x, 2], Subscript[y, 2], Subscript[z, 2]}}, r]]Region[Cone[{{0, 0, 0}, {0, 0, 2}}, 1]]数式定義領域 (2)
ImplicitRegionとして表された円板の測度：
RegionMeasure[ImplicitRegion[x^2 + y^2 ≤ 1, {x, y}]]RegionMeasure[ImplicitRegion[x^2 + y^2 ≤ 1, {x, y, {z, 0, 2}}]]ParametricRegionとして表された円板の測度：
RegionMeasure[ParametricRegion[{r Cos[θ], r Sin[θ]}, {{r, 0, 1}, {θ, 0, 2π}}]]RegionMeasure[ParametricRegion[{r(1 - t^2/1 + t^2), r(2t/1 + t^2)}, {t, {r, 0, 1}}]]RegionMeasure[ParametricRegion[{r Cos[θ], r Sin[θ], z}, {{r, 0, 1}, {θ, 0, 2π}, {z, 0, 2}}]]メッシュ領域 (2)
2DにおけるMeshRegionの測度：
DelaunayMesh[RandomReal[1, {10, 2}]]RegionMeasure[%]MeshRegion[{{0, 0}, {1, 0}, {2, -1}, {2, 1}}, {Line[{{1, 2, 3, 4, 2}}]}]RegionMeasure[%]DelaunayMesh[RandomReal[1, {20, 3}]]RegionMeasure[%]ConvexHullMesh[RandomReal[1, {10, 2}]]RegionMeasure[%]ConvexHullMesh[RandomReal[1, {30, 3}]]RegionMeasure[%]派生領域 (3)
ℛ = RegionIntersection[Disk[{0, 0}, 1], Disk[{0, 1}, 1]];Region[ℛ]RegionMeasure[ℛ]ℛ = TransformedRegion[Disk[{0, 0}, 1], ShearingTransform[θ, {1, 0}, {0, 1}]];DiscretizeRegion[ℛ /. {θ -> 30Degree}, {{-2, 2}, {-1, 1}}]RegionMeasure[ℛ]RegionBoundaryの測度：
ℛ = RegionBoundary[Simplex[2]];DiscretizeRegion[ℛ, {{-1.1, 1.1}, {-1.1, 1.1}}]RegionMeasure[ℛ]地理的領域 (2)
ℛ = Polygon[["france"]];RegionMeasure[ℛ]GeoPositionを使った多角形：
ℛ = Polygon[GeoPosition[{{{40.083441, -88.235716}, {40.083607, -88.257488}, {40.082603, -88.257149},
{40.076136999999996, -88.25740499999999}, {40.076178, -88.270888}, {40.076516, -88.271558},
{40.083686, -88.271512}, {40.083659999999995, -88.267046}, ... 33323}, {40.098112, -88.228687},
{40.095216, -88.228627}, {40.095179, -88.238547}, {40.094480999999995, -88.238546},
{40.094508999999995, -88.23267}, {40.094106, -88.232556}, {40.090666999999996, -88.232477},
{40.090741, -88.235745}}}]];RegionMeasure[ℛ]GeoGridPositionを使った多角形の測度：
ℛ = Polygon[GeoGridPosition[{{{-0.9950503945490105, 1.2366760550756015},
{-0.9952074890903578, 1.2369207053693891}, {-0.9952196732768064, 1.2369073327446167},
{-0.9953160063787643, 1.236848436956935}, {-0.9954141759436825, 1.2369993898475449},
{-0. ... 197645333103}, {-0.9949098578570917, 1.2368130881428654},
{-0.9948663952535768, 1.2367477711687371}, {-0.9948714472169538, 1.2367426500757825},
{-0.9949211061652593, 1.2367089232486177}, {-0.9949439717990124, 1.236746107097628}}}, "Bonne"]];RegionMeasure[ℛ]パラメトリック式 (8)
RegionMeasure[{Cos[x], Sin[x]}, {{x, 0, 5 / 4}}]ParametricPlot[{Cos[x], Sin[x]}, {x, 0, 5 / 4}, PlotRange -> {0, 1}]RegionMeasure[{Exp[-t / 10], t}, {{t, 0, ∞}}, "Polar"]ParametricPlot[CoordinateTransform[ "Polar" -> "Cartesian", {Exp[-t / 10], t}]//Evaluate, {t, 0, 50}, PlotRange -> All]RegionMeasure[{(5 + 2Sin[p])Cos[t], (5 + 2Sin[p])Sin[t], 2Cos[p]}, {{t, 0, 2Pi}, {p, 0, 2Pi}}]RegionMeasure[{(5 + 2 r Sin[p])Cos[t], (5 + 2 r Sin[p])Sin[t], 5 Cos[p]}, {{r, 0, 1}, {t, 0, 2Pi}, {p, 0, 2Pi}}]ParametricPlot3D[{(5 + 2Sin[p])Cos[t], (5 + 2Sin[p])Sin[t], 2Cos[p]}, {t, 0, 2Pi}, {p, 0, 2Pi} ]RegionMeasure[{5Sin[t], 5Cos[t], 2Sin[p], 2Cos[p]}, {{t, 0, 2Pi}, {p, 0, 2Pi}}]RegionMeasure[{Cos[θ], Cos[φ] Sin[θ], Cos[ψ] Sin[θ] Sin[φ], Cos[χ] Sin[θ] Sin[φ] Sin[ψ], Sin[θ] Sin[φ] Sin[χ] Sin[ψ]}, {{θ, 0, Pi}, {φ, 0, Pi}, {ψ, 0, Pi}, {χ, 0, 2Pi}}]
RegionMeasure[w^2 + x^2 + y^2 + z^2, {{w, 0, 1.}, {x, 0, 1.}, {y, 0, 1.}, {z, 0, 1.}}]RegionMeasure[{TriangleWave[{0, Pi}, p / (2Pi)], p}, {{p, 0, 2Pi}}, {"Standard", {"Sphere", 1}}]RegionMeasure[{TriangleWave[{0, Pi}, p / (2Pi)], p}, {{p, 0, 2Pi}}, {"Standard", {"Sphere", 1}}]Show[{Graphics3D[{Opacity[.5], Sphere[]}], ParametricPlot3D[Evaluate@CoordinateTransform[ "Spherical" -> "Cartesian", {1, TriangleWave[{0, Pi}, p / (2Pi)], p}], {p, 0, 2Pi}]}]RegionMeasure[{x, y}, {{x, 0, 1}, {y, 0, 1}}, {"Stereographic", {"Sphere", 1}}]Show[{Graphics3D[{Opacity[.5], Sphere[]}], ParametricPlot3D[Evaluate@CoordinateTransform[ "Spherical" -> "Cartesian", Prepend[CoordinateTransform[{"Stereographic", {"Sphere", 1}} -> {"Standard", {"Sphere", 1}}, {x, y}], 1]], {x, 0, 1}, {y, 0, 1}]}]CSG領域 (1)
2DにおけるCSGRegionの測度：
ℛ = CSGRegion["Difference", {Disk[], Disk[{1 / 2, 1 / 2}]}]RegionMeasure[ℛ]ℛ = CSGRegion["Difference", {Cube[2], Cylinder[{{1, 1, 1}, {1, -1, 1}}]}]RegionMeasure[ℛ]細分割領域 (1)
2DにおけるSubdivisionRegionの測度：
ℛ = SubdivisionRegion[Rectangle[]]RegionMeasure[ℛ]ℛ = SubdivisionRegion[Cube[]]RegionMeasure[ℛ]オプション (4)
Assumptions (2)
RegionMeasure[ImplicitRegion[x ^ 2 + a y ^ 2 == 1, {x, y}], GenerateConditions -> True]
RegionMeasure[ImplicitRegion[x ^ 2 + a y ^ 2 == 1, {x, y}], Assumptions -> a > 0]
RegionMeasure[{r, v}, {{r, 0, ArcSech[Sqrt[1 - (b^2/a^2)]]}, {v, 0, 2Pi}}, {{"Elliptic", Sqrt[a^2 - b^2]}}]RegionMeasure[{r, v}, {{r, 0, ArcSech[Sqrt[1 - (b^2/a^2)]]}, {v, 0, 2Pi}}, {{"Elliptic", Sqrt[a^2 - b^2]}}, Assumptions -> a > 0 && b > 0]アプリケーション (13)
点 (2)
pts = Point[Tuples[Range[10], 2]];
Region[pts]RegionMeasure[pts]一定した点の質量 
について，測定値に 
を掛けて全体の質量を求める：
m = 0.5;
pts = Point[Tuples[Range[10], 2]];
m RegionMeasure[pts]一定しない点の質量関数 
についてはIntegrateを使う：
ρ[x_, y_] := (x^2 + y^2) / 100;Integrate[ρ[x, y], {x, y}∈pts]曲線 (4)
RegionMeasure[ParametricRegion[{x, x^2}, {{x, 0, 1}}]]RegionMeasure[ImplicitRegion[x^2 + y^2 == 1, {x, y}]]RegionMeasure[ImplicitRegion[x^2 + y^2 == 1∧z == x, {x, y, z}]]curves = {[image], [image], [image], [image]};RegionMeasure /@ curvesFindSequenceFunction[Rationalize[%], n]
δ = 3 / 10;
r = ImplicitRegion[x^2 + y^2 == 1, {x, y}];
δ RegionMeasure[r]一定しない密度 
の場合はIntegrateを使う：
ρ[x_, y_] := Exp[-x^2];Integrate[ρ[x, y], {x, y}∈r]曲面 (2)
RegionMeasure[ParametricRegion[{x, y, x y}, {{x, 0, 1}, {y, 0, 1}}]]ℛ = Rectangle[];
δ RegionMeasure[ℛ]
で与えられる一定しない質量密度の場合はIntegrateを使う：
Integrate[x y, {x, y}∈ℛ]立体 (3)
一定した密度 
のBallの全質量：
δ RegionMeasure[Ball[3]]一定していない密度関数 
にはIntegrateを使う：
ρ[x_, y_, z_] := x^2 + y^2 + z^2;Integrate[ρ[x, y, z], {x, y, z}∈Ball[3]]Cone中のエタノールの質量を求める：
ℛ = Cone[{{0, 0, 0}, Quantity[{0, 0, 7}, "Centimeters"]}, Quantity[8, "Centimeters"]];d = ChemicalData["Ethanol", "Density"]v = RegionMeasure[ℛ]FormulaData["MassDensity", {"ρ" -> d, "V" -> v}]Cylinderの質量を求める．ただし，質量の密度は一様ではなく 
で定義される：
ℛ = Cylinder[{{0, 0, 0}, {0, 0, h}}, r];d = Integrate[x ^ 2 + y ^ 2 + z ^ 2, {x, y, z}∈ℛ, Assumptions -> h > 0 && r > 0]v = RegionMeasure[ℛ]FormulaData["MassDensity", {"ρ" -> d, "V" -> v}]Solve[% , M]
特性と関係 (10)
領域 ℛ についてのRegionMeasureは積分 
で与えられる：
ℛ = Circle[];{RegionMeasure[ℛ], Integrate[1, {x, y}∈ℛ]}ℛ = Ball[];{RegionMeasure[ℛ], Integrate[1, {x, y, z}∈ℛ]}ArcLengthは一次元領域についてのRegionMeasureの特殊ケースである：
{ArcLength[Circle[]], RegionMeasure[Circle[]]}Areaは，二次元領域についてのRegionMeasureの特殊ケースである：
{Area[Disk[]], RegionMeasure[Disk[]]}Volumeは，三次元領域についてのRegionMeasureの特殊ケースである：
{Volume[Ball[]], RegionMeasure[Ball[]]}使われる測度は，零次元の数を含むRegionDimensionによって決められる：
ℛ = Point[{0, 0, 0}];{RegionDimension[ℛ], RegionMeasure[ℛ]}ℛ = Line[{{0, 0}, {1, 1}}];{RegionDimension[ℛ], RegionMeasure[ℛ]}ℛ = Triangle[{{0, 0}, {1, 0}, {0, 1}}];{RegionDimension[ℛ], RegionMeasure[ℛ]}ℛ = Tetrahedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];{RegionDimension[ℛ], RegionMeasure[ℛ]}混合次元の領域については，RegionDimensionは最大の次元を与える：
ℛ = RegionUnion[Point[{1, 0}], Line[{{0, 0}, {1, 1}}]];{RegionDimension[ℛ], RegionMeasure[ℛ]}RegionMeasure[x,{t},c]はArcLength[x,t,c]に等しい：
RegionMeasure[{t ^ 2, Pi / 2, Pi / 4, t}, {{t, 0, 2Pi}}, "Hyperspherical"]ArcLength[{t ^ 2, Pi / 2, Pi / 4, t}, {t, 0, 2Pi}, "Hyperspherical"]RegionMeasure[x,{s,t},c]はArea[x,s,t,c]に等しい：
RegionMeasure[{s t ^ 2, Pi / 2, Pi / 4, s t}, {{s, 0, 1}, {t, 0, 2Pi}}, "Hyperspherical"]Area[{s t ^ 2, Pi / 2, Pi / 4, s t}, {s, 0, 1}, {t, 0, 2Pi}, "Hyperspherical"]RegionMeasure[x,{s,t,u},c]はVolume[x,s,t,u,c]に等しい：
RegionMeasure[{s t ^ 2, Pi / 2, u, s t}, {{s, 0, 1}, {t, 0, 2Pi}, {u, 0, 1}}, "Hyperspherical"]Volume[{s t ^ 2, Pi / 2, u, s t}, {s, 0, 1}, {t, 0, 2Pi}, {u, 0, 1}, "Hyperspherical"]RegionCentroidは m=RegionMeasure[ℛ]のIntegrate[p,p∈ℛ]/m に等しい：
ℛ = Ball[{1, 2, 3}];
m = RegionMeasure[ℛ];{RegionCentroid[ℛ], Integrate[{x, y, z}, {x, y, z}∈ℛ] / m}考えられる問題 (3)
RegionMeasureは，離散点については計数測度を使う：
ℛ = RegionIntersection[Disk[{0, 0}, 1], Disk[{0, 2}, 1]];RegionMeasure[ℛ]RegionMeasure[ℛ, 2]パラメトリック形式はパラメータ化を基本的なものとし，複数の被覆を数える：
RegionMeasure[{Sin[t], Cos[t]}, {{t, 0, 4Pi}}]RegionMeasure[ParametricRegion[{Sin[t], Cos[t]}, {{t, 0, 4Pi}}]]RegionMeasureは，厳密値による答が計算できないときは機械精度の演算を行う：
RegionMeasure[ImplicitRegion[x ^ 6 + y ^ 6 - x y == 1, {x, y}]]おもしろい例題 (1)
ℛℛ = Table[CantorMesh[n], {n, 0, 5}];Column[ℛℛ]RegionMeasure /@ ℛℛ//RationalizeFindSequenceFunction[%, k]Limit[%, k -> ∞]
Wolfram Research (2014), RegionMeasure, Wolfram言語関数， https://reference.wolfram.com/language/ref/RegionMeasure.html （2019年に更新）.
テキスト
Wolfram Research (2014), RegionMeasure, Wolfram言語関数， https://reference.wolfram.com/language/ref/RegionMeasure.html （2019年に更新）.
CMS
Wolfram Language. 2014. "RegionMeasure." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2019. https://reference.wolfram.com/language/ref/RegionMeasure.html.
APA
Wolfram Language. (2014). RegionMeasure. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/RegionMeasure.html