WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BernoulliDistribution[p]

確率母数が p のベルヌーイ(Bernoulli)分布を表す．

詳細
Details and Options Details and Options
予備知識
例題  
例  
スコープ  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

BernoulliDistribution

BernoulliDistribution[p]

確率母数が p のベルヌーイ(Bernoulli)分布を表す．

詳細

予備知識

  • BernoulliDistribution[p]は，実数上で定義される離散統計分布を表す．母数 p はを満足する確率母数を表す．ベルヌーイ分布はコイントス分布あるいはベルヌーイ試行の分布と呼ばれることがある．この分布の確率密度関数(PDF)は，では値 p，では を返し，その他のすべての実数について評価すると0になる．
  • ベルヌーイ分布はスイスの数学者であるJacob Bernoulliの名前に因んで命名された．この分布は，（公正な，あるいは不正な）コインをトスするという単純な動作のモデル化のためのものである．伝統的に，p は実験が「成功する」確率（1は成功した実験を表す）， は実験が「失敗する」確率（0は失敗した実験を表す）であると考えられる．コイントスの類推から，1は表を表すことが多く，0は裏を表すことが多い．値 は公正なコインのトスに相当する．非常に簡単に定義されているのにもかかわらず，ベルヌーイ分布は，確率におけるベルヌーイ列，測度論におけるベルヌーイ測度，力学系におけベルヌーイ系等の，より複雑な数多くの他の数学概念の基礎になっていることがよくある．確率過程の研究の中で，ベルヌーイ分布は，いわゆるベルヌーイ過程(BernoulliProcess)，つまり，1つ1つが独立同ベルヌーイ分布に従う（有限あるいは無限の）確率変数の列からなる離散時間確率過程のきっかけにもなっている．さらに，独立した結果の確率についてのよく定義された二分法を示す数多くの現実世界の出来事が，ベルヌーイ過程としてモデル化できる．例には，1つの（公正な）サイコロで特定の値が出る確率や，欠陥率が生産スケールには依存しない場合の欠陥製品の数が含まれる．
  • RandomVariateを使ってベルヌーイ分布から，1つあるいは複数の機械精度あるいは任意精度の擬似乱数変量を得ることができる．Distributed[x,BernoulliDistribution[p]]（より簡略すると xBernoulliDistribution[p]）を使って，確率変数 x が，ベルヌーイ分布に従って分布していると宣言することができる．このような宣言は，Probability，NProbability，Expectation，NExpectation等の関数で使うことができる．
  • 確率密度関数および累積分布関数は，PDF[BernoulliDistribution[p],x]およびCDF[BernoulliDistribution[p],x]を使って得られることがある．平均，中央値，分散，原点の周りのモーメント，中心モーメントは，それぞれMean，Median，Variance，Moment，CentralMomentを使って計算することができる．これらの数量はDiscretePlotを使って可視化することができる．
  • DistributionFitTestを使って，与えられたデータ集合がベルヌーイ分布と一致するかどうかを検定することが，EstimatedDistributionを使って与えられたデータからパラメトリックベルヌーイ分布を推定することが，FindDistributionParametersを使ってデータをベルヌーイ分布にフィットすることができる．ProbabilityPlotを使って記号ベルヌーイ分布のCDFに対する与えられたデータのCDFのプロットを生成することが，QuantilePlotを使って記号ベルヌーイ分布の変位値に対する与えられたデータの変位値のプロットを生成することができる．
  • TransformedDistributionを使って変換されたベルヌーイ分布を表すことが，TruncatedDistributionを使って上限値と下限値の間で切断された値の分布を表すことができる．CopulaDistributionを使ってベルヌーイ分布を含む高次元分布を構築することが，ProductDistributionを使ってベルヌーイ分布を含む独立成分分布の結合分布を計算することができる．
  • BernoulliDistributionは他の多くの確率分布と関連している．例えば，BernoulliDistribution[p]は一回のBinomialDistribution[1,p]に等しい．つまり，PDF[BernoulliDistribution[p],k]はPiecewise[Table[{PDF[BinomialDistribution[1,p],l],kl},{l,0,1}]]と同じである．同様に，共通の成功率が p である n 個の独立したベルヌーイ変数の和はBinomialDistribution[n,p]でモデル化される．加えて，ベルヌーイ独立分布に従う確率変数集合から浮かび出る数多くの自然発生的な数量は，よく知られる多の分布に従ってモデル化できることがある．例えば，BernoulliDistribution[p]に従って分布するデータ点の最初の n 個における成功数はBinomialDistribution[n,p]に従って分布しているのに対し，1回（あるいは r 回）の成功を得るための試行回数はGeometricDistribution[p]（あるいは NegativeBinomialDistribution[r,p]）に従って分布している．

例題

すべて開く すべて閉じる

例  (4)

確率質量関数：

Wolfram Language code: DiscretePlot[Table[PDF[BernoulliDistribution[p], x], {p, {0.3, 0.5, 0.7, 0.9}}]//Evaluate, {x, 0, 1}, AxesOrigin -> {1 / 2, 0}, PlotMarkers -> Automatic]
Wolfram Language code: PDF[BernoulliDistribution[p], k]

累積分布関数：

Wolfram Language code: DiscretePlot[Table[CDF[BernoulliDistribution[p], x], {p, {0.3, 0.5, 0.7, 0.9}}]//Evaluate, {x, 0, 1.5}, ExtentSize -> Right, ExtentMarkers -> {"Filled", "Empty"}]
Wolfram Language code: CDF[BernoulliDistribution[p], k]

平均と分散：

Wolfram Language code: Mean[BernoulliDistribution[p]]
Wolfram Language code: Variance[BernoulliDistribution[p]]

中央値：

Wolfram Language code: Median[BernoulliDistribution[p]]

スコープ  (8)

ベルヌーイ分布から擬似乱数のサンプルを生成する：

Wolfram Language code: sample = RandomVariate[BernoulliDistribution[0.4], 10 ^ 4];

サンプル中の1の頻度を1となる確率と比較する：

Wolfram Language code: Mean[sample]//N
Wolfram Language code: PDF[BernoulliDistribution[0.4], 1]

分布母数推定：

Wolfram Language code: sample = RandomVariate[BernoulliDistribution[0.3], 10 ^ 3];

サンプルデータから分布母数を推定する：

Wolfram Language code: edist = EstimatedDistribution[sample, BernoulliDistribution[p]]

サンプルの密度ヒストグラムを推定分布の確率密度関数と比較する：

Wolfram Language code: Show[Histogram[sample, {1}, "PDF"], DiscretePlot[PDF[edist, x], {x, 0, 1}, Filling -> 0, PlotStyle -> PointSize[Medium]]]

歪度：

Wolfram Language code: Plot[Skewness[BernoulliDistribution[p]], {p, 0, 1}, Filling -> Axis]
Wolfram Language code: Skewness[BernoulliDistribution[p]]

のとき，分布は対称である：

Wolfram Language code: Solve[Skewness[BernoulliDistribution[p]] == 0, p]

尖度：

Wolfram Language code: Plot[Kurtosis[BernoulliDistribution[p]], {p, 0, 1}, Filling -> Axis]
Wolfram Language code: Kurtosis[BernoulliDistribution[p]]

尖度はその最小値に達する：

Wolfram Language code: FindMinimum[Kurtosis[BernoulliDistribution[p]], {p, 0.6}]

母数の関数としての閉じた形の種々のモーメント：

Wolfram Language code: FormulaGrid[list_, type_] := Grid[...]

Moment：

Wolfram Language code: FormulaGrid[Table[Moment[BernoulliDistribution[p], k]//Simplify, {k, 3}], M]

CentralMoment：

Wolfram Language code: FormulaGrid[Table[CentralMoment[BernoulliDistribution[p], k], {k, 5}], CM]

記号次数の閉じた形：

Wolfram Language code: CentralMoment[BernoulliDistribution[p], r]

FactorialMoment：

Wolfram Language code: FormulaGrid[Table[FactorialMoment[BernoulliDistribution[p], k], {k, 3}], FM]

Cumulant：

Wolfram Language code: FormulaGrid[Table[Cumulant[BernoulliDistribution[p], k], {k, 5}], C]

ハザード関数：

Wolfram Language code: DiscretePlot[Table[HazardFunction[BernoulliDistribution[p], x], {p, {0.1, 0.5, 0.7}}]//Evaluate, {x, 0, 2}, AxesOrigin -> {0.5, 0}, PlotMarkers -> Automatic]
Wolfram Language code: HazardFunction[BernoulliDistribution[p], x]

分位関数：

Wolfram Language code: 𝒟 = BernoulliDistribution[0.7]; points = Table[CDF[𝒟, x], {x, 0, 1}]//N;
Wolfram Language code: DiscretePlot[Quantile[𝒟, p], {p, points}, ExtentSize -> Right, ExtentMarkers -> {"Empty", "Filled"}, AxesOrigin -> {0, 0}]
Wolfram Language code: Quantile[BernoulliDistribution[p], q]

無次元のQuantityを使ってBernoulliDistributionを定義する：

Wolfram Language code: BernoulliDistribution[Quantity[60, "Percent"]]

アプリケーション  (6)

一連の公正なコイン投げをシミュレーションする：

Wolfram Language code: RandomVariate[BernoulliDistribution[1 / 2], 20]

六面のサイコロを振って6が出る確率はベルヌーイ分布としてモデル化できる：

Wolfram Language code: PDF[BernoulliDistribution[1 / 6], k]

6の目が出る場合だけに関心があるとしてサイコロ投げのシミュレーションをしてみる：

Wolfram Language code: RandomVariate[BernoulliDistribution[1 / 6], 20]

製造される電球10個につき1個の割合で不良品が出るとして，100個の電球を製造するシミュレーションを行う：

Wolfram Language code: bulbs = RandomVariate[BernoulliDistribution[9 / 10], 100]

100個の電球中の問題のないものの数を求める：

Wolfram Language code: Count[bulbs, 1]

100個の電球中の問題のない電球の期待される数を求める：

Wolfram Language code: Mean[BinomialDistribution[100, 9 / 10]]

無作為に抽出した電球に問題がない確率を求める：

Wolfram Language code: Probability[x == 1, xBernoulliDistribution[9 / 10]]

1枚1ドルで10枚発売する宝くじがある．その中で当選するのは毎回1枚だけである．ある賭博者が宝くじに5ドル使うとする．この賭博者が5つの宝くじでそれぞれ1枚ずつ，合計5枚買った場合の勝率を求める：

Wolfram Language code: 𝒟 = ProductDistribution[{BernoulliDistribution[1 / 10], 5}];
Wolfram Language code: Probability[1 ≤ x + y + u + v + w, {x, y, u, v, w}𝒟]
Wolfram Language code: N[%]

この男の勝率は1つの宝くじでまとめて5枚買った場合の方が高い：

Wolfram Language code: PDF[HypergeometricDistribution[5, 1, 10], 1]
Wolfram Language code: N[%]

値-1と1で対称ランダムウォークのシミュレーションを行う：

Wolfram Language code: RandomWalk[n_] := FoldList[Plus, 0, RandomVariate[TransformedDistribution[2u - 1, uBernoulliDistribution[1 / 2]], n - 1]]
Wolfram Language code: ListPlot[RandomWalk[100], Joined -> True]

ある光通信システムでは送信された光が受信装置で電流を生ずる．電子の数は光のタイプによってポアソン分布と他の分布の母数混合に従う．ソースが強度 のコヒーレントレーザー光を使う場合，電子の数の分布はポアソン分布になる：

Wolfram Language code: Bdist = TransformedDistribution[λ x, xBernoulliDistribution[1]];
Wolfram Language code: PDF[Bdist, x]
Wolfram Language code: 𝒟1 = ParameterMixtureDistribution[PoissonDistribution[μ], μBdist];
Wolfram Language code: PDF[𝒟1, x]

これはPoissonDistributionである：

Wolfram Language code: PDF[PoissonDistribution[λ], x]

ソースで熱照明が使われている場合，ポアソン母数は 母数でExponentialDistributionに従い，電子数の分布は次のようになる：

Wolfram Language code: 𝒟2 = ParameterMixtureDistribution[PoissonDistribution[μ], μExponentialDistribution[1 / λ]]

これら2つの分布は識別可能でソースの種類が確定できる：

Wolfram Language code: Block[{λ = 3}, Histogram[{RandomVariate[𝒟1, 10 ^ 3], RandomVariate[𝒟2, 10 ^ 3]}, {1}, "PDF"]]

特性と関係  (4)

零と1以外を得る確率は零である：

Wolfram Language code: PDF[BernoulliDistribution[p], 1 / 2]

他の分布との関係：

BernoulliDistributionは試行1回のBinomialDistributionに等しい：

Wolfram Language code: PDF[BernoulliDistribution[p], k]
Wolfram Language code: Piecewise[Table[{PDF[BinomialDistribution[1, p], l], k == l}, {l, 0, 1}]]
Wolfram Language code: % - %%

BinomialDistributionは 個の独立したベルヌーイ変数の和である：

Wolfram Language code: TransformedDistribution[u1 + u2 + u3, {u1, u2, u3}ProductDistribution[{BernoulliDistribution[p], 3}]]
Wolfram Language code: TransformedDistribution[u1 + u2 + u3 + u4, {u1, u2, u3, u4}ProductDistribution[{BernoulliDistribution[p], 4}]]

考えられる問題  (2)

BernoulliDistributionは，p が0から1の間にない場合は定義されない：

Wolfram Language code: Mean[BernoulliDistribution[3]]

記号出力に無効なパラメータ値を代入すると意味のない結果となる：

Wolfram Language code: Mean[BernoulliDistribution[p]] /. {p -> 3}
Wolfram Research (2007), BernoulliDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/BernoulliDistribution.html （2016年に更新）.

テキスト

Wolfram Research (2007), BernoulliDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/BernoulliDistribution.html （2016年に更新）.

CMS

Wolfram Language. 2007. "BernoulliDistribution." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2016. https://reference.wolfram.com/language/ref/BernoulliDistribution.html.

APA

Wolfram Language. (2007). BernoulliDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BernoulliDistribution.html

BibTeX

@misc{reference.wolfram_2026_bernoullidistribution, author="Wolfram Research", title="{BernoulliDistribution}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/BernoulliDistribution.html}", note=[Accessed: 06-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_bernoullidistribution, organization={Wolfram Research}, title={BernoulliDistribution}, year={2016}, url={https://reference.wolfram.com/language/ref/BernoulliDistribution.html}, note=[Accessed: 06-September-2026]}