BetaBinomialDistribution

BetaBinomialDistribution[α,β,n]

ベータ分布の母数がおよびで回二項試行するベータ二項分布を表す．

詳細

BetaBinomialDistributionはポリヤ(Pólya)分布や負の超幾何分布としても知られている．
ベータ二項分布は，確率母数が形状母数 α および β のベータ分布に従う試行回数が n 回の二項分布である． »
BetaBinomialDistributionでは，α および β は任意の正の実数でよく，n は任意の正の整数でよい．
BetaBinomialDistributionは，Mean，CDF，RandomVariate等の関数で使うことができる． »

予備知識

BetaBinomialDistribution[α,β,n]は，の整数値で定義される離散統計分布を表す．ただし，母数 α および β は形状母数として知られる正の実数であり，確率分密度関数(PDF)の全体的な形と動作を決定する．ベータ二項分布は離散PDFを持つことが多く，α および β の値によってPDFは単調増加，領域内に単一の「峰」または「谷」，あるいは一様な値を持つことがある．ベータ二項分布はPólya分布あるいは負の超幾何分布と呼ばれることがある．
ベータ二項分布は，ベルヌーイ試行の既知の回数の成功確率 p がランダムで，関連する二項分布の成功確率 p がベータ分布(BetaDistribution)に従う，ベルヌーイ分布BernoulliDistribution)および二項分布(BinomialDistribution)の抽象化と考えることができる．ベイズの用語では，これはベータ二項分布が，成功確率 p についての事前分布がベータ分布である，二項変数の事後予測分布として発生したことを意味する．最初にドキュメントされたベータ二項分布の応用例は，1930年代のHugo Muenchによる臨床試験の確率的モデリングまで遡ることができる．今日でも，世界の現象の多くがベータ二項分布でモデル化できる．例えば，Pólyaの壷モデルの特別な抽出集合と置換規則にベータ二項分布を使うことができる．より最近では，ベータ二項分布は，生体認証デバイスのパフォーマンス評価，ベイズネットワークの研究，さまざまな人口知能アルゴリズム等に使われている．
RandomVariateを使ってベータ二項分布から，1つあるいは複数の機械精度あるいは任意精度の（後者はWorkingPrecisionオプションを介して）擬似乱数変量を得ることができる．Distributed[x,BetaBinomialDistribution[α,β,n]]（より簡略すると xBetaBinomialDistribution[α,β,n]）を使って，確率変数 x が，ベルヌーイ分布に従って分布していると宣言することができる．このような宣言は，Probability，NProbability，Expectation，NExpectation等の関数で使うことができる．
確率密度関数および累積分布関数は，PDF[BetaBinomialDistribution[α,β,n],x]およびCDF[BetaBinomialDistribution[α,β,n],x]を使って得られることがある．平均，中央値，分散，原点の周りのモーメント，中心モーメントは，それぞれMean，Median，Variance，Moment，CentralMomentを使って計算することができる．これらの数量はDiscretePlotを使って可視化することができる．
DistributionFitTestを使って，与えられたデータ集合がベータ二項分布と一致するかどうかを検定することが，EstimatedDistributionを使って与えられたデータからパラメトリックベータ二項分布を推定することが，FindDistributionParametersを使ってデータをベータ二項分布にフィットすることができる．ProbabilityPlotを使って記号ベータ二項分布のCDFに対する与えられたデータのCDFのプロットを生成することが，QuantilePlotを使って記号ベータ二項分布の変位値に対する与えられたデータの変位値のプロットを生成することができる．
TransformedDistributionを使って変換されたベータ二項分布を表すことが，CensoredDistributionを使って上限値と下限値の間で切り取られた値の分布を表すことが，TruncatedDistributionを使って上限値と下限値の間で切断された値の分布を表すことができる．CopulaDistributionを使ってベータ二項分布を含む高次元分布を構築することが，ProductDistributionを使ってベータ二項分布を含む独立成分分布の結合分布を計算することができる．
BetaBinomialDistributionは，他の多くの統計分布と関連がある．先述の通り，BetaBinomialDistributionは，BinomialDistributionとBetaDistributionの両方の特徴を組み合せており，この事実はParameterMixtureDistribution[BinomialDistribution[n,p],pBetaDistribution[α,β]]を評価するとBetaBinomialDistribution[α,β,n]になることを観察することで明白になる．同様に，DiscreteUniformDistribution[{0,n}]は厳密にBetaBinomialDistribution[1,1,n]と等しい．この事実から，UniformDistribution, TriangularDistribution，PERTDistributionとの定性的な繋がりが導かれる．BetaBinomialDistributionは，非常に自然なあり方でBetaNegativeBinomialDistributionと関係があり，MultinomialDistributionとDirichletDistributionがそれぞれBinomialDistributionとBetaDistributionのより高次のバージョンであるという事実から，BetaBinomialDistributionはいわゆるディリクレ多項式分布の1次元バージョンであると見ることができる．

例題

すべて開くすべて閉じる

例 (3)

確率質量関数：

Wolfram Language code:

DiscretePlot[Table[PDF[BetaBinomialDistribution[α, .3, 20], x], {α, {0.5, 1, 3}}]//Evaluate, {x, 0, 20}, PlotMarkers -> Automatic]

Wolfram Language code:

DiscretePlot[Table[PDF[BetaBinomialDistribution[1.2, β, 20], x], {β, {0.5, 2, 3}}]//Evaluate, {x, 0, 20}, PlotMarkers -> Automatic]

Wolfram Language code: PDF[BetaBinomialDistribution[α, β, n], x]

累積分布関数：

Wolfram Language code:

DiscretePlot[Table[CDF[BetaBinomialDistribution[α, .3, 20], x], {α, {0.5, 1, 3}}]//Evaluate, {x, 0, 20}, ExtentSize -> Right]

Wolfram Language code:

DiscretePlot[Table[CDF[BetaBinomialDistribution[1.2, β, 20], x], {β, {0.5, 2, 3}}]//Evaluate, {x, 0, 20}, ExtentSize -> Right]

Wolfram Language code: CDF[BetaBinomialDistribution[α, β, n], x]

平均と分散：

Wolfram Language code: Mean[BetaBinomialDistribution[α, β, n]]

Wolfram Language code: Variance[BetaBinomialDistribution[α, β, n]]

スコープ (7)

ベータ二項分布から擬似乱数のサンプルを生成する：

Wolfram Language code: data = RandomVariate[BetaBinomialDistribution[2, 3, 50], 10 ^ 4];

このヒストグラムを確率密度関数と比較する：

Wolfram Language code:

Show[
	Histogram[data, {5}, "PDF"], 
	DiscretePlot[PDF[BetaBinomialDistribution[2, 3, 50], x], {x, 0, 50}, PlotStyle -> PointSize[Medium]]]

分布母数推定：

Wolfram Language code: sample = RandomVariate[BetaBinomialDistribution[.5, .3, 30], 10 ^ 3];

n が既知であると仮定し，分布母数をサンプルから推定する：

Wolfram Language code: edist = EstimatedDistribution[sample, BetaBinomialDistribution[α, β, 30]]

サンプルの密度ヒストグラムを推定分布の確率密度関数と比較する：

Wolfram Language code: Show[Histogram[sample, {1}, "PDF"], DiscretePlot[PDF[edist, x], {x, 0, 30}, PlotStyle -> PointSize[Medium]]]

歪度：

Wolfram Language code:

Plot3D[Skewness[BetaBinomialDistribution[α, β, 100]], {α, 0, 20}, {β, 0, 20}, MeshFunctions -> {#3&}, MeshShading -> ColorData[35, "ColorList"], AxesLabel -> Automatic, ViewPoint -> {15, -8, 5}]

Wolfram Language code: Skewness[BetaBinomialDistribution[α, β, n]]

尖度：

Wolfram Language code:

Plot3D[Kurtosis[BetaBinomialDistribution[α, β, 100]], {α, 0, 20}, {β, 0, 20}, MeshFunctions -> {#3&}, MeshShading -> ColorData[35, "ColorList"], AxesLabel -> Automatic, ViewPoint -> {15, 8, 5}]

Wolfram Language code: Kurtosis[BetaBinomialDistribution[α, β, n]]

母数の関数としての閉じた形の種々のモーメント：

Wolfram Language code: FormulaGrid[list_, type_] := Grid[...]

Moment：

Wolfram Language code: FormulaGrid[Table[Moment[BetaBinomialDistribution[α, β, n], k]//FullSimplify, {k, 3}], M]

CentralMoment：

Wolfram Language code: FormulaGrid[Table[CentralMoment[BetaBinomialDistribution[α, β, n], k]//Simplify, {k, 3}], CM]

FactorialMoment：

Wolfram Language code: FormulaGrid[Table[FactorialMoment[BetaBinomialDistribution[α, β, n], k]//Simplify, {k, 3}], FM]

記号次数の閉じた形式：

Wolfram Language code: FactorialMoment[BetaBinomialDistribution[α, β, n], r]

Cumulant：

Wolfram Language code: FormulaGrid[Table[Cumulant[BetaBinomialDistribution[α, β, n], k]//Simplify, {k, 3}], C]

ハザード関数：

Wolfram Language code:

DiscretePlot[Table[HazardFunction[BetaBinomialDistribution[α, .2, 20], x], {α, {0.1, 0.5, 1}}]//Evaluate, {x, 0, 20}, PlotMarkers -> Automatic]

Wolfram Language code:

DiscretePlot[Table[HazardFunction[BetaBinomialDistribution[0.4, β, 20], x], {β, {0.1, 0.5, 0.7}}]//Evaluate, {x, 0, 20}, PlotMarkers -> Automatic]

Wolfram Language code: HazardFunction[BetaBinomialDistribution[α, β, n], x]

分位関数：

Wolfram Language code:

𝒟 = BetaBinomialDistribution[3, 2, 10];
points = Table[CDF[𝒟, x], {x, 0, 10}]//N;

Wolfram Language code: DiscretePlot[Quantile[𝒟, p], {p, points}, ExtentSize -> Right, ExtentMarkers -> {"Empty", "Filled"}]

アプリケーション (4)

についてベータ二項分布であると仮定し，100回試行して成功回数が50回より多くなる確率：

Wolfram Language code: 1 - CDF[BetaBinomialDistribution[4, 5, 100], 50]

Wolfram Language code: N[%]

負の超幾何分布を定義する：

Wolfram Language code: NegativeHypergeometricDistribution[w_, wtot_, btot_] := BetaBinomialDistribution[w, wtot - w + 1, btot]

黒いボールが個，白いボールが個入っている壷がある．番目の白いボールが壷から取り出される前に個の黒いボールが置き換えなしにサンプルとして取られる確率を求める：

Wolfram Language code: Probability[x == b, xNegativeHypergeometricDistribution[w, Subscript[k, w], Subscript[k, b]]]

あるいは，前述の回の置き換えなしのサンプル抽出で個の黒いボールがあったと仮定して白いボールを取り出す確率を計算する：

Wolfram Language code:

FullSimplify[% == Probability[y == b, yHypergeometricDistribution[w + b - 1, Subscript[k, b], Subscript[k, w] + Subscript[k, b]]]((Subscript[k, w] - w + 1)/Subscript[k, w] + Subscript[k, b] - w - b + 1), 0 < w < Subscript[k, w] && 0 < b < Subscript[k, b] && (w | b | Subscript[k, w] | Subscript[k, b])∈Integers]

ポリヤ分布を定義する：

Wolfram Language code: PolyaDistribution[p_, α_, n_] := BetaBinomialDistribution[p / α, (1 - p) / α, n]

Wolfram Language code: PDF[PolyaDistribution[p, α, n], k]

乱数を生成する：

Wolfram Language code: RandomVariate[PolyaDistribution[1 / 3, 10 / 3, 10], 10]

確率を計算する：

Wolfram Language code: Probability[x ≤ 5, xPolyaDistribution[1 / 3, 10 / 3, 10]]

Pólya–Eggenbergの壷分布を定義する：

Wolfram Language code: PolyaEggenbergDistribution[w_, b_, c_, n_] := BetaBinomialDistribution[w / c, b / c, n]

この分布は壷問題をモデル化する．壷には個の白いボールと個の黒いボールが入っている．壷からボールを取り出し，取り出したボールと同色の個のボールと共に壷に戻す．この分布は回試行して個の白いボールを引き当てる確率を示している：

Wolfram Language code: PDF[PolyaEggenbergDistribution[w, b, c, n], k]

10回の試行で引き当てる白いボールの数を求める：

Wolfram Language code: RandomVariate[PolyaEggenbergDistribution[5, 5, 1, 10], 20]

特性と関係 (5)

負の整数，n より大きい整数，および整数ではない数を得る確率はゼロである：

Wolfram Language code: PDF[BetaBinomialDistribution[α, β, n], π]

他の分布との関係：

DiscreteUniformDistributionはベータ二項分布の特殊なケースである：

Wolfram Language code: PDF[BetaBinomialDistribution[1, 1, 99], x]//FullSimplify

Wolfram Language code: PDF[DiscreteUniformDistribution[{0, 99}], x]

Wolfram Language code: % - %%//Simplify

でのときは，ベータ二項分布は三角形になるが，TriangularDistributionの離散ケースではない：

Wolfram Language code:

DiscretePlot[{PDF[BetaBinomialDistribution[1, 2, 6], x], DifferenceDelta[CDF[TriangularDistribution[{0, 7}, 0], x], x]}//Evaluate, {x, 0, 7}, Filling -> {1 -> {2}}, PlotLegends -> {"BetaBinomial", "floor of Triangular"}]

Wolfram Language code: PDF[BetaBinomialDistribution[1, 2, 6], x]//FullSimplify

Wolfram Language code: FullSimplify[DifferenceDelta[CDF[TriangularDistribution[{0, 7}, 0], x], x], x∈Integers]

上記の式が，がTriangularDistributionに従う場合のの確率密度関数を与えることを確認する：

Wolfram Language code:

Assuming[x∈Integers, FullSimplify[PiecewiseExpand[% == Probability[x ≤ y < x + 1, yTriangularDistribution[{0, 7}, 0]]]]]

BetaBinomialDistributionはBinomialDistributionとBetaDistributionを混合したものである：

Wolfram Language code: ParameterMixtureDistribution[BinomialDistribution[n, p], pBetaDistribution[α, β]]

考えられる問題 (3)

BetaBinomialDistributionは，α あるいは β が正ではない場合は定義されない：

Wolfram Language code: Mean[BetaBinomialDistribution[-4, 6.2, 40]]

BetaBinomialDistributionは，n が正の整数でない場合は定義されない：

Wolfram Language code: Mean[BetaBinomialDistribution[5, 6.2, -10]]

記号出力に無効な母数値を代入すると意味のない結果となる：

Wolfram Language code: Mean[BetaBinomialDistribution[α, β, n]] /. {α -> 3 + I, β -> 7, n -> 23}

Top

その他のラーニングリソース

テクニカルサポート

Wolframソリューション

教育のためのWolframソリューション

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

BetaBinomialDistribution

詳細

予備知識

例題

例 (3)

スコープ (7)

アプリケーション (4)

特性と関係 (5)

考えられる問題 (3)

テキスト

CMS

APA

BibTeX

BibLaTeX

BetaBinomialDistribution

詳細

予備知識

例題

例 (3)

スコープ (7)

アプリケーション (4)

特性と関係 (5)

考えられる問題 (3)

関連項目

テクニカルノート

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX