Wolfram 语言与系统参考资料中心

AudioLocalMeasurements

参见
- 函数
- AudioIntervals
- AudioAnnotate
- PitchRecognize
- SpeechRecognize
- AudioDistance
- AudioPartition
- AudioBlockMap
- AudioMeasurements
- 神经网络编码器
- AudioMFCC
- AudioSTFT
- AudioSpectrogram
- AudioMelSpectrogram
- Audio
相关指南
- 参见
  - 函数
  - AudioIntervals
  - AudioAnnotate
  - PitchRecognize
  - SpeechRecognize
  - AudioDistance
  - AudioPartition
  - AudioBlockMap
  - AudioMeasurements
  - 神经网络编码器
  - AudioMFCC
  - AudioSTFT
  - AudioSpectrogram
  - AudioMelSpectrogram
  - Audio
- 相关指南

AudioLocalMeasurements

AudioLocalMeasurements[audio,"prop"]

为 audio 分区计算局部属性 "prop".

AudioLocalMeasurements[audio,{"prop₁","prop₂",…}]

计算数个属性 "prop_i".

AudioLocalMeasurements[audio,"prop",format]

在指定输出 format 中返回测量值.

AudioLocalMeasurements[video,…]

计算 video 中第一条音轨的测量值.

范例

打开所有单元关闭所有单元

基本范例 (3)

计算音频振幅的均方根：

Wolfram Language code: AudioLocalMeasurements[\!\(\*AudioBox["![Embedded Audio Player](audio://content-76niz)"]\), "RMSAmplitude"]

绘制测量结果：

Wolfram Language code: ListLinePlot[%, PlotRange -> All]

计算 Video 对象的第一个音轨的 RMS（均方根）振幅：

Wolfram Language code: AudioLocalMeasurements[\!\(\*VideoBox["![Video Player: ExampleData/fish.mp4](video://content-2sfji)"]\), "RMSAmplitude"]

绘制测量值：

Wolfram Language code: ListLinePlot[%, PlotRange -> All]

计算多个测量结果：

Wolfram Language code:

AudioLocalMeasurements[\!\(\*AudioBox["![Embedded Audio Player](audio://content-76niz)"]\), {"Power", "RMSAmplitude"}, Association]

绘制测量结果：

Wolfram Language code: ListLinePlot[%, PlotRange -> All]

范围 (24)

基本用法 (1)

将输出格式化为 Association:

Wolfram Language code: a = Import["ExampleData/rule30.wav"];

Wolfram Language code: AudioLocalMeasurements[a, {"RMSAmplitude", "Power"}, "Association"]

返回一个 TimeSeries 列表：

Wolfram Language code: AudioLocalMeasurements[a, {"RMSAmplitude", "Power"}, "List"]

返回一个规则列表：

Wolfram Language code: AudioLocalMeasurements[a, {"RMSAmplitude", "Power"}, "RuleList"]

返回一个 Dataset：

Wolfram Language code: AudioLocalMeasurements[a, {"RMSAmplitude", "Power"}, "Dataset"]

直方图属性 (2)

基本直方图属性：

Wolfram Language code: a = Import["ExampleData/rule30.wav"];

Wolfram Language code: ListLinePlot[AudioLocalMeasurements[a, {"Max", "MaxAbs", "Min", "MinAbs"}]]

Wolfram Language code: ListLinePlot[AudioLocalMeasurements[a, "Total"]]

统计直方图属性：

Wolfram Language code: a = Import["ExampleData/rule30.wav"];

Wolfram Language code: ListLinePlot[AudioLocalMeasurements[a, {"Mean", "Median", "StandardDeviation"}]]

强度属性 (1)

基于强度的基本属性：

Wolfram Language code: a = Import["ExampleData/rule30.wav"];

Wolfram Language code: AudioLocalMeasurements[a, {"Power", "RMSAmplitude", "Loudness"}]//ListLinePlot[#, PlotRange -> All]&

时域属性 (6)

属性 "CrestFactor" 测量最高值和在分段上的 RMS 的比例. "PeakToAveragePowerRatio" 计算相同值的平方：

Wolfram Language code: a = Import["ExampleData/rule30.wav"];

Wolfram Language code: AudioLocalMeasurements[a, {"CrestFactor", "PeakToAveragePowerRatio"}]//ListLinePlot[#, PlotRange -> All]&

属性 "TemporalCentroid" 计算每个分段的能量分布比重中心：

Wolfram Language code: a = Import["ExampleData/rule30.wav"];

Wolfram Language code: ListLinePlot[AudioLocalMeasurements[a, "TemporalCentroid"], PlotRange -> All]

输出值的边界在 0 和 1 之间，其中 0 代表全部能量都集中在开始分段.

"ZeroCrossings" 返回在分段中的零的数目； "ZeroCrossingRate" 正态化分段的时间长度：

Wolfram Language code: a = Import["ExampleData/rule30.wav"];

Wolfram Language code: ListLinePlot[AudioLocalMeasurements[a, "ZeroCrossingRate"], PlotRange -> All]

属性 "LPC" 返回用线性预测编码估计的 12 个系数：

Wolfram Language code: a = Import["ExampleData/rule30.wav"];

Wolfram Language code: AudioLocalMeasurements[a, "LPC"]["Values"]//Transpose//ArrayPlot

控制具有高采样率的音频对象的 LPC 系数数目：

Wolfram Language code: AudioLocalMeasurements[a, {"LPC", 66}]["Values"]//Transpose//ArrayPlot

提取信号共振峰的频率：

Wolfram Language code:

a = ExampleData[{"Audio", "MaleVoice"}];
formants = AudioLocalMeasurements[a, "Formants"]

Wolfram Language code: Show[Spectrogram[a, AspectRatio -> 1, PlotRange -> {All, {0, 7000}}], formants//ListLinePlot]

控制用于计算的共振峰和 LPC 系数的数目：

Wolfram Language code: formants = AudioLocalMeasurements[a, {"Formants", 2, 40}]

Wolfram Language code: Show[Spectrogram[a, AspectRatio -> 1, PlotRange -> {All, {0, 7000}}], formants//ListLinePlot]

音频信号的熵：

Wolfram Language code: a = Import["ExampleData/rule30.wav"];

Wolfram Language code: AudioLocalMeasurements[a, "Entropy"]//ListLinePlot[#, PlotRange -> All]&

频率域属性 (8)

"SpectralCrest" 测量功率谱的最大值和均值的比率：

Wolfram Language code: a = ExampleData[{"Audio", "PianoScale"}];

Wolfram Language code: AudioLocalMeasurements[a, {"SpectralCrest"}]//ListLinePlot

谱能量的 95% 集中在 "SpectralRollOff" 所测量的频率值之下：

Wolfram Language code: a = ExampleData[{"Audio", "PianoScale"}];

Wolfram Language code: AudioLocalMeasurements[a, {"SpectralRollOff"}]//ListLinePlot

"SpectralSlope" 是功率谱斜率的度量：

Wolfram Language code: a = ExampleData[{"Audio", "PianoScale"}];

Wolfram Language code: AudioLocalMeasurements[a, {"SpectralSlope"}]//ListLinePlot

"SpectralFlatness" 是功率谱平坦度的度量：

Wolfram Language code: a = ExampleData[{"Audio", "PianoScale"}];

Wolfram Language code: AudioLocalMeasurements[a, {"SpectralFlatness"}]//ListLinePlot

计算功率谱的常用统计属性：

Wolfram Language code: a = ExampleData[{"Audio", "PianoScale"}];

Wolfram Language code:

AudioLocalMeasurements[a, {"SpectralCentroid", "SpectralKurtosis", "SpectralSpread"}]//ListLinePlot[#, PlotRange -> All]&

"FundamentalFrequency" 估计单声道音频的基本频率：

Wolfram Language code: a = ExampleData[{"Audio", "PianoScale"}];

Wolfram Language code: AudioLocalMeasurements[a, "FundamentalFrequency"]//ListLinePlot

控制探测的敏感度：

Wolfram Language code: AudioLocalMeasurements[a, {"FundamentalFrequency", .2}]//ListLinePlot

控制执行探测所在的频率范围：

Wolfram Language code: AudioLocalMeasurements[a, {"FundamentalFrequency", .2, 100, 700}]//ListLinePlot

"HighFrequencyContent" 使用随频率线性增加的加权计算平均功率谱:

Wolfram Language code: a = ExampleData[{"Audio", "PianoScale"}];

Wolfram Language code: AudioLocalMeasurements[a, "HighFrequencyContent"]//ListLinePlot[#, PlotRange -> All]&

频谱的线性加权为更高频谱端添加更多重要性，使得 "HighFrequencyContent" 成为瞬态检测的最佳候选.

属性 "MFCC" 返回 12 个梅尔频率倒谱系数：

Wolfram Language code: a = ExampleData[{"Audio", "PianoScale"}];

Wolfram Language code: AudioLocalMeasurements[a, "MFCC"]["Values"]//Transpose//ListDensityPlot

控制系数和滤波器的数目，以及频率范围：

Wolfram Language code:

AudioLocalMeasurements[a, {"MFCC", 30, 40, Quantity[40, "Hertz"], Quantity[30000, "Radians"/"Seconds"]}]["Values"]//Transpose//ListDensityPlot

在邻域部分计算的频域属性 (2)

基于两个相邻帧间傅里叶变换的距离的不同测量属性：

Wolfram Language code: a = ExampleData[{"Audio", "PianoScale"}];

Wolfram Language code:

Rescale /@ AudioLocalMeasurements[a, {"ComplexDomainDistance", "ModifiedKullbackLeibler", "PhaseDeviation", "SpectralFlux"}]//ListLinePlot

属性 "Novelty" 计算与邻域时间帧相差多少：

Wolfram Language code: a = ExampleData[{"Audio", "PianoScale"}];

Wolfram Language code: ListLinePlot[AudioLocalMeasurements[a, "Novelty"], PlotRange -> All]

语音和扬声器属性 (4)

"VoiceActivity" 属性是语音信号的有声部分的指示符功能：

Wolfram Language code:

a = ExampleData[{"Audio", "MaleVoice"}];
va = AudioLocalMeasurements[a, "VoiceActivity"]

通过音频波形图显示语音活动：

Wolfram Language code: Show[AudioPlot[a, PlotLayout -> "Averaged"], ListLinePlot[va, PlotStyle -> Red], ImageSize -> Medium]

使用较小的 10 毫秒窗口来提高分辨率：

Wolfram Language code:

va = AudioLocalMeasurements[a, "VoiceActivity", PartitionGranularity -> .01];
Show[AudioPlot[a, PlotLayout -> "Averaged"], ListLinePlot[va, PlotStyle -> Red], ImageSize -> Medium]

"SpeechFundamentalFrequency" 属性估计语音的基本频率：

Wolfram Language code: a = ExampleData[{"Audio", "MaleVoice"}];

Wolfram Language code:

ListLinePlot[AudioLocalMeasurements[a, "SpeechFundamentalFrequency", PartitionGranularity -> {Quantity[25, "Milliseconds"], Quantity[5, "Milliseconds"]}], PlotRange -> All]

"SpeechSpectralEnvelope" 属性返回信号频谱包络的系数：

Wolfram Language code:

a = ExampleData[{"Audio", "MaleVoice"}];
se = AudioLocalMeasurements[a, "SpeechSpectralEnvelope"]

绘制结果：

Wolfram Language code: MatrixPlot[Transpose@Log[Values[se]], DataReversed -> True, AspectRatio -> 1]

"SpeechAperiodicity" 属性返回信号的非周期性分量的系数：

Wolfram Language code:

a = ExampleData[{"Audio", "MaleVoice"}];
ap = AudioLocalMeasurements[a, "SpeechAperiodicity"]

绘制结果值：

Wolfram Language code: MatrixPlot[Transpose@Log[Values[ap]], DataReversed -> True, AspectRatio -> 1]

选项 (5)

校准 (1)

TimeSeries 结果的时间戳默认放置于每个分段的中心：

Wolfram Language code:

a = Import["ExampleData/rule30.wav"];
audioplot = AudioPlot[a, AspectRatio -> 1 / 2, PlotRange -> All, PlotRangePadding -> {.15, .05}, GridLines -> {Table[i, {i, -.15, QuantityMagnitude@Duration@a, .3}], None}];
res = AudioLocalMeasurements[a, "Max", PartitionGranularity -> {.3, .3}];

Wolfram Language code:

Show[audioplot, 
	ListPlot[res, PlotStyle -> Red, Filling -> Axis, PlotMarkers -> Automatic, PlotRange -> {-1, 1}]]

使用 Alignment->Right 将计算的属性放置于每个分段的结尾：

Wolfram Language code:

res = AudioLocalMeasurements[a, "Max", PartitionGranularity -> {.3, .3}, Alignment -> Right];
Show[audioplot, 
	ListPlot[res, PlotStyle -> Red, Filling -> Axis, PlotMarkers -> Automatic, PlotRange -> {-1, 1}]]

填补 (1)

在默认情况下，使用 "Silent" 填补：

Wolfram Language code: a = Import["ExampleData/rule30.wav"];

Wolfram Language code: AudioLocalMeasurements[a, "Max", PaddingSize -> 1]//ListLinePlot

使用 "Reversed" 填补：

Wolfram Language code: AudioLocalMeasurements[a, "Max", Padding -> "Reversed", PaddingSize -> 1]//ListLinePlot

填补大小 (1)

在默认情况下，等于分段大小一半的填补应用与信号的末端：

Wolfram Language code: a = Import["ExampleData/rule30.wav"];

Wolfram Language code: ListLinePlot[AudioLocalMeasurements[a, "Power"]]

增加填补量：

Wolfram Language code: ListLinePlot[AudioLocalMeasurements[a, "Power", PaddingSize -> 1], PlotRange -> All]

在信号开始和结束部分使用不同填补量：

Wolfram Language code: ListLinePlot[AudioLocalMeasurements[a, "Power", PaddingSize -> {0, 2}], PlotRange -> All]

PartitionGranularity (2)

指定 100 ms 大小的分段：

Wolfram Language code: a = Import["ExampleData/rule30.wav"];

Wolfram Language code: AudioLocalMeasurements[a, "Power", PartitionGranularity -> Quantity[100, "Milliseconds"]]//ListLinePlot

使用 10 ms 的补偿：

Wolfram Language code:

AudioLocalMeasurements[a, "Power", PartitionGranularity -> {Quantity[100, "Milliseconds"], Quantity[10, "Milliseconds"]}]//ListLinePlot

使用平滑视窗：

Wolfram Language code:

AudioLocalMeasurements[a, "Power", PartitionGranularity -> {Quantity[100, "Milliseconds"], Quantity[10, "Milliseconds"], HannWindow}]//ListLinePlot

所有频域属性默认使用平滑视窗：

Wolfram Language code: a = Import["ExampleData/rule30.wav"];

Wolfram Language code:

ListLinePlot[{AudioLocalMeasurements[a, "SpectralFlux", PartitionGranularity -> {.05, .01, Automatic}], AudioLocalMeasurements[a, "SpectralFlux", PartitionGranularity -> {.05, .01, None}]}, PlotLegends -> {"HannWindow", "None"}]

应用 (4)

探测复杂音频信号中的瞬态：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-9ghc6)"]\);

通过对于原始信号多个测量的平均化计算 "探测函数"：

Wolfram Language code:

properties = {"ComplexDomainDistance", "HighFrequencyContent", "ModifiedKullbackLeibler", "Novelty", "PhaseDeviation"};detectionFunctions = Rescale /@ AudioLocalMeasurements[a, properties, PartitionGranularity -> {.02, .005}];
detectionFunction = Mean[Lookup[detectionFunctions, {"HighFrequencyContent", "ModifiedKullbackLeibler", "Novelty"}]]

用自适应阈值过滤探测函数：

Wolfram Language code: filteredDetectionFunction = (detectionFunction - MedianFilter[detectionFunction, .02])

找出过滤后的探测函数的峰值：

Wolfram Language code:

peaks = FindPeaks[filteredDetectionFunction, 0, 0, 0.07];
ListLinePlot[filteredDetectionFunction, PlotRange -> All, ImageSize -> Medium, Epilog -> {Red, PointSize[0.02], Point[peaks//Normal]}]

绘制在波形中探测到得瞬态：

Wolfram Language code:

AudioPlot[a, ColorFunction -> Function[{x, y}, If[AnyTrue[peaks["Times"], Abs[x - #] < .015&], RGBColor[1, 0.2, 0.2], RGBColor[0.368417, 0.506779, 0.709798]]], PlotRange -> {All, All}, ImageSize -> Medium, FillingStyle -> Opacity[.9]]

计算音频对象的信号

Wolfram Language code: a = Audio["http://exampledata.wolfram.com/bach.mp3"]

计算 MFCC 特性并提取数值：

Wolfram Language code: mfcc = AudioLocalMeasurements[AudioResample[a, 11025], "LPC", PartitionGranularity -> {.5, .25}]["Values"];

绘制距离矩阵结果：

Wolfram Language code:

MatrixPlot[DistanceMatrix[mfcc], DataRange -> {{0, QuantityMagnitude[Duration@a, "s"]}, {0, QuantityMagnitude[Duration@a, "s"]}}, ImageSize -> 300, FrameTicks -> {Automatic, Automatic}]

使用动态时间翘曲比较同样序列的两个记录：

Wolfram Language code:

alice = {\!\(\*AudioBox["![Embedded Audio Player](audio://content-kk35x)"]\), \!\(\*AudioBox["![Embedded Audio Player](audio://content-fvmpy)"]\)};

计算并绘制记录的 MFCC 特性：

Wolfram Language code: mfcc = AudioLocalMeasurements[#, "MFCC", PartitionGranularity -> {.05, .01}]["Values"]& /@ alice;

Wolfram Language code:

Column[MatrixPlot[#, PlotTheme -> "Minimal", MaxPlotPoints -> 2000, AspectRatio -> 1 / 10, ImageSize -> Medium]& /@ Transpose /@ mfcc]

使用 WarpingCorrespondence 计算介于俩记录间的动态时间翘曲响应：

Wolfram Language code: {n, m} = WarpingCorrespondence[mfcc[[1]], mfcc[[2]]];

绘制两个记录间的响应：

Wolfram Language code:

dur = QuantityMagnitude[Duration[alice[[1]]], "s"];
s = {n, m} / Max[{n, m}]dur;
Labeled[
	ListLinePlot[
	s, AspectRatio -> 1, PlotStyle -> Thickness[.01], ImageSize -> Medium, Prolog -> {RGBColor[0.6666666666666666, 0.6666666666666666, 0.6666666666666666], {Line[{{#[[1]], 0}, #}], Line[{{0, #[[2]]}, #}]}& /@ (s[[ ;;  ;; 100]])}
	], 
	AudioPlot[#, PlotStyle -> RGBColor[0.560181, 0.691569, 0.194885], Frame -> False, Axes -> False, ImageSize -> Medium, AspectRatio -> 1 / 15]& /@ alice, {Bottom, Left}, RotateLabel -> True, Spacings -> {0, 0}]

使用 "MFCC" 测量作为特性，计算 ExampleData["Audio"] 不同元素间的距离：

Wolfram Language code:

list = Select[ExampleData["Audio"], ExampleData[#, "Duration"] < 10&];
a = ConformAudio[AudioNormalize@AudioChannelMix[#, 1]& /@ ExampleData[#, "Audio"]& /@ list, SampleRate -> 11025];

Wolfram Language code: mfcc = AudioLocalMeasurements[#, "MFCC", PartitionGranularity -> {.05, .01}]["Values"]& /@ a;

Wolfram Language code:

ticks = Thread[{Range[Length@list], Text /@ list[[All, 2]]}];MatrixPlot[DistanceMatrix[mfcc], ImageSize -> Medium, FrameTicks -> {ticks, Apply[Rotate[#, Pi / 2]&, ticks, {2}]}]

可能存在的问题 (1)

"FundamentalFrequency" 返回无法估计（帧率可能包含切片或复调音频）基本频率分段的 Missing[] 值：

Wolfram Language code: a = ExampleData[{"Audio", "PianoScale"}, "Audio"];

Wolfram Language code: AudioLocalMeasurements[a, "FundamentalFrequency"][0.]

未定义复调音频的基本频率：

Wolfram Language code: AudioLocalMeasurements[Import["ExampleData/rule30.wav"], "FundamentalFrequency"]["Values"]//Short

巧妙范例 (3)

使用 AudioGenerator 重复长笛音符的频率和幅度：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-llour)"]\);

计算 "RMSAmplitude" 和 "FundamentalFrequency" 度量：

Wolfram Language code:

m = AudioLocalMeasurements[a, {"RMSAmplitude", "FundamentalFrequency"}, MissingDataMethod -> {"Interpolation", InterpolationOrder -> 0}];

使用 "FundamentalFrequency" 度量控制结果的频率：

Wolfram Language code: AudioGenerator[{"Sin", m["FundamentalFrequency"]}]

使用 "RMSAmplitude" 度量控制幅度：

Wolfram Language code: %×AudioGenerator[m["RMSAmplitude"]]

莫尔斯电码译码：

Wolfram Language code: morse = \!\(\*AudioBox["![Embedded Audio Player](audio://content-gycdz)"]\);

计算信号的 RMS 振幅并进行取整：

Wolfram Language code:

rms = AudioLocalMeasurements[morse, "RMSAmplitude", PartitionGranularity -> {.01, .002}];
rounded = Round[rms / Max@rms];
ListLinePlot[rounded]

仅选择有瞬态的点：

Wolfram Language code:

crossings = TimeSeriesInsert[TimeSeries[CrossingDetect[rounded["Values"] - .5, CornerNeighbors -> True], {rounded["Times"]}], {0, 1}];
transients = TimeSeries@Select[Normal@crossings, #[[2]] == 1&];

确保第一个点为 t=0 并计算最小的时间增加：

Wolfram Language code:

shifted = TimeSeriesShift[transients, -transients["FirstTime"]];
dit = MinimumTimeIncrement[shifted];

定义莫尔斯电码映射：

Wolfram Language code:

code = <|".-" -> "a", "-..." -> "b", "-.-." -> "c", "-.." -> "d", "." -> "e", "..-." -> "f", "--." -> "g", "...." -> "h", ".." -> "i", ".---" -> "j", "-.-" -> "k", ".-.." -> "l", "--" -> "m", "-." -> "n", "---" -> "o", ".--." -> "p", "--.-" -> "q", ".-." -> "r", "..." -> "s", "-" -> "t", "..-" -> "u", "...-" -> "v", ".--" -> "w", "-..-" -> "x", "-.--" -> "y", "--.." -> "z", ".----" -> "1", "..---" -> "2", "...--" -> "3", "....-" -> "4", "....." -> "5", "-...." -> "6", "--..." -> "7", "---.." -> "8", "----." -> "9", "-----" -> "0", ".-.-.-" -> ".", "--..--" -> ",", "-.-.--" -> "!", "..--.." -> "?", "_" -> " "|>;

信号译码：

Wolfram Language code:

StringJoin[StringSplit[StringJoin[Table[{Differences[shifted["Times"]][[i]], Mod[i, 2]}, {i, Length@Differences[shifted["Times"]]}] /. {{x_, 1} /; .5dit < x < 1.5dit -> ".", {x_, 1} /; 2.5dit < x < 3.5dit -> "-", {x_, 0} /; 2.5dit < x < 3.5dit -> "/", {x_, 0} /; .5dit < x < 1.5dit -> Nothing, {x_, 0} /; 5dit < x < 12dit -> "/_/"}], "/"] /. Normal[code]]

创建音频对象波形的三维打印模型：

Wolfram Language code:

a = ExampleData[{"Audio", "Drums"}];
AudioPlot[a, PlotRange -> All]

Wolfram Language code: dur = QuantityMagnitude[Duration@a, "s"]

计算 "Min" 和 "Max" 度量：

Wolfram Language code:

aspectRatio = 1 / 3;
numPoints = 100;
minmax  = Normal[aspectRatio dur AudioLocalMeasurements[a, #, PartitionGranularity -> {dur / numPoints, dur / numPoints}]]& /@ {"Min", "Max"};

创建波形的三维模型：

Wolfram Language code: RegionProduct[Polygon[Join[minmax[[1]], Reverse[minmax[[2]]]]], Line[{{0}, {0.1 dur}}]]

三维打印模型：

Wolfram Language code: Printout3D[%, "waveform.stl"]

Top

	"Max"	最大值
	"MaxAbs"	最大绝对值
	"Min"	最小值
	"MinAbs"	最小绝对值
	"MinMax"	最小和最大值
	"MinMaxAbs"	最小和最大绝对值
	"Mean"	平均值
	"Median"	中间值
	"StandardDeviation"	数值的标准差
	"Total"	数值总和

Alignment	Center	对齐带分区的时间戳
FourierParameters	{-1,1}	傅里叶参数
Padding	Automatic	填充设计
PaddingSize	Automatic	填充量
PartitionGranularity	Automatic	音频分区规格说明
MetaInformation	None	包括额外的元信息
MissingDataMethod	None	用于确实数据的方法
ResamplingMethod	Automatic	用于重采样路径的方法

更多学习资源

技术支持

Wolfram 解决方案

Wolfram 的教育解决方案

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

AudioLocalMeasurements

更多信息和选项

范例

基本范例 (3)

范围 (24)

基本用法 (1)

直方图属性 (2)

强度属性 (1)

时域属性 (6)

频率域属性 (8)

在邻域部分计算的频域属性 (2)

语音和扬声器属性 (4)

选项 (5)

校准 (1)

填补 (1)

填补大小 (1)

PartitionGranularity (2)

应用 (4)

可能存在的问题 (1)

巧妙范例 (3)

文本

CMS

APA

BibTeX

BibLaTeX

	"Power"	根号平均值
	"RMSAmplitude"	均方根值
	"Loudness"	估算响度计量

	"CrestFactor"	最大值除以均方根值
	"Entropy"	值的熵
	"LPC"	线性预测系数
	"PeakToAveragePowerRatio"	最大幂除以平均幂
	"TemporalCentroid"	数值的时域质心
	"ZeroCrossingRate"	零交叉率
	"ZeroCrossings"	分区的零交叉数量

	"FundamentalFrequency"	估算基础频率
	"Formants"	信号的共振峰频率
	"HighFrequencyContent"	功率谱的线性加权平均值
	"MFCC"	梅尔频率倒谱系数
	"SpectralCentroid"	功率谱的质心
	"SpectralCrest"	最大值除以功率谱的平均值
	"SpectralFlatness"	几何平均除以功率谱的平均值
	"SpectralKurtosis"	幅度谱的峰度
	"SpectralRollOff"	大部分能量频率集中在该值之下的频率
	"SpectralSkewness"	幅度谱的峰度
	"SpectralSlope"	幅度谱的估算斜率
	"SpectralSpread"	功率谱的带宽计量

	"ComplexDomainDistance"	预测出和测量出的傅里叶（Fourier）之间的距离
	"ModifiedKullbackLeibler"	波谱间经调整的 KL 距离（Kullback–Liebler distance）
	"Novelty"	重大变化的预估测量
	"PhaseDeviation"	预测出和测量出的傅里叶（Fourier）之间的相位差
	"SpectralFlux"	连续光谱间差异的范数

AudioLocalMeasurements

更多信息和选项

范例

基本范例 (3)

范围 (24)

基本用法 (1)

直方图属性 (2)

强度属性 (1)

时域属性 (6)

频率域属性 (8)

在邻域部分计算的频域属性 (2)

语音和扬声器属性 (4)

选项 (5)

校准 (1)

填补 (1)

填补大小 (1)

PartitionGranularity (2)

应用 (4)

可能存在的问题 (1)

巧妙范例 (3)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX