WOLFRAM

Wolfram 语言与系统参考资料中心

Annotation[expr,data]

表示一个带有注释 data 的表达式 expr.

Annotation[expr,data,"type"]

指定给出的注释类型.

Annotation[items,keyvalue]

将 keyvalue 组对与 Graph、MeshRegion 等对象中的 items 相关联.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
Basic Uses  
Specifications  
应用  
图  
导出  
栅格化  
属性和关系  
参见
技术笔记
相关指南
历史
按以下格式引用：

Annotation

Annotation[expr,data]

表示一个带有注释 data 的表达式 expr.

Annotation[expr,data,"type"]

指定给出的注释类型.

Annotation[items,keyvalue]

将 keyvalue 组对与 Graph、MeshRegion 等对象中的 items 相关联.

更多信息

  • Annotation[expr,data] 如同 expr 一样显示.
  • Annotation 其作用类似惰性包装袋，用于储存表达式中的注释.
  • Annotation 可以和图形或其它任意表达式一起使用.
  • 根据特定 "type" 规范，注释由各种内部构造函数收集.
  • "Hyperlink"用于输出的影像映射等的超链接
    "Mouse"用于 MouseAnnotation 的注释
    "Region"用于 Rasterize、Export 等的区域.
    "Tooltip"用于 Export 等的工具提示说明
  • 通过 keyvalue 规范，注释与各种对象中的项相关联：
  • Audio时间点和时间间隔
    BoundaryMeshRegion网格单元
    CSGRegion几何区域
    Graph顶点和边
    MeshRegion网格单元

范例

打开所有单元 关闭所有单元

基本范例  (3)

鼠标进入圆盘时动态获得注释：

Wolfram Language code: {Annotation[Graphics[Disk[]], "An annotation", "Mouse"], Dynamic[MouseAnnotation[]]}

注释图中的边：

Wolfram Language code: Graph[{Annotation[12, EdgeLabels -> "hello"], 23, 31}]

检索注释：

Wolfram Language code: AnnotationValue[%, EdgeLabels]

当鼠标指针悬停在曲线上时，在图上注释曲线并显示标签：

Wolfram Language code: Plot[{Annotation[Sin[x], "Sine", "Mouse"], Annotation[Cos[x], "Cosine", "Mouse"]}, {x, 0, 2π}, PlotLabel -> Dynamic[MouseAnnotation[""]]]

范围  (8)

Basic Uses  (5)

将注释存储在表达式中：

Wolfram Language code: a = Table[Annotation[i, PrimeQ[i]], {i, 20}]

检索带有特定注释的表达式：

Wolfram Language code: Cases[a, Annotation[_, True]]

注释图的边：

Wolfram Language code: Graph[{Annotation[12, EdgeLabels -> "hello"], 23, 31}]

注释图形中的曲线：

Wolfram Language code: Plot[{Annotation[Sin[x], "Sine", "Mouse"], Annotation[Cos[x], "Cosine", "Mouse"]}, {x, 0, 2π}, PlotStyle -> Thick]
Wolfram Language code: Dynamic[MouseAnnotation[]]

在转换为 HTML 文件时，将超链接添加到表达式的任何部分：

Wolfram Language code: g = Graphics[{Annotation[Disk[], "http://www.wolfram.com", "Hyperlink"], Disk[{2, 2}]}];
Wolfram Language code: Export["test.html", g]

使用 Rasterize 查找带注释的对象在图像中的位置：

Wolfram Language code: g = Graphics[{Annotation[Disk[{0, 0}], "Disk1", "Region"], Disk[{2, 2}]}, ImageSize -> 50];
Wolfram Language code: Rasterize[g, "Regions"]

Specifications  (3)

注释表达式：

Wolfram Language code: Annotation[1, "one"]

指定注释的类型：

Wolfram Language code: Annotation[Graphics[Disk[]], "An annotation", "Mouse"]
Wolfram Language code: Dynamic[MouseAnnotation[]]

将键和值对与对象相关联：

Wolfram Language code: Graph[{Annotation[12, EdgeLabels -> "hello"], 23, 31}]

应用  (6)

图  (2)

在顶点上构建带有 VertexSize 和 VertexStyle 注释的图形：

Wolfram Language code: Graph[Table[Annotation[v, {VertexSize -> 0.2 + 0.2Mod[v, 5], VertexStyle -> Hue[(v/15), 1, 1]}], {v, 0, 14}], Table[vMod[v + 1, 15], {v, 0, 14}]]

使用 Annotation 来指定单个边缘的权重：

Wolfram Language code: Graph[{12, Annotation[23, EdgeWeight -> 2], 31}, EdgeLabels -> "EdgeWeight"]

边缘权重列表按图中给出的顺序进行：

Wolfram Language code: AnnotationValue[%, EdgeWeight]

导出  (2)

在转换为 HTML 文件时，将超链接添加到表达式的任何部分：

Wolfram Language code: g = Graphics[{Annotation[Disk[], "http://www.wolfram.com", "Hyperlink"], Disk[{2, 2}]}];
Wolfram Language code: Export["test.html", g]

转换为 HTML 文件时，将工具提示添加到表达式的任何部分：

Wolfram Language code: g = Graphics[{Annotation[Disk[], "A Disk", "Tooltip"], Disk[{2, 2}]}];
Wolfram Language code: Export["test.html", g]

栅格化  (2)

Wolfram Language code: g = Graphics[{Annotation[Disk[{0, 0}], "Disk1", "Region"], Disk[{2, 2}]}, ImageSize -> 50];

Rasterize 返回对象的图形描述，并在 Export 中使用：

Wolfram Language code: Rasterize[g]

用 Rasterize 查找图像中带注释的对象的位置：

Wolfram Language code: Rasterize[g, "Regions"]
Wolfram Language code: ras = Column[{Annotation["Disk1:", "Label", "Region"], Graphics[Disk[], ImageSize -> 100], Annotation["Text", "Explanation", "Region"]}, Alignment -> Center];

Rasterize 将任何表达式作为输入：

Wolfram Language code: Rasterize[ras]

自动查找多个表达式的位置：

Wolfram Language code: Rasterize[ras, "Regions"]

属性和关系  (1)

Tooltip 和 Hyperlink 注释可以被它们各自的函数取代：

Wolfram Language code: g1 = Graphics[{Annotation[Disk[], "http://www.wolfram.com", "Hyperlink"], Annotation[Disk[{2, 2}], "A Disk", "Tooltip"]}];
Wolfram Language code: Export[FileNameJoin[{$TemporaryDirectory, "test1.html"}], g1]

一个等价的表达式：

Wolfram Language code: g2 = Graphics[{Hyperlink[Disk[], "http://www.wolfram.com"], Tooltip[Disk[{2, 2}], "A Disk"]}];
Wolfram Language code: Export[FileNameJoin[{$TemporaryDirectory, "test2.html"}], g2]
Wolfram Research (2007)，Annotation，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Annotation.html （更新于 2025 年）.

文本

Wolfram Research (2007)，Annotation，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Annotation.html （更新于 2025 年）.

CMS

Wolfram 语言. 2007. "Annotation." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2025. https://reference.wolfram.com/language/ref/Annotation.html.

APA

Wolfram 语言. (2007). Annotation. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Annotation.html 年

BibTeX

@misc{reference.wolfram_2026_annotation, author="Wolfram Research", title="{Annotation}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/Annotation.html}", note=[Accessed: 10-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_annotation, organization={Wolfram Research}, title={Annotation}, year={2025}, url={https://reference.wolfram.com/language/ref/Annotation.html}, note=[Accessed: 10-August-2026]}